epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30
  31 (defgroup epa nil
  32   "The EasyPG Assistant"
  33   :group 'epg)
  34
  35 (defcustom epa-armor nil
  36   "If non-nil, epa commands create ASCII armored output."
  37   :type 'boolean
  38   :group 'epa)
  39
  40 (defcustom epa-textmode nil
  41   "If non-nil, epa commands treat input files as text."
  42   :type 'boolean
  43   :group 'epa)
  44
  45 (defcustom epa-popup-info-window nil
  46   "If non-nil, status information from epa commands is displayed on
  47 the separate window."
  48   :type 'boolean
  49   :group 'epa)
  50
  51 (defcustom epa-info-window-height 5
  52   "Number of lines used to display status information."
  53   :type 'integer
  54   :group 'epa)
  55
  56 (defgroup epa-faces nil
  57   "Faces for epa-mode."
  58   :group 'epa)
  59
  60 (defface epa-validity-high-face
  61   '((((class color) (background dark))
  62      (:foreground "PaleTurquoise" :bold t))
  63     (t
  64      (:bold t)))
  65   "Face used for displaying the high validity."
  66   :group 'epa-faces)
  67 (defvar epa-validity-high-face 'epa-validity-high-face)
  68
  69 (defface epa-validity-medium-face
  70   '((((class color) (background dark))
  71      (:foreground "PaleTurquoise" :italic t))
  72     (t
  73      ()))
  74   "Face used for displaying the medium validity."
  75   :group 'epa-faces)
  76 (defvar epa-validity-medium-face 'epa-validity-medium-face)
  77
  78 (defface epa-validity-low-face
  79   '((t
  80      (:italic t)))
  81   "Face used for displaying the low validity."
  82   :group 'epa-faces)
  83 (defvar epa-validity-low-face 'epa-validity-low-face)
  84
  85 (defface epa-validity-disabled-face
  86   '((t
  87      (:italic t :inverse-video t)))
  88   "Face used for displaying the disabled validity."
  89   :group 'epa-faces)
  90 (defvar epa-validity-disabled-face 'epa-validity-disabled-face)
  91
  92 (defface epa-string-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "lightyellow"))
  96     (((class color)
  97       (background light))
  98      (:foreground "blue4"))
  99     (t
 100      ()))
 101   "Face used for displaying the string."
 102   :group 'epa-faces)
 103 (defvar epa-string-face 'epa-string-face)
 104
 105 (defface epa-mark-face
 106   '((((class color) (background dark))
 107      (:foreground "orange" :bold t))
 108     (t
 109      (:foreground "red" :bold t)))
 110   "Face used for displaying the high validity."
 111   :group 'epa-faces)
 112 (defvar epa-mark-face 'epa-mark-face)
 113
 114 (defface epa-field-name-face
 115   '((((class color) (background dark))
 116      (:foreground "PaleTurquoise" :bold t))
 117     (t (:bold t)))
 118   "Face for the name of the attribute field."
 119   :group 'epa)
 120 (defvar epa-field-name-face 'epa-field-name-face)
 121
 122 (defface epa-field-body-face
 123   '((((class color) (background dark))
 124      (:foreground "turquoise" :italic t))
 125     (t (:italic t)))
 126   "Face for the body of the attribute field."
 127   :group 'epa)
 128 (defvar epa-field-body-face 'epa-field-body-face)
 129
 130 (defcustom epa-validity-face-alist
 131   '((unknown . epa-validity-disabled-face)
 132     (invalid . epa-validity-disabled-face)
 133     (disabled . epa-validity-disabled-face)
 134     (revoked . epa-validity-disabled-face)
 135     (expired . epa-validity-disabled-face)
 136     (none . epa-validity-low-face)
 137     (undefined . epa-validity-low-face)
 138     (never . epa-validity-low-face)
 139     (marginal . epa-validity-medium-face)
 140     (full . epa-validity-high-face)
 141     (ultimate . epa-validity-high-face))
 142   "An alist mapping validity values to faces."
 143   :type 'list
 144   :group 'epa)
 145
 146 (defcustom epa-font-lock-keywords
 147   '(("^\\*"
 148      (0 epa-mark-face))
 149     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 150      (1 epa-field-name-face)
 151      (2 epa-field-body-face)))
 152   "Default expressions to addon in epa-mode."
 153   :type '(repeat (list string))
 154   :group 'epa)
 155
 156 (defconst epa-pubkey-algorithm-letter-alist
 157   '((1 . ?R)
 158     (2 . ?r)
 159     (3 . ?s)
 160     (16 . ?g)
 161     (17 . ?D)
 162     (20 . ?G)))
 163
 164 (defvar epa-keys-buffer nil)
 165 (defvar epa-key-buffer-alist nil)
 166 (defvar epa-key nil)
 167 (defvar epa-list-keys-arguments nil)
 168 (defvar epa-info-buffer nil)
 169
 170 (defvar epa-keys-mode-map
 171   (let ((keymap (make-sparse-keymap)))
 172     (define-key keymap "m" 'epa-mark)
 173     (define-key keymap "u" 'epa-unmark)
 174     (define-key keymap "d" 'epa-decrypt-file)
 175     (define-key keymap "v" 'epa-verify-file)
 176     (define-key keymap "s" 'epa-sign-file)
 177     (define-key keymap "S" 'epa-sign-keys)
 178     (define-key keymap "e" 'epa-encrypt-file)
 179     (define-key keymap "r" 'epa-delete-keys)
 180     (define-key keymap "i" 'epa-import-keys)
 181     (define-key keymap "o" 'epa-export-keys)
 182     (define-key keymap "g" 'epa-list-keys)
 183     (define-key keymap "n" 'next-line)
 184     (define-key keymap "p" 'previous-line)
 185     (define-key keymap " " 'scroll-up)
 186     (define-key keymap [delete] 'scroll-down)
 187     (define-key keymap "q" 'epa-exit-buffer)
 188     keymap))
 189
 190 (defvar epa-key-mode-map
 191   (let ((keymap (make-sparse-keymap)))
 192     (define-key keymap "q" 'bury-buffer)
 193     keymap))
 194
 195 (defvar epa-info-mode-map
 196   (let ((keymap (make-sparse-keymap)))
 197     (define-key keymap "q" 'delete-window)
 198     keymap))
 199
 200 (defvar epa-exit-buffer-function #'bury-buffer)
 201
 202 (define-widget 'epa-key 'push-button
 203   "Button for representing a epg-key object."
 204   :format "%[%v%]"
 205   :button-face-get 'epa--key-widget-button-face-get
 206   :value-create 'epa--key-widget-value-create
 207   :action 'epa--key-widget-action
 208   :help-echo 'epa--key-widget-help-echo)
 209
 210 (defun epa--key-widget-action (widget &optional event)
 211   (epa--show-key (widget-get widget :value)))
 212
 213 (defun epa--key-widget-value-create (widget)
 214   (let* ((key (widget-get widget :value))
 215          (primary-sub-key (car (epg-key-sub-key-list key)))
 216          (primary-user-id (car (epg-key-user-id-list key))))
 217     (insert (format "%c "
 218                     (if (epg-sub-key-validity primary-sub-key)
 219                         (car (rassq (epg-sub-key-validity primary-sub-key)
 220                                     epg-key-validity-alist))
 221                       ? ))
 222             (epg-sub-key-id primary-sub-key)
 223             " "
 224             (if (stringp (epg-user-id-string primary-user-id))
 225                 (epg-user-id-string primary-user-id)
 226               (epg-decode-dn (epg-user-id-string primary-user-id))))))
 227
 228 (defun epa--key-widget-button-face-get (widget)
 229   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 230                                               (widget-get widget :value))))))
 231     (if validity
 232         (cdr (assq validity epa-validity-face-alist))
 233       'default)))
 234
 235 (defun epa--key-widget-help-echo (widget)
 236   (format "Show %s"
 237           (epg-sub-key-id (car (epg-key-sub-key-list
 238                                 (widget-get widget :value))))))
 239
 240 (defun epa-keys-mode ()
 241   "Major mode for `epa-list-keys'."
 242   (kill-all-local-variables)
 243   (buffer-disable-undo)
 244   (setq major-mode 'epa-keys-mode
 245         mode-name "Keys"
 246         truncate-lines t
 247         buffer-read-only t)
 248   (use-local-map epa-keys-mode-map)
 249   (set-keymap-parent (current-local-map) widget-keymap)
 250   (make-local-variable 'font-lock-defaults)
 251   (setq font-lock-defaults '(epa-font-lock-keywords t))
 252   ;; In XEmacs, auto-initialization of font-lock is not effective
 253   ;; if buffer-file-name is not set.
 254   (font-lock-set-defaults)
 255   (widget-setup)
 256   (make-local-variable 'epa-exit-buffer-function)
 257   (run-hooks 'epa-keys-mode-hook))
 258
 259 (defun epa-key-mode ()
 260   "Major mode for a key description."
 261   (kill-all-local-variables)
 262   (buffer-disable-undo)
 263   (setq major-mode 'epa-key-mode
 264         mode-name "Key"
 265         truncate-lines t
 266         buffer-read-only t)
 267   (use-local-map epa-key-mode-map)
 268   (make-local-variable 'font-lock-defaults)
 269   (setq font-lock-defaults '(epa-font-lock-keywords t))
 270   ;; In XEmacs, auto-initialization of font-lock is not effective
 271   ;; if buffer-file-name is not set.
 272   (font-lock-set-defaults)
 273   (make-local-variable 'epa-exit-buffer-function)
 274   (run-hooks 'epa-key-mode-hook))
 275
 276 (defun epa-info-mode ()
 277   "Major mode for `epa-info-buffer'."
 278   (kill-all-local-variables)
 279   (buffer-disable-undo)
 280   (setq major-mode 'epa-info-mode
 281         mode-name "Info"
 282         truncate-lines t
 283         buffer-read-only t)
 284   (use-local-map epa-info-mode-map)
 285   (run-hooks 'epa-info-mode-hook))
 286
 287 (defun epa-mark (&optional arg)
 288   "Mark the current line.
 289 If ARG is non-nil, unmark the current line."
 290   (interactive "P")
 291   (let ((inhibit-read-only t)
 292         buffer-read-only
 293         properties)
 294     (beginning-of-line)
 295     (setq properties (text-properties-at (point)))
 296     (delete-char 1)
 297     (insert (if arg " " "*"))
 298     (set-text-properties (1- (point)) (point) properties)
 299     (forward-line)))
 300
 301 (defun epa-unmark (&optional arg)
 302   "Unmark the current line.
 303 If ARG is non-nil, mark the current line."
 304   (interactive "P")
 305   (epa-mark (not arg)))
 306
 307 (defun epa-toggle-mark ()
 308   "Toggle the mark the current line."
 309   (interactive)
 310   (epa-mark (eq (char-after (save-excursion (beginning-of-line) (point))) ?*)))
 311
 312 (defun epa-exit-buffer ()
 313   "Exit the current buffer.
 314 `epa-exit-buffer-function' is called if it is set."
 315   (interactive)
 316   (funcall epa-exit-buffer-function))
 317
 318 ;;;###autoload
 319 (defun epa-list-keys (&optional name mode protocol)
 320   (interactive
 321    (if current-prefix-arg
 322        (let ((name (read-string "Pattern: "
 323                                 (if epa-list-keys-arguments
 324                                     (car epa-list-keys-arguments)))))
 325          (list (if (equal name "") nil name)
 326                (y-or-n-p "Secret keys? ")
 327                (intern (completing-read "Protocol? "
 328                                         '(("OpenPGP") ("CMS"))
 329                                         nil t))))
 330      (or epa-list-keys-arguments (list nil nil nil))))
 331   (unless (and epa-keys-buffer
 332                (buffer-live-p epa-keys-buffer))
 333     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 334   (set-buffer epa-keys-buffer)
 335   (let ((inhibit-read-only t)
 336         buffer-read-only
 337         (point (point-min))
 338         (context (epg-make-context protocol)))
 339     (unless (get-text-property point 'epa-list-keys)
 340       (setq point (next-single-property-change point 'epa-list-keys)))
 341     (when point
 342       (delete-region point
 343                      (or (next-single-property-change point 'epa-list-keys)
 344                          (point-max)))
 345       (goto-char point))
 346     (epa-insert-keys context name mode)
 347     (epa-keys-mode))
 348   (make-local-variable 'epa-list-keys-arguments)
 349   (setq epa-list-keys-arguments (list name mode protocol))
 350   (goto-char (point-min))
 351   (pop-to-buffer (current-buffer)))
 352
 353 (defun epa-insert-keys (context name mode)
 354   (save-excursion
 355     (save-restriction
 356       (narrow-to-region (point) (point))
 357       (let ((keys (epg-list-keys context name mode))
 358             point)
 359         (while keys
 360           (setq point (point))
 361           (insert "  ")
 362           (add-text-properties point (point)
 363                                (list 'epa-key (car keys)
 364                                      'front-sticky nil
 365                                      'rear-nonsticky t
 366                                      'start-open t
 367                                      'end-open t))
 368           (widget-create 'epa-key :value (car keys))
 369           (insert "\n")
 370           (setq keys (cdr keys))))
 371       (add-text-properties (point-min) (point-max)
 372                            (list 'epa-list-keys t
 373                                  'front-sticky nil
 374                                  'rear-nonsticky t
 375                                  'start-open t
 376                                  'end-open t)))))
 377
 378 (defun epa--marked-keys ()
 379   (or (save-excursion
 380         (set-buffer epa-keys-buffer)
 381         (goto-char (point-min))
 382         (let (keys key)
 383           (while (re-search-forward "^\\*" nil t)
 384             (if (setq key (get-text-property (match-beginning 0)
 385                                              'epa-key))
 386                 (setq keys (cons key keys))))
 387           (nreverse keys)))
 388       (save-excursion
 389         (beginning-of-line)
 390         (let ((key (get-text-property (point) 'epa-key)))
 391           (if key
 392               (list key))))))
 393
 394 ;;;###autoload
 395 (defun epa-select-keys (context prompt &optional names secret)
 396   "Display a user's keyring and ask him to select keys.
 397 CONTEXT is an epg-context.
 398 PROMPT is a string to prompt with.
 399 NAMES is a list of strings to be matched with keys.  If it is nil, all
 400 the keys are listed.
 401 If SECRET is non-nil, list secret keys instead of public keys."
 402   (save-excursion
 403     (unless (and epa-keys-buffer
 404                  (buffer-live-p epa-keys-buffer))
 405       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 406     (let ((inhibit-read-only t)
 407           buffer-read-only)
 408       (set-buffer epa-keys-buffer)
 409       (erase-buffer)
 410       (insert prompt "\n")
 411       (widget-create 'link
 412                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 413                      :help-echo
 414                      (substitute-command-keys
 415                       "Click here or \\[abort-recursive-edit] to cancel")
 416                      "Cancel")
 417       (widget-create 'link
 418                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 419                      :help-echo
 420                      (substitute-command-keys
 421                       "Click here or \\[exit-recursive-edit] to finish")
 422                      "OK")
 423       (insert "\n\n")
 424       (if names
 425           (while names
 426             (epa-insert-keys context (car names) secret)
 427             (if (get-text-property (point) 'epa-list-keys)
 428                 (epa-mark))
 429             (goto-char (point-max))
 430             (setq names (cdr names)))
 431         (if secret
 432             (progn
 433               (epa-insert-keys context nil secret)
 434               (if (get-text-property (point) 'epa-list-keys)
 435                   (epa-mark)))
 436           (epa-insert-keys context nil nil)))
 437       (epa-keys-mode)
 438       (setq epa-exit-buffer-function #'abort-recursive-edit)
 439       (goto-char (point-min))
 440       (pop-to-buffer (current-buffer)))
 441     (unwind-protect
 442         (progn
 443           (recursive-edit)
 444           (epa--marked-keys))
 445       (if (get-buffer-window epa-keys-buffer)
 446           (delete-window (get-buffer-window epa-keys-buffer)))
 447       (kill-buffer epa-keys-buffer))))
 448
 449 (defun epa--show-key (key)
 450   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 451          (entry (assoc (epg-sub-key-id primary-sub-key)
 452                        epa-key-buffer-alist))
 453          (inhibit-read-only t)
 454          buffer-read-only
 455          pointer)
 456     (unless entry
 457       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 458             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 459     (unless (and (cdr entry)
 460                  (buffer-live-p (cdr entry)))
 461       (setcdr entry (generate-new-buffer
 462                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 463     (set-buffer (cdr entry))
 464     (make-local-variable 'epa-key)
 465     (setq epa-key key)
 466     (erase-buffer)
 467     (setq pointer (epg-key-user-id-list key))
 468     (while pointer
 469       (insert " "
 470               (if (epg-user-id-validity (car pointer))
 471                   (char-to-string
 472                    (car (rassq (epg-user-id-validity (car pointer))
 473                                epg-key-validity-alist)))
 474                 " ")
 475               " "
 476               (if (stringp (epg-user-id-string (car pointer)))
 477                   (epg-user-id-string (car pointer))
 478                 (epg-decode-dn (epg-user-id-string (car pointer))))
 479               "\n")
 480       (setq pointer (cdr pointer)))
 481     (setq pointer (epg-key-sub-key-list key))
 482     (while pointer
 483       (insert " "
 484               (if (epg-sub-key-validity (car pointer))
 485                   (char-to-string
 486                    (car (rassq (epg-sub-key-validity (car pointer))
 487                                epg-key-validity-alist)))
 488                 " ")
 489               " "
 490               (epg-sub-key-id (car pointer))
 491               " "
 492               (format "%dbits"
 493                       (epg-sub-key-length (car pointer)))
 494               " "
 495               (cdr (assq (epg-sub-key-algorithm (car pointer))
 496                          epg-pubkey-algorithm-alist))
 497               "\n\tCreated: "
 498               (format-time-string "%Y-%m-%d"
 499                                   (epg-sub-key-creation-time (car pointer)))
 500               (if (epg-sub-key-expiration-time (car pointer))
 501                   (format "\n\tExpires: %s"
 502                           (format-time-string "%Y-%m-%d"
 503                                               (epg-sub-key-expiration-time
 504                                                (car pointer))))
 505                 "")
 506               "\n\tCapabilities: "
 507               (mapconcat #'symbol-name
 508                          (epg-sub-key-capability (car pointer))
 509                          " ")
 510               "\n\tFingerprint: "
 511               (epg-sub-key-fingerprint (car pointer))
 512               "\n")
 513       (setq pointer (cdr pointer)))
 514     (goto-char (point-min))
 515     (pop-to-buffer (current-buffer))
 516     (epa-key-mode)))
 517
 518 (defun epa-display-verify-result (verify-result)
 519   (if epa-popup-info-window
 520       (progn
 521         (unless epa-info-buffer
 522           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 523         (save-excursion
 524           (set-buffer epa-info-buffer)
 525           (let ((inhibit-read-only t)
 526                 buffer-read-only)
 527             (erase-buffer)
 528             (insert (epg-verify-result-to-string verify-result)))
 529           (epa-info-mode))
 530         (pop-to-buffer epa-info-buffer)
 531         (if (> (window-height) epa-info-window-height)
 532             (shrink-window (- (window-height) epa-info-window-height)))
 533         (goto-char (point-min)))
 534     (message "%s" (epg-verify-result-to-string verify-result))))
 535
 536 (defun epa-passphrase-callback-function (context key-id handback)
 537   (if (eq key-id 'SYM)
 538       (read-passwd "Passphrase for symmetric encryption: "
 539                    (eq (epg-context-operation context) 'encrypt))
 540     (read-passwd
 541      (if (eq key-id 'PIN)
 542         "Passphrase for PIN: "
 543        (let ((entry (assoc key-id epg-user-id-alist)))
 544          (if entry
 545              (format "Passphrase for %s %s: " key-id (cdr entry))
 546            (format "Passphrase for %s: " key-id)))))))
 547
 548 (defun epa-progress-callback-function (context what char current total
 549                                                handback)
 550   (message "%s: %d%% (%d/%d)" what
 551            (if (> total 0) (floor (* (/ current (float total)) 100)) 0)
 552            current total))
 553
 554 ;;;###autoload
 555 (defun epa-decrypt-file (file)
 556   "Decrypt FILE."
 557   (interactive "fFile: ")
 558   (let* ((default-name (file-name-sans-extension file))
 559          (plain (expand-file-name
 560                  (read-file-name
 561                   (concat "To file (default "
 562                           (file-name-nondirectory default-name)
 563                           ") ")
 564                   (file-name-directory default-name)
 565                   default-name)))
 566          (context (epg-make-context)))
 567     (epg-context-set-passphrase-callback context
 568                                          #'epa-passphrase-callback-function)
 569     (message "Decrypting %s..." (file-name-nondirectory file))
 570     (epg-decrypt-file context file plain)
 571     (message "Decrypting %s...done" (file-name-nondirectory file))
 572     (if (epg-context-result-for context 'verify)
 573         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 574
 575 ;;;###autoload
 576 (defun epa-verify-file (file)
 577   "Verify FILE."
 578   (interactive "fFile: ")
 579   (let* ((context (epg-make-context))
 580          (plain (if (equal (file-name-extension file) "sig")
 581                     (file-name-sans-extension file))))
 582     (message "Verifying %s..." (file-name-nondirectory file))
 583     (epg-verify-file context file plain)
 584     (message "Verifying %s...done" (file-name-nondirectory file))
 585     (if (epg-context-result-for context 'verify)
 586         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 587
 588 ;;;###autoload
 589 (defun epa-sign-file (file signers mode)
 590   "Sign FILE by SIGNERS keys selected."
 591   (interactive
 592    (list (expand-file-name (read-file-name "File: "))
 593          (epa-select-keys (epg-make-context) "Select keys for signing.
 594 If no one is selected, default secret key is used.  "
 595                           nil t)
 596          (if (y-or-n-p "Make a detached signature? ")
 597              'detached
 598            (if (y-or-n-p "Make a cleartext signature? ")
 599                'clear))))
 600   (let ((signature (concat file
 601                            (if (or epa-armor
 602                                    (not (memq mode '(nil t normal detached))))
 603                                ".asc"
 604                              (if (memq mode '(t detached))
 605                                  ".sig"
 606                                ".gpg"))))
 607         (context (epg-make-context)))
 608     (epg-context-set-armor context epa-armor)
 609     (epg-context-set-textmode context epa-textmode)
 610     (epg-context-set-signers context signers)
 611     (epg-context-set-passphrase-callback context
 612                                          #'epa-passphrase-callback-function)
 613     (message "Signing %s..." (file-name-nondirectory file))
 614     (epg-sign-file context file signature mode)
 615     (message "Signing %s...done" (file-name-nondirectory file))))
 616
 617 ;;;###autoload
 618 (defun epa-encrypt-file (file recipients)
 619   "Encrypt FILE for RECIPIENTS."
 620   (interactive
 621    (list (expand-file-name (read-file-name "File: "))
 622          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 623 If no one is selected, symmetric encryption will be performed.  ")))
 624   (let ((cipher (concat file (if epa-armor ".asc" ".gpg")))
 625         (context (epg-make-context)))
 626     (epg-context-set-armor context epa-armor)
 627     (epg-context-set-textmode context epa-textmode)
 628     (epg-context-set-passphrase-callback context
 629                                          #'epa-passphrase-callback-function)
 630     (message "Encrypting %s..." (file-name-nondirectory file))
 631     (epg-encrypt-file context file recipients cipher)
 632     (message "Encrypting %s...done" (file-name-nondirectory file))))
 633
 634 ;;;###autoload
 635 (defun epa-decrypt-region (start end)
 636   "Decrypt the current region between START and END.
 637
 638 Don't use this command in Lisp programs!"
 639   (interactive "r")
 640   (save-excursion
 641     (let ((context (epg-make-context))
 642           plain)
 643       (epg-context-set-passphrase-callback context
 644                                            #'epa-passphrase-callback-function)
 645       (message "Decrypting...")
 646       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 647       (message "Decrypting...done")
 648       (delete-region start end)
 649       (goto-char start)
 650       (insert (decode-coding-string plain coding-system-for-read))
 651       (if (epg-context-result-for context 'verify)
 652           (epa-display-verify-result (epg-context-result-for context 'verify))))))
 653
 654 ;;;###autoload
 655 (defun epa-decrypt-armor-in-region (start end)
 656   "Decrypt OpenPGP armors in the current region between START and END.
 657
 658 Don't use this command in Lisp programs!"
 659   (interactive "r")
 660   (save-excursion
 661     (save-restriction
 662       (narrow-to-region start end)
 663       (goto-char start)
 664       (let (armor-start armor-end charset coding-system)
 665         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 666           (setq armor-start (match-beginning 0)
 667                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 668                                              nil t))
 669           (unless armor-end
 670             (error "No armor tail"))
 671           (goto-char armor-start)
 672           (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 673               (setq charset (match-string 1)))
 674           (if coding-system-for-read
 675               (setq coding-system coding-system-for-read)
 676             (if charset
 677                 (setq coding-system (intern (downcase charset)))
 678               (setq coding-system 'utf-8)))
 679           (let ((coding-system-for-read coding-system))
 680             (epa-decrypt-region start end)))))))
 681
 682 ;;;###autoload
 683 (defun epa-verify-region (start end)
 684   "Verify the current region between START and END.
 685
 686 Don't use this command in Lisp programs!"
 687   (interactive "r")
 688   (let ((context (epg-make-context)))
 689     (epg-verify-string context
 690                        (encode-coding-string
 691                         (buffer-substring start end)
 692                         coding-system-for-write))
 693     (if (epg-context-result-for context 'verify)
 694         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 695
 696 ;;;###autoload
 697 (defun epa-verify-armor-in-region (start end)
 698   "Verify OpenPGP armors in the current region between START and END.
 699
 700 Don't use this command in Lisp programs!"
 701   (interactive "r")
 702   (save-excursion
 703     (save-restriction
 704       (narrow-to-region start end)
 705       (goto-char start)
 706       (let (armor-start armor-end)
 707         (while (re-search-forward "-----BEGIN PGP\\( SIGNED\\)? MESSAGE-----$"
 708                                   nil t)
 709           (setq armor-start (match-beginning 0))
 710           (if (match-beginning 1)       ;cleartext signed message
 711               (progn
 712                 (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 713                                            nil t)
 714                   (error "Invalid cleartext signed message"))
 715                 (setq armor-end (re-search-forward
 716                                  "^-----END PGP SIGNATURE-----$"
 717                                  nil t)))
 718             (setq armor-end (re-search-forward
 719                              "^-----END PGP MESSAGE-----$"
 720                              nil t)))
 721           (unless armor-end
 722             (error "No armor tail"))
 723           (epa-verify-region armor-start armor-end))))))
 724
 725 ;;;###autoload
 726 (defun epa-sign-region (start end signers mode)
 727   "Sign the current region between START and END by SIGNERS keys selected.
 728
 729 Don't use this command in Lisp programs!"
 730   (interactive
 731    (list (region-beginning) (region-end)
 732          (epa-select-keys (epg-make-context) "Select keys for signing.
 733 If no one is selected, default secret key is used.  "
 734                           nil t)
 735          (if (y-or-n-p "Make a detached signature? ")
 736              'detached
 737            (if (y-or-n-p "Make a cleartext signature? ")
 738                'clear))))
 739   (save-excursion
 740     (let ((context (epg-make-context))
 741           signature)
 742       (epg-context-set-armor context epa-armor)
 743       (epg-context-set-textmode context epa-textmode)
 744       (epg-context-set-signers context signers)
 745       (epg-context-set-passphrase-callback context
 746                                            #'epa-passphrase-callback-function)
 747       (message "Signing...")
 748       (setq signature (epg-sign-string context
 749                                        (encode-coding-string
 750                                         (buffer-substring start end)
 751                                         coding-system-for-write)
 752                                        mode))
 753       (message "Signing...done")
 754       (delete-region start end)
 755       (insert (decode-coding-string signature coding-system-for-read)))))
 756
 757 ;;;###autoload
 758 (defun epa-encrypt-region (start end recipients)
 759   "Encrypt the current region between START and END for RECIPIENTS.
 760
 761 Don't use this command in Lisp programs!"
 762   (interactive
 763    (list (region-beginning) (region-end)
 764          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 765 If no one is selected, symmetric encryption will be performed.  ")))
 766   (save-excursion
 767     (let ((context (epg-make-context))
 768           cipher)
 769       (epg-context-set-armor context epa-armor)
 770       (epg-context-set-textmode context epa-textmode)
 771       (epg-context-set-passphrase-callback context
 772                                            #'epa-passphrase-callback-function)
 773       (message "Encrypting...")
 774       (setq cipher (epg-encrypt-string context
 775                                        (encode-coding-string
 776                                         (buffer-substring start end)
 777                                         coding-system-for-write)
 778                                        recipients))
 779       (message "Encrypting...done")
 780       (delete-region start end)
 781       (insert cipher))))
 782
 783 ;;;###autoload
 784 (defun epa-delete-keys (keys &optional allow-secret)
 785   "Delete selected KEYS."
 786   (interactive
 787    (let ((keys (epa--marked-keys)))
 788      (unless keys
 789        (error "No keys selected"))
 790      (list keys
 791            (eq (nth 1 epa-list-keys-arguments) t))))
 792   (let ((context (epg-make-context)))
 793     (message "Deleting...")
 794     (epg-delete-keys context keys allow-secret)
 795     (message "Deleting...done")
 796     (apply #'epa-list-keys epa-list-keys-arguments)))
 797
 798 ;;;###autoload
 799 (defun epa-import-keys (file)
 800   "Import keys from FILE."
 801   (interactive "fFile: ")
 802   (let ((context (epg-make-context)))
 803     (message "Importing %s..." (file-name-nondirectory file))
 804     (epg-import-keys-from-file context (expand-file-name file))
 805     (message "Importing %s...done" (file-name-nondirectory file))
 806     (apply #'epa-list-keys epa-list-keys-arguments)))
 807
 808 ;;;###autoload
 809 (defun epa-export-keys (keys file)
 810   "Export selected KEYS to FILE."
 811   (interactive
 812    (let ((keys (epa--marked-keys))
 813          default-name)
 814      (unless keys
 815        (error "No keys selected"))
 816      (setq default-name
 817            (expand-file-name
 818             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
 819                     (if epa-armor ".asc" ".gpg"))
 820             default-directory))
 821      (list keys
 822            (expand-file-name
 823             (read-file-name
 824              (concat "To file (default "
 825                      (file-name-nondirectory default-name)
 826                      ") ")
 827              (file-name-directory default-name)
 828              default-name)))))
 829   (let ((context (epg-make-context)))
 830     (epg-context-set-armor context epa-armor)
 831     (message "Exporting to %s..." (file-name-nondirectory file))
 832     (epg-export-keys-to-file context keys file)
 833     (message "Exporting to %s...done" (file-name-nondirectory file))))
 834
 835 ;;;###autoload
 836 (defun epa-sign-keys (keys &optional local)
 837   "Sign selected KEYS.
 838 If LOCAL is non-nil, the signature is marked as non exportable."
 839   (interactive
 840    (let ((keys (epa--marked-keys)))
 841      (unless keys
 842        (error "No keys selected"))
 843      (list keys current-prefix-arg)))
 844   (let ((context (epg-make-context)))
 845     (epg-context-set-passphrase-callback context
 846                                          #'epa-passphrase-callback-function)
 847     (message "Signing keys...")
 848     (epg-sign-keys context keys local)
 849     (message "Signing keys...done")))
 850
 851 (provide 'epa)
 852
 853 ;;; epa.el ends here