epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30 (require 'mail-utils)
  31 (require 'derived)
  32
  33 (defgroup epa nil
  34   "The EasyPG Assistant"
  35   :group 'epg)
  36
  37 (defcustom epa-protocol 'OpenPGP
  38   "The default protocol."
  39   :type '(choice (const :tag "OpenPGP" OpenPGP)
  40                  (const :tag "CMS" CMS))
  41   :group 'epa)
  42
  43 (defcustom epa-armor nil
  44   "If non-nil, epa commands create ASCII armored output."
  45   :type 'boolean
  46   :group 'epa)
  47
  48 (defcustom epa-textmode nil
  49   "If non-nil, epa commands treat input files as text."
  50   :type 'boolean
  51   :group 'epa)
  52
  53 (defcustom epa-popup-info-window t
  54   "If non-nil, status information from epa commands is displayed on
  55 the separate window."
  56   :type 'boolean
  57   :group 'epa)
  58
  59 (defcustom epa-info-window-height 5
  60   "Number of lines used to display status information."
  61   :type 'integer
  62   :group 'epa)
  63
  64 (defcustom epa-mail-modes '(mail-mode message-mode)
  65   "List of major-modes to compose mails."
  66   :type 'list
  67   :group 'epa)
  68
  69 (defgroup epa-faces nil
  70   "Faces for epa-mode."
  71   :group 'epa)
  72
  73 (defface epa-validity-high-face
  74   '((((class color) (background dark))
  75      (:foreground "PaleTurquoise" :bold t))
  76     (t
  77      (:bold t)))
  78   "Face used for displaying the high validity."
  79   :group 'epa-faces)
  80 (defvar epa-validity-high-face 'epa-validity-high-face)
  81
  82 (defface epa-validity-medium-face
  83   '((((class color) (background dark))
  84      (:foreground "PaleTurquoise" :italic t))
  85     (t
  86      ()))
  87   "Face used for displaying the medium validity."
  88   :group 'epa-faces)
  89 (defvar epa-validity-medium-face 'epa-validity-medium-face)
  90
  91 (defface epa-validity-low-face
  92   '((t
  93      (:italic t)))
  94   "Face used for displaying the low validity."
  95   :group 'epa-faces)
  96 (defvar epa-validity-low-face 'epa-validity-low-face)
  97
  98 (defface epa-validity-disabled-face
  99   '((t
 100      (:italic t :inverse-video t)))
 101   "Face used for displaying the disabled validity."
 102   :group 'epa-faces)
 103 (defvar epa-validity-disabled-face 'epa-validity-disabled-face)
 104
 105 (defface epa-string-face
 106   '((((class color)
 107       (background dark))
 108      (:foreground "lightyellow"))
 109     (((class color)
 110       (background light))
 111      (:foreground "blue4"))
 112     (t
 113      ()))
 114   "Face used for displaying the string."
 115   :group 'epa-faces)
 116 (defvar epa-string-face 'epa-string-face)
 117
 118 (defface epa-mark-face
 119   '((((class color) (background dark))
 120      (:foreground "orange" :bold t))
 121     (t
 122      (:foreground "red" :bold t)))
 123   "Face used for displaying the high validity."
 124   :group 'epa-faces)
 125 (defvar epa-mark-face 'epa-mark-face)
 126
 127 (defface epa-field-name-face
 128   '((((class color) (background dark))
 129      (:foreground "PaleTurquoise" :bold t))
 130     (t (:bold t)))
 131   "Face for the name of the attribute field."
 132   :group 'epa)
 133 (defvar epa-field-name-face 'epa-field-name-face)
 134
 135 (defface epa-field-body-face
 136   '((((class color) (background dark))
 137      (:foreground "turquoise" :italic t))
 138     (t (:italic t)))
 139   "Face for the body of the attribute field."
 140   :group 'epa)
 141 (defvar epa-field-body-face 'epa-field-body-face)
 142
 143 (defcustom epa-validity-face-alist
 144   '((unknown . epa-validity-disabled-face)
 145     (invalid . epa-validity-disabled-face)
 146     (disabled . epa-validity-disabled-face)
 147     (revoked . epa-validity-disabled-face)
 148     (expired . epa-validity-disabled-face)
 149     (none . epa-validity-low-face)
 150     (undefined . epa-validity-low-face)
 151     (never . epa-validity-low-face)
 152     (marginal . epa-validity-medium-face)
 153     (full . epa-validity-high-face)
 154     (ultimate . epa-validity-high-face))
 155   "An alist mapping validity values to faces."
 156   :type 'list
 157   :group 'epa)
 158
 159 (defcustom epa-font-lock-keywords
 160   '(("^\\*"
 161      (0 epa-mark-face))
 162     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 163      (1 epa-field-name-face)
 164      (2 epa-field-body-face)))
 165   "Default expressions to addon in epa-mode."
 166   :type '(repeat (list string))
 167   :group 'epa)
 168
 169 (defconst epa-pubkey-algorithm-letter-alist
 170   '((1 . ?R)
 171     (2 . ?r)
 172     (3 . ?s)
 173     (16 . ?g)
 174     (17 . ?D)
 175     (20 . ?G)))
 176
 177 (defvar epa-keys-buffer nil)
 178 (defvar epa-key-buffer-alist nil)
 179 (defvar epa-key nil)
 180 (defvar epa-list-keys-arguments nil)
 181 (defvar epa-info-buffer nil)
 182 (defvar epa-last-coding-system-specified nil)
 183
 184 (defvar epa-keys-mode-map
 185   (let ((keymap (make-sparse-keymap)))
 186     (define-key keymap "m" 'epa-mark)
 187     (define-key keymap "u" 'epa-unmark)
 188     (define-key keymap "d" 'epa-decrypt-file)
 189     (define-key keymap "v" 'epa-verify-file)
 190     (define-key keymap "s" 'epa-sign-file)
 191     (define-key keymap "e" 'epa-encrypt-file)
 192     (define-key keymap "r" 'epa-delete-keys)
 193     (define-key keymap "i" 'epa-import-keys)
 194     (define-key keymap "o" 'epa-export-keys)
 195     (define-key keymap "g" 'epa-list-keys)
 196     (define-key keymap "n" 'next-line)
 197     (define-key keymap "p" 'previous-line)
 198     (define-key keymap " " 'scroll-up)
 199     (define-key keymap [delete] 'scroll-down)
 200     (define-key keymap "q" 'epa-exit-buffer)
 201     keymap))
 202
 203 (defvar epa-key-mode-map
 204   (let ((keymap (make-sparse-keymap)))
 205     (define-key keymap "q" 'bury-buffer)
 206     keymap))
 207
 208 (defvar epa-info-mode-map
 209   (let ((keymap (make-sparse-keymap)))
 210     (define-key keymap "q" 'delete-window)
 211     keymap))
 212
 213 (defvar epa-exit-buffer-function #'bury-buffer)
 214
 215 (define-widget 'epa-key 'push-button
 216   "Button for representing a epg-key object."
 217   :format "%[%v%]"
 218   :button-face-get 'epa--key-widget-button-face-get
 219   :value-create 'epa--key-widget-value-create
 220   :action 'epa--key-widget-action
 221   :help-echo 'epa--key-widget-help-echo)
 222
 223 (defun epa--key-widget-action (widget &optional event)
 224   (epa--show-key (widget-get widget :value)))
 225
 226 (defun epa--key-widget-value-create (widget)
 227   (let* ((key (widget-get widget :value))
 228          (primary-sub-key (car (epg-key-sub-key-list key)))
 229          (primary-user-id (car (epg-key-user-id-list key))))
 230     (insert (format "%c "
 231                     (if (epg-sub-key-validity primary-sub-key)
 232                         (car (rassq (epg-sub-key-validity primary-sub-key)
 233                                     epg-key-validity-alist))
 234                       ? ))
 235             (epg-sub-key-id primary-sub-key)
 236             " "
 237             (if primary-user-id
 238                 (if (stringp (epg-user-id-string primary-user-id))
 239                     (epg-user-id-string primary-user-id)
 240                   (epg-decode-dn (epg-user-id-string primary-user-id)))
 241               ""))))
 242
 243 (defun epa--key-widget-button-face-get (widget)
 244   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 245                                               (widget-get widget :value))))))
 246     (if validity
 247         (cdr (assq validity epa-validity-face-alist))
 248       'default)))
 249
 250 (defun epa--key-widget-help-echo (widget)
 251   (format "Show %s"
 252           (epg-sub-key-id (car (epg-key-sub-key-list
 253                                 (widget-get widget :value))))))
 254
 255 (if (fboundp 'encode-coding-string)
 256     (defalias 'epa--encode-coding-string 'encode-coding-string)
 257   (defalias 'epa--encode-coding-string 'identity))
 258
 259 (if (fboundp 'decode-coding-string)
 260     (defalias 'epa--decode-coding-string 'decode-coding-string)
 261   (defalias 'epa--decode-coding-string 'identity))
 262
 263 (defun epa-keys-mode ()
 264   "Major mode for `epa-list-keys'."
 265   (kill-all-local-variables)
 266   (buffer-disable-undo)
 267   (setq major-mode 'epa-keys-mode
 268         mode-name "Keys"
 269         truncate-lines t
 270         buffer-read-only t)
 271   (use-local-map epa-keys-mode-map)
 272   (make-local-variable 'font-lock-defaults)
 273   (setq font-lock-defaults '(epa-font-lock-keywords t))
 274   ;; In XEmacs, auto-initialization of font-lock is not effective
 275   ;; if buffer-file-name is not set.
 276   (font-lock-set-defaults)
 277   (make-local-variable 'epa-exit-buffer-function)
 278   (run-hooks 'epa-keys-mode-hook))
 279
 280 (defun epa-key-mode ()
 281   "Major mode for a key description."
 282   (kill-all-local-variables)
 283   (buffer-disable-undo)
 284   (setq major-mode 'epa-key-mode
 285         mode-name "Key"
 286         truncate-lines t
 287         buffer-read-only t)
 288   (use-local-map epa-key-mode-map)
 289   (make-local-variable 'font-lock-defaults)
 290   (setq font-lock-defaults '(epa-font-lock-keywords t))
 291   ;; In XEmacs, auto-initialization of font-lock is not effective
 292   ;; if buffer-file-name is not set.
 293   (font-lock-set-defaults)
 294   (make-local-variable 'epa-exit-buffer-function)
 295   (run-hooks 'epa-key-mode-hook))
 296
 297 (defun epa-info-mode ()
 298   "Major mode for `epa-info-buffer'."
 299   (kill-all-local-variables)
 300   (buffer-disable-undo)
 301   (setq major-mode 'epa-info-mode
 302         mode-name "Info"
 303         truncate-lines t
 304         buffer-read-only t)
 305   (use-local-map epa-info-mode-map)
 306   (run-hooks 'epa-info-mode-hook))
 307
 308 (defun epa-mark (&optional arg)
 309   "Mark the current line.
 310 If ARG is non-nil, unmark the current line."
 311   (interactive "P")
 312   (let ((inhibit-read-only t)
 313         buffer-read-only
 314         properties)
 315     (beginning-of-line)
 316     (setq properties (text-properties-at (point)))
 317     (delete-char 1)
 318     (insert (if arg " " "*"))
 319     (set-text-properties (1- (point)) (point) properties)
 320     (forward-line)))
 321
 322 (defun epa-unmark (&optional arg)
 323   "Unmark the current line.
 324 If ARG is non-nil, mark the current line."
 325   (interactive "P")
 326   (epa-mark (not arg)))
 327
 328 (defun epa-toggle-mark ()
 329   "Toggle the mark the current line."
 330   (interactive)
 331   (epa-mark (eq (char-after (save-excursion (beginning-of-line) (point))) ?*)))
 332
 333 (defun epa-exit-buffer ()
 334   "Exit the current buffer.
 335 `epa-exit-buffer-function' is called if it is set."
 336   (interactive)
 337   (funcall epa-exit-buffer-function))
 338
 339 ;;;###autoload
 340 (defun epa-list-keys (&optional name mode)
 341   "List all keys matched with NAME from the keyring.
 342 If MODE is non-nil, it reads the private keyring.  Otherwise, it
 343 reads the public keyring."
 344   (interactive
 345    (if current-prefix-arg
 346        (let ((name (read-string "Pattern: "
 347                                 (if epa-list-keys-arguments
 348                                     (car epa-list-keys-arguments)))))
 349          (list (if (equal name "") nil name)
 350                (y-or-n-p "Secret keys? ")))
 351      (or epa-list-keys-arguments (list nil nil))))
 352   (unless (and epa-keys-buffer
 353                (buffer-live-p epa-keys-buffer))
 354     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 355   (set-buffer epa-keys-buffer)
 356   (let ((inhibit-read-only t)
 357         buffer-read-only
 358         (point (point-min))
 359         (context (epg-make-context epa-protocol)))
 360     (unless (get-text-property point 'epa-list-keys)
 361       (setq point (next-single-property-change point 'epa-list-keys)))
 362     (when point
 363       (delete-region point
 364                      (or (next-single-property-change point 'epa-list-keys)
 365                          (point-max)))
 366       (goto-char point))
 367     (epa--insert-keys context name mode)
 368     (epa-keys-mode)
 369     (widget-setup)
 370     (set-keymap-parent (current-local-map) widget-keymap))
 371   (make-local-variable 'epa-list-keys-arguments)
 372   (setq epa-list-keys-arguments (list name mode))
 373   (goto-char (point-min))
 374   (pop-to-buffer (current-buffer)))
 375
 376 (defun epa--insert-keys (context name mode)
 377   (save-excursion
 378     (save-restriction
 379       (narrow-to-region (point) (point))
 380       (let ((keys (epg-list-keys context name mode))
 381             point)
 382         (while keys
 383           (setq point (point))
 384           (insert "  ")
 385           (add-text-properties point (point)
 386                                (list 'epa-key (car keys)
 387                                      'front-sticky nil
 388                                      'rear-nonsticky t
 389                                      'start-open t
 390                                      'end-open t))
 391           (widget-create 'epa-key :value (car keys))
 392           (insert "\n")
 393           (setq keys (cdr keys))))
 394       (add-text-properties (point-min) (point-max)
 395                            (list 'epa-list-keys t
 396                                  'front-sticky nil
 397                                  'rear-nonsticky t
 398                                  'start-open t
 399                                  'end-open t)))))
 400
 401 (defun epa--marked-keys ()
 402   (or (save-excursion
 403         (set-buffer epa-keys-buffer)
 404         (goto-char (point-min))
 405         (let (keys key)
 406           (while (re-search-forward "^\\*" nil t)
 407             (if (setq key (get-text-property (match-beginning 0)
 408                                              'epa-key))
 409                 (setq keys (cons key keys))))
 410           (nreverse keys)))
 411       (save-excursion
 412         (beginning-of-line)
 413         (let ((key (get-text-property (point) 'epa-key)))
 414           (if key
 415               (list key))))))
 416
 417 ;;;###autoload
 418 (defun epa-select-keys (context prompt &optional names secret)
 419   "Display a user's keyring and ask him to select keys.
 420 CONTEXT is an epg-context.
 421 PROMPT is a string to prompt with.
 422 NAMES is a list of strings to be matched with keys.  If it is nil, all
 423 the keys are listed.
 424 If SECRET is non-nil, list secret keys instead of public keys."
 425   (save-excursion
 426     (unless (and epa-keys-buffer
 427                  (buffer-live-p epa-keys-buffer))
 428       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 429     (let ((inhibit-read-only t)
 430           buffer-read-only)
 431       (set-buffer epa-keys-buffer)
 432       (erase-buffer)
 433       (insert prompt "\n")
 434       (widget-create 'link
 435                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 436                      :help-echo
 437                      (substitute-command-keys
 438                       "Click here or \\[abort-recursive-edit] to cancel")
 439                      "Cancel")
 440       (widget-create 'link
 441                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 442                      :help-echo
 443                      (substitute-command-keys
 444                       "Click here or \\[exit-recursive-edit] to finish")
 445                      "OK")
 446       (insert "\n\n")
 447       (if names
 448           (while names
 449             (epa--insert-keys context (car names) secret)
 450             (if (get-text-property (point) 'epa-list-keys)
 451                 (epa-mark))
 452             (goto-char (point-max))
 453             (setq names (cdr names)))
 454         (if secret
 455             (progn
 456               (epa--insert-keys context nil secret)
 457               (if (get-text-property (point) 'epa-list-keys)
 458                   (epa-mark)))
 459           (epa--insert-keys context nil nil)))
 460       (epa-keys-mode)
 461       (widget-setup)
 462       (set-keymap-parent (current-local-map) widget-keymap)
 463       (setq epa-exit-buffer-function #'abort-recursive-edit)
 464       (goto-char (point-min))
 465       (pop-to-buffer (current-buffer)))
 466     (unwind-protect
 467         (progn
 468           (recursive-edit)
 469           (epa--marked-keys))
 470       (if (get-buffer-window epa-keys-buffer)
 471           (delete-window (get-buffer-window epa-keys-buffer)))
 472       (kill-buffer epa-keys-buffer))))
 473
 474 (defun epa--format-fingerprint-1 (fingerprint unit-size block-size)
 475   (let ((unit 0))
 476     (with-temp-buffer
 477       (insert fingerprint)
 478       (goto-char (point-min))
 479       (while (progn
 480                (goto-char (+ (point) unit-size))
 481                (not (eobp)))
 482         (setq unit (1+ unit))
 483         (insert (if (= (% unit block-size) 0) "  " " ")))
 484       (buffer-string))))
 485
 486 (defun epa--format-fingerprint (fingerprint)
 487   (if fingerprint
 488       (if (= (length fingerprint) 40)
 489           ;; 1234 5678 9ABC DEF0 1234  5678 9ABC DEF0 1234 5678
 490           (epa--format-fingerprint-1 fingerprint 4 5)
 491         ;; 12 34 56 78 9A BC DE F0  12 34 56 78 9A BC DE F0
 492         (epa--format-fingerprint-1 fingerprint 2 8))))
 493
 494 (defun epa--show-key (key)
 495   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 496          (entry (assoc (epg-sub-key-id primary-sub-key)
 497                        epa-key-buffer-alist))
 498          (inhibit-read-only t)
 499          buffer-read-only
 500          pointer)
 501     (unless entry
 502       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 503             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 504     (unless (and (cdr entry)
 505                  (buffer-live-p (cdr entry)))
 506       (setcdr entry (generate-new-buffer
 507                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 508     (set-buffer (cdr entry))
 509     (make-local-variable 'epa-key)
 510     (setq epa-key key)
 511     (erase-buffer)
 512     (setq pointer (epg-key-user-id-list key))
 513     (while pointer
 514       (if (car pointer)
 515           (insert " "
 516                   (if (epg-user-id-validity (car pointer))
 517                       (char-to-string
 518                        (car (rassq (epg-user-id-validity (car pointer))
 519                                    epg-key-validity-alist)))
 520                     " ")
 521                   " "
 522                   (if (stringp (epg-user-id-string (car pointer)))
 523                       (epg-user-id-string (car pointer))
 524                     (epg-decode-dn (epg-user-id-string (car pointer))))
 525                   "\n"))
 526       (setq pointer (cdr pointer)))
 527     (setq pointer (epg-key-sub-key-list key))
 528     (while pointer
 529       (insert " "
 530               (if (epg-sub-key-validity (car pointer))
 531                   (char-to-string
 532                    (car (rassq (epg-sub-key-validity (car pointer))
 533                                epg-key-validity-alist)))
 534                 " ")
 535               " "
 536               (epg-sub-key-id (car pointer))
 537               " "
 538               (format "%dbits"
 539                       (epg-sub-key-length (car pointer)))
 540               " "
 541               (cdr (assq (epg-sub-key-algorithm (car pointer))
 542                          epg-pubkey-algorithm-alist))
 543               "\n\tCreated: "
 544               (format-time-string "%Y-%m-%d"
 545                                   (epg-sub-key-creation-time (car pointer)))
 546               (if (epg-sub-key-expiration-time (car pointer))
 547                   (format "\n\tExpires: %s"
 548                           (format-time-string "%Y-%m-%d"
 549                                               (epg-sub-key-expiration-time
 550                                                (car pointer))))
 551                 "")
 552               "\n\tCapabilities: "
 553               (mapconcat #'symbol-name
 554                          (epg-sub-key-capability (car pointer))
 555                          " ")
 556               "\n\tFingerprint: "
 557               (epa--format-fingerprint (epg-sub-key-fingerprint (car pointer)))
 558               "\n")
 559       (setq pointer (cdr pointer)))
 560     (goto-char (point-min))
 561     (pop-to-buffer (current-buffer))
 562     (epa-key-mode)))
 563
 564 (defun epa-display-info (info)
 565   (if epa-popup-info-window
 566       (save-selected-window
 567         (unless epa-info-buffer
 568           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 569         (if (get-buffer-window epa-info-buffer)
 570             (delete-window (get-buffer-window epa-info-buffer)))
 571         (save-excursion
 572           (set-buffer epa-info-buffer)
 573           (let ((inhibit-read-only t)
 574                 buffer-read-only)
 575             (erase-buffer)
 576             (insert info))
 577           (epa-info-mode)
 578           (goto-char (point-min)))
 579         (if (> (window-height)
 580                epa-info-window-height)
 581             (set-window-buffer (split-window nil (- (window-height)
 582                                                     epa-info-window-height))
 583                                epa-info-buffer)
 584           (pop-to-buffer epa-info-buffer)
 585           (if (> (window-height) epa-info-window-height)
 586               (shrink-window (- (window-height) epa-info-window-height)))))
 587     (message "%s" info)))
 588
 589 (defun epa-display-verify-result (verify-result)
 590   (epa-display-info (epg-verify-result-to-string verify-result)))
 591 (make-obsolete 'epa-display-verify-result 'epa-display-info)
 592
 593 (defun epa-passphrase-callback-function (context key-id handback)
 594   (if (eq key-id 'SYM)
 595       (read-passwd "Passphrase for symmetric encryption: "
 596                    (eq (epg-context-operation context) 'encrypt))
 597     (read-passwd
 598      (if (eq key-id 'PIN)
 599         "Passphrase for PIN: "
 600        (let ((entry (assoc key-id epg-user-id-alist)))
 601          (if entry
 602              (format "Passphrase for %s %s: " key-id (cdr entry))
 603            (format "Passphrase for %s: " key-id)))))))
 604
 605 (defun epa-progress-callback-function (context what char current total
 606                                                handback)
 607   (message "%s: %d%% (%d/%d)" what
 608            (if (> total 0) (floor (* (/ current (float total)) 100)) 0)
 609            current total))
 610
 611 ;;;###autoload
 612 (defun epa-decrypt-file (file)
 613   "Decrypt FILE."
 614   (interactive "fFile: ")
 615   (setq file (expand-file-name file))
 616   (let* ((default-name (file-name-sans-extension file))
 617          (plain (expand-file-name
 618                  (read-file-name
 619                   (concat "To file (default "
 620                           (file-name-nondirectory default-name)
 621                           ") ")
 622                   (file-name-directory default-name)
 623                   default-name)))
 624          (context (epg-make-context epa-protocol)))
 625     (epg-context-set-passphrase-callback context
 626                                          #'epa-passphrase-callback-function)
 627     (epg-context-set-progress-callback context
 628                                        #'epa-progress-callback-function)
 629     (message "Decrypting %s..." (file-name-nondirectory file))
 630     (epg-decrypt-file context file plain)
 631     (message "Decrypting %s...wrote %s" (file-name-nondirectory file)
 632              (file-name-nondirectory plain))
 633     (if (epg-context-result-for context 'verify)
 634         (epa-display-info (epg-verify-result-to-string
 635                            (epg-context-result-for context 'verify))))))
 636
 637 ;;;###autoload
 638 (defun epa-verify-file (file)
 639   "Verify FILE."
 640   (interactive "fFile: ")
 641   (setq file (expand-file-name file))
 642   (let* ((context (epg-make-context epa-protocol))
 643          (plain (if (equal (file-name-extension file) "sig")
 644                     (file-name-sans-extension file))))
 645     (epg-context-set-progress-callback context
 646                                        #'epa-progress-callback-function)
 647     (message "Verifying %s..." (file-name-nondirectory file))
 648     (epg-verify-file context file plain)
 649     (message "Verifying %s...done" (file-name-nondirectory file))
 650     (if (epg-context-result-for context 'verify)
 651         (epa-display-info (epg-verify-result-to-string
 652                            (epg-context-result-for context 'verify))))))
 653
 654 (defun epa--read-signature-type ()
 655   (let (type c)
 656     (while (null type)
 657       (message "Signature type (n,c,d,?) ")
 658       (setq c (read-char))
 659       (cond ((eq c ?c)
 660              (setq type 'clear))
 661             ((eq c ?d)
 662              (setq type 'detached))
 663             ((eq c ??)
 664              (with-output-to-temp-buffer "*Help*"
 665                (save-excursion
 666                  (set-buffer standard-output)
 667                  (insert "\
 668 n - Create a normal signature
 669 c - Create a cleartext signature
 670 d - Create a detached signature
 671 ? - Show this help
 672 "))))
 673             (t
 674              (setq type 'normal))))))
 675
 676 ;;;###autoload
 677 (defun epa-sign-file (file signers mode)
 678   "Sign FILE by SIGNERS keys selected."
 679   (interactive
 680    (list (expand-file-name (read-file-name "File: "))
 681          (if current-prefix-arg
 682              (epa-select-keys (epg-make-context epa-protocol)
 683                               "Select keys for signing.
 684 If no one is selected, default secret key is used.  "
 685                               nil t))
 686          (if current-prefix-arg
 687              (epa--read-signature-type)
 688            'clear)))
 689   (let ((signature (concat file
 690                            (if (eq epa-protocol 'OpenPGP)
 691                                (if (or epa-armor
 692                                        (not (memq mode
 693                                                   '(nil t normal detached))))
 694                                    ".asc"
 695                                  (if (memq mode '(t detached))
 696                                      ".sig"
 697                                    ".gpg"))
 698                              (if (memq mode '(t detached))
 699                                  ".p7s"
 700                                ".p7m"))))
 701         (context (epg-make-context epa-protocol)))
 702     (epg-context-set-armor context epa-armor)
 703     (epg-context-set-textmode context epa-textmode)
 704     (epg-context-set-signers context signers)
 705     (epg-context-set-passphrase-callback context
 706                                          #'epa-passphrase-callback-function)
 707     (epg-context-set-progress-callback context
 708                                        #'epa-progress-callback-function)
 709     (message "Signing %s..." (file-name-nondirectory file))
 710     (epg-sign-file context file signature mode)
 711     (message "Signing %s...wrote %s" (file-name-nondirectory file)
 712              (file-name-nondirectory signature))))
 713
 714 ;;;###autoload
 715 (defun epa-encrypt-file (file recipients)
 716   "Encrypt FILE for RECIPIENTS."
 717   (interactive
 718    (list (expand-file-name (read-file-name "File: "))
 719          (epa-select-keys (epg-make-context epa-protocol)
 720                           "Select recipients for encryption.
 721 If no one is selected, symmetric encryption will be performed.  ")))
 722   (let ((cipher (concat file (if (eq epa-protocol 'OpenPGP)
 723                                  (if epa-armor ".asc" ".gpg")
 724                                ".p7m")))
 725         (context (epg-make-context epa-protocol)))
 726     (epg-context-set-armor context epa-armor)
 727     (epg-context-set-textmode context epa-textmode)
 728     (epg-context-set-passphrase-callback context
 729                                          #'epa-passphrase-callback-function)
 730     (epg-context-set-progress-callback context
 731                                        #'epa-progress-callback-function)
 732     (message "Encrypting %s..." (file-name-nondirectory file))
 733     (epg-encrypt-file context file recipients cipher)
 734     (message "Encrypting %s...wrote %s" (file-name-nondirectory file)
 735              (file-name-nondirectory cipher))))
 736
 737 ;;;###autoload
 738 (defun epa-decrypt-region (start end)
 739   "Decrypt the current region between START and END.
 740
 741 Don't use this command in Lisp programs!"
 742   (interactive "r")
 743   (save-excursion
 744     (let ((context (epg-make-context epa-protocol))
 745           plain)
 746       (epg-context-set-passphrase-callback context
 747                                            #'epa-passphrase-callback-function)
 748       (epg-context-set-progress-callback context
 749                                          #'epa-progress-callback-function)
 750       (message "Decrypting...")
 751       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 752       (message "Decrypting...done")
 753       (setq plain (epa--decode-coding-string
 754                    plain
 755                    (or coding-system-for-read
 756                        (get-text-property start 'epa-coding-system-used))))
 757       (if (y-or-n-p "Replace the text in the region? ")
 758           (let ((inhibit-read-only t)
 759                 buffer-read-only)
 760             (delete-region start end)
 761             (goto-char start)
 762             (insert plain))
 763         (let ((epa-popup-info-window t))
 764           (epa-display-info plain)))
 765       (if (epg-context-result-for context 'verify)
 766           (epa-display-info (epg-verify-result-to-string
 767                              (epg-context-result-for context 'verify)))))))
 768
 769 (defun epa--find-coding-system-for-mime-charset (mime-charset)
 770   (if (featurep 'xemacs)
 771       (if (fboundp 'find-coding-system)
 772           (find-coding-system mime-charset))
 773     (let ((pointer (coding-system-list)))
 774       (while (and pointer
 775                   (eq (coding-system-get (car pointer) 'mime-charset)
 776                       mime-charset))
 777         (setq pointer (cdr pointer)))
 778       pointer)))
 779
 780 ;;;###autoload
 781 (defun epa-decrypt-armor-in-region (start end)
 782   "Decrypt OpenPGP armors in the current region between START and END.
 783
 784 Don't use this command in Lisp programs!"
 785   (interactive "r")
 786   (save-excursion
 787     (save-restriction
 788       (narrow-to-region start end)
 789       (goto-char start)
 790       (let (armor-start armor-end coding-system)
 791         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 792           (setq armor-start (match-beginning 0)
 793                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 794                                              nil t))
 795           (unless armor-end
 796             (error "No armor tail"))
 797           (goto-char armor-start)
 798           (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 799               (setq coding-system (epa--find-coding-system-for-mime-charset
 800                                    (intern (downcase (match-string 1))))))
 801           (let ((coding-system-for-read
 802                  (or coding-system-for-read
 803                      coding-system)))
 804             (epa-decrypt-region armor-start armor-end)))))))
 805
 806 ;;;###autoload
 807 (defun epa-decrypt ()
 808   "Decrypt OpenPGP armors in the current buffer.
 809
 810 Don't use this command in Lisp programs!"
 811   (interactive)
 812   (epa-decrypt-armor-in-region (point-min) (point-max)))
 813
 814 (if (fboundp 'select-safe-coding-system)
 815     (defalias 'epa--select-safe-coding-system 'select-safe-coding-system)
 816   (defun epa--select-safe-coding-system (from to)
 817     buffer-file-coding-system))
 818
 819 ;;;###autoload
 820 (defun epa-verify-region (start end)
 821   "Verify the current region between START and END.
 822
 823 Don't use this command in Lisp programs!"
 824   (interactive "r")
 825   (let ((context (epg-make-context epa-protocol)))
 826     (epg-context-set-progress-callback context
 827                                        #'epa-progress-callback-function)
 828     (epg-verify-string context
 829                        (epa--encode-coding-string
 830                         (buffer-substring start end)
 831                         (or coding-system-for-write
 832                             (get-text-property start
 833                                                'epa-coding-system-used))))
 834     (if (epg-context-result-for context 'verify)
 835         (epa-display-info (epg-verify-result-to-string
 836                            (epg-context-result-for context 'verify))))))
 837
 838 ;;;###autoload
 839 (defun epa-verify-cleartext-in-region (start end)
 840   "Verify OpenPGP cleartext signed messages in the current region
 841 between START and END.
 842
 843 Don't use this command in Lisp programs!"
 844   (interactive "r")
 845   (save-excursion
 846     (save-restriction
 847       (narrow-to-region start end)
 848       (goto-char start)
 849       (let (armor-start armor-end)
 850         (while (re-search-forward "-----BEGIN PGP SIGNED MESSAGE-----$"
 851                                   nil t)
 852           (setq armor-start (match-beginning 0))
 853           (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 854                                            nil t)
 855             (error "Invalid cleartext signed message"))
 856           (setq armor-end (re-search-forward
 857                            "^-----END PGP SIGNATURE-----$"
 858                            nil t))
 859           (unless armor-end
 860             (error "No armor tail"))
 861           (epa-verify-region armor-start armor-end))))))
 862
 863 ;;;###autoload
 864 (defun epa-verify ()
 865   "Verify OpenPGP cleartext signed messages in the current buffer.
 866
 867 Don't use this command in Lisp programs!"
 868   (interactive)
 869   (epa-verify-cleartext-in-region (point-min) (point-max)))
 870
 871 ;;;###autoload
 872 (defun epa-sign-region (start end signers mode)
 873   "Sign the current region between START and END by SIGNERS keys selected.
 874
 875 Don't use this command in Lisp programs!"
 876   (interactive
 877    (progn
 878      (setq epa-last-coding-system-specified
 879            (or coding-system-for-write
 880                (epa--select-safe-coding-system
 881                 (region-beginning) (region-end))))
 882      (list (region-beginning) (region-end)
 883            (if current-prefix-arg
 884                (epa-select-keys (epg-make-context epa-protocol)
 885                                 "Select keys for signing.
 886 If no one is selected, default secret key is used.  "
 887                                 nil t))
 888            (if current-prefix-arg
 889                (epa--read-signature-type)
 890              'clear))))
 891   (save-excursion
 892     (let ((context (epg-make-context epa-protocol))
 893           signature)
 894       ;;(epg-context-set-armor context epa-armor)
 895       (epg-context-set-armor context t)
 896       ;;(epg-context-set-textmode context epa-textmode)
 897       (epg-context-set-textmode context t)
 898       (epg-context-set-signers context signers)
 899       (epg-context-set-passphrase-callback context
 900                                            #'epa-passphrase-callback-function)
 901       (epg-context-set-progress-callback context
 902                                          #'epa-progress-callback-function)
 903       (message "Signing...")
 904       (setq signature (epg-sign-string context
 905                                        (epa--encode-coding-string
 906                                         (buffer-substring start end)
 907                                         epa-last-coding-system-specified)
 908                                        mode))
 909       (message "Signing...done")
 910       (delete-region start end)
 911       (add-text-properties (point)
 912                            (progn
 913                              (insert (epa--decode-coding-string
 914                                       signature
 915                                       (or coding-system-for-read
 916                                           epa-last-coding-system-specified)))
 917                              (point))
 918                            (list 'epa-coding-system-used
 919                                  epa-last-coding-system-specified
 920                                  'front-sticky nil
 921                                  'rear-nonsticky t
 922                                  'start-open t
 923                                  'end-open t)))))
 924
 925 (if (fboundp 'derived-mode-p)
 926     (defalias 'epa--derived-mode-p 'derived-mode-p)
 927   (defun epa--derived-mode-p (&rest modes)
 928     "Non-nil if the current major mode is derived from one of MODES.
 929 Uses the `derived-mode-parent' property of the symbol to trace backwards."
 930     (let ((parent major-mode))
 931       (while (and (not (memq parent modes))
 932                   (setq parent (get parent 'derived-mode-parent))))
 933       parent)))
 934
 935 (defun epa--mail-mode-p ()
 936   (let ((pointer epa-mail-modes))
 937     (while (and pointer
 938                 (epa--derived-mode-p (car pointer)))
 939       (setq pointer (cdr pointer)))
 940     pointer))
 941
 942 ;;;###autoload
 943 (defun epa-sign (start end signers mode)
 944   "Sign the current buffer.
 945
 946 Don't use this command in Lisp programs!"
 947   (interactive
 948    (save-excursion
 949      (goto-char (point-min))
 950      (if (and (epa--mail-mode-p)
 951               (search-forward mail-header-separator nil t))
 952          (forward-line))
 953      (setq epa-last-coding-system-specified
 954            (or coding-system-for-write
 955                (epa--select-safe-coding-system (point) (point-max))))
 956      (list (point) (point-max)
 957            (if current-prefix-arg
 958                (epa-select-keys (epg-make-context epa-protocol)
 959                                 "Select keys for signing.
 960 If no one is selected, default secret key is used.  "
 961                                 nil t))
 962            (if current-prefix-arg
 963                (epa--read-signature-type)
 964              'clear))))
 965   (epa-sign-region start end signers mode))
 966
 967 ;;;###autoload
 968 (defun epa-encrypt-region (start end recipients)
 969   "Encrypt the current region between START and END for RECIPIENTS.
 970
 971 Don't use this command in Lisp programs!"
 972   (interactive
 973    (progn
 974      (setq epa-last-coding-system-specified
 975            (or coding-system-for-write
 976                (epa--select-safe-coding-system
 977                 (region-beginning) (region-end))))
 978      (list (region-beginning) (region-end)
 979            (epa-select-keys (epg-make-context epa-protocol)
 980                             "Select recipients for encryption.
 981 If no one is selected, symmetric encryption will be performed.  "))))
 982   (save-excursion
 983     (let ((context (epg-make-context epa-protocol))
 984           cipher)
 985       ;;(epg-context-set-armor context epa-armor)
 986       (epg-context-set-armor context t)
 987       ;;(epg-context-set-textmode context epa-textmode)
 988       (epg-context-set-textmode context t)
 989       (epg-context-set-passphrase-callback context
 990                                            #'epa-passphrase-callback-function)
 991       (epg-context-set-progress-callback context
 992                                          #'epa-progress-callback-function)
 993       (message "Encrypting...")
 994       (setq cipher (epg-encrypt-string context
 995                                        (epa--encode-coding-string
 996                                         (buffer-substring start end)
 997                                         epa-last-coding-system-specified)
 998                                        recipients))
 999       (message "Encrypting...done")
1000       (delete-region start end)
1001       (add-text-properties (point)
1002                            (progn
1003                              (insert cipher)
1004                              (point))
1005                            (list 'epa-coding-system-used
1006                                  epa-last-coding-system-specified
1007                                  'front-sticky nil
1008                                  'rear-nonsticky t
1009                                  'start-open t
1010                                  'end-open t)))))
1011
1012 ;;;###autoload
1013 (defun epa-encrypt (start end recipients)
1014   "Encrypt the current buffer.
1015
1016 Don't use this command in Lisp programs!"
1017   (interactive
1018    (save-excursion
1019      (let (recipients)
1020        (goto-char (point-min))
1021        (when (epa--mail-mode-p)
1022          (save-restriction
1023            (narrow-to-region (point)
1024                              (progn
1025                                (search-forward mail-header-separator nil 0)
1026                                (match-beginning 0)))
1027            (setq recipients
1028                  (mail-strip-quoted-names
1029                   (mapconcat #'identity
1030                              (nconc (mail-fetch-field "to" nil nil t)
1031                                     (mail-fetch-field "cc" nil nil t)
1032                                     (mail-fetch-field "bcc" nil nil t))
1033                              ","))))
1034          (if recipients
1035              (setq recipients (delete ""
1036                                       (split-string recipients "[ \t\n]+"))))
1037          (goto-char (point-min))
1038          (if (search-forward mail-header-separator nil t)
1039              (forward-line)))
1040        (setq epa-last-coding-system-specified
1041              (or coding-system-for-write
1042                  (epa--select-safe-coding-system (point) (point-max))))
1043        (list (point) (point-max)
1044              (if current-prefix-arg
1045                  (epa-select-keys
1046                   (epg-make-context epa-protocol)
1047                   "Select recipients for encryption.
1048 If no one is selected, symmetric encryption will be performed.  "
1049                   recipients)
1050                (if recipients
1051                    (delq nil
1052                          (apply #'nconc
1053                                 (mapcar
1054                                  (lambda (recipient)
1055                                    (epg-list-keys
1056                                     (epg-make-context epa-protocol)
1057                                     (concat "<" recipient ">")))
1058                                  recipients)))))))))
1059   (epa-encrypt-region start end recipients))
1060
1061 ;;;###autoload
1062 (defun epa-delete-keys (keys &optional allow-secret)
1063   "Delete selected KEYS.
1064
1065 Don't use this command in Lisp programs!"
1066   (interactive
1067    (let ((keys (epa--marked-keys)))
1068      (unless keys
1069        (error "No keys selected"))
1070      (list keys
1071            (eq (nth 1 epa-list-keys-arguments) t))))
1072   (let ((context (epg-make-context epa-protocol)))
1073     (message "Deleting...")
1074     (epg-delete-keys context keys allow-secret)
1075     (message "Deleting...done")
1076     (apply #'epa-list-keys epa-list-keys-arguments)))
1077
1078 ;;;###autoload
1079 (defun epa-import-keys (file)
1080   "Import keys from FILE.
1081
1082 Don't use this command in Lisp programs!"
1083   (interactive "fFile: ")
1084   (setq file (expand-file-name file))
1085   (let ((context (epg-make-context epa-protocol)))
1086     (message "Importing %s..." (file-name-nondirectory file))
1087     (condition-case nil
1088         (progn
1089           (epg-import-keys-from-file context file)
1090           (message "Importing %s...done" (file-name-nondirectory file)))
1091       (error
1092        (message "Importing %s...failed" (file-name-nondirectory file))))
1093     (if (epg-context-result-for context 'import)
1094         (epa-display-info (epg-import-result-to-string
1095                            (epg-context-result-for context 'import))))
1096     (if (eq major-mode 'epa-keys-mode)
1097         (apply #'epa-list-keys epa-list-keys-arguments))))
1098
1099 ;;;###autoload
1100 (defun epa-import-keys-region (start end)
1101   "Import keys from the region.
1102
1103 Don't use this command in Lisp programs!"
1104   (interactive "r")
1105   (let ((context (epg-make-context epa-protocol)))
1106     (message "Importing...")
1107     (condition-case nil
1108         (progn
1109           (epg-import-keys-from-string context (buffer-substring start end))
1110           (message "Importing...done"))
1111       (error
1112        (message "Importing...failed")))
1113     (if (epg-context-result-for context 'import)
1114         (epa-display-info (epg-import-result-to-string
1115                            (epg-context-result-for context 'import))))))
1116
1117 ;;;###autoload
1118 (defun epa-import-armor-in-region (start end)
1119   "Import keys in the OpenPGP armor format in the current region
1120 between START and END.
1121
1122 Don't use this command in Lisp programs!"
1123   (interactive "r")
1124   (save-excursion
1125     (save-restriction
1126       (narrow-to-region start end)
1127       (goto-char start)
1128       (let (armor-start armor-end)
1129         (while (re-search-forward
1130                 "-----BEGIN \\(PGP \\(PUBLIC\\|PRIVATE\\) KEY BLOCK\\)-----$"
1131                 nil t)
1132           (setq armor-start (match-beginning 0)
1133                 armor-end (re-search-forward
1134                            (concat "^-----END " (match-string 1) "-----$")
1135                            nil t))
1136           (unless armor-end
1137             (error "No armor tail"))
1138           (epa-import-keys-region armor-start armor-end))))))
1139
1140 ;;;###autoload
1141 (defun epa-import ()
1142   "Import keys in the OpenPGP armor format in the current buffer.
1143
1144 Don't use this command in Lisp programs!"
1145   (interactive)
1146   (epa-import-armor-in-region (point-min) (point-max)))
1147
1148 ;;;###autoload
1149 (defun epa-export-keys (keys file)
1150   "Export selected KEYS to FILE.
1151
1152 Don't use this command in Lisp programs!"
1153   (interactive
1154    (let ((keys (epa--marked-keys))
1155          default-name)
1156      (unless keys
1157        (error "No keys selected"))
1158      (setq default-name
1159            (expand-file-name
1160             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
1161                     (if epa-armor ".asc" ".gpg"))
1162             default-directory))
1163      (list keys
1164            (expand-file-name
1165             (read-file-name
1166              (concat "To file (default "
1167                      (file-name-nondirectory default-name)
1168                      ") ")
1169              (file-name-directory default-name)
1170              default-name)))))
1171   (let ((context (epg-make-context epa-protocol)))
1172     (epg-context-set-armor context epa-armor)
1173     (message "Exporting to %s..." (file-name-nondirectory file))
1174     (epg-export-keys-to-file context keys file)
1175     (message "Exporting to %s...done" (file-name-nondirectory file))))
1176
1177 ;;;###autoload
1178 (defun epa-insert-keys (keys)
1179   "Insert selected KEYS after the point.
1180
1181 Don't use this command in Lisp programs!"
1182   (interactive
1183    (list (epa-select-keys (epg-make-context epa-protocol)
1184                           "Select keys to export.  ")))
1185   (let ((context (epg-make-context epa-protocol)))
1186     ;;(epg-context-set-armor context epa-armor)
1187     (epg-context-set-armor context t)
1188     (insert (epg-export-keys-to-string context keys))))
1189
1190 ;;;###autoload
1191 (defun epa-sign-keys (keys &optional local)
1192   "Sign selected KEYS.
1193 If a prefix-arg is specified, the signature is marked as non exportable.
1194
1195 Don't use this command in Lisp programs!"
1196   (interactive
1197    (let ((keys (epa--marked-keys)))
1198      (unless keys
1199        (error "No keys selected"))
1200      (list keys current-prefix-arg)))
1201   (let ((context (epg-make-context epa-protocol)))
1202     (epg-context-set-passphrase-callback context
1203                                          #'epa-passphrase-callback-function)
1204     (epg-context-set-progress-callback context
1205                                        #'epa-progress-callback-function)
1206     (message "Signing keys...")
1207     (epg-sign-keys context keys local)
1208     (message "Signing keys...done")))
1209 (make-obsolete 'epa-sign-keys "Do not use.")
1210
1211 (provide 'epa)
1212
1213 ;;; epa.el ends here