epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30 (require 'derived)
  31
  32 (defgroup epa nil
  33   "The EasyPG Assistant"
  34   :group 'epg)
  35
  36 (defcustom epa-popup-info-window t
  37   "If non-nil, status information from epa commands is displayed on
  38 the separate window."
  39   :type 'boolean
  40   :group 'epa)
  41
  42 (defcustom epa-info-window-height 5
  43   "Number of lines used to display status information."
  44   :type 'integer
  45   :group 'epa)
  46
  47 (defgroup epa-faces nil
  48   "Faces for epa-mode."
  49   :group 'epa)
  50
  51 (defface epa-validity-high
  52   `((((class color) (background dark))
  53      (:foreground "PaleTurquoise"
  54                   ,@(if (assq ':weight custom-face-attributes)
  55                         '(:weight bold)
  56                       '(:bold t))))
  57     (t
  58      (,@(if (assq ':weight custom-face-attributes)
  59             '(:weight bold)
  60           '(:bold t)))))
  61   "Face used for displaying the high validity."
  62   :group 'epa-faces)
  63
  64 (defface epa-validity-medium
  65   `((((class color) (background dark))
  66      (:foreground "PaleTurquoise"
  67                   ,@(if (assq ':slant custom-face-attributes)
  68                         '(:slant italic)
  69                       '(:italic t))))
  70     (t
  71      (,@(if (assq ':slant custom-face-attributes)
  72             '(:slant italic)
  73           '(:italic t)))))
  74   "Face used for displaying the medium validity."
  75   :group 'epa-faces)
  76
  77 (defface epa-validity-low
  78   `((t
  79      (,@(if (assq ':slant custom-face-attributes)
  80             '(:slant italic)
  81           '(:italic t)))))
  82   "Face used for displaying the low validity."
  83   :group 'epa-faces)
  84
  85 (defface epa-validity-disabled
  86   `((t
  87      (,@(if (assq ':slant custom-face-attributes)
  88             '(:slant italic)
  89           '(:italic t))
  90         :inverse-video t)))
  91   "Face used for displaying the disabled validity."
  92   :group 'epa-faces)
  93
  94 (defface epa-string
  95   '((((class color) (background dark))
  96      (:foreground "lightyellow"))
  97     (((class color) (background light))
  98      (:foreground "blue4")))
  99   "Face used for displaying the string."
 100   :group 'epa-faces)
 101
 102 (defface epa-mark
 103   `((((class color) (background dark))
 104      (:foreground "orange"
 105                   ,@(if (assq ':weight custom-face-attributes)
 106                         '(:weight bold)
 107                       '(:bold t))))
 108     (((class color) (background light))
 109      (:foreground "red"
 110                   ,@(if (assq ':weight custom-face-attributes)
 111                         '(:weight bold)
 112                       '(:bold t))))
 113     (t
 114      (,@(if (assq ':weight custom-face-attributes)
 115             '(:weight bold)
 116           '(:bold t)))))
 117   "Face used for displaying the high validity."
 118   :group 'epa-faces)
 119
 120 (defface epa-field-name
 121   `((((class color) (background dark))
 122      (:foreground "PaleTurquoise"
 123                   ,@(if (assq ':weight custom-face-attributes)
 124                         '(:weight bold)
 125                       '(:bold t))))
 126     (t
 127      (,@(if (assq ':weight custom-face-attributes)
 128             '(:weight bold)
 129           '(:bold t)))))
 130   "Face for the name of the attribute field."
 131   :group 'epa)
 132
 133 (defface epa-field-body
 134   `((((class color) (background dark))
 135      (:foreground "turquoise"
 136                   ,@(if (assq ':slant custom-face-attributes)
 137                         '(:slant italic)
 138                       '(:italic t))))
 139     (t
 140      (,@(if (assq ':slant custom-face-attributes)
 141             '(:slant italic)
 142           '(:italic t)))))
 143   "Face for the body of the attribute field."
 144   :group 'epa)
 145
 146 (defcustom epa-validity-face-alist
 147   '((unknown . epa-validity-disabled)
 148     (invalid . epa-validity-disabled)
 149     (disabled . epa-validity-disabled)
 150     (revoked . epa-validity-disabled)
 151     (expired . epa-validity-disabled)
 152     (none . epa-validity-low)
 153     (undefined . epa-validity-low)
 154     (never . epa-validity-low)
 155     (marginal . epa-validity-medium)
 156     (full . epa-validity-high)
 157     (ultimate . epa-validity-high))
 158   "An alist mapping validity values to faces."
 159   :type '(repeat (cons symbol face))
 160   :group 'epa)
 161
 162 (defvar epa-font-lock-keywords
 163   '(("^\\*"
 164      (0 'epa-mark))
 165     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 166      (1 'epa-field-name)
 167      (2 'epa-field-body)))
 168   "Default expressions to addon in epa-mode.")
 169
 170 (defconst epa-pubkey-algorithm-letter-alist
 171   '((1 . ?R)
 172     (2 . ?r)
 173     (3 . ?s)
 174     (16 . ?g)
 175     (17 . ?D)
 176     (20 . ?G)))
 177
 178 (defvar epa-protocol 'OpenPGP
 179   "*The default protocol.
 180 The value can be either OpenPGP or CMS.
 181
 182 You should bind this variable with `let', but do not set it globally.")
 183
 184 (defvar epa-armor nil
 185   "*If non-nil, epa commands create ASCII armored output.
 186
 187 You should bind this variable with `let', but do not set it globally.")
 188
 189 (defvar epa-textmode nil
 190   "*If non-nil, epa commands treat input files as text.
 191
 192 You should bind this variable with `let', but do not set it globally.")
 193
 194 (defvar epa-keys-buffer nil)
 195 (defvar epa-key-buffer-alist nil)
 196 (defvar epa-key nil)
 197 (defvar epa-list-keys-arguments nil)
 198 (defvar epa-info-buffer nil)
 199 (defvar epa-last-coding-system-specified nil)
 200
 201 (defvar epa-key-list-mode-map
 202   (let ((keymap (make-sparse-keymap)))
 203     (define-key keymap "m" 'epa-mark-key)
 204     (define-key keymap "u" 'epa-unmark-key)
 205     (define-key keymap "d" 'epa-decrypt-file)
 206     (define-key keymap "v" 'epa-verify-file)
 207     (define-key keymap "s" 'epa-sign-file)
 208     (define-key keymap "e" 'epa-encrypt-file)
 209     (define-key keymap "r" 'epa-delete-keys)
 210     (define-key keymap "i" 'epa-import-keys)
 211     (define-key keymap "o" 'epa-export-keys)
 212     (define-key keymap "g" 'revert-buffer)
 213     (define-key keymap "n" 'next-line)
 214     (define-key keymap "p" 'previous-line)
 215     (define-key keymap " " 'scroll-up)
 216     (define-key keymap [delete] 'scroll-down)
 217     (define-key keymap "q" 'epa-exit-buffer)
 218     keymap))
 219
 220 (defvar epa-key-mode-map
 221   (let ((keymap (make-sparse-keymap)))
 222     (define-key keymap "q" 'epa-exit-buffer)
 223     keymap))
 224
 225 (defvar epa-info-mode-map
 226   (let ((keymap (make-sparse-keymap)))
 227     (define-key keymap "q" 'delete-window)
 228     keymap))
 229
 230 (defvar epa-exit-buffer-function #'bury-buffer)
 231
 232 (define-widget 'epa-key 'push-button
 233   "Button for representing a epg-key object."
 234   :format "%[%v%]"
 235   :button-face-get 'epa--key-widget-button-face-get
 236   :value-create 'epa--key-widget-value-create
 237   :action 'epa--key-widget-action
 238   :help-echo 'epa--key-widget-help-echo)
 239
 240 (defun epa--key-widget-action (widget &optional event)
 241   (epa--show-key (widget-get widget :value)))
 242
 243 (defun epa--key-widget-value-create (widget)
 244   (let* ((key (widget-get widget :value))
 245          (primary-sub-key (car (epg-key-sub-key-list key)))
 246          (primary-user-id (car (epg-key-user-id-list key))))
 247     (insert (format "%c "
 248                     (if (epg-sub-key-validity primary-sub-key)
 249                         (car (rassq (epg-sub-key-validity primary-sub-key)
 250                                     epg-key-validity-alist))
 251                       ? ))
 252             (epg-sub-key-id primary-sub-key)
 253             " "
 254             (if primary-user-id
 255                 (if (stringp (epg-user-id-string primary-user-id))
 256                     (epg-user-id-string primary-user-id)
 257                   (epg-decode-dn (epg-user-id-string primary-user-id)))
 258               ""))))
 259
 260 (defun epa--key-widget-button-face-get (widget)
 261   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 262                                               (widget-get widget :value))))))
 263     (if validity
 264         (cdr (assq validity epa-validity-face-alist))
 265       'default)))
 266
 267 (defun epa--key-widget-help-echo (widget)
 268   (format "Show %s"
 269           (epg-sub-key-id (car (epg-key-sub-key-list
 270                                 (widget-get widget :value))))))
 271
 272 (eval-and-compile
 273   (if (fboundp 'encode-coding-string)
 274       (defalias 'epa--encode-coding-string 'encode-coding-string)
 275     (defalias 'epa--encode-coding-string 'identity)))
 276
 277 (eval-and-compile
 278   (if (fboundp 'decode-coding-string)
 279       (defalias 'epa--decode-coding-string 'decode-coding-string)
 280     (defalias 'epa--decode-coding-string 'identity)))
 281
 282 (defun epa-key-list-mode ()
 283   "Major mode for `epa-list-keys'."
 284   (kill-all-local-variables)
 285   (buffer-disable-undo)
 286   (setq major-mode 'epa-key-list-mode
 287         mode-name "Keys"
 288         truncate-lines t
 289         buffer-read-only t)
 290   (use-local-map epa-key-list-mode-map)
 291   (make-local-variable 'font-lock-defaults)
 292   (setq font-lock-defaults '(epa-font-lock-keywords t))
 293   ;; In XEmacs, auto-initialization of font-lock is not effective
 294   ;; if buffer-file-name is not set.
 295   (font-lock-set-defaults)
 296   (make-local-variable 'epa-exit-buffer-function)
 297   (make-local-variable 'revert-buffer-function)
 298   (setq revert-buffer-function 'epa--key-list-revert-buffer)
 299   (run-hooks 'epa-key-list-mode-hook))
 300
 301 (defun epa-key-mode ()
 302   "Major mode for a key description."
 303   (kill-all-local-variables)
 304   (buffer-disable-undo)
 305   (setq major-mode 'epa-key-mode
 306         mode-name "Key"
 307         truncate-lines t
 308         buffer-read-only t)
 309   (use-local-map epa-key-mode-map)
 310   (make-local-variable 'font-lock-defaults)
 311   (setq font-lock-defaults '(epa-font-lock-keywords t))
 312   ;; In XEmacs, auto-initialization of font-lock is not effective
 313   ;; if buffer-file-name is not set.
 314   (font-lock-set-defaults)
 315   (make-local-variable 'epa-exit-buffer-function)
 316   (run-hooks 'epa-key-mode-hook))
 317
 318 (defun epa-info-mode ()
 319   "Major mode for `epa-info-buffer'."
 320   (kill-all-local-variables)
 321   (buffer-disable-undo)
 322   (setq major-mode 'epa-info-mode
 323         mode-name "Info"
 324         truncate-lines t
 325         buffer-read-only t)
 326   (use-local-map epa-info-mode-map)
 327   (run-hooks 'epa-info-mode-hook))
 328
 329 (defun epa-mark-key (&optional arg)
 330   "Mark a key on the current line.
 331 If ARG is non-nil, unmark the key."
 332   (interactive "P")
 333   (let ((inhibit-read-only t)
 334         buffer-read-only
 335         properties)
 336     (beginning-of-line)
 337     (unless (get-text-property (point) 'epa-key)
 338       (error "No key on this line"))
 339     (setq properties (text-properties-at (point)))
 340     (delete-char 1)
 341     (insert (if arg " " "*"))
 342     (set-text-properties (1- (point)) (point) properties)
 343     (forward-line)))
 344
 345 (defun epa-unmark-key (&optional arg)
 346   "Unmark a key on the current line.
 347 If ARG is non-nil, mark the key."
 348   (interactive "P")
 349   (epa-mark-key (not arg)))
 350
 351 (defun epa-exit-buffer ()
 352   "Exit the current buffer.
 353 `epa-exit-buffer-function' is called if it is set."
 354   (interactive)
 355   (funcall epa-exit-buffer-function))
 356
 357 (defun epa--insert-keys (keys)
 358   (save-excursion
 359     (save-restriction
 360       (narrow-to-region (point) (point))
 361       (let (point)
 362         (while keys
 363           (setq point (point))
 364           (insert "  ")
 365           (add-text-properties point (point)
 366                                (list 'epa-key (car keys)
 367                                      'front-sticky nil
 368                                      'rear-nonsticky t
 369                                      'start-open t
 370                                      'end-open t))
 371           (widget-create 'epa-key :value (car keys))
 372           (insert "\n")
 373           (setq keys (cdr keys))))
 374       (add-text-properties (point-min) (point-max)
 375                            (list 'epa-list-keys t
 376                                  'front-sticky nil
 377                                  'rear-nonsticky t
 378                                  'start-open t
 379                                  'end-open t)))))
 380
 381 (defun epa--list-keys (name secret)
 382   (unless (and epa-keys-buffer
 383                (buffer-live-p epa-keys-buffer))
 384     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 385   (set-buffer epa-keys-buffer)
 386   (epa-key-list-mode)
 387   (let ((inhibit-read-only t)
 388         buffer-read-only
 389         (point (point-min))
 390         (context (epg-make-context epa-protocol)))
 391     (unless (get-text-property point 'epa-list-keys)
 392       (setq point (next-single-property-change point 'epa-list-keys)))
 393     (when point
 394       (delete-region point
 395                      (or (next-single-property-change point 'epa-list-keys)
 396                          (point-max)))
 397       (goto-char point))
 398     (epa--insert-keys (epg-list-keys context name secret))
 399     (widget-setup)
 400     (set-keymap-parent (current-local-map) widget-keymap))
 401   (make-local-variable 'epa-list-keys-arguments)
 402   (setq epa-list-keys-arguments (list name secret))
 403   (goto-char (point-min))
 404   (pop-to-buffer (current-buffer)))
 405
 406 ;;;###autoload
 407 (defun epa-list-keys (&optional name)
 408   "List all keys matched with NAME from the public keyring."
 409   (interactive
 410    (if current-prefix-arg
 411        (let ((name (read-string "Pattern: "
 412                                 (if epa-list-keys-arguments
 413                                     (car epa-list-keys-arguments)))))
 414          (list (if (equal name "") nil name)))
 415      (list nil)))
 416   (epa--list-keys name nil))
 417
 418 ;;;###autoload
 419 (defun epa-list-secret-keys (&optional name)
 420   "List all keys matched with NAME from the private keyring."
 421   (interactive
 422    (if current-prefix-arg
 423        (let ((name (read-string "Pattern: "
 424                                 (if epa-list-keys-arguments
 425                                     (car epa-list-keys-arguments)))))
 426          (list (if (equal name "") nil name)))
 427      (list nil)))
 428   (epa--list-keys name t))
 429
 430 (defun epa--key-list-revert-buffer (&optional ignore-auto noconfirm)
 431   (apply #'epa--list-keys epa-list-keys-arguments))
 432
 433 (defun epa--marked-keys ()
 434   (or (save-excursion
 435         (set-buffer epa-keys-buffer)
 436         (goto-char (point-min))
 437         (let (keys key)
 438           (while (re-search-forward "^\\*" nil t)
 439             (if (setq key (get-text-property (match-beginning 0)
 440                                              'epa-key))
 441                 (setq keys (cons key keys))))
 442           (nreverse keys)))
 443       (save-excursion
 444         (beginning-of-line)
 445         (let ((key (get-text-property (point) 'epa-key)))
 446           (if key
 447               (list key))))))
 448
 449 (defun epa--select-keys (prompt keys)
 450   (save-excursion
 451     (unless (and epa-keys-buffer
 452                  (buffer-live-p epa-keys-buffer))
 453       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 454     (set-buffer epa-keys-buffer)
 455     (epa-key-list-mode)
 456     (let ((inhibit-read-only t)
 457           buffer-read-only)
 458       (erase-buffer)
 459       (insert prompt "\n"
 460               (substitute-command-keys "\
 461 - `\\[epa-mark-key]' to mark a key on the line
 462 - `\\[epa-unmark-key]' to unmark a key on the line\n"))
 463       (widget-create 'link
 464                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 465                      :help-echo
 466                      (substitute-command-keys
 467                       "Click here or \\[abort-recursive-edit] to cancel")
 468                      "Cancel")
 469       (widget-create 'link
 470                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 471                      :help-echo
 472                      (substitute-command-keys
 473                       "Click here or \\[exit-recursive-edit] to finish")
 474                      "OK")
 475       (insert "\n\n")
 476       (epa--insert-keys keys)
 477       (widget-setup)
 478       (set-keymap-parent (current-local-map) widget-keymap)
 479       (setq epa-exit-buffer-function #'abort-recursive-edit)
 480       (goto-char (point-min))
 481       (pop-to-buffer (current-buffer)))
 482     (unwind-protect
 483         (progn
 484           (recursive-edit)
 485           (epa--marked-keys))
 486       (if (get-buffer-window epa-keys-buffer)
 487           (delete-window (get-buffer-window epa-keys-buffer)))
 488       (kill-buffer epa-keys-buffer))))
 489
 490 ;;;###autoload
 491 (defun epa-select-keys (context prompt &optional names secret)
 492   "Display a user's keyring and ask him to select keys.
 493 CONTEXT is an epg-context.
 494 PROMPT is a string to prompt with.
 495 NAMES is a list of strings to be matched with keys.  If it is nil, all
 496 the keys are listed.
 497 If SECRET is non-nil, list secret keys instead of public keys."
 498   (let ((keys (epg-list-keys context names secret)))
 499     (if (> (length keys) 1)
 500         (epa--select-keys prompt keys)
 501       keys)))
 502
 503 (defun epa--format-fingerprint-1 (fingerprint unit-size block-size)
 504   (let ((unit 0))
 505     (with-temp-buffer
 506       (insert fingerprint)
 507       (goto-char (point-min))
 508       (while (progn
 509                (goto-char (+ (point) unit-size))
 510                (not (eobp)))
 511         (setq unit (1+ unit))
 512         (insert (if (= (% unit block-size) 0) "  " " ")))
 513       (buffer-string))))
 514
 515 (defun epa--format-fingerprint (fingerprint)
 516   (if fingerprint
 517       (if (= (length fingerprint) 40)
 518           ;; 1234 5678 9ABC DEF0 1234  5678 9ABC DEF0 1234 5678
 519           (epa--format-fingerprint-1 fingerprint 4 5)
 520         ;; 12 34 56 78 9A BC DE F0  12 34 56 78 9A BC DE F0
 521         (epa--format-fingerprint-1 fingerprint 2 8))))
 522
 523 (defun epa--show-key (key)
 524   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 525          (entry (assoc (epg-sub-key-id primary-sub-key)
 526                        epa-key-buffer-alist))
 527          (inhibit-read-only t)
 528          buffer-read-only
 529          pointer)
 530     (unless entry
 531       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 532             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 533     (unless (and (cdr entry)
 534                  (buffer-live-p (cdr entry)))
 535       (setcdr entry (generate-new-buffer
 536                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 537     (set-buffer (cdr entry))
 538     (epa-key-mode)
 539     (make-local-variable 'epa-key)
 540     (setq epa-key key)
 541     (erase-buffer)
 542     (setq pointer (epg-key-user-id-list key))
 543     (while pointer
 544       (if (car pointer)
 545           (insert " "
 546                   (if (epg-user-id-validity (car pointer))
 547                       (char-to-string
 548                        (car (rassq (epg-user-id-validity (car pointer))
 549                                    epg-key-validity-alist)))
 550                     " ")
 551                   " "
 552                   (if (stringp (epg-user-id-string (car pointer)))
 553                       (epg-user-id-string (car pointer))
 554                     (epg-decode-dn (epg-user-id-string (car pointer))))
 555                   "\n"))
 556       (setq pointer (cdr pointer)))
 557     (setq pointer (epg-key-sub-key-list key))
 558     (while pointer
 559       (insert " "
 560               (if (epg-sub-key-validity (car pointer))
 561                   (char-to-string
 562                    (car (rassq (epg-sub-key-validity (car pointer))
 563                                epg-key-validity-alist)))
 564                 " ")
 565               " "
 566               (epg-sub-key-id (car pointer))
 567               " "
 568               (format "%dbits"
 569                       (epg-sub-key-length (car pointer)))
 570               " "
 571               (cdr (assq (epg-sub-key-algorithm (car pointer))
 572                          epg-pubkey-algorithm-alist))
 573               "\n\tCreated: "
 574               (format-time-string "%Y-%m-%d"
 575                                   (epg-sub-key-creation-time (car pointer)))
 576               (if (epg-sub-key-expiration-time (car pointer))
 577                   (format "\n\tExpires: %s"
 578                           (format-time-string "%Y-%m-%d"
 579                                               (epg-sub-key-expiration-time
 580                                                (car pointer))))
 581                 "")
 582               "\n\tCapabilities: "
 583               (mapconcat #'symbol-name
 584                          (epg-sub-key-capability (car pointer))
 585                          " ")
 586               "\n\tFingerprint: "
 587               (epa--format-fingerprint (epg-sub-key-fingerprint (car pointer)))
 588               "\n")
 589       (setq pointer (cdr pointer)))
 590     (goto-char (point-min))
 591     (pop-to-buffer (current-buffer))))
 592
 593 (defun epa-display-info (info)
 594   (if epa-popup-info-window
 595       (save-selected-window
 596         (unless (and epa-info-buffer (buffer-live-p epa-info-buffer))
 597           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 598         (if (get-buffer-window epa-info-buffer)
 599             (delete-window (get-buffer-window epa-info-buffer)))
 600         (save-excursion
 601           (set-buffer epa-info-buffer)
 602           (let ((inhibit-read-only t)
 603                 buffer-read-only)
 604             (erase-buffer)
 605             (insert info))
 606           (epa-info-mode)
 607           (goto-char (point-min)))
 608         (if (> (window-height)
 609                epa-info-window-height)
 610             (set-window-buffer (split-window nil (- (window-height)
 611                                                     epa-info-window-height))
 612                                epa-info-buffer)
 613           (pop-to-buffer epa-info-buffer)
 614           (if (> (window-height) epa-info-window-height)
 615               (shrink-window (- (window-height) epa-info-window-height)))))
 616     (message "%s" info)))
 617
 618 (defun epa-display-verify-result (verify-result)
 619   (epa-display-info (epg-verify-result-to-string verify-result)))
 620 (make-obsolete 'epa-display-verify-result 'epa-display-info)
 621
 622 (defun epa-passphrase-callback-function (context key-id handback)
 623   (if (eq key-id 'SYM)
 624       (read-passwd "Passphrase for symmetric encryption: "
 625                    (eq (epg-context-operation context) 'encrypt))
 626     (read-passwd
 627      (if (eq key-id 'PIN)
 628         "Passphrase for PIN: "
 629        (let ((entry (assoc key-id epg-user-id-alist)))
 630          (if entry
 631              (format "Passphrase for %s %s: " key-id (cdr entry))
 632            (format "Passphrase for %s: " key-id)))))))
 633
 634 (defun epa-progress-callback-function (context what char current total
 635                                                handback)
 636   (message "%s%d%% (%d/%d)" (or handback
 637                                 (concat what ": "))
 638            (if (> total 0) (floor (* (/ current (float total)) 100)) 0)
 639            current total))
 640
 641 ;;;###autoload
 642 (defun epa-decrypt-file (file)
 643   "Decrypt FILE."
 644   (interactive "fFile: ")
 645   (setq file (expand-file-name file))
 646   (let* ((default-name (file-name-sans-extension file))
 647          (plain (expand-file-name
 648                  (read-file-name
 649                   (concat "To file (default "
 650                           (file-name-nondirectory default-name)
 651                           ") ")
 652                   (file-name-directory default-name)
 653                   default-name)))
 654          (context (epg-make-context epa-protocol)))
 655     (epg-context-set-passphrase-callback context
 656                                          #'epa-passphrase-callback-function)
 657     (epg-context-set-progress-callback context
 658                                        #'epa-progress-callback-function
 659                                        (format "Decrypting %s..."
 660                                                (file-name-nondirectory file)))
 661     (message "Decrypting %s..." (file-name-nondirectory file))
 662     (epg-decrypt-file context file plain)
 663     (message "Decrypting %s...wrote %s" (file-name-nondirectory file)
 664              (file-name-nondirectory plain))
 665     (if (epg-context-result-for context 'verify)
 666         (epa-display-info (epg-verify-result-to-string
 667                            (epg-context-result-for context 'verify))))))
 668
 669 ;;;###autoload
 670 (defun epa-verify-file (file)
 671   "Verify FILE."
 672   (interactive "fFile: ")
 673   (setq file (expand-file-name file))
 674   (let* ((context (epg-make-context epa-protocol))
 675          (plain (if (equal (file-name-extension file) "sig")
 676                     (file-name-sans-extension file))))
 677     (epg-context-set-progress-callback context
 678                                        #'epa-progress-callback-function
 679                                        (format "Verifying %s..."
 680                                                (file-name-nondirectory file)))
 681     (message "Verifying %s..." (file-name-nondirectory file))
 682     (epg-verify-file context file plain)
 683     (message "Verifying %s...done" (file-name-nondirectory file))
 684     (if (epg-context-result-for context 'verify)
 685         (epa-display-info (epg-verify-result-to-string
 686                            (epg-context-result-for context 'verify))))))
 687
 688 (defun epa--read-signature-type ()
 689   (let (type c)
 690     (while (null type)
 691       (message "Signature type (n,c,d,?) ")
 692       (setq c (read-char))
 693       (cond ((eq c ?c)
 694              (setq type 'clear))
 695             ((eq c ?d)
 696              (setq type 'detached))
 697             ((eq c ??)
 698              (with-output-to-temp-buffer "*Help*"
 699                (save-excursion
 700                  (set-buffer standard-output)
 701                  (insert "\
 702 n - Create a normal signature
 703 c - Create a cleartext signature
 704 d - Create a detached signature
 705 ? - Show this help
 706 "))))
 707             (t
 708              (setq type 'normal))))))
 709
 710 ;;;###autoload
 711 (defun epa-sign-file (file signers mode)
 712   "Sign FILE by SIGNERS keys selected."
 713   (interactive
 714    (let ((verbose current-prefix-arg))
 715      (list (expand-file-name (read-file-name "File: "))
 716            (if verbose
 717                (epa-select-keys (epg-make-context epa-protocol)
 718                                 "Select keys for signing.
 719 If no one is selected, default secret key is used.  "
 720                                 nil t))
 721            (if verbose
 722                (epa--read-signature-type)
 723              'clear))))
 724   (let ((signature (concat file
 725                            (if (eq epa-protocol 'OpenPGP)
 726                                (if (or epa-armor
 727                                        (not (memq mode
 728                                                   '(nil t normal detached))))
 729                                    ".asc"
 730                                  (if (memq mode '(t detached))
 731                                      ".sig"
 732                                    ".gpg"))
 733                              (if (memq mode '(t detached))
 734                                  ".p7s"
 735                                ".p7m"))))
 736         (context (epg-make-context epa-protocol)))
 737     (epg-context-set-armor context epa-armor)
 738     (epg-context-set-textmode context epa-textmode)
 739     (epg-context-set-signers context signers)
 740     (epg-context-set-passphrase-callback context
 741                                          #'epa-passphrase-callback-function)
 742     (epg-context-set-progress-callback context
 743                                        #'epa-progress-callback-function
 744                                        (format "Signing %s..."
 745                                                (file-name-nondirectory file)))
 746     (message "Signing %s..." (file-name-nondirectory file))
 747     (epg-sign-file context file signature mode)
 748     (message "Signing %s...wrote %s" (file-name-nondirectory file)
 749              (file-name-nondirectory signature))))
 750
 751 ;;;###autoload
 752 (defun epa-encrypt-file (file recipients)
 753   "Encrypt FILE for RECIPIENTS."
 754   (interactive
 755    (list (expand-file-name (read-file-name "File: "))
 756          (epa-select-keys (epg-make-context epa-protocol)
 757                           "Select recipients for encryption.
 758 If no one is selected, symmetric encryption will be performed.  ")))
 759   (let ((cipher (concat file (if (eq epa-protocol 'OpenPGP)
 760                                  (if epa-armor ".asc" ".gpg")
 761                                ".p7m")))
 762         (context (epg-make-context epa-protocol)))
 763     (epg-context-set-armor context epa-armor)
 764     (epg-context-set-textmode context epa-textmode)
 765     (epg-context-set-passphrase-callback context
 766                                          #'epa-passphrase-callback-function)
 767     (epg-context-set-progress-callback context
 768                                        #'epa-progress-callback-function
 769                                        (format "Encrypting %s..."
 770                                                (file-name-nondirectory file)))
 771     (message "Encrypting %s..." (file-name-nondirectory file))
 772     (epg-encrypt-file context file recipients cipher)
 773     (message "Encrypting %s...wrote %s" (file-name-nondirectory file)
 774              (file-name-nondirectory cipher))))
 775
 776 ;;;###autoload
 777 (defun epa-decrypt-region (start end)
 778   "Decrypt the current region between START and END.
 779
 780 Don't use this command in Lisp programs!"
 781   (interactive "r")
 782   (save-excursion
 783     (let ((context (epg-make-context epa-protocol))
 784           plain)
 785       (epg-context-set-passphrase-callback context
 786                                            #'epa-passphrase-callback-function)
 787       (epg-context-set-progress-callback context
 788                                          #'epa-progress-callback-function
 789                                          "Decrypting...")
 790       (message "Decrypting...")
 791       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 792       (message "Decrypting...done")
 793       (setq plain (epa--decode-coding-string
 794                    plain
 795                    (or coding-system-for-read
 796                        (get-text-property start 'epa-coding-system-used))))
 797       (if (y-or-n-p "Replace the original text? ")
 798           (let ((inhibit-read-only t)
 799                 buffer-read-only)
 800             (delete-region start end)
 801             (goto-char start)
 802             (insert plain))
 803         (with-output-to-temp-buffer "*Temp*"
 804           (set-buffer standard-output)
 805           (insert plain)
 806           (epa-info-mode)))
 807       (if (epg-context-result-for context 'verify)
 808           (epa-display-info (epg-verify-result-to-string
 809                              (epg-context-result-for context 'verify)))))))
 810
 811 (defun epa--find-coding-system-for-mime-charset (mime-charset)
 812   (if (featurep 'xemacs)
 813       (if (fboundp 'find-coding-system)
 814           (find-coding-system mime-charset))
 815     (let ((pointer (coding-system-list)))
 816       (while (and pointer
 817                   (eq (coding-system-get (car pointer) 'mime-charset)
 818                       mime-charset))
 819         (setq pointer (cdr pointer)))
 820       pointer)))
 821
 822 ;;;###autoload
 823 (defun epa-decrypt-armor-in-region (start end)
 824   "Decrypt OpenPGP armors in the current region between START and END.
 825
 826 Don't use this command in Lisp programs!"
 827   (interactive "r")
 828   (save-excursion
 829     (save-restriction
 830       (narrow-to-region start end)
 831       (goto-char start)
 832       (let (armor-start armor-end)
 833         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 834           (setq armor-start (match-beginning 0)
 835                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 836                                              nil t))
 837           (unless armor-end
 838             (error "No armor tail"))
 839           (goto-char armor-start)
 840           (let ((coding-system-for-read
 841                  (or coding-system-for-read
 842                      (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 843                          (epa--find-coding-system-for-mime-charset
 844                           (intern (downcase (match-string 1))))))))
 845             (goto-char armor-end)
 846             (epa-decrypt-region armor-start armor-end)))))))
 847
 848 ;;;###autoload
 849 (defun epa-verify-region (start end)
 850   "Verify the current region between START and END.
 851
 852 Don't use this command in Lisp programs!"
 853   (interactive "r")
 854   (let ((context (epg-make-context epa-protocol))
 855         plain)
 856     (epg-context-set-progress-callback context
 857                                        #'epa-progress-callback-function
 858                                        "Verifying...")
 859     (message "Verifying...")
 860     (setq plain (epg-verify-string
 861                  context
 862                  (epa--encode-coding-string
 863                   (buffer-substring start end)
 864                   (or coding-system-for-write
 865                       (get-text-property start 'epa-coding-system-used)))))
 866     (message "Verifying...done")
 867     (setq plain (epa--decode-coding-string
 868                  plain
 869                  (or coding-system-for-read
 870                      (get-text-property start 'epa-coding-system-used))))
 871     (if (y-or-n-p "Replace the original text? ")
 872         (let ((inhibit-read-only t)
 873               buffer-read-only)
 874           (delete-region start end)
 875           (goto-char start)
 876           (insert plain))
 877       (with-output-to-temp-buffer "*Temp*"
 878         (set-buffer standard-output)
 879         (insert plain)
 880         (epa-info-mode)))
 881     (if (epg-context-result-for context 'verify)
 882         (epa-display-info (epg-verify-result-to-string
 883                            (epg-context-result-for context 'verify))))))
 884
 885 ;;;###autoload
 886 (defun epa-verify-cleartext-in-region (start end)
 887   "Verify OpenPGP cleartext signed messages in the current region
 888 between START and END.
 889
 890 Don't use this command in Lisp programs!"
 891   (interactive "r")
 892   (save-excursion
 893     (save-restriction
 894       (narrow-to-region start end)
 895       (goto-char start)
 896       (let (cleartext-start cleartext-end)
 897         (while (re-search-forward "-----BEGIN PGP SIGNED MESSAGE-----$"
 898                                   nil t)
 899           (setq cleartext-start (match-beginning 0))
 900           (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 901                                            nil t)
 902             (error "Invalid cleartext signed message"))
 903           (setq cleartext-end (re-search-forward
 904                            "^-----END PGP SIGNATURE-----$"
 905                            nil t))
 906           (unless cleartext-end
 907             (error "No cleartext tail"))
 908           (epa-verify-region cleartext-start cleartext-end))))))
 909
 910 (eval-and-compile
 911   (if (fboundp 'select-safe-coding-system)
 912       (defalias 'epa--select-safe-coding-system 'select-safe-coding-system)
 913     (defun epa--select-safe-coding-system (from to)
 914       buffer-file-coding-system)))
 915
 916 ;;;###autoload
 917 (defun epa-sign-region (start end signers mode)
 918   "Sign the current region between START and END by SIGNERS keys selected.
 919
 920 Don't use this command in Lisp programs!"
 921   (interactive
 922    (let ((verbose current-prefix-arg))
 923      (setq epa-last-coding-system-specified
 924            (or coding-system-for-write
 925                (epa--select-safe-coding-system
 926                 (region-beginning) (region-end))))
 927      (list (region-beginning) (region-end)
 928            (if verbose
 929                (epa-select-keys (epg-make-context epa-protocol)
 930                                 "Select keys for signing.
 931 If no one is selected, default secret key is used.  "
 932                                 nil t))
 933            (if verbose
 934                (epa--read-signature-type)
 935              'clear))))
 936   (save-excursion
 937     (let ((context (epg-make-context epa-protocol))
 938           signature)
 939       ;;(epg-context-set-armor context epa-armor)
 940       (epg-context-set-armor context t)
 941       ;;(epg-context-set-textmode context epa-textmode)
 942       (epg-context-set-textmode context t)
 943       (epg-context-set-signers context signers)
 944       (epg-context-set-passphrase-callback context
 945                                            #'epa-passphrase-callback-function)
 946       (epg-context-set-progress-callback context
 947                                          #'epa-progress-callback-function
 948                                          "Signing...")
 949       (message "Signing...")
 950       (setq signature (epg-sign-string context
 951                                        (epa--encode-coding-string
 952                                         (buffer-substring start end)
 953                                         epa-last-coding-system-specified)
 954                                        mode))
 955       (message "Signing...done")
 956       (delete-region start end)
 957       (goto-char start)
 958       (add-text-properties (point)
 959                            (progn
 960                              (insert (epa--decode-coding-string
 961                                       signature
 962                                       (or coding-system-for-read
 963                                           epa-last-coding-system-specified)))
 964                              (point))
 965                            (list 'epa-coding-system-used
 966                                  epa-last-coding-system-specified
 967                                  'front-sticky nil
 968                                  'rear-nonsticky t
 969                                  'start-open t
 970                                  'end-open t)))))
 971
 972 (eval-and-compile
 973   (if (fboundp 'derived-mode-p)
 974       (defalias 'epa--derived-mode-p 'derived-mode-p)
 975     (defun epa--derived-mode-p (&rest modes)
 976       "Non-nil if the current major mode is derived from one of MODES.
 977 Uses the `derived-mode-parent' property of the symbol to trace backwards."
 978       (let ((parent major-mode))
 979         (while (and (not (memq parent modes))
 980                     (setq parent (get parent 'derived-mode-parent))))
 981         parent))))
 982
 983 ;;;###autoload
 984 (defun epa-encrypt-region (start end recipients sign signers)
 985   "Encrypt the current region between START and END for RECIPIENTS.
 986
 987 Don't use this command in Lisp programs!"
 988   (interactive
 989    (let ((verbose current-prefix-arg)
 990          (context (epg-make-context epa-protocol))
 991          sign)
 992      (setq epa-last-coding-system-specified
 993            (or coding-system-for-write
 994                (epa--select-safe-coding-system
 995                 (region-beginning) (region-end))))
 996      (list (region-beginning) (region-end)
 997            (epa-select-keys context
 998                             "Select recipients for encryption.
 999 If no one is selected, symmetric encryption will be performed.  ")
1000            (setq sign (if verbose (y-or-n-p "Sign? ")))
1001            (if sign
1002                (epa-select-keys context
1003                                 "Select keys for signing.  ")))))
1004   (save-excursion
1005     (let ((context (epg-make-context epa-protocol))
1006           cipher)
1007       ;;(epg-context-set-armor context epa-armor)
1008       (epg-context-set-armor context t)
1009       ;;(epg-context-set-textmode context epa-textmode)
1010       (epg-context-set-textmode context t)
1011       (if sign
1012           (epg-context-set-signers context signers))
1013       (epg-context-set-passphrase-callback context
1014                                            #'epa-passphrase-callback-function)
1015       (epg-context-set-progress-callback context
1016                                          #'epa-progress-callback-function
1017                                          "Encrypting...")
1018       (message "Encrypting...")
1019       (setq cipher (epg-encrypt-string context
1020                                        (epa--encode-coding-string
1021                                         (buffer-substring start end)
1022                                         epa-last-coding-system-specified)
1023                                        recipients
1024                                        sign))
1025       (message "Encrypting...done")
1026       (delete-region start end)
1027       (goto-char start)
1028       (add-text-properties (point)
1029                            (progn
1030                              (insert cipher)
1031                              (point))
1032                            (list 'epa-coding-system-used
1033                                  epa-last-coding-system-specified
1034                                  'front-sticky nil
1035                                  'rear-nonsticky t
1036                                  'start-open t
1037                                  'end-open t)))))
1038
1039 ;;;###autoload
1040 (defun epa-delete-keys (keys &optional allow-secret)
1041   "Delete selected KEYS.
1042
1043 Don't use this command in Lisp programs!"
1044   (interactive
1045    (let ((keys (epa--marked-keys)))
1046      (unless keys
1047        (error "No keys selected"))
1048      (list keys
1049            (eq (nth 1 epa-list-keys-arguments) t))))
1050   (let ((context (epg-make-context epa-protocol)))
1051     (message "Deleting...")
1052     (epg-delete-keys context keys allow-secret)
1053     (message "Deleting...done")
1054     (apply #'epa-list-keys epa-list-keys-arguments)))
1055
1056 ;;;###autoload
1057 (defun epa-import-keys (file)
1058   "Import keys from FILE.
1059
1060 Don't use this command in Lisp programs!"
1061   (interactive "fFile: ")
1062   (setq file (expand-file-name file))
1063   (let ((context (epg-make-context epa-protocol)))
1064     (message "Importing %s..." (file-name-nondirectory file))
1065     (condition-case nil
1066         (progn
1067           (epg-import-keys-from-file context file)
1068           (message "Importing %s...done" (file-name-nondirectory file)))
1069       (error
1070        (message "Importing %s...failed" (file-name-nondirectory file))))
1071     (if (epg-context-result-for context 'import)
1072         (epa-display-info (epg-import-result-to-string
1073                            (epg-context-result-for context 'import))))
1074     (if (eq major-mode 'epa-key-list-mode)
1075         (apply #'epa-list-keys epa-list-keys-arguments))))
1076
1077 ;;;###autoload
1078 (defun epa-import-keys-region (start end)
1079   "Import keys from the region.
1080
1081 Don't use this command in Lisp programs!"
1082   (interactive "r")
1083   (let ((context (epg-make-context epa-protocol)))
1084     (message "Importing...")
1085     (condition-case nil
1086         (progn
1087           (epg-import-keys-from-string context (buffer-substring start end))
1088           (message "Importing...done"))
1089       (error
1090        (message "Importing...failed")))
1091     (if (epg-context-result-for context 'import)
1092         (epa-display-info (epg-import-result-to-string
1093                            (epg-context-result-for context 'import))))))
1094
1095 ;;;###autoload
1096 (defun epa-import-armor-in-region (start end)
1097   "Import keys in the OpenPGP armor format in the current region
1098 between START and END.
1099
1100 Don't use this command in Lisp programs!"
1101   (interactive "r")
1102   (save-excursion
1103     (save-restriction
1104       (narrow-to-region start end)
1105       (goto-char start)
1106       (let (armor-start armor-end)
1107         (while (re-search-forward
1108                 "-----BEGIN \\(PGP \\(PUBLIC\\|PRIVATE\\) KEY BLOCK\\)-----$"
1109                 nil t)
1110           (setq armor-start (match-beginning 0)
1111                 armor-end (re-search-forward
1112                            (concat "^-----END " (match-string 1) "-----$")
1113                            nil t))
1114           (unless armor-end
1115             (error "No armor tail"))
1116           (epa-import-keys-region armor-start armor-end))))))
1117
1118 ;;;###autoload
1119 (defun epa-export-keys (keys file)
1120   "Export selected KEYS to FILE.
1121
1122 Don't use this command in Lisp programs!"
1123   (interactive
1124    (let ((keys (epa--marked-keys))
1125          default-name)
1126      (unless keys
1127        (error "No keys selected"))
1128      (setq default-name
1129            (expand-file-name
1130             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
1131                     (if epa-armor ".asc" ".gpg"))
1132             default-directory))
1133      (list keys
1134            (expand-file-name
1135             (read-file-name
1136              (concat "To file (default "
1137                      (file-name-nondirectory default-name)
1138                      ") ")
1139              (file-name-directory default-name)
1140              default-name)))))
1141   (let ((context (epg-make-context epa-protocol)))
1142     (epg-context-set-armor context epa-armor)
1143     (message "Exporting to %s..." (file-name-nondirectory file))
1144     (epg-export-keys-to-file context keys file)
1145     (message "Exporting to %s...done" (file-name-nondirectory file))))
1146
1147 ;;;###autoload
1148 (defun epa-insert-keys (keys)
1149   "Insert selected KEYS after the point.
1150
1151 Don't use this command in Lisp programs!"
1152   (interactive
1153    (list (epa-select-keys (epg-make-context epa-protocol)
1154                           "Select keys to export.  ")))
1155   (let ((context (epg-make-context epa-protocol)))
1156     ;;(epg-context-set-armor context epa-armor)
1157     (epg-context-set-armor context t)
1158     (insert (epg-export-keys-to-string context keys))))
1159
1160 ;;;###autoload
1161 (defun epa-sign-keys (keys &optional local)
1162   "Sign selected KEYS.
1163 If a prefix-arg is specified, the signature is marked as non exportable.
1164
1165 Don't use this command in Lisp programs!"
1166   (interactive
1167    (let ((keys (epa--marked-keys)))
1168      (unless keys
1169        (error "No keys selected"))
1170      (list keys current-prefix-arg)))
1171   (let ((context (epg-make-context epa-protocol)))
1172     (epg-context-set-passphrase-callback context
1173                                          #'epa-passphrase-callback-function)
1174     (epg-context-set-progress-callback context
1175                                        #'epa-progress-callback-function
1176                                        "Signing keys...")
1177     (message "Signing keys...")
1178     (epg-sign-keys context keys local)
1179     (message "Signing keys...done")))
1180 (make-obsolete 'epa-sign-keys "Do not use.")
1181
1182 (provide 'epa)
1183
1184 ;;; epa.el ends here