epa-file.el

   1 ;;; epa-file.el --- the EasyPG Assistant hooks for transparent file encryption
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epa)
  27
  28 (defgroup epa-file nil
  29   "The EasyPG Assistant hooks for transparent file encryption"
  30   :group 'epa)
  31
  32 (defcustom epa-file-name-regexp "\\.gpg\\'"
  33   "Regexp which matches filenames to be encrypted with GnuPG."
  34   :type 'regexp
  35   :group 'epa-file)
  36
  37 (defvar epa-file nil)
  38 (defvar epa-passphrase nil)
  39
  40 (defun epa-file-passphrase-callback-function (key-id buffer)
  41   (save-excursion
  42     (set-buffer buffer)
  43     (if (and (eq key-id 'SYM)
  44              epa-file)
  45         (or epa-passphrase
  46             (let ((passphrase (epg-passphrase-callback-function
  47                                key-id buffer)))
  48               (setq epa-passphrase (copy-sequence passphrase))
  49               passphrase))
  50       (epg-passphrase-callback-function key-id buffer))))
  51
  52 (defvar last-coding-system-used)
  53 (defun epa-find-file ()
  54   (when (string-match epa-file-name-regexp (buffer-file-name))
  55     (when (file-exists-p (expand-file-name (buffer-file-name)))
  56       (if (fboundp 'set-buffer-multibyte)
  57           (set-buffer-multibyte t))
  58       (goto-char (point-min))
  59       (let ((context (epg-make-context)))
  60         (epg-context-set-passphrase-callback
  61          context
  62          (cons #'epa-file-passphrase-callback-function
  63                (current-buffer)))
  64         (insert (epg-decrypt-file context
  65                                   (expand-file-name (buffer-file-name))
  66                                   nil)))
  67       (delete-region (point) (point-max))
  68       (decode-coding-region (point-min) (point-max) 'undecided)
  69       (if (boundp 'last-coding-system-used)
  70           (set-buffer-file-coding-system last-coding-system-used))
  71       (set-auto-mode)
  72       (hack-local-variables)
  73       (auto-save-mode nil)
  74       (set-buffer-modified-p nil)
  75       (setq buffer-undo-list nil))
  76     (make-local-variable 'epa-file)
  77     (setq epa-file (buffer-file-name))
  78     (make-local-variable 'epa-passphrase)))
  79
  80 (defun epa-write-file ()
  81   (when epa-file
  82     (let* ((coding-system (if (boundp 'last-coding-system-used)
  83                               (condition-case nil
  84                                   (write-region (point-min) (point-max) "/")
  85                                 (error last-coding-system-used))
  86                             buffer-file-coding-system))
  87            (coding-system-for-write 'binary)
  88            (context (epg-make-context)))
  89       (epg-context-set-passphrase-callback
  90        context
  91        (cons #'epa-file-passphrase-callback-function
  92              (current-buffer)))
  93       (write-region
  94        (epg-encrypt-string
  95         context
  96         (encode-coding-string (buffer-string) coding-system)
  97         (mapcar (lambda (key)
  98                   (epg-sub-key-id (car (epg-key-sub-key-list key))))
  99                 (unless epa-passphrase
 100                   (epa-select-keys
 101                    "Select recipents for encryption.
 102 If no one is selected, symmetric encryption will be performed.  "))))
 103        nil (expand-file-name (buffer-file-name))))
 104     (set-visited-file-modtime)
 105     (set-buffer-modified-p nil)
 106     t))
 107
 108 (provide 'epa-file)
 109
 110 ;;; epa-file.el ends here