epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30
  31 (defgroup epa nil
  32   "The EasyPG Assistant"
  33   :group 'epg)
  34
  35 (defcustom epa-armor nil
  36   "If non-nil, epa commands create ASCII armored output."
  37   :type 'boolean
  38   :group 'epa)
  39
  40 (defcustom epa-textmode nil
  41   "If non-nil, epa commands treat input files as text."
  42   :type 'boolean
  43   :group 'epa)
  44
  45 (defcustom epa-popup-info-window nil
  46   "If non-nil, status information from epa commands is displayed on
  47 the separate window."
  48   :type 'boolean
  49   :group 'epa)
  50
  51 (defcustom epa-info-window-height 5
  52   "Number of lines used to display status information."
  53   :type 'integer
  54   :group 'epa)
  55
  56 (defgroup epa-faces nil
  57   "Faces for epa-mode."
  58   :group 'epa)
  59
  60 (defface epa-validity-high-face
  61   '((((class color) (background dark))
  62      (:foreground "PaleTurquoise" :bold t))
  63     (t
  64      (:bold t)))
  65   "Face used for displaying the high validity."
  66   :group 'epa-faces)
  67 (defvar epa-validity-high-face 'epa-validity-high-face)
  68
  69 (defface epa-validity-medium-face
  70   '((((class color) (background dark))
  71      (:foreground "PaleTurquoise" :italic t))
  72     (t
  73      ()))
  74   "Face used for displaying the medium validity."
  75   :group 'epa-faces)
  76 (defvar epa-validity-medium-face 'epa-validity-medium-face)
  77
  78 (defface epa-validity-low-face
  79   '((t
  80      (:italic t)))
  81   "Face used for displaying the low validity."
  82   :group 'epa-faces)
  83 (defvar epa-validity-low-face 'epa-validity-low-face)
  84
  85 (defface epa-validity-disabled-face
  86   '((t
  87      (:italic t :inverse-video t)))
  88   "Face used for displaying the disabled validity."
  89   :group 'epa-faces)
  90 (defvar epa-validity-disabled-face 'epa-validity-disabled-face)
  91
  92 (defface epa-string-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "lightyellow"))
  96     (((class color)
  97       (background light))
  98      (:foreground "blue4"))
  99     (t
 100      ()))
 101   "Face used for displaying the string."
 102   :group 'epa-faces)
 103 (defvar epa-string-face 'epa-string-face)
 104
 105 (defface epa-mark-face
 106   '((((class color) (background dark))
 107      (:foreground "orange" :bold t))
 108     (t
 109      (:foreground "red" :bold t)))
 110   "Face used for displaying the high validity."
 111   :group 'epa-faces)
 112 (defvar epa-mark-face 'epa-mark-face)
 113
 114 (defface epa-field-name-face
 115   '((((class color) (background dark))
 116      (:foreground "PaleTurquoise" :bold t))
 117     (t (:bold t)))
 118   "Face for the name of the attribute field."
 119   :group 'epa)
 120 (defvar epa-field-name-face 'epa-field-name-face)
 121
 122 (defface epa-field-body-face
 123   '((((class color) (background dark))
 124      (:foreground "turquoise" :italic t))
 125     (t (:italic t)))
 126   "Face for the body of the attribute field."
 127   :group 'epa)
 128 (defvar epa-field-body-face 'epa-field-body-face)
 129
 130 (defcustom epa-validity-face-alist
 131   '((unknown . epa-validity-disabled-face)
 132     (invalid . epa-validity-disabled-face)
 133     (disabled . epa-validity-disabled-face)
 134     (revoked . epa-validity-disabled-face)
 135     (expired . epa-validity-disabled-face)
 136     (none . epa-validity-low-face)
 137     (undefined . epa-validity-low-face)
 138     (never . epa-validity-low-face)
 139     (marginal . epa-validity-medium-face)
 140     (full . epa-validity-high-face)
 141     (ultimate . epa-validity-high-face))
 142   "An alist mapping validity values to faces."
 143   :type 'list
 144   :group 'epa)
 145
 146 (defcustom epa-font-lock-keywords
 147   '(("^\\*"
 148      (0 epa-mark-face))
 149     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 150      (1 epa-field-name-face)
 151      (2 epa-field-body-face)))
 152   "Default expressions to addon in epa-mode."
 153   :type '(repeat (list string))
 154   :group 'epa)
 155
 156 (defconst epa-pubkey-algorithm-letter-alist
 157   '((1 . ?R)
 158     (2 . ?r)
 159     (3 . ?s)
 160     (16 . ?g)
 161     (17 . ?D)
 162     (20 . ?G)))
 163
 164 (defvar epa-keys-buffer nil)
 165 (defvar epa-key-buffer-alist nil)
 166 (defvar epa-key nil)
 167 (defvar epa-list-keys-arguments nil)
 168 (defvar epa-info-buffer nil)
 169
 170 (defvar epa-keys-mode-map
 171   (let ((keymap (make-sparse-keymap)))
 172     (define-key keymap "m" 'epa-mark)
 173     (define-key keymap "u" 'epa-unmark)
 174     (define-key keymap "d" 'epa-decrypt-file)
 175     (define-key keymap "v" 'epa-verify-file)
 176     (define-key keymap "s" 'epa-sign-file)
 177     (define-key keymap "S" 'epa-sign-keys)
 178     (define-key keymap "e" 'epa-encrypt-file)
 179     (define-key keymap "r" 'epa-delete-keys)
 180     (define-key keymap "i" 'epa-import-keys)
 181     (define-key keymap "o" 'epa-export-keys)
 182     (define-key keymap "g" 'epa-list-keys)
 183     (define-key keymap "n" 'next-line)
 184     (define-key keymap "p" 'previous-line)
 185     (define-key keymap " " 'scroll-up)
 186     (define-key keymap [delete] 'scroll-down)
 187     (define-key keymap "q" 'epa-exit-buffer)
 188     keymap))
 189
 190 (defvar epa-key-mode-map
 191   (let ((keymap (make-sparse-keymap)))
 192     (define-key keymap "q" 'bury-buffer)
 193     keymap))
 194
 195 (defvar epa-info-mode-map
 196   (let ((keymap (make-sparse-keymap)))
 197     (define-key keymap "q" 'delete-window)
 198     keymap))
 199
 200 (defvar epa-exit-buffer-function #'bury-buffer)
 201
 202 (define-widget 'epa-key 'push-button
 203   "Button for representing a epg-key object."
 204   :format "%[%v%]"
 205   :button-face-get 'epa-key-widget-button-face-get
 206   :value-create 'epa-key-widget-value-create
 207   :action 'epa-key-widget-action
 208   :help-echo 'epa-key-widget-help-echo)
 209
 210 (defun epa-key-widget-action (widget &optional event)
 211   (epa-show-key (widget-get widget :value)))
 212
 213 (defun epa-key-widget-value-create (widget)
 214   (let* ((key (widget-get widget :value))
 215          (primary-sub-key (car (epg-key-sub-key-list key)))
 216          (primary-user-id (car (epg-key-user-id-list key))))
 217     (insert (format "%c "
 218                     (if (epg-sub-key-validity primary-sub-key)
 219                         (car (rassq (epg-sub-key-validity primary-sub-key)
 220                                     epg-key-validity-alist))
 221                       ? ))
 222             (epg-sub-key-id primary-sub-key)
 223             " "
 224             (if (stringp (epg-user-id-string primary-user-id))
 225                 (epg-user-id-string primary-user-id)
 226               (epg-decode-dn (epg-user-id-string primary-user-id))))))
 227
 228 (defun epa-key-widget-button-face-get (widget)
 229   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 230                                               (widget-get widget :value))))))
 231     (if validity
 232         (cdr (assq validity epa-validity-face-alist))
 233       'default)))
 234
 235 (defun epa-key-widget-help-echo (widget)
 236   (format "Show %s"
 237           (epg-sub-key-id (car (epg-key-sub-key-list
 238                                 (widget-get widget :value))))))
 239
 240 (defun epa-keys-mode ()
 241   "Major mode for `epa-list-keys'."
 242   (kill-all-local-variables)
 243   (buffer-disable-undo)
 244   (setq major-mode 'epa-keys-mode
 245         mode-name "Keys"
 246         truncate-lines t
 247         buffer-read-only t)
 248   (use-local-map epa-keys-mode-map)
 249   (set-keymap-parent (current-local-map) widget-keymap)
 250   (make-local-variable 'font-lock-defaults)
 251   (setq font-lock-defaults '(epa-font-lock-keywords t))
 252   ;; In XEmacs, auto-initialization of font-lock is not effective
 253   ;; if buffer-file-name is not set.
 254   (font-lock-set-defaults)
 255   (widget-setup)
 256   (make-local-variable 'epa-exit-buffer-function)
 257   (run-hooks 'epa-keys-mode-hook))
 258
 259 (defun epa-key-mode ()
 260   "Major mode for `epa-show-key'."
 261   (kill-all-local-variables)
 262   (buffer-disable-undo)
 263   (setq major-mode 'epa-key-mode
 264         mode-name "Key"
 265         truncate-lines t
 266         buffer-read-only t)
 267   (use-local-map epa-key-mode-map)
 268   (make-local-variable 'font-lock-defaults)
 269   (setq font-lock-defaults '(epa-font-lock-keywords t))
 270   ;; In XEmacs, auto-initialization of font-lock is not effective
 271   ;; if buffer-file-name is not set.
 272   (font-lock-set-defaults)
 273   (make-local-variable 'epa-exit-buffer-function)
 274   (run-hooks 'epa-key-mode-hook))
 275
 276 ;;;###autoload
 277 (defun epa-list-keys (&optional name mode protocol)
 278   (interactive
 279    (if current-prefix-arg
 280        (let ((name (read-string "Pattern: "
 281                                 (if epa-list-keys-arguments
 282                                     (car epa-list-keys-arguments)))))
 283          (list (if (equal name "") nil name)
 284                (y-or-n-p "Secret keys? ")
 285                (intern (completing-read "Protocol? "
 286                                         '(("OpenPGP") ("CMS"))
 287                                         nil t))))
 288      (or epa-list-keys-arguments (list nil nil nil))))
 289   (unless (and epa-keys-buffer
 290                (buffer-live-p epa-keys-buffer))
 291     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 292   (set-buffer epa-keys-buffer)
 293   (let ((inhibit-read-only t)
 294         buffer-read-only
 295         (point (point-min))
 296         (context (epg-make-context protocol)))
 297     (unless (get-text-property point 'epa-list-keys)
 298       (setq point (next-single-property-change point 'epa-list-keys)))
 299     (when point
 300       (delete-region point
 301                      (or (next-single-property-change point 'epa-list-keys)
 302                          (point-max)))
 303       (goto-char point))
 304     (epa-insert-keys context name mode)
 305     (epa-keys-mode))
 306   (make-local-variable 'epa-list-keys-arguments)
 307   (setq epa-list-keys-arguments (list name mode protocol))
 308   (goto-char (point-min))
 309   (pop-to-buffer (current-buffer)))
 310
 311 (defun epa-insert-keys (context name mode)
 312   (save-excursion
 313     (save-restriction
 314       (narrow-to-region (point) (point))
 315       (let ((keys (epg-list-keys context name mode))
 316             point)
 317         (while keys
 318           (setq point (point))
 319           (insert "  ")
 320           (add-text-properties point (point)
 321                                (list 'epa-key (car keys)
 322                                      'front-sticky nil
 323                                      'rear-nonsticky t
 324                                      'start-open t
 325                                      'end-open t))
 326           (widget-create 'epa-key :value (car keys))
 327           (insert "\n")
 328           (setq keys (cdr keys))))
 329       (add-text-properties (point-min) (point-max)
 330                            (list 'epa-list-keys t
 331                                  'front-sticky nil
 332                                  'rear-nonsticky t
 333                                  'start-open t
 334                                  'end-open t)))))
 335
 336 (defun epa-marked-keys ()
 337   (or (save-excursion
 338         (set-buffer epa-keys-buffer)
 339         (goto-char (point-min))
 340         (let (keys key)
 341           (while (re-search-forward "^\\*" nil t)
 342             (if (setq key (get-text-property (match-beginning 0)
 343                                              'epa-key))
 344                 (setq keys (cons key keys))))
 345           (nreverse keys)))
 346       (save-excursion
 347         (beginning-of-line)
 348         (let ((key (get-text-property (point) 'epa-key)))
 349           (if key
 350               (list key))))))
 351
 352 ;;;###autoload
 353 (defun epa-select-keys (context prompt &optional names secret)
 354   "Display a user's keyring and ask him to select keys.
 355 CONTEXT is an epg-context.
 356 PROMPT is a string to prompt with.
 357 NAMES is a list of strings to be matched with keys.  If it is nil, all
 358 the keys are listed.
 359 If SECRET is non-nil, list secret keys instead of public keys."
 360   (save-excursion
 361     (unless (and epa-keys-buffer
 362                  (buffer-live-p epa-keys-buffer))
 363       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 364     (let ((inhibit-read-only t)
 365           buffer-read-only
 366           point)
 367       (set-buffer epa-keys-buffer)
 368       (erase-buffer)
 369       (insert prompt "\n")
 370       (widget-create 'link
 371                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 372                      :help-echo
 373                      (substitute-command-keys
 374                       "Click here or \\[abort-recursive-edit] to cancel")
 375                      "Cancel")
 376       (widget-create 'link
 377                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 378                      :help-echo
 379                      (substitute-command-keys
 380                       "Click here or \\[exit-recursive-edit] to finish")
 381                      "OK")
 382       (insert "\n\n")
 383       (if names
 384           (while names
 385             (setq point (point))
 386             (epa-insert-keys context (car names) secret)
 387             (goto-char point)
 388             (epa-mark)
 389             (goto-char (point-max))
 390             (setq names (cdr names)))
 391         (epa-insert-keys context nil secret))
 392       (epa-keys-mode)
 393       (setq epa-exit-buffer-function #'abort-recursive-edit)
 394       (goto-char (point-min))
 395       (pop-to-buffer (current-buffer)))
 396     (unwind-protect
 397           (progn
 398             (recursive-edit)
 399             (epa-marked-keys))
 400         (if (get-buffer-window epa-keys-buffer)
 401             (delete-window (get-buffer-window epa-keys-buffer)))
 402         (kill-buffer epa-keys-buffer))))
 403
 404 (defun epa-show-key (key)
 405   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 406          (entry (assoc (epg-sub-key-id primary-sub-key)
 407                        epa-key-buffer-alist))
 408          (inhibit-read-only t)
 409          buffer-read-only
 410          pointer)
 411     (unless entry
 412       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 413             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 414     (unless (and (cdr entry)
 415                  (buffer-live-p (cdr entry)))
 416       (setcdr entry (generate-new-buffer
 417                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 418     (set-buffer (cdr entry))
 419     (make-local-variable 'epa-key)
 420     (setq epa-key key)
 421     (erase-buffer)
 422     (setq pointer (epg-key-user-id-list key))
 423     (while pointer
 424       (insert " "
 425               (if (epg-user-id-validity (car pointer))
 426                   (char-to-string
 427                    (car (rassq (epg-user-id-validity (car pointer))
 428                                epg-key-validity-alist)))
 429                 " ")
 430               " "
 431               (if (stringp (epg-user-id-string (car pointer)))
 432                   (epg-user-id-string (car pointer))
 433                 (epg-decode-dn (epg-user-id-string (car pointer))))
 434               "\n")
 435       (setq pointer (cdr pointer)))
 436     (setq pointer (epg-key-sub-key-list key))
 437     (while pointer
 438       (insert " "
 439               (if (epg-sub-key-validity (car pointer))
 440                   (char-to-string
 441                    (car (rassq (epg-sub-key-validity (car pointer))
 442                                epg-key-validity-alist)))
 443                 " ")
 444               " "
 445               (epg-sub-key-id (car pointer))
 446               " "
 447               (format "%dbits"
 448                       (epg-sub-key-length (car pointer)))
 449               " "
 450               (cdr (assq (epg-sub-key-algorithm (car pointer))
 451                          epg-pubkey-algorithm-alist))
 452               "\n\tCreated: "
 453               (format-time-string "%Y-%m-%d"
 454                                   (epg-sub-key-creation-time (car pointer)))
 455               (if (epg-sub-key-expiration-time (car pointer))
 456                   (format "\n\tExpires: %s"
 457                           (format-time-string "%Y-%m-%d"
 458                                               (epg-sub-key-expiration-time
 459                                                (car pointer))))
 460                 "")
 461               "\n\tCapabilities: "
 462               (mapconcat #'symbol-name
 463                          (epg-sub-key-capability (car pointer))
 464                          " ")
 465               "\n\tFingerprint: "
 466               (epg-sub-key-fingerprint (car pointer))
 467               "\n")
 468       (setq pointer (cdr pointer)))
 469     (goto-char (point-min))
 470     (pop-to-buffer (current-buffer))
 471     (epa-key-mode)))
 472
 473 (defun epa-show-key-notify (widget &rest ignore)
 474   (epa-show-key (widget-get widget :value)))
 475
 476 (defun epa-mark (&optional arg)
 477   "Mark the current line.
 478 If ARG is non-nil, unmark the current line."
 479   (interactive "P")
 480   (let ((inhibit-read-only t)
 481         buffer-read-only
 482         properties)
 483     (beginning-of-line)
 484     (setq properties (text-properties-at (point)))
 485     (delete-char 1)
 486     (insert (if arg " " "*"))
 487     (set-text-properties (1- (point)) (point) properties)
 488     (forward-line)))
 489
 490 (defun epa-unmark (&optional arg)
 491   "Unmark the current line.
 492 If ARG is non-nil, mark the current line."
 493   (interactive "P")
 494   (epa-mark (not arg)))
 495
 496 (defun epa-exit-buffer ()
 497   "Exit the current buffer.
 498 `epa-exit-buffer-function' is called if it is set."
 499   (interactive)
 500   (funcall epa-exit-buffer-function))
 501
 502 (defun epa-display-verify-result (verify-result)
 503   (if epa-popup-info-window
 504       (progn
 505         (unless epa-info-buffer
 506           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 507         (save-excursion
 508           (set-buffer epa-info-buffer)
 509           (let ((inhibit-read-only t)
 510                 buffer-read-only)
 511             (erase-buffer)
 512             (insert (epg-verify-result-to-string verify-result)))
 513           (epa-info-mode))
 514         (pop-to-buffer epa-info-buffer)
 515         (if (> (window-height) epa-info-window-height)
 516             (shrink-window (- (window-height) epa-info-window-height)))
 517         (goto-char (point-min)))
 518     (message "%s" (epg-verify-result-to-string verify-result))))
 519
 520 (defun epa-info-mode ()
 521   "Major mode for `epa-info-buffer'."
 522   (kill-all-local-variables)
 523   (buffer-disable-undo)
 524   (setq major-mode 'epa-info-mode
 525         mode-name "Info"
 526         truncate-lines t
 527         buffer-read-only t)
 528   (use-local-map epa-info-mode-map)
 529   (run-hooks 'epa-info-mode-hook))
 530
 531 ;;;###autoload
 532 (defun epa-decrypt-file (file)
 533   "Decrypt FILE."
 534   (interactive "fFile: ")
 535   (let* ((default-name (file-name-sans-extension file))
 536          (plain (expand-file-name
 537                  (read-file-name
 538                   (concat "To file (default "
 539                           (file-name-nondirectory default-name)
 540                           ") ")
 541                   (file-name-directory default-name)
 542                   default-name)))
 543          (context (epg-make-context)))
 544     (message "Decrypting %s..." (file-name-nondirectory file))
 545     (epg-decrypt-file context file plain)
 546     (message "Decrypting %s...done" (file-name-nondirectory file))
 547     (if (epg-context-result-for context 'verify)
 548         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 549
 550 ;;;###autoload
 551 (defun epa-verify-file (file)
 552   "Verify FILE."
 553   (interactive "fFile: ")
 554   (let* ((context (epg-make-context))
 555          (plain (if (equal (file-name-extension file) "sig")
 556                     (file-name-sans-extension file))))
 557     (message "Verifying %s..." (file-name-nondirectory file))
 558     (epg-verify-file context file plain)
 559     (message "Verifying %s...done" (file-name-nondirectory file))
 560     (if (epg-context-result-for context 'verify)
 561         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 562
 563 ;;;###autoload
 564 (defun epa-sign-file (file signers mode)
 565   "Sign FILE by SIGNERS keys selected."
 566   (interactive
 567    (list (expand-file-name (read-file-name "File: "))
 568          (epa-select-keys (epg-make-context) "Select keys for signing.
 569 If no one is selected, default secret key is used.  "
 570                           nil t)
 571          (if (y-or-n-p "Make a detached signature? ")
 572              'detached
 573            (if (y-or-n-p "Make a cleartext signature? ")
 574                'clear))))
 575   (let ((signature (concat file
 576                            (if (or epa-armor
 577                                    (not (memq mode '(nil t normal detached))))
 578                                ".asc"
 579                              (if (memq mode '(t detached))
 580                                  ".sig"
 581                                ".gpg"))))
 582         (context (epg-make-context)))
 583     (epg-context-set-armor context epa-armor)
 584     (epg-context-set-textmode context epa-textmode)
 585     (epg-context-set-signers context signers)
 586     (message "Signing %s..." (file-name-nondirectory file))
 587     (epg-sign-file context file signature mode)
 588     (message "Signing %s...done" (file-name-nondirectory file))))
 589
 590 ;;;###autoload
 591 (defun epa-encrypt-file (file recipients)
 592   "Encrypt FILE for RECIPIENTS."
 593   (interactive
 594    (list (expand-file-name (read-file-name "File: "))
 595          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 596 If no one is selected, symmetric encryption will be performed.  ")))
 597   (let ((cipher (concat file (if epa-armor ".asc" ".gpg")))
 598         (context (epg-make-context)))
 599     (epg-context-set-armor context epa-armor)
 600     (epg-context-set-textmode context epa-textmode)
 601     (message "Encrypting %s..." (file-name-nondirectory file))
 602     (epg-encrypt-file context file recipients cipher)
 603     (message "Encrypting %s...done" (file-name-nondirectory file))))
 604
 605 ;;;###autoload
 606 (defun epa-decrypt-region (start end)
 607   "Decrypt the current region between START and END.
 608
 609 Don't use this command in Lisp programs!"
 610   (interactive "r")
 611   (save-excursion
 612     (let ((context (epg-make-context))
 613           plain)
 614       (message "Decrypting...")
 615       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 616       (message "Decrypting...done")
 617       (delete-region start end)
 618       (goto-char start)
 619       (insert (decode-coding-string plain coding-system-for-read))
 620       (if (epg-context-result-for context 'verify)
 621           (epa-display-verify-result (epg-context-result-for context 'verify))))))
 622
 623 ;;;###autoload
 624 (defun epa-decrypt-armor-in-region (start end)
 625   "Decrypt OpenPGP armors in the current region between START and END.
 626
 627 Don't use this command in Lisp programs!"
 628   (interactive "r")
 629   (save-excursion
 630     (save-restriction
 631       (narrow-to-region start end)
 632       (goto-char start)
 633       (let (armor-start armor-end charset coding-system)
 634         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 635           (setq armor-start (match-beginning 0)
 636                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 637                                              nil t))
 638           (unless armor-end
 639             (error "No armor tail"))
 640           (goto-char armor-start)
 641           (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 642               (setq charset (match-string 1)))
 643           (if coding-system-for-read
 644               (setq coding-system coding-system-for-read)
 645             (if charset
 646                 (setq coding-system (intern (downcase charset)))
 647               (setq coding-system 'utf-8)))
 648           (let ((coding-system-for-read coding-system))
 649             (epa-decrypt-region start end)))))))
 650
 651 ;;;###autoload
 652 (defun epa-verify-region (start end)
 653   "Verify the current region between START and END.
 654
 655 Don't use this command in Lisp programs!"
 656   (interactive "r")
 657   (let ((context (epg-make-context)))
 658     (epg-verify-string context
 659                        (encode-coding-string
 660                         (buffer-substring start end)
 661                         coding-system-for-write))
 662     (if (epg-context-result-for context 'verify)
 663         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 664
 665 ;;;###autoload
 666 (defun epa-verify-armor-in-region (start end)
 667   "Verify OpenPGP armors in the current region between START and END.
 668
 669 Don't use this command in Lisp programs!"
 670   (interactive "r")
 671   (save-excursion
 672     (save-restriction
 673       (narrow-to-region start end)
 674       (goto-char start)
 675       (let (armor-start armor-end)
 676         (while (re-search-forward "-----BEGIN PGP\\( SIGNED\\)? MESSAGE-----$"
 677                                   nil t)
 678           (setq armor-start (match-beginning 0))
 679           (if (match-beginning 1)       ;cleartext signed message
 680               (progn
 681                 (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 682                                            nil t)
 683                   (error "Invalid cleartext signed message"))
 684                 (setq armor-end (re-search-forward
 685                                  "^-----END PGP SIGNATURE-----$"
 686                                  nil t)))
 687             (setq armor-end (re-search-forward
 688                              "^-----END PGP MESSAGE-----$"
 689                              nil t)))
 690           (unless armor-end
 691             (error "No armor tail"))
 692           (epa-verify-region armor-start armor-end))))))
 693
 694 ;;;###autoload
 695 (defun epa-sign-region (start end signers mode)
 696   "Sign the current region between START and END by SIGNERS keys selected.
 697
 698 Don't use this command in Lisp programs!"
 699   (interactive
 700    (list (region-beginning) (region-end)
 701          (epa-select-keys (epg-make-context) "Select keys for signing.
 702 If no one is selected, default secret key is used.  "
 703                           nil t)
 704          (if (y-or-n-p "Make a detached signature? ")
 705              'detached
 706            (if (y-or-n-p "Make a cleartext signature? ")
 707                'clear))))
 708   (save-excursion
 709     (let ((context (epg-make-context))
 710           signature)
 711       (epg-context-set-armor context epa-armor)
 712       (epg-context-set-textmode context epa-textmode)
 713       (epg-context-set-signers context signers)
 714       (message "Signing...")
 715       (setq signature (epg-sign-string context
 716                                        (encode-coding-string
 717                                         (buffer-substring start end)
 718                                         coding-system-for-write)
 719                                        mode))
 720       (message "Signing...done")
 721       (delete-region start end)
 722       (insert (decode-coding-string signature coding-system-for-read)))))
 723
 724 ;;;###autoload
 725 (defun epa-encrypt-region (start end recipients)
 726   "Encrypt the current region between START and END for RECIPIENTS.
 727
 728 Don't use this command in Lisp programs!"
 729   (interactive
 730    (list (region-beginning) (region-end)
 731          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 732 If no one is selected, symmetric encryption will be performed.  ")))
 733   (save-excursion
 734     (let ((context (epg-make-context))
 735           cipher)
 736       (epg-context-set-armor context epa-armor)
 737       (epg-context-set-textmode context epa-textmode)
 738       (message "Encrypting...")
 739       (setq cipher (epg-encrypt-string context
 740                                        (encode-coding-string
 741                                         (buffer-substring start end)
 742                                         coding-system-for-write)
 743                                        recipients))
 744       (message "Encrypting...done")
 745       (delete-region start end)
 746       (insert cipher))))
 747
 748 ;;;###autoload
 749 (defun epa-delete-keys (keys &optional allow-secret)
 750   "Delete selected KEYS."
 751   (interactive
 752    (let ((keys (epa-marked-keys)))
 753      (unless keys
 754        (error "No keys selected"))
 755      (list keys
 756            (eq (nth 1 epa-list-keys-arguments) t))))
 757   (let ((context (epg-make-context)))
 758     (message "Deleting...")
 759     (epg-delete-keys context keys allow-secret)
 760     (message "Deleting...done")
 761     (apply #'epa-list-keys epa-list-keys-arguments)))
 762
 763 ;;;###autoload
 764 (defun epa-import-keys (file)
 765   "Import keys from FILE."
 766   (interactive "fFile: ")
 767   (let ((context (epg-make-context)))
 768     (message "Importing %s..." (file-name-nondirectory file))
 769     (epg-import-keys-from-file context (expand-file-name file))
 770     (message "Importing %s...done" (file-name-nondirectory file))
 771     (apply #'epa-list-keys epa-list-keys-arguments)))
 772
 773 ;;;###autoload
 774 (defun epa-export-keys (keys file)
 775   "Export selected KEYS to FILE."
 776   (interactive
 777    (let ((keys (epa-marked-keys))
 778          default-name)
 779      (unless keys
 780        (error "No keys selected"))
 781      (setq default-name
 782            (expand-file-name
 783             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
 784                     (if epa-armor ".asc" ".gpg"))
 785             default-directory))
 786      (list keys
 787            (expand-file-name
 788             (read-file-name
 789              (concat "To file (default "
 790                      (file-name-nondirectory default-name)
 791                      ") ")
 792              (file-name-directory default-name)
 793              default-name)))))
 794   (let ((context (epg-make-context)))
 795     (epg-context-set-armor context epa-armor)
 796     (message "Exporting to %s..." (file-name-nondirectory file))
 797     (epg-export-keys-to-file context keys file)
 798     (message "Exporting to %s...done" (file-name-nondirectory file))))
 799
 800 ;;;###autoload
 801 (defun epa-sign-keys (keys &optional local)
 802   "Sign selected KEYS.
 803 If LOCAL is non-nil, the signature is marked as non exportable."
 804   (interactive
 805    (let ((keys (epa-marked-keys)))
 806      (unless keys
 807        (error "No keys selected"))
 808      (list keys current-prefix-arg)))
 809   (let ((context (epg-make-context)))
 810     (message "Signing keys...")
 811     (epg-sign-keys context keys local)
 812     (message "Signing keys...done")))
 813
 814 (provide 'epa)
 815
 816 ;;; epa.el ends here