epa-file.el

   1 ;;; epa-file.el --- the EasyPG Assistant, transparent file encryption
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epa)
  27
  28 (defgroup epa-file nil
  29   "The EasyPG Assistant hooks for transparent file encryption"
  30   :group 'epa)
  31
  32 (defun epa-file--file-name-regexp-set (variable value)
  33   (set-default variable value)
  34   (if (fboundp 'epa-file-name-regexp-update)
  35       (epa-file-name-regexp-update)))
  36
  37 (defcustom epa-file-name-regexp "\\.gpg\\(~\\|\\.~[0-9]+~\\)?\\'"
  38   "Regexp which matches filenames to be encrypted with GnuPG.
  39
  40 If you set this outside Custom while epa-file is already enabled, you
  41 have to call `epa-file-name-regexp-update' after setting it to
  42 properly update file-name-handler-alist.  Setting this through Custom
  43 does that automatically."
  44   :type 'regexp
  45   :group 'epa-file
  46   :set 'epa-file--file-name-regexp-set)
  47
  48 (defcustom epa-file-cache-passphrase-for-symmetric-encryption nil
  49   "If non-nil, cache passphrase for symmetric encryption."
  50   :type 'boolean
  51   :group 'epa-file)
  52
  53 (defcustom epa-file-inhibit-auto-save t
  54   "If non-nil, disable auto-saving when opening an encrypted file."
  55   :type 'boolean
  56   :group 'epa-file)
  57
  58 (defcustom epa-file-select-keys nil
  59   "If non-nil, always asks user to select recipients."
  60   :type 'boolean
  61   :group 'epa-file)
  62
  63 (defvar epa-file-encrypt-to nil
  64   "*Recipient(s) used for encrypting files.
  65 May either be a string or a list of strings.")
  66
  67 ;;;###autoload
  68 (put 'epa-file-encrypt-to 'safe-local-variable
  69      (lambda (val)
  70        (or (stringp val)
  71            (and (listp val)
  72                 (catch 'safe
  73                   (mapc (lambda (elt)
  74                           (unless (stringp elt)
  75                             (throw 'safe nil)))
  76                         val)
  77                   t)))))
  78
  79 ;;;###autoload
  80 (put 'epa-file-encrypt-to 'permanent-local t)
  81
  82 (defvar epa-file-handler
  83   (cons epa-file-name-regexp 'epa-file-handler))
  84
  85 (defvar epa-file-passphrase-alist nil)
  86
  87 (eval-and-compile
  88   (if (fboundp 'encode-coding-string)
  89       (defalias 'epa-file--encode-coding-string 'encode-coding-string)
  90     (defalias 'epa-file--encode-coding-string 'identity)))
  91
  92 (eval-and-compile
  93   (if (fboundp 'decode-coding-string)
  94       (defalias 'epa-file--decode-coding-string 'decode-coding-string)
  95     (defalias 'epa-file--decode-coding-string 'identity)))
  96
  97 (defun epa-file-name-regexp-update ()
  98   (interactive)
  99   (unless (equal (car epa-file-handler) epa-file-name-regexp)
 100     (setcar epa-file-handler epa-file-name-regexp)))
 101
 102 (defun epa-file-passphrase-callback-function (context key-id file)
 103   (if (and epa-file-cache-passphrase-for-symmetric-encryption
 104            (eq key-id 'SYM))
 105       (let ((entry (assoc file epa-file-passphrase-alist))
 106             passphrase)
 107         (or (copy-sequence (cdr entry))
 108             (progn
 109               (unless entry
 110                 (setq entry (list file)
 111                       epa-file-passphrase-alist (cons entry
 112                                                  epa-file-passphrase-alist)))
 113               (setq passphrase (epa-passphrase-callback-function context
 114                                                                  key-id nil))
 115               (setcdr entry (copy-sequence passphrase))
 116               passphrase)))
 117     (epa-passphrase-callback-function context key-id nil)))
 118
 119 (defun epa-file-handler (operation &rest args)
 120   (save-match-data
 121     (let ((op (get operation 'epa-file)))
 122       (if op
 123           (apply op args)
 124         (epa-file-run-real-handler operation args)))))
 125
 126 (defun epa-file-run-real-handler (operation args)
 127   (let ((inhibit-file-name-handlers
 128          (cons 'epa-file-handler
 129                (and (eq inhibit-file-name-operation operation)
 130                     inhibit-file-name-handlers)))
 131         (inhibit-file-name-operation operation))
 132     (apply operation args)))
 133
 134 (defun epa-file-decode-and-insert (string file visit beg end replace)
 135   (if (fboundp 'decode-coding-inserted-region)
 136       (save-restriction
 137         (narrow-to-region (point) (point))
 138         (let ((multibyte enable-multibyte-characters))
 139           (set-buffer-multibyte nil)
 140           (insert string)
 141           (set-buffer-multibyte multibyte)
 142           (decode-coding-inserted-region
 143            (point-min) (point-max)
 144            (substring file 0 (string-match epa-file-name-regexp file))
 145            visit beg end replace)))
 146     (insert (epa-file--decode-coding-string string (or coding-system-for-read
 147                                                        'undecided)))))
 148
 149 (defvar last-coding-system-used)
 150 (defun epa-file-insert-file-contents (file &optional visit beg end replace)
 151   (barf-if-buffer-read-only)
 152   (if (and visit (or beg end))
 153       (error "Attempt to visit less than an entire file"))
 154   (setq file (expand-file-name file))
 155   (let* ((local-copy (epa-file-run-real-handler #'file-local-copy (list file)))
 156          (local-file (or local-copy file))
 157          (context (epg-make-context))
 158          string length entry)
 159     (if visit
 160         (setq buffer-file-name file))
 161     (epg-context-set-passphrase-callback
 162      context
 163      (cons #'epa-file-passphrase-callback-function
 164            local-file))
 165     (epg-context-set-progress-callback context
 166                                        #'epa-progress-callback-function)
 167     (unwind-protect
 168         (progn
 169           (if replace
 170               (goto-char (point-min)))
 171           (condition-case error
 172               (setq string (epg-decrypt-file context local-file nil))
 173             (error
 174              (if (setq entry (assoc file epa-file-passphrase-alist))
 175                  (setcdr entry nil))
 176              (signal 'file-error
 177                      (cons "Opening input file" (cdr error)))))
 178           (make-local-variable 'epa-file-encrypt-to)
 179           (setq epa-file-encrypt-to
 180                 (mapcar #'car (epg-context-result-for context 'encrypted-to)))
 181           (if (or beg end)
 182               (setq string (substring string (or beg 0) end)))
 183           (save-excursion
 184             (save-restriction
 185               (narrow-to-region (point) (point))
 186               (epa-file-decode-and-insert string file visit beg end replace)
 187               (setq length (- (point-max) (point-min))))
 188             (if replace
 189                 (delete-region (point) (point-max)))))
 190       (if (and local-copy
 191                (file-exists-p local-copy))
 192           (delete-file local-copy)))
 193     (list file length)))
 194 (put 'insert-file-contents 'epa-file 'epa-file-insert-file-contents)
 195
 196 (defun epa-file-write-region (start end file &optional append visit lockname
 197                                     mustbenew)
 198   (if append
 199       (error "Can't append to the file."))
 200   (setq file (expand-file-name file))
 201   (let* ((coding-system (or coding-system-for-write
 202                             (if (fboundp 'select-safe-coding-system)
 203                                 ;; This is needed since Emacs 22 has
 204                                 ;; no-conversion setting for *.gpg in
 205                                 ;; `auto-coding-alist'.
 206                                 (let ((buffer-file-name
 207                                        (file-name-sans-extension file)))
 208                                   (select-safe-coding-system
 209                                    (point-min) (point-max)))
 210                               buffer-file-coding-system)))
 211          (context (epg-make-context))
 212          (coding-system-for-write 'binary)
 213          string entry
 214          (recipients
 215           (cond
 216            ((listp epa-file-encrypt-to) epa-file-encrypt-to)
 217            ((stringp epa-file-encrypt-to) (list epa-file-encrypt-to)))))
 218     (epg-context-set-passphrase-callback
 219      context
 220      (cons #'epa-file-passphrase-callback-function
 221            file))
 222     (epg-context-set-progress-callback context
 223                                        #'epa-progress-callback-function)
 224     (epg-context-set-armor context epa-armor)
 225     (condition-case error
 226         (setq string
 227               (epg-encrypt-string
 228                context
 229                (if (stringp start)
 230                    (epa-file--encode-coding-string start coding-system)
 231                  (epa-file--encode-coding-string (buffer-substring start end)
 232                                                  coding-system))
 233                (if (or epa-file-select-keys
 234                        (not (local-variable-p 'epa-file-encrypt-to
 235                                               (current-buffer))))
 236                    (epa-select-keys
 237                     context
 238                     "Select recipents for encryption.
 239 If no one is selected, symmetric encryption will be performed.  "
 240                     recipients)
 241                  (if epa-file-encrypt-to
 242                      (epg-list-keys context recipients)))))
 243       (error
 244        (if (setq entry (assoc file epa-file-passphrase-alist))
 245            (setcdr entry nil))
 246        (signal 'file-error (cons "Opening output file" (cdr error)))))
 247     (epa-file-run-real-handler
 248      #'write-region
 249      (list string nil file append visit lockname mustbenew))
 250     (if (boundp 'last-coding-system-used)
 251         (setq last-coding-system-used coding-system))
 252     (if (eq visit t)
 253         (progn
 254           (setq buffer-file-name file)
 255           (set-visited-file-modtime))
 256       (if (stringp visit)
 257           (progn
 258             (set-visited-file-modtime)
 259             (setq buffer-file-name visit))))
 260     (if (or (eq visit t)
 261             (eq visit nil)
 262             (stringp visit))
 263         (message "Wrote %s" buffer-file-name))))
 264 (put 'write-region 'epa-file 'epa-file-write-region)
 265
 266 (defun epa-file-find-file-hook ()
 267   (if (and buffer-file-name
 268            (string-match epa-file-name-regexp buffer-file-name)
 269            epa-file-inhibit-auto-save)
 270       (auto-save-mode 0))
 271   (set-buffer-modified-p nil))
 272
 273 (defun epa-file-select-keys ()
 274   "Select recipients for encryption."
 275   (interactive)
 276   (make-local-variable 'epa-file-encrypt-to)
 277   (setq epa-file-encrypt-to
 278         (epa-select-keys
 279          (epg-make-context)
 280          "Select recipents for encryption.
 281 If no one is selected, symmetric encryption will be performed.  ")))
 282
 283 ;;;###autoload
 284 (defun epa-file-enable ()
 285   (interactive)
 286   (if (memq epa-file-handler file-name-handler-alist)
 287       (message "`epa-file' already enabled")
 288     (setq file-name-handler-alist
 289           (cons epa-file-handler file-name-handler-alist))
 290     (add-hook 'find-file-hooks 'epa-file-find-file-hook)
 291     (message "`epa-file' enabled")))
 292
 293 ;;;###autoload
 294 (defun epa-file-disable ()
 295   (interactive)
 296   (if (memq epa-file-handler file-name-handler-alist)
 297       (progn
 298         (setq file-name-handler-alist
 299               (delq epa-file-handler file-name-handler-alist))
 300         (remove-hook 'find-file-hooks 'epa-file-find-file-hook)
 301         (message "`epa-file' disabled"))
 302     (message "`epa-file' already disabled")))
 303
 304 (provide 'epa-file)
 305
 306 ;;; epa-file.el ends here