epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30
  31 (defgroup epa nil
  32   "The EasyPG Assistant"
  33   :group 'epg)
  34
  35 (defcustom epa-armor nil
  36   "If non-nil, epa commands create ASCII armored output."
  37   :type 'boolean
  38   :group 'epa)
  39
  40 (defcustom epa-textmode nil
  41   "If non-nil, epa commands treat input files as text."
  42   :type 'boolean
  43   :group 'epa)
  44
  45 (defcustom epa-popup-info-window t
  46   "If non-nil, status information from epa commands is displayed on
  47 the separate window."
  48   :type 'boolean
  49   :group 'epa)
  50
  51 (defcustom epa-info-window-height 5
  52   "Number of lines used to display status information."
  53   :type 'integer
  54   :group 'epa)
  55
  56 (defgroup epa-faces nil
  57   "Faces for epa-mode."
  58   :group 'epa)
  59
  60 (defface epa-validity-high-face
  61   '((((class color) (background dark))
  62      (:foreground "PaleTurquoise" :bold t))
  63     (t
  64      (:bold t)))
  65   "Face used for displaying the high validity."
  66   :group 'epa-faces)
  67 (defvar epa-validity-high-face 'epa-validity-high-face)
  68
  69 (defface epa-validity-medium-face
  70   '((((class color) (background dark))
  71      (:foreground "PaleTurquoise" :italic t))
  72     (t
  73      ()))
  74   "Face used for displaying the medium validity."
  75   :group 'epa-faces)
  76 (defvar epa-validity-medium-face 'epa-validity-medium-face)
  77
  78 (defface epa-validity-low-face
  79   '((t
  80      (:italic t)))
  81   "Face used for displaying the low validity."
  82   :group 'epa-faces)
  83 (defvar epa-validity-low-face 'epa-validity-low-face)
  84
  85 (defface epa-validity-disabled-face
  86   '((t
  87      (:italic t :inverse-video t)))
  88   "Face used for displaying the disabled validity."
  89   :group 'epa-faces)
  90 (defvar epa-validity-disabled-face 'epa-validity-disabled-face)
  91
  92 (defface epa-string-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "lightyellow"))
  96     (((class color)
  97       (background light))
  98      (:foreground "blue4"))
  99     (t
 100      ()))
 101   "Face used for displaying the string."
 102   :group 'epa-faces)
 103 (defvar epa-string-face 'epa-string-face)
 104
 105 (defface epa-mark-face
 106   '((((class color) (background dark))
 107      (:foreground "orange" :bold t))
 108     (t
 109      (:foreground "red" :bold t)))
 110   "Face used for displaying the high validity."
 111   :group 'epa-faces)
 112 (defvar epa-mark-face 'epa-mark-face)
 113
 114 (defface epa-field-name-face
 115   '((((class color) (background dark))
 116      (:foreground "PaleTurquoise" :bold t))
 117     (t (:bold t)))
 118   "Face for the name of the attribute field."
 119   :group 'epa)
 120 (defvar epa-field-name-face 'epa-field-name-face)
 121
 122 (defface epa-field-body-face
 123   '((((class color) (background dark))
 124      (:foreground "turquoise" :italic t))
 125     (t (:italic t)))
 126   "Face for the body of the attribute field."
 127   :group 'epa)
 128 (defvar epa-field-body-face 'epa-field-body-face)
 129
 130 (defcustom epa-validity-face-alist
 131   '((unknown . epa-validity-disabled-face)
 132     (invalid . epa-validity-disabled-face)
 133     (disabled . epa-validity-disabled-face)
 134     (revoked . epa-validity-disabled-face)
 135     (expired . epa-validity-disabled-face)
 136     (none . epa-validity-low-face)
 137     (undefined . epa-validity-low-face)
 138     (never . epa-validity-low-face)
 139     (marginal . epa-validity-medium-face)
 140     (full . epa-validity-high-face)
 141     (ultimate . epa-validity-high-face))
 142   "An alist mapping validity values to faces."
 143   :type 'list
 144   :group 'epa)
 145
 146 (defcustom epa-font-lock-keywords
 147   '(("^\\*"
 148      (0 epa-mark-face))
 149     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 150      (1 epa-field-name-face)
 151      (2 epa-field-body-face)))
 152   "Default expressions to addon in epa-mode."
 153   :type '(repeat (list string))
 154   :group 'epa)
 155
 156 (defconst epa-pubkey-algorithm-letter-alist
 157   '((1 . ?R)
 158     (2 . ?r)
 159     (3 . ?s)
 160     (16 . ?g)
 161     (17 . ?D)
 162     (20 . ?G)))
 163
 164 (defvar epa-keys-buffer nil)
 165 (defvar epa-key-buffer-alist nil)
 166 (defvar epa-key nil)
 167 (defvar epa-list-keys-arguments nil)
 168 (defvar epa-info-buffer nil)
 169
 170 (defvar epa-keys-mode-map
 171   (let ((keymap (make-sparse-keymap)))
 172     (define-key keymap "m" 'epa-mark)
 173     (define-key keymap "u" 'epa-unmark)
 174     (define-key keymap "d" 'epa-decrypt-file)
 175     (define-key keymap "v" 'epa-verify-file)
 176     (define-key keymap "s" 'epa-sign-file)
 177     (define-key keymap "e" 'epa-encrypt-file)
 178     (define-key keymap "r" 'epa-delete-keys)
 179     (define-key keymap "i" 'epa-import-keys)
 180     (define-key keymap "o" 'epa-export-keys)
 181     (define-key keymap "g" 'epa-list-keys)
 182     (define-key keymap "n" 'next-line)
 183     (define-key keymap "p" 'previous-line)
 184     (define-key keymap " " 'scroll-up)
 185     (define-key keymap [delete] 'scroll-down)
 186     (define-key keymap "q" 'epa-exit-buffer)
 187     keymap))
 188
 189 (defvar epa-key-mode-map
 190   (let ((keymap (make-sparse-keymap)))
 191     (define-key keymap "q" 'bury-buffer)
 192     keymap))
 193
 194 (defvar epa-info-mode-map
 195   (let ((keymap (make-sparse-keymap)))
 196     (define-key keymap "q" 'delete-window)
 197     keymap))
 198
 199 (defvar epa-exit-buffer-function #'bury-buffer)
 200
 201 (define-widget 'epa-key 'push-button
 202   "Button for representing a epg-key object."
 203   :format "%[%v%]"
 204   :button-face-get 'epa--key-widget-button-face-get
 205   :value-create 'epa--key-widget-value-create
 206   :action 'epa--key-widget-action
 207   :help-echo 'epa--key-widget-help-echo)
 208
 209 (defun epa--key-widget-action (widget &optional event)
 210   (epa--show-key (widget-get widget :value)))
 211
 212 (defun epa--key-widget-value-create (widget)
 213   (let* ((key (widget-get widget :value))
 214          (primary-sub-key (car (epg-key-sub-key-list key)))
 215          (primary-user-id (car (epg-key-user-id-list key))))
 216     (insert (format "%c "
 217                     (if (epg-sub-key-validity primary-sub-key)
 218                         (car (rassq (epg-sub-key-validity primary-sub-key)
 219                                     epg-key-validity-alist))
 220                       ? ))
 221             (epg-sub-key-id primary-sub-key)
 222             " "
 223             (if primary-user-id
 224                 (if (stringp (epg-user-id-string primary-user-id))
 225                     (epg-user-id-string primary-user-id)
 226                   (epg-decode-dn (epg-user-id-string primary-user-id)))
 227               ""))))
 228
 229 (defun epa--key-widget-button-face-get (widget)
 230   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 231                                               (widget-get widget :value))))))
 232     (if validity
 233         (cdr (assq validity epa-validity-face-alist))
 234       'default)))
 235
 236 (defun epa--key-widget-help-echo (widget)
 237   (format "Show %s"
 238           (epg-sub-key-id (car (epg-key-sub-key-list
 239                                 (widget-get widget :value))))))
 240
 241 (defun epa-keys-mode ()
 242   "Major mode for `epa-list-keys'."
 243   (kill-all-local-variables)
 244   (buffer-disable-undo)
 245   (setq major-mode 'epa-keys-mode
 246         mode-name "Keys"
 247         truncate-lines t
 248         buffer-read-only t)
 249   (use-local-map epa-keys-mode-map)
 250   (set-keymap-parent (current-local-map) widget-keymap)
 251   (make-local-variable 'font-lock-defaults)
 252   (setq font-lock-defaults '(epa-font-lock-keywords t))
 253   ;; In XEmacs, auto-initialization of font-lock is not effective
 254   ;; if buffer-file-name is not set.
 255   (font-lock-set-defaults)
 256   (widget-setup)
 257   (make-local-variable 'epa-exit-buffer-function)
 258   (run-hooks 'epa-keys-mode-hook))
 259
 260 (defun epa-key-mode ()
 261   "Major mode for a key description."
 262   (kill-all-local-variables)
 263   (buffer-disable-undo)
 264   (setq major-mode 'epa-key-mode
 265         mode-name "Key"
 266         truncate-lines t
 267         buffer-read-only t)
 268   (use-local-map epa-key-mode-map)
 269   (make-local-variable 'font-lock-defaults)
 270   (setq font-lock-defaults '(epa-font-lock-keywords t))
 271   ;; In XEmacs, auto-initialization of font-lock is not effective
 272   ;; if buffer-file-name is not set.
 273   (font-lock-set-defaults)
 274   (make-local-variable 'epa-exit-buffer-function)
 275   (run-hooks 'epa-key-mode-hook))
 276
 277 (defun epa-info-mode ()
 278   "Major mode for `epa-info-buffer'."
 279   (kill-all-local-variables)
 280   (buffer-disable-undo)
 281   (setq major-mode 'epa-info-mode
 282         mode-name "Info"
 283         truncate-lines t
 284         buffer-read-only t)
 285   (use-local-map epa-info-mode-map)
 286   (run-hooks 'epa-info-mode-hook))
 287
 288 (defun epa-mark (&optional arg)
 289   "Mark the current line.
 290 If ARG is non-nil, unmark the current line."
 291   (interactive "P")
 292   (let ((inhibit-read-only t)
 293         buffer-read-only
 294         properties)
 295     (beginning-of-line)
 296     (setq properties (text-properties-at (point)))
 297     (delete-char 1)
 298     (insert (if arg " " "*"))
 299     (set-text-properties (1- (point)) (point) properties)
 300     (forward-line)))
 301
 302 (defun epa-unmark (&optional arg)
 303   "Unmark the current line.
 304 If ARG is non-nil, mark the current line."
 305   (interactive "P")
 306   (epa-mark (not arg)))
 307
 308 (defun epa-toggle-mark ()
 309   "Toggle the mark the current line."
 310   (interactive)
 311   (epa-mark (eq (char-after (save-excursion (beginning-of-line) (point))) ?*)))
 312
 313 (defun epa-exit-buffer ()
 314   "Exit the current buffer.
 315 `epa-exit-buffer-function' is called if it is set."
 316   (interactive)
 317   (funcall epa-exit-buffer-function))
 318
 319 ;;;###autoload
 320 (defun epa-list-keys (&optional name mode protocol)
 321   (interactive
 322    (if current-prefix-arg
 323        (let ((name (read-string "Pattern: "
 324                                 (if epa-list-keys-arguments
 325                                     (car epa-list-keys-arguments)))))
 326          (list (if (equal name "") nil name)
 327                (y-or-n-p "Secret keys? ")
 328                (intern (completing-read "Protocol? "
 329                                         '(("OpenPGP") ("CMS"))
 330                                         nil t))))
 331      (or epa-list-keys-arguments (list nil nil nil))))
 332   (unless (and epa-keys-buffer
 333                (buffer-live-p epa-keys-buffer))
 334     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 335   (set-buffer epa-keys-buffer)
 336   (let ((inhibit-read-only t)
 337         buffer-read-only
 338         (point (point-min))
 339         (context (epg-make-context protocol)))
 340     (unless (get-text-property point 'epa-list-keys)
 341       (setq point (next-single-property-change point 'epa-list-keys)))
 342     (when point
 343       (delete-region point
 344                      (or (next-single-property-change point 'epa-list-keys)
 345                          (point-max)))
 346       (goto-char point))
 347     (epa-insert-keys context name mode)
 348     (epa-keys-mode))
 349   (make-local-variable 'epa-list-keys-arguments)
 350   (setq epa-list-keys-arguments (list name mode protocol))
 351   (goto-char (point-min))
 352   (pop-to-buffer (current-buffer)))
 353
 354 (defun epa-insert-keys (context name mode)
 355   (save-excursion
 356     (save-restriction
 357       (narrow-to-region (point) (point))
 358       (let ((keys (epg-list-keys context name mode))
 359             point)
 360         (while keys
 361           (setq point (point))
 362           (insert "  ")
 363           (add-text-properties point (point)
 364                                (list 'epa-key (car keys)
 365                                      'front-sticky nil
 366                                      'rear-nonsticky t
 367                                      'start-open t
 368                                      'end-open t))
 369           (widget-create 'epa-key :value (car keys))
 370           (insert "\n")
 371           (setq keys (cdr keys))))
 372       (add-text-properties (point-min) (point-max)
 373                            (list 'epa-list-keys t
 374                                  'front-sticky nil
 375                                  'rear-nonsticky t
 376                                  'start-open t
 377                                  'end-open t)))))
 378
 379 (defun epa--marked-keys ()
 380   (or (save-excursion
 381         (set-buffer epa-keys-buffer)
 382         (goto-char (point-min))
 383         (let (keys key)
 384           (while (re-search-forward "^\\*" nil t)
 385             (if (setq key (get-text-property (match-beginning 0)
 386                                              'epa-key))
 387                 (setq keys (cons key keys))))
 388           (nreverse keys)))
 389       (save-excursion
 390         (beginning-of-line)
 391         (let ((key (get-text-property (point) 'epa-key)))
 392           (if key
 393               (list key))))))
 394
 395 ;;;###autoload
 396 (defun epa-select-keys (context prompt &optional names secret)
 397   "Display a user's keyring and ask him to select keys.
 398 CONTEXT is an epg-context.
 399 PROMPT is a string to prompt with.
 400 NAMES is a list of strings to be matched with keys.  If it is nil, all
 401 the keys are listed.
 402 If SECRET is non-nil, list secret keys instead of public keys."
 403   (save-excursion
 404     (unless (and epa-keys-buffer
 405                  (buffer-live-p epa-keys-buffer))
 406       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 407     (let ((inhibit-read-only t)
 408           buffer-read-only)
 409       (set-buffer epa-keys-buffer)
 410       (erase-buffer)
 411       (insert prompt "\n")
 412       (widget-create 'link
 413                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 414                      :help-echo
 415                      (substitute-command-keys
 416                       "Click here or \\[abort-recursive-edit] to cancel")
 417                      "Cancel")
 418       (widget-create 'link
 419                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 420                      :help-echo
 421                      (substitute-command-keys
 422                       "Click here or \\[exit-recursive-edit] to finish")
 423                      "OK")
 424       (insert "\n\n")
 425       (if names
 426           (while names
 427             (epa-insert-keys context (car names) secret)
 428             (if (get-text-property (point) 'epa-list-keys)
 429                 (epa-mark))
 430             (goto-char (point-max))
 431             (setq names (cdr names)))
 432         (if secret
 433             (progn
 434               (epa-insert-keys context nil secret)
 435               (if (get-text-property (point) 'epa-list-keys)
 436                   (epa-mark)))
 437           (epa-insert-keys context nil nil)))
 438       (epa-keys-mode)
 439       (setq epa-exit-buffer-function #'abort-recursive-edit)
 440       (goto-char (point-min))
 441       (pop-to-buffer (current-buffer)))
 442     (unwind-protect
 443         (progn
 444           (recursive-edit)
 445           (epa--marked-keys))
 446       (if (get-buffer-window epa-keys-buffer)
 447           (delete-window (get-buffer-window epa-keys-buffer)))
 448       (kill-buffer epa-keys-buffer))))
 449
 450 (defun epa--show-key (key)
 451   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 452          (entry (assoc (epg-sub-key-id primary-sub-key)
 453                        epa-key-buffer-alist))
 454          (inhibit-read-only t)
 455          buffer-read-only
 456          pointer)
 457     (unless entry
 458       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 459             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 460     (unless (and (cdr entry)
 461                  (buffer-live-p (cdr entry)))
 462       (setcdr entry (generate-new-buffer
 463                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 464     (set-buffer (cdr entry))
 465     (make-local-variable 'epa-key)
 466     (setq epa-key key)
 467     (erase-buffer)
 468     (setq pointer (epg-key-user-id-list key))
 469     (while pointer
 470       (if (car pointer)
 471           (insert " "
 472                   (if (epg-user-id-validity (car pointer))
 473                       (char-to-string
 474                        (car (rassq (epg-user-id-validity (car pointer))
 475                                    epg-key-validity-alist)))
 476                     " ")
 477                   " "
 478                   (if (stringp (epg-user-id-string (car pointer)))
 479                       (epg-user-id-string (car pointer))
 480                     (epg-decode-dn (epg-user-id-string (car pointer))))
 481                   "\n"))
 482       (setq pointer (cdr pointer)))
 483     (setq pointer (epg-key-sub-key-list key))
 484     (while pointer
 485       (insert " "
 486               (if (epg-sub-key-validity (car pointer))
 487                   (char-to-string
 488                    (car (rassq (epg-sub-key-validity (car pointer))
 489                                epg-key-validity-alist)))
 490                 " ")
 491               " "
 492               (epg-sub-key-id (car pointer))
 493               " "
 494               (format "%dbits"
 495                       (epg-sub-key-length (car pointer)))
 496               " "
 497               (cdr (assq (epg-sub-key-algorithm (car pointer))
 498                          epg-pubkey-algorithm-alist))
 499               "\n\tCreated: "
 500               (format-time-string "%Y-%m-%d"
 501                                   (epg-sub-key-creation-time (car pointer)))
 502               (if (epg-sub-key-expiration-time (car pointer))
 503                   (format "\n\tExpires: %s"
 504                           (format-time-string "%Y-%m-%d"
 505                                               (epg-sub-key-expiration-time
 506                                                (car pointer))))
 507                 "")
 508               "\n\tCapabilities: "
 509               (mapconcat #'symbol-name
 510                          (epg-sub-key-capability (car pointer))
 511                          " ")
 512               "\n\tFingerprint: "
 513               (epg-sub-key-fingerprint (car pointer))
 514               "\n")
 515       (setq pointer (cdr pointer)))
 516     (goto-char (point-min))
 517     (pop-to-buffer (current-buffer))
 518     (epa-key-mode)))
 519
 520 (defun epa-display-info (info)
 521   (if epa-popup-info-window
 522       (save-selected-window
 523         (unless epa-info-buffer
 524           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 525         (save-excursion
 526           (set-buffer epa-info-buffer)
 527           (let ((inhibit-read-only t)
 528                 buffer-read-only)
 529             (erase-buffer)
 530             (insert info))
 531           (epa-info-mode)
 532           (goto-char (point-min)))
 533         (if (> (window-height)
 534                epa-info-window-height)
 535             (set-window-buffer (split-window nil (- (window-height)
 536                                                     epa-info-window-height))
 537                                epa-info-buffer)
 538           (pop-to-buffer epa-info-buffer)
 539           (if (> (window-height) epa-info-window-height)
 540               (shrink-window (- (window-height) epa-info-window-height)))))
 541     (message "%s" info)))
 542
 543 (defun epa-display-verify-result (verify-result)
 544   (epa-display-info (epg-verify-result-to-string verify-result)))
 545 (make-obsolete 'epa-display-verify-result 'epa-display-info)
 546
 547 (defun epa-passphrase-callback-function (context key-id handback)
 548   (if (eq key-id 'SYM)
 549       (read-passwd "Passphrase for symmetric encryption: "
 550                    (eq (epg-context-operation context) 'encrypt))
 551     (read-passwd
 552      (if (eq key-id 'PIN)
 553         "Passphrase for PIN: "
 554        (let ((entry (assoc key-id epg-user-id-alist)))
 555          (if entry
 556              (format "Passphrase for %s %s: " key-id (cdr entry))
 557            (format "Passphrase for %s: " key-id)))))))
 558
 559 (defun epa-progress-callback-function (context what char current total
 560                                                handback)
 561   (message "%s: %d%% (%d/%d)" what
 562            (if (> total 0) (floor (* (/ current (float total)) 100)) 0)
 563            current total))
 564
 565 ;;;###autoload
 566 (defun epa-decrypt-file (file)
 567   "Decrypt FILE."
 568   (interactive "fFile: ")
 569   (setq file (expand-file-name file))
 570   (let* ((default-name (file-name-sans-extension file))
 571          (plain (expand-file-name
 572                  (read-file-name
 573                   (concat "To file (default "
 574                           (file-name-nondirectory default-name)
 575                           ") ")
 576                   (file-name-directory default-name)
 577                   default-name)))
 578          (context (epg-make-context)))
 579     (epg-context-set-passphrase-callback context
 580                                          #'epa-passphrase-callback-function)
 581     (epg-context-set-progress-callback context
 582                                        #'epa-progress-callback-function)
 583     (message "Decrypting %s..." (file-name-nondirectory file))
 584     (epg-decrypt-file context file plain)
 585     (message "Decrypting %s...done" (file-name-nondirectory file))
 586     (if (epg-context-result-for context 'verify)
 587         (epa-display-info (epg-verify-result-to-string
 588                            (epg-context-result-for context 'verify))))))
 589
 590 ;;;###autoload
 591 (defun epa-verify-file (file)
 592   "Verify FILE."
 593   (interactive "fFile: ")
 594   (setq file (expand-file-name file))
 595   (let* ((context (epg-make-context))
 596          (plain (if (equal (file-name-extension file) "sig")
 597                     (file-name-sans-extension file))))
 598     (epg-context-set-progress-callback context
 599                                        #'epa-progress-callback-function)
 600     (message "Verifying %s..." (file-name-nondirectory file))
 601     (epg-verify-file context file plain)
 602     (message "Verifying %s...done" (file-name-nondirectory file))
 603     (if (epg-context-result-for context 'verify)
 604         (epa-display-info (epg-verify-result-to-string
 605                            (epg-context-result-for context 'verify))))))
 606
 607 ;;;###autoload
 608 (defun epa-sign-file (file signers mode)
 609   "Sign FILE by SIGNERS keys selected."
 610   (interactive
 611    (list (expand-file-name (read-file-name "File: "))
 612          (epa-select-keys (epg-make-context) "Select keys for signing.
 613 If no one is selected, default secret key is used.  "
 614                           nil t)
 615          (if (y-or-n-p "Make a detached signature? ")
 616              'detached
 617            (if (y-or-n-p "Make a cleartext signature? ")
 618                'clear))))
 619   (let ((signature (concat file
 620                            (if (or epa-armor
 621                                    (not (memq mode '(nil t normal detached))))
 622                                ".asc"
 623                              (if (memq mode '(t detached))
 624                                  ".sig"
 625                                ".gpg"))))
 626         (context (epg-make-context)))
 627     (epg-context-set-armor context epa-armor)
 628     (epg-context-set-textmode context epa-textmode)
 629     (epg-context-set-signers context signers)
 630     (epg-context-set-passphrase-callback context
 631                                          #'epa-passphrase-callback-function)
 632     (epg-context-set-progress-callback context
 633                                        #'epa-progress-callback-function)
 634     (message "Signing %s..." (file-name-nondirectory file))
 635     (epg-sign-file context file signature mode)
 636     (message "Signing %s...done" (file-name-nondirectory file))))
 637
 638 ;;;###autoload
 639 (defun epa-encrypt-file (file recipients)
 640   "Encrypt FILE for RECIPIENTS."
 641   (interactive
 642    (list (expand-file-name (read-file-name "File: "))
 643          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 644 If no one is selected, symmetric encryption will be performed.  ")))
 645   (let ((cipher (concat file (if epa-armor ".asc" ".gpg")))
 646         (context (epg-make-context)))
 647     (epg-context-set-armor context epa-armor)
 648     (epg-context-set-textmode context epa-textmode)
 649     (epg-context-set-passphrase-callback context
 650                                          #'epa-passphrase-callback-function)
 651     (epg-context-set-progress-callback context
 652                                        #'epa-progress-callback-function)
 653     (message "Encrypting %s..." (file-name-nondirectory file))
 654     (epg-encrypt-file context file recipients cipher)
 655     (message "Encrypting %s...done" (file-name-nondirectory file))))
 656
 657 ;;;###autoload
 658 (defun epa-decrypt-region (start end)
 659   "Decrypt the current region between START and END.
 660
 661 Don't use this command in Lisp programs!"
 662   (interactive "r")
 663   (save-excursion
 664     (let ((context (epg-make-context))
 665           plain)
 666       (epg-context-set-passphrase-callback context
 667                                            #'epa-passphrase-callback-function)
 668       (epg-context-set-progress-callback context
 669                                          #'epa-progress-callback-function)
 670       (message "Decrypting...")
 671       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 672       (message "Decrypting...done")
 673       (delete-region start end)
 674       (goto-char start)
 675       (insert (decode-coding-string plain coding-system-for-read))
 676       (if (epg-context-result-for context 'verify)
 677           (epa-display-info (epg-verify-result-to-string
 678                              (epg-context-result-for context 'verify)))))))
 679
 680 ;;;###autoload
 681 (defun epa-decrypt-armor-in-region (start end)
 682   "Decrypt OpenPGP armors in the current region between START and END.
 683
 684 Don't use this command in Lisp programs!"
 685   (interactive "r")
 686   (save-excursion
 687     (save-restriction
 688       (narrow-to-region start end)
 689       (goto-char start)
 690       (let (armor-start armor-end charset coding-system)
 691         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 692           (setq armor-start (match-beginning 0)
 693                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 694                                              nil t))
 695           (unless armor-end
 696             (error "No armor tail"))
 697           (goto-char armor-start)
 698           (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 699               (setq charset (match-string 1)))
 700           (if coding-system-for-read
 701               (setq coding-system coding-system-for-read)
 702             (if charset
 703                 (setq coding-system (intern (downcase charset)))
 704               (setq coding-system 'utf-8)))
 705           (let ((coding-system-for-read coding-system))
 706             (epa-decrypt-region start end)))))))
 707
 708 ;;;###autoload
 709 (defun epa-verify-region (start end)
 710   "Verify the current region between START and END.
 711
 712 Don't use this command in Lisp programs!"
 713   (interactive "r")
 714   (let ((context (epg-make-context)))
 715     (epg-context-set-progress-callback context
 716                                        #'epa-progress-callback-function)
 717     (epg-verify-string context
 718                        (encode-coding-string
 719                         (buffer-substring start end)
 720                         coding-system-for-write))
 721     (if (epg-context-result-for context 'verify)
 722         (epa-display-info (epg-verify-result-to-string
 723                            (epg-context-result-for context 'verify))))))
 724
 725 ;;;###autoload
 726 (defun epa-verify-cleartext-in-region (start end)
 727   "Verify OpenPGP cleartext signed messages in the current region
 728 between START and END.
 729
 730 Don't use this command in Lisp programs!"
 731   (interactive "r")
 732   (save-excursion
 733     (save-restriction
 734       (narrow-to-region start end)
 735       (goto-char start)
 736       (let (armor-start armor-end)
 737         (while (re-search-forward "-----BEGIN PGP SIGNED MESSAGE-----$"
 738                                   nil t)
 739           (setq armor-start (match-beginning 0))
 740           (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 741                                            nil t)
 742             (error "Invalid cleartext signed message"))
 743           (setq armor-end (re-search-forward
 744                            "^-----END PGP SIGNATURE-----$"
 745                            nil t))
 746           (unless armor-end
 747             (error "No armor tail"))
 748           (epa-verify-region armor-start armor-end))))))
 749
 750 ;;;###autoload
 751 (defun epa-sign-region (start end signers mode)
 752   "Sign the current region between START and END by SIGNERS keys selected.
 753
 754 Don't use this command in Lisp programs!"
 755   (interactive
 756    (list (region-beginning) (region-end)
 757          (epa-select-keys (epg-make-context) "Select keys for signing.
 758 If no one is selected, default secret key is used.  "
 759                           nil t)
 760          (catch 'done
 761            (while t
 762              (message "Signature type (n,c,d,?) ")
 763              (let ((c (read-char)))
 764                (cond ((eq c ?c)
 765                       (throw 'done 'clear))
 766                      ((eq c ?d)
 767                       (throw 'done 'detached))
 768                      ((eq c ??)
 769                       (with-output-to-temp-buffer "*Help*"
 770                         (save-excursion
 771                           (set-buffer standard-output)
 772                           (insert "\
 773 n - Create a normal signature
 774 c - Create a cleartext signature
 775 d - Create a detached signature
 776 ? - Show this help
 777 "))))
 778                      (t
 779                       (throw 'done nil))))))))
 780   (save-excursion
 781     (let ((context (epg-make-context))
 782           signature)
 783       (epg-context-set-armor context epa-armor)
 784       (epg-context-set-textmode context epa-textmode)
 785       (epg-context-set-signers context signers)
 786       (epg-context-set-passphrase-callback context
 787                                            #'epa-passphrase-callback-function)
 788       (epg-context-set-progress-callback context
 789                                          #'epa-progress-callback-function)
 790       (message "Signing...")
 791       (setq signature (epg-sign-string context
 792                                        (encode-coding-string
 793                                         (buffer-substring start end)
 794                                         coding-system-for-write)
 795                                        mode))
 796       (message "Signing...done")
 797       (delete-region start end)
 798       (insert (decode-coding-string signature coding-system-for-read)))))
 799
 800 ;;;###autoload
 801 (defun epa-encrypt-region (start end recipients)
 802   "Encrypt the current region between START and END for RECIPIENTS.
 803
 804 Don't use this command in Lisp programs!"
 805   (interactive
 806    (list (region-beginning) (region-end)
 807          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 808 If no one is selected, symmetric encryption will be performed.  ")))
 809   (save-excursion
 810     (let ((context (epg-make-context))
 811           cipher)
 812       (epg-context-set-armor context epa-armor)
 813       (epg-context-set-textmode context epa-textmode)
 814       (epg-context-set-passphrase-callback context
 815                                            #'epa-passphrase-callback-function)
 816       (epg-context-set-progress-callback context
 817                                          #'epa-progress-callback-function)
 818       (message "Encrypting...")
 819       (setq cipher (epg-encrypt-string context
 820                                        (encode-coding-string
 821                                         (buffer-substring start end)
 822                                         coding-system-for-write)
 823                                        recipients))
 824       (message "Encrypting...done")
 825       (delete-region start end)
 826       (insert cipher))))
 827
 828 ;;;###autoload
 829 (defun epa-delete-keys (keys &optional allow-secret)
 830   "Delete selected KEYS.
 831
 832 Don't use this command in Lisp programs!"
 833   (interactive
 834    (let ((keys (epa--marked-keys)))
 835      (unless keys
 836        (error "No keys selected"))
 837      (list keys
 838            (eq (nth 1 epa-list-keys-arguments) t))))
 839   (let ((context (epg-make-context)))
 840     (message "Deleting...")
 841     (epg-delete-keys context keys allow-secret)
 842     (message "Deleting...done")
 843     (apply #'epa-list-keys epa-list-keys-arguments)))
 844
 845 ;;;###autoload
 846 (defun epa-import-keys (file)
 847   "Import keys from FILE.
 848
 849 Don't use this command in Lisp programs!"
 850   (interactive "fFile: ")
 851   (setq file (expand-file-name file))
 852   (let ((context (epg-make-context)))
 853     (message "Importing %s..." (file-name-nondirectory file))
 854     (condition-case nil
 855         (progn
 856           (epg-import-keys-from-file context file)
 857           (message "Importing %s...done" (file-name-nondirectory file)))
 858       (error
 859        (message "Importing %s...failed" (file-name-nondirectory file))))
 860     (if (epg-context-result-for context 'import)
 861         (epa-display-info (epg-import-result-to-string
 862                            (epg-context-result-for context 'import))))
 863     (if (eq major-mode 'epa-keys-mode)
 864         (apply #'epa-list-keys epa-list-keys-arguments))))
 865
 866 ;;;###autoload
 867 (defun epa-export-keys (keys file)
 868   "Export selected KEYS to FILE.
 869
 870 Don't use this command in Lisp programs!"
 871   (interactive
 872    (let ((keys (epa--marked-keys))
 873          default-name)
 874      (unless keys
 875        (error "No keys selected"))
 876      (setq default-name
 877            (expand-file-name
 878             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
 879                     (if epa-armor ".asc" ".gpg"))
 880             default-directory))
 881      (list keys
 882            (expand-file-name
 883             (read-file-name
 884              (concat "To file (default "
 885                      (file-name-nondirectory default-name)
 886                      ") ")
 887              (file-name-directory default-name)
 888              default-name)))))
 889   (let ((context (epg-make-context)))
 890     (epg-context-set-armor context epa-armor)
 891     (message "Exporting to %s..." (file-name-nondirectory file))
 892     (epg-export-keys-to-file context keys file)
 893     (message "Exporting to %s...done" (file-name-nondirectory file))))
 894
 895 ;;;###autoload
 896 (defun epa-sign-keys (keys &optional local)
 897   "Sign selected KEYS.
 898 If a prefix-arg is specified, the signature is marked as non exportable.
 899
 900 Don't use this command in Lisp programs!"
 901   (interactive
 902    (let ((keys (epa--marked-keys)))
 903      (unless keys
 904        (error "No keys selected"))
 905      (list keys current-prefix-arg)))
 906   (let ((context (epg-make-context)))
 907     (epg-context-set-passphrase-callback context
 908                                          #'epa-passphrase-callback-function)
 909     (epg-context-set-progress-callback context
 910                                        #'epa-progress-callback-function)
 911     (message "Signing keys...")
 912     (epg-sign-keys context keys local)
 913     (message "Signing keys...done")))
 914 (make-obsolete 'epa-sign-keys "Do not use.")
 915
 916 (provide 'epa)
 917
 918 ;;; epa.el ends here