elmo/modb-legacy.el

   1 ;;; modb-legacy.el --- Legacy Implement of MODB.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;;      Hiroya Murata <lapis-lazuli@pop06.odn.ne.jp>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32
  33 (eval-when-compile (require 'cl))
  34
  35 (require 'elmo-util)
  36 (require 'modb)
  37
  38 ;;; legacy implement
  39 ;;
  40
  41 (defconst modb-legacy-new-mark "N"
  42   "Mark for new message.")
  43
  44 (defconst modb-legacy-unread-uncached-mark "U"
  45   "Mark for unread and uncached message.")
  46
  47 (defconst modb-legacy-unread-cached-mark "!"
  48   "Mark for unread but already cached message.")
  49
  50 (defconst modb-legacy-read-uncached-mark "u"
  51   "Mark for read but uncached message.")
  52
  53 (defconst modb-legacy-answered-cached-mark "&"
  54   "Mark for answered and cached message.")
  55
  56 (defconst modb-legacy-answered-uncached-mark "A"
  57   "Mark for answered but uncached message.")
  58
  59 (defconst modb-legacy-important-mark "$"
  60   "Mark for important message.")
  61
  62 (defconst modb-legacy-flag-list
  63   '(new unread important answered cached read uncached)
  64   "A list of flag symbol which is supported by legacy msgdb.")
  65
  66 (eval-and-compile
  67   (luna-define-class modb-legacy (modb-generic)
  68                      (overview number-alist mark-alist index))
  69   (luna-define-internal-accessors 'modb-legacy))
  70
  71 ;; for internal use only
  72 (defsubst elmo-msgdb-get-overview (msgdb)
  73   (modb-legacy-overview-internal msgdb))
  74
  75 (defsubst elmo-msgdb-get-number-alist (msgdb)
  76   (modb-legacy-number-alist-internal msgdb))
  77
  78 (defsubst elmo-msgdb-get-mark-alist (msgdb)
  79   (modb-legacy-mark-alist-internal msgdb))
  80
  81 (defsubst elmo-msgdb-get-index (msgdb)
  82   (modb-legacy-index-internal msgdb))
  83
  84 (defsubst elmo-msgdb-get-entity-hashtb (msgdb)
  85   (car (modb-legacy-index-internal msgdb)))
  86
  87 (defsubst elmo-msgdb-get-mark-hashtb (msgdb)
  88   (cdr (modb-legacy-index-internal msgdb)))
  89
  90 (defsubst elmo-msgdb-get-path (msgdb)
  91   (elmo-msgdb-location msgdb))
  92
  93 (defsubst elmo-msgdb-set-overview (msgdb overview)
  94   (modb-legacy-set-overview-internal msgdb overview))
  95
  96 (defsubst elmo-msgdb-set-number-alist (msgdb number-alist)
  97   (modb-legacy-set-number-alist-internal msgdb number-alist))
  98
  99 (defsubst elmo-msgdb-set-mark-alist (msgdb mark-alist)
 100   (modb-legacy-set-mark-alist-internal msgdb mark-alist))
 101
 102 (defsubst elmo-msgdb-set-index (msgdb index)
 103   (modb-legacy-set-index-internal msgdb index))
 104
 105 (defsubst elmo-msgdb-set-path (msgdb path)
 106   (modb-generic-set-location-internal msgdb path))
 107
 108 ;;;
 109 ;; Internal use only (obsolete interface)
 110 ;;
 111 (defsubst elmo-msgdb-overview-entity-get-id-internal (entity)
 112   (and entity (car entity)))
 113
 114 (defsubst elmo-msgdb-overview-entity-get-number-internal (entity)
 115   (and entity (aref (cdr entity) 0)))
 116
 117 ;;; load & save
 118 (defun elmo-msgdb-number-load (dir)
 119   (elmo-object-load
 120    (expand-file-name elmo-msgdb-number-filename dir)))
 121
 122 (defun elmo-msgdb-overview-load (dir)
 123   (elmo-object-load
 124    (expand-file-name elmo-msgdb-overview-filename dir)))
 125
 126 (defun elmo-msgdb-mark-load (dir)
 127   (elmo-object-load
 128    (expand-file-name elmo-msgdb-mark-filename dir)))
 129
 130 (defun elmo-msgdb-number-save (dir obj)
 131   (elmo-object-save
 132    (expand-file-name elmo-msgdb-number-filename dir)
 133    obj))
 134
 135 (defun elmo-msgdb-mark-save (dir obj)
 136   (elmo-object-save
 137    (expand-file-name elmo-msgdb-mark-filename dir)
 138    obj))
 139
 140 (defsubst elmo-msgdb-overview-save (dir overview)
 141   (elmo-object-save
 142    (expand-file-name elmo-msgdb-overview-filename dir)
 143    overview))
 144
 145 ;;;
 146
 147 (defsubst modb-legacy-supported-flag-p (flag)
 148   (memq flag modb-legacy-flag-list))
 149
 150 (defvar modb-legacy-unread-marks-internal nil)
 151 (defsubst modb-legacy-unread-marks ()
 152   "Return an unread mark list"
 153   (or modb-legacy-unread-marks-internal
 154       (setq modb-legacy-unread-marks-internal
 155             (list modb-legacy-new-mark
 156                   modb-legacy-unread-uncached-mark
 157                   modb-legacy-unread-cached-mark))))
 158
 159 (defvar modb-legacy-answered-marks-internal nil)
 160 (defsubst modb-legacy-answered-marks ()
 161   "Return an answered mark list"
 162   (or modb-legacy-answered-marks-internal
 163       (setq modb-legacy-answered-marks-internal
 164             (list modb-legacy-answered-cached-mark
 165                   modb-legacy-answered-uncached-mark))))
 166
 167 (defvar modb-legacy-uncached-marks-internal nil)
 168 (defsubst modb-legacy-uncached-marks ()
 169   (or modb-legacy-uncached-marks-internal
 170       (setq modb-legacy-uncached-marks-internal
 171             (list modb-legacy-new-mark
 172                   modb-legacy-answered-uncached-mark
 173                   modb-legacy-unread-uncached-mark
 174                   modb-legacy-read-uncached-mark))))
 175
 176 (defsubst modb-legacy-mark-to-flags (mark)
 177   (append
 178    (and (string= mark modb-legacy-new-mark)
 179         '(new))
 180    (and (string= mark modb-legacy-important-mark)
 181         '(important))
 182    (and (member mark (modb-legacy-unread-marks))
 183         '(unread))
 184    (and (member mark (modb-legacy-answered-marks))
 185         '(answered))
 186    (and (not (member mark (modb-legacy-uncached-marks)))
 187         '(cached))))
 188
 189 (defsubst modb-legacy-flags-to-mark (flags)
 190   (cond ((memq 'new flags)
 191          modb-legacy-new-mark)
 192         ((memq 'important flags)
 193          modb-legacy-important-mark)
 194         ((memq 'answered flags)
 195          (if (memq 'cached flags)
 196              modb-legacy-answered-cached-mark
 197            modb-legacy-answered-uncached-mark))
 198         ((memq 'unread flags)
 199          (if (memq 'cached flags)
 200              modb-legacy-unread-cached-mark
 201            modb-legacy-unread-uncached-mark))
 202         (t
 203          (if (memq 'cached flags)
 204              nil
 205            modb-legacy-read-uncached-mark))))
 206
 207 (defsubst elmo-msgdb-get-mark (msgdb number)
 208   "Get mark string from MSGDB which corresponds to the message with NUMBER."
 209   (cadr (elmo-get-hash-val (format "#%d" number)
 210                            (elmo-msgdb-get-mark-hashtb msgdb))))
 211
 212 (defsubst elmo-msgdb-set-mark (msgdb number mark)
 213   "Set MARK of the message with NUMBER in the MSGDB.
 214 if MARK is nil, mark is removed."
 215   (let ((elem (elmo-get-hash-val (format "#%d" number)
 216                                  (elmo-msgdb-get-mark-hashtb msgdb))))
 217     (if elem
 218         (if mark
 219             ;; Set mark of the elem
 220             (setcar (cdr elem) mark)
 221           ;; Delete elem from mark-alist
 222           (elmo-msgdb-set-mark-alist
 223            msgdb
 224            (delq elem (elmo-msgdb-get-mark-alist msgdb)))
 225           (elmo-clear-hash-val (format "#%d" number)
 226                                (elmo-msgdb-get-mark-hashtb msgdb)))
 227       (when mark
 228         ;; Append new element.
 229         (elmo-msgdb-set-mark-alist
 230          msgdb
 231          (nconc
 232           (elmo-msgdb-get-mark-alist msgdb)
 233           (list (setq elem (list number mark)))))
 234         (elmo-set-hash-val (format "#%d" number) elem
 235                            (elmo-msgdb-get-mark-hashtb msgdb))))
 236     (modb-generic-set-flag-modified-internal msgdb t)
 237     ;; return value.
 238     t))
 239
 240 (defun elmo-msgdb-make-index (msgdb &optional overview mark-alist)
 241   "Append OVERVIEW and MARK-ALIST to the index of MSGDB.
 242 If OVERVIEW and MARK-ALIST are nil, make index for current MSGDB.
 243 Return a list of message numbers which have duplicated message-ids."
 244   (when msgdb
 245     (let* ((overview (or overview (elmo-msgdb-get-overview msgdb)))
 246            (mark-alist (or mark-alist (elmo-msgdb-get-mark-alist msgdb)))
 247            (index (elmo-msgdb-get-index msgdb))
 248            (ehash (or (car index) ;; append
 249                       (elmo-make-hash (length overview))))
 250            (mhash (or (cdr index) ;; append
 251                       (elmo-make-hash (length overview))))
 252            duplicates)
 253       (while overview
 254         ;; key is message-id
 255         (if (elmo-get-hash-val (caar overview) ehash) ; duplicated.
 256             (setq duplicates (cons
 257                               (elmo-msgdb-overview-entity-get-number-internal
 258                                (car overview))
 259                               duplicates)))
 260         (if (caar overview)
 261             (elmo-set-hash-val (caar overview) (car overview) ehash))
 262         ;; key is number
 263         (elmo-set-hash-val
 264          (format "#%d"
 265                  (elmo-msgdb-overview-entity-get-number-internal
 266                   (car overview)))
 267          (car overview) ehash)
 268         (setq overview (cdr overview)))
 269       (while mark-alist
 270         ;; key is number
 271         (elmo-set-hash-val
 272          (format "#%d" (car (car mark-alist)))
 273          (car mark-alist) mhash)
 274         (setq mark-alist (cdr mark-alist)))
 275       (setq index (or index (cons ehash mhash)))
 276       (elmo-msgdb-set-index msgdb index)
 277       duplicates)))
 278
 279 (defun elmo-msgdb-clear-index (msgdb entity)
 280   (let ((ehash (elmo-msgdb-get-entity-hashtb msgdb))
 281         (mhash (elmo-msgdb-get-mark-hashtb msgdb))
 282         number)
 283     (when (and entity ehash)
 284       (and (setq number (elmo-msgdb-overview-entity-get-number-internal
 285                          entity))
 286            (elmo-clear-hash-val (format "#%d" number) ehash))
 287       (and (car entity) ;; message-id
 288            (elmo-clear-hash-val (car entity) ehash)))
 289     (when (and entity mhash)
 290       (and (setq number (elmo-msgdb-overview-entity-get-number-internal
 291                          entity))
 292            (elmo-clear-hash-val (format "#%d" number) mhash)))))
 293
 294 ;;; Implement
 295 ;;
 296 (luna-define-method elmo-msgdb-load ((msgdb modb-legacy))
 297   (let ((inhibit-quit t)
 298         (path (elmo-msgdb-location msgdb)))
 299     (when (file-exists-p (expand-file-name elmo-msgdb-mark-filename path))
 300       (modb-legacy-set-overview-internal
 301        msgdb
 302        (elmo-msgdb-overview-load path))
 303       (modb-legacy-set-number-alist-internal
 304        msgdb
 305        (elmo-msgdb-number-load path))
 306       (modb-legacy-set-mark-alist-internal
 307        msgdb
 308        (elmo-msgdb-mark-load path))
 309       (elmo-msgdb-make-index msgdb)
 310       t)))
 311
 312 (luna-define-method elmo-msgdb-save ((msgdb modb-legacy))
 313   (let ((path (elmo-msgdb-location msgdb)))
 314     (when (elmo-msgdb-message-modified-p msgdb)
 315       (elmo-msgdb-overview-save
 316        path
 317        (modb-legacy-overview-internal msgdb))
 318       (elmo-msgdb-number-save
 319        path
 320        (modb-legacy-number-alist-internal msgdb))
 321       (modb-generic-set-message-modified-internal msgdb nil))
 322     (when (elmo-msgdb-flag-modified-p msgdb)
 323       (elmo-msgdb-mark-save
 324        path
 325        (modb-legacy-mark-alist-internal msgdb))
 326       (modb-generic-set-flag-modified-internal msgdb nil))))
 327
 328 (luna-define-method elmo-msgdb-append :around ((msgdb modb-legacy)
 329                                                msgdb-append)
 330   (if (eq (luna-class-name msgdb-append)
 331           'modb-legacy)
 332       (let (duplicates)
 333         (elmo-msgdb-set-overview
 334          msgdb
 335          (nconc (elmo-msgdb-get-overview msgdb)
 336                 (elmo-msgdb-get-overview msgdb-append)))
 337         (elmo-msgdb-set-number-alist
 338          msgdb
 339          (nconc (elmo-msgdb-get-number-alist msgdb)
 340                 (elmo-msgdb-get-number-alist msgdb-append)))
 341         (elmo-msgdb-set-mark-alist
 342          msgdb
 343          (nconc (elmo-msgdb-get-mark-alist msgdb)
 344                 (elmo-msgdb-get-mark-alist msgdb-append)))
 345         (setq duplicates (elmo-msgdb-make-index
 346                           msgdb
 347                           (elmo-msgdb-get-overview msgdb-append)
 348                           (elmo-msgdb-get-mark-alist msgdb-append)))
 349         (elmo-msgdb-set-path
 350          msgdb
 351          (or (elmo-msgdb-get-path msgdb)
 352              (elmo-msgdb-get-path msgdb-append)))
 353         (modb-generic-set-message-modified-internal msgdb t)
 354         (modb-generic-set-flag-modified-internal msgdb t)
 355         duplicates)
 356     (luna-call-next-method)))
 357
 358 (luna-define-method elmo-msgdb-clear :after ((msgdb modb-legacy))
 359   (elmo-msgdb-set-overview msgdb nil)
 360   (elmo-msgdb-set-number-alist msgdb nil)
 361   (elmo-msgdb-set-mark-alist msgdb nil)
 362   (elmo-msgdb-set-index msgdb nil))
 363
 364 (luna-define-method elmo-msgdb-length ((msgdb modb-legacy))
 365   (length (modb-legacy-overview-internal msgdb)))
 366
 367 (luna-define-method elmo-msgdb-flag-available-p ((msgdb modb-legacy) flag)
 368   (modb-legacy-supported-flag-p flag))
 369
 370 (luna-define-method elmo-msgdb-flags ((msgdb modb-legacy) number)
 371   (modb-legacy-mark-to-flags (elmo-msgdb-get-mark msgdb number)))
 372
 373 (luna-define-method elmo-msgdb-set-flag ((msgdb modb-legacy)
 374                                          number flag)
 375   (unless (modb-legacy-supported-flag-p flag)
 376     (error "Flag `%s' is not supproted by this msgdb type"
 377            (capitalize (symbol-name flag))))
 378   (case flag
 379     (read
 380      (elmo-msgdb-unset-flag msgdb number 'unread))
 381     (uncached
 382      (elmo-msgdb-unset-flag msgdb number 'cached))
 383     (t
 384      (let* ((cur-mark (elmo-msgdb-get-mark msgdb number))
 385             (flags (modb-legacy-mark-to-flags cur-mark))
 386             new-mark)
 387        (and (memq 'new flags)
 388             (setq flags (delq 'new flags)))
 389        (or (memq flag flags)
 390            (setq flags (cons flag flags)))
 391        (when (and (eq flag 'unread)
 392                   (memq 'answered flags))
 393          (setq flags (delq 'answered flags)))
 394        (setq new-mark (modb-legacy-flags-to-mark flags))
 395        (unless (string= new-mark cur-mark)
 396          (elmo-msgdb-set-mark msgdb number new-mark))))))
 397
 398 (luna-define-method elmo-msgdb-unset-flag ((msgdb modb-legacy)
 399                                            number flag)
 400   (unless (modb-legacy-supported-flag-p flag)
 401     (error "Flag `%s' is not supproted by this msgdb type"
 402            (capitalize (symbol-name flag))))
 403   (case flag
 404     (read
 405      (elmo-msgdb-set-flag msgdb number 'unread))
 406     (uncached
 407      (elmo-msgdb-set-flag msgdb number 'cached))
 408     (all
 409      (elmo-msgdb-set-mark msgdb number nil))
 410     (t
 411      (let* ((cur-mark (elmo-msgdb-get-mark msgdb number))
 412             (flags (modb-legacy-mark-to-flags cur-mark))
 413             new-mark)
 414        (and (memq 'new flags)
 415             (setq flags (delq 'new flags)))
 416        (and (memq flag flags)
 417             (setq flags (delq flag flags)))
 418        (when (and (eq flag 'unread)
 419                   (memq 'answered flags))
 420          (setq flags (delq 'answered flags)))
 421        (setq new-mark (modb-legacy-flags-to-mark flags))
 422        (unless (string= new-mark cur-mark)
 423          (elmo-msgdb-set-mark msgdb number new-mark))))))
 424
 425 (luna-define-method elmo-msgdb-flag-count ((msgdb modb-legacy))
 426   (let ((new 0)
 427         (unread 0)
 428         (answered 0))
 429     (dolist (elem (elmo-msgdb-get-mark-alist msgdb))
 430       (cond
 431        ((string= (cadr elem) modb-legacy-new-mark)
 432         (incf new)
 433         (incf unread))
 434        ((member (cadr elem) (modb-legacy-unread-marks))
 435         (incf unread))
 436        ((member (cadr elem) (modb-legacy-answered-marks))
 437         (incf answered))))
 438     (list (cons 'new new)
 439           (cons 'unread unread)
 440           (cons 'answered answered))))
 441
 442 (luna-define-method elmo-msgdb-list-messages ((msgdb modb-legacy))
 443   (mapcar 'elmo-msgdb-overview-entity-get-number-internal
 444           (elmo-msgdb-get-overview msgdb)))
 445
 446 (luna-define-method elmo-msgdb-list-flagged ((msgdb modb-legacy) flag)
 447   (let ((case-fold-search nil)
 448         mark-regexp matched)
 449     (case flag
 450       (new
 451        (setq mark-regexp (regexp-quote modb-legacy-new-mark)))
 452       (unread
 453        (setq mark-regexp (elmo-regexp-opt (modb-legacy-unread-marks))))
 454       (answered
 455        (setq mark-regexp (elmo-regexp-opt (modb-legacy-answered-marks))))
 456       (important
 457        (setq mark-regexp (regexp-quote modb-legacy-important-mark)))
 458       (read
 459        (setq mark-regexp (elmo-regexp-opt (modb-legacy-unread-marks))))
 460       (digest
 461        (setq mark-regexp (elmo-regexp-opt
 462                           (append (modb-legacy-unread-marks)
 463                                   (list modb-legacy-important-mark)))))
 464       (any
 465        (setq mark-regexp (elmo-regexp-opt
 466                           (append
 467                            (modb-legacy-unread-marks)
 468                            (modb-legacy-answered-marks)
 469                            (list modb-legacy-important-mark))))))
 470     (when mark-regexp
 471       (if (eq flag 'read)
 472           (dolist (number (elmo-msgdb-list-messages msgdb))
 473             (let ((mark (elmo-msgdb-get-mark msgdb number)))
 474               (unless (and mark (string-match mark-regexp mark))
 475                 (setq matched (cons number matched)))))
 476         (dolist (elem (elmo-msgdb-get-mark-alist msgdb))
 477           (if (string-match mark-regexp (cadr elem))
 478               (setq matched (cons (car elem) matched))))))
 479     matched))
 480
 481 (luna-define-method elmo-msgdb-search ((msgdb modb-legacy)
 482                                        condition &optional numbers)
 483   (if (vectorp condition)
 484       (let ((key (elmo-filter-key condition))
 485             results)
 486         (cond
 487          ((and (string= key "flag")
 488                (eq (elmo-filter-type condition) 'match))
 489           (setq results (elmo-msgdb-list-flagged
 490                          msgdb
 491                          (intern (elmo-filter-value condition))))
 492           (if numbers
 493               (elmo-list-filter numbers results)
 494             results))
 495          ((member key '("first" "last"))
 496           (let* ((numbers (or numbers (elmo-msgdb-list-messages msgdb)))
 497                  (len (length numbers))
 498                  (lastp (string= key "last"))
 499                  (value (string-to-number (elmo-filter-value condition))))
 500             (when (eq (elmo-filter-type condition) 'unmatch)
 501               (setq lastp (not lastp)
 502                     value (- len value)))
 503             (if lastp
 504                 (nthcdr (max (- len value) 0) numbers)
 505               (when (> value 0)
 506                 (let* ((numbers (copy-sequence numbers))
 507                        (last (nthcdr (1- value) numbers)))
 508                   (when last
 509                     (setcdr last nil))
 510                   numbers)))))
 511          (t
 512           t)))
 513     t))
 514
 515 (luna-define-method elmo-msgdb-append-entity ((msgdb modb-legacy)
 516                                               entity &optional flags)
 517   (when entity
 518     (let ((number (elmo-msgdb-overview-entity-get-number-internal entity))
 519           (message-id (elmo-msgdb-overview-entity-get-id-internal entity))
 520           mark cell)
 521       (elmo-msgdb-set-overview
 522        msgdb
 523        (nconc (elmo-msgdb-get-overview msgdb)
 524               (list entity)))
 525       (elmo-msgdb-set-number-alist
 526        msgdb
 527        (nconc (elmo-msgdb-get-number-alist msgdb)
 528               (list (cons number message-id))))
 529       (modb-generic-set-message-modified-internal msgdb t)
 530       (when (setq mark (modb-legacy-flags-to-mark flags))
 531         (setq cell (list number mark))
 532         (elmo-msgdb-set-mark-alist
 533          msgdb
 534          (nconc (elmo-msgdb-get-mark-alist msgdb) (list cell)))
 535         (modb-generic-set-flag-modified-internal msgdb t))
 536       (elmo-msgdb-make-index
 537        msgdb
 538        (list entity)
 539        (and cell (list cell))))))
 540
 541 (luna-define-method elmo-msgdb-delete-messages ((msgdb modb-legacy)
 542                                                 numbers)
 543   (let* ((overview (elmo-msgdb-get-overview msgdb))
 544          (number-alist (elmo-msgdb-get-number-alist msgdb))
 545          (mark-alist (elmo-msgdb-get-mark-alist msgdb))
 546          (index (elmo-msgdb-get-index msgdb))
 547          ov-entity)
 548     ;; remove from current database.
 549     (dolist (number numbers)
 550       (setq overview
 551             (delq
 552              (setq ov-entity
 553                    (elmo-msgdb-message-entity msgdb number))
 554              overview))
 555       (setq number-alist (delq (assq number number-alist) number-alist))
 556       (setq mark-alist (delq (assq number mark-alist) mark-alist))
 557       ;;
 558       (when index (elmo-msgdb-clear-index msgdb ov-entity)))
 559     (elmo-msgdb-set-overview msgdb overview)
 560     (elmo-msgdb-set-number-alist msgdb number-alist)
 561     (elmo-msgdb-set-mark-alist msgdb mark-alist)
 562     (elmo-msgdb-set-index msgdb index)
 563     (modb-generic-set-message-modified-internal msgdb t)
 564     (modb-generic-set-flag-modified-internal msgdb t)
 565     t)) ;return value
 566
 567 (luna-define-method elmo-msgdb-sort-entities ((msgdb modb-legacy)
 568                                               predicate &optional app-data)
 569   (message "Sorting...")
 570   (let ((overview (elmo-msgdb-get-overview msgdb)))
 571     (elmo-msgdb-set-overview
 572      msgdb
 573      (sort overview (lambda (a b) (funcall predicate a b app-data))))
 574     (message "Sorting...done")
 575     msgdb))
 576
 577 (luna-define-method elmo-msgdb-message-entity ((msgdb modb-legacy) key)
 578   (when key
 579     (elmo-get-hash-val
 580      (cond ((stringp key) key)
 581            ((numberp key) (format "#%d" key)))
 582      (elmo-msgdb-get-entity-hashtb msgdb))))
 583
 584 (require 'product)
 585 (product-provide (provide 'modb-legacy) (require 'elmo-version))
 586
 587 ;;; modb-legacy.el ends here