epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30
  31 (defgroup epa nil
  32   "The EasyPG Assistant"
  33   :group 'epg)
  34
  35 (defcustom epa-armor nil
  36   "If non-nil, epa commands create ASCII armored output."
  37   :type 'boolean
  38   :group 'epa)
  39
  40 (defcustom epa-textmode nil
  41   "If non-nil, epa commands treat input files as text."
  42   :type 'boolean
  43   :group 'epa)
  44
  45 (defcustom epa-popup-info-window nil
  46   "If non-nil, status information from epa commands is displayed on
  47 the separate window."
  48   :type 'boolean
  49   :group 'epa)
  50
  51 (defcustom epa-info-window-height 5
  52   "Number of lines used to display status information."
  53   :type 'integer
  54   :group 'epa)
  55
  56 (defgroup epa-faces nil
  57   "Faces for epa-mode."
  58   :group 'epa)
  59
  60 (defface epa-validity-high-face
  61   '((((class color) (background dark))
  62      (:foreground "PaleTurquoise" :bold t))
  63     (t
  64      (:bold t)))
  65   "Face used for displaying the high validity."
  66   :group 'epa-faces)
  67 (defvar epa-validity-high-face 'epa-validity-high-face)
  68
  69 (defface epa-validity-medium-face
  70   '((((class color) (background dark))
  71      (:foreground "PaleTurquoise" :italic t))
  72     (t
  73      ()))
  74   "Face used for displaying the medium validity."
  75   :group 'epa-faces)
  76 (defvar epa-validity-medium-face 'epa-validity-medium-face)
  77
  78 (defface epa-validity-low-face
  79   '((t
  80      (:italic t)))
  81   "Face used for displaying the low validity."
  82   :group 'epa-faces)
  83 (defvar epa-validity-low-face 'epa-validity-low-face)
  84
  85 (defface epa-validity-disabled-face
  86   '((t
  87      (:italic t :inverse-video t)))
  88   "Face used for displaying the disabled validity."
  89   :group 'epa-faces)
  90 (defvar epa-validity-disabled-face 'epa-validity-disabled-face)
  91
  92 (defface epa-string-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "lightyellow"))
  96     (((class color)
  97       (background light))
  98      (:foreground "blue4"))
  99     (t
 100      ()))
 101   "Face used for displaying the string."
 102   :group 'epa-faces)
 103 (defvar epa-string-face 'epa-string-face)
 104
 105 (defface epa-mark-face
 106   '((((class color) (background dark))
 107      (:foreground "orange" :bold t))
 108     (t
 109      (:foreground "red" :bold t)))
 110   "Face used for displaying the high validity."
 111   :group 'epa-faces)
 112 (defvar epa-mark-face 'epa-mark-face)
 113
 114 (defface epa-field-name-face
 115   '((((class color) (background dark))
 116      (:foreground "PaleTurquoise" :bold t))
 117     (t (:bold t)))
 118   "Face for the name of the attribute field."
 119   :group 'epa)
 120 (defvar epa-field-name-face 'epa-field-name-face)
 121
 122 (defface epa-field-body-face
 123   '((((class color) (background dark))
 124      (:foreground "turquoise" :italic t))
 125     (t (:italic t)))
 126   "Face for the body of the attribute field."
 127   :group 'epa)
 128 (defvar epa-field-body-face 'epa-field-body-face)
 129
 130 (defcustom epa-validity-face-alist
 131   '((unknown . epa-validity-disabled-face)
 132     (invalid . epa-validity-disabled-face)
 133     (disabled . epa-validity-disabled-face)
 134     (revoked . epa-validity-disabled-face)
 135     (expired . epa-validity-disabled-face)
 136     (none . epa-validity-low-face)
 137     (undefined . epa-validity-low-face)
 138     (never . epa-validity-low-face)
 139     (marginal . epa-validity-medium-face)
 140     (full . epa-validity-high-face)
 141     (ultimate . epa-validity-high-face))
 142   "An alist mapping validity values to faces."
 143   :type 'list
 144   :group 'epa)
 145
 146 (defcustom epa-font-lock-keywords
 147   '(("^\\*"
 148      (0 epa-mark-face))
 149     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 150      (1 epa-field-name-face)
 151      (2 epa-field-body-face)))
 152   "Default expressions to addon in epa-mode."
 153   :type '(repeat (list string))
 154   :group 'epa)
 155
 156 (defconst epa-pubkey-algorithm-letter-alist
 157   '((1 . ?R)
 158     (2 . ?r)
 159     (3 . ?s)
 160     (16 . ?g)
 161     (17 . ?D)
 162     (20 . ?G)))
 163
 164 (defvar epa-keys-buffer nil)
 165 (defvar epa-key-buffer-alist nil)
 166 (defvar epa-key nil)
 167 (defvar epa-list-keys-arguments nil)
 168 (defvar epa-info-buffer nil)
 169
 170 (defvar epa-keys-mode-map
 171   (let ((keymap (make-sparse-keymap)))
 172     (define-key keymap "m" 'epa-mark)
 173     (define-key keymap "u" 'epa-unmark)
 174     (define-key keymap "d" 'epa-decrypt-file)
 175     (define-key keymap "v" 'epa-verify-file)
 176     (define-key keymap "s" 'epa-sign-file)
 177     (define-key keymap "S" 'epa-sign-keys)
 178     (define-key keymap "e" 'epa-encrypt-file)
 179     (define-key keymap "r" 'epa-delete-keys)
 180     (define-key keymap "i" 'epa-import-keys)
 181     (define-key keymap "o" 'epa-export-keys)
 182     (define-key keymap "g" 'epa-list-keys)
 183     (define-key keymap "n" 'next-line)
 184     (define-key keymap "p" 'previous-line)
 185     (define-key keymap " " 'scroll-up)
 186     (define-key keymap [delete] 'scroll-down)
 187     (define-key keymap "q" 'epa-exit-buffer)
 188     keymap))
 189
 190 (defvar epa-key-mode-map
 191   (let ((keymap (make-sparse-keymap)))
 192     (define-key keymap "q" 'bury-buffer)
 193     keymap))
 194
 195 (defvar epa-info-mode-map
 196   (let ((keymap (make-sparse-keymap)))
 197     (define-key keymap "q" 'delete-window)
 198     keymap))
 199
 200 (defvar epa-exit-buffer-function #'bury-buffer)
 201
 202 (define-widget 'epa-key 'push-button
 203   "Button for representing a epg-key object."
 204   :format "%[%v%]"
 205   :button-face-get 'epa-key-widget-button-face-get
 206   :value-create 'epa-key-widget-value-create
 207   :action 'epa-key-widget-action
 208   :help-echo 'epa-key-widget-help-echo)
 209
 210 (defun epa-key-widget-action (widget &optional event)
 211   (epa-show-key (widget-get widget :value)))
 212
 213 (defun epa-key-widget-value-create (widget)
 214   (let* ((key (widget-get widget :value))
 215          (primary-sub-key (car (epg-key-sub-key-list key)))
 216          (primary-user-id (car (epg-key-user-id-list key))))
 217     (insert (format "%c "
 218                     (if (epg-sub-key-validity primary-sub-key)
 219                         (car (rassq (epg-sub-key-validity primary-sub-key)
 220                                     epg-key-validity-alist))
 221                       ? ))
 222             (epg-sub-key-id primary-sub-key)
 223             " "
 224             (if (stringp (epg-user-id-string primary-user-id))
 225                 (epg-user-id-string primary-user-id)
 226               (epg-decode-dn (epg-user-id-string primary-user-id))))))
 227
 228 (defun epa-key-widget-button-face-get (widget)
 229   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 230                                               (widget-get widget :value))))))
 231     (if validity
 232         (cdr (assq validity epa-validity-face-alist))
 233       'default)))
 234
 235 (defun epa-key-widget-help-echo (widget)
 236   (format "Show %s"
 237           (epg-sub-key-id (car (epg-key-sub-key-list
 238                                 (widget-get widget :value))))))
 239
 240 (defun epa-keys-mode ()
 241   "Major mode for `epa-list-keys'."
 242   (kill-all-local-variables)
 243   (buffer-disable-undo)
 244   (setq major-mode 'epa-keys-mode
 245         mode-name "Keys"
 246         truncate-lines t
 247         buffer-read-only t)
 248   (use-local-map epa-keys-mode-map)
 249   (set-keymap-parent (current-local-map) widget-keymap)
 250   (make-local-variable 'font-lock-defaults)
 251   (setq font-lock-defaults '(epa-font-lock-keywords t))
 252   ;; In XEmacs, auto-initialization of font-lock is not effective
 253   ;; if buffer-file-name is not set.
 254   (font-lock-set-defaults)
 255   (widget-setup)
 256   (make-local-variable 'epa-exit-buffer-function)
 257   (run-hooks 'epa-keys-mode-hook))
 258
 259 (defun epa-key-mode ()
 260   "Major mode for `epa-show-key'."
 261   (kill-all-local-variables)
 262   (buffer-disable-undo)
 263   (setq major-mode 'epa-key-mode
 264         mode-name "Key"
 265         truncate-lines t
 266         buffer-read-only t)
 267   (use-local-map epa-key-mode-map)
 268   (make-local-variable 'font-lock-defaults)
 269   (setq font-lock-defaults '(epa-font-lock-keywords t))
 270   ;; In XEmacs, auto-initialization of font-lock is not effective
 271   ;; if buffer-file-name is not set.
 272   (font-lock-set-defaults)
 273   (make-local-variable 'epa-exit-buffer-function)
 274   (run-hooks 'epa-key-mode-hook))
 275
 276 ;;;###autoload
 277 (defun epa-list-keys (&optional name mode protocol)
 278   (interactive
 279    (if current-prefix-arg
 280        (let ((name (read-string "Pattern: "
 281                                 (if epa-list-keys-arguments
 282                                     (car epa-list-keys-arguments)))))
 283          (list (if (equal name "") nil name)
 284                (y-or-n-p "Secret keys? ")
 285                (intern (completing-read "Protocol? "
 286                                         '(("OpenPGP") ("CMS"))
 287                                         nil t))))
 288      (or epa-list-keys-arguments (list nil nil nil))))
 289   (unless (and epa-keys-buffer
 290                (buffer-live-p epa-keys-buffer))
 291     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 292   (set-buffer epa-keys-buffer)
 293   (let ((inhibit-read-only t)
 294         buffer-read-only
 295         (point (point-min))
 296         (context (epg-make-context protocol)))
 297     (unless (get-text-property point 'epa-list-keys)
 298       (setq point (next-single-property-change point 'epa-list-keys)))
 299     (when point
 300       (delete-region point
 301                      (or (next-single-property-change point 'epa-list-keys)
 302                          (point-max)))
 303       (goto-char point))
 304     (epa-insert-keys context name mode)
 305     (epa-keys-mode))
 306   (make-local-variable 'epa-list-keys-arguments)
 307   (setq epa-list-keys-arguments (list name mode protocol))
 308   (goto-char (point-min))
 309   (pop-to-buffer (current-buffer)))
 310
 311 (defun epa-insert-keys (context name mode)
 312   (save-excursion
 313     (save-restriction
 314       (narrow-to-region (point) (point))
 315       (let ((keys (epg-list-keys context name mode))
 316             point)
 317         (while keys
 318           (setq point (point))
 319           (insert "  ")
 320           (add-text-properties point (point)
 321                                (list 'epa-key (car keys)
 322                                      'front-sticky nil
 323                                      'rear-nonsticky t
 324                                      'start-open t
 325                                      'end-open t))
 326           (widget-create 'epa-key :value (car keys))
 327           (insert "\n")
 328           (setq keys (cdr keys))))
 329       (add-text-properties (point-min) (point-max)
 330                            (list 'epa-list-keys t
 331                                  'front-sticky nil
 332                                  'rear-nonsticky t
 333                                  'start-open t
 334                                  'end-open t)))))
 335
 336 (defun epa-marked-keys ()
 337   (or (save-excursion
 338         (set-buffer epa-keys-buffer)
 339         (goto-char (point-min))
 340         (let (keys key)
 341           (while (re-search-forward "^\\*" nil t)
 342             (if (setq key (get-text-property (match-beginning 0)
 343                                              'epa-key))
 344                 (setq keys (cons key keys))))
 345           (nreverse keys)))
 346       (save-excursion
 347         (beginning-of-line)
 348         (let ((key (get-text-property (point) 'epa-key)))
 349           (if key
 350               (list key))))))
 351
 352 ;;;###autoload
 353 (defun epa-select-keys (context prompt &optional names secret)
 354   "Display a user's keyring and ask him to select keys.
 355 CONTEXT is an epg-context.
 356 PROMPT is a string to prompt with.
 357 NAMES is a list of strings to be matched with keys.  If it is nil, all
 358 the keys are listed.
 359 If SECRET is non-nil, list secret keys instead of public keys."
 360   (save-excursion
 361     (unless (and epa-keys-buffer
 362                  (buffer-live-p epa-keys-buffer))
 363       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 364     (let ((inhibit-read-only t)
 365           buffer-read-only
 366           point)
 367       (set-buffer epa-keys-buffer)
 368       (erase-buffer)
 369       (insert prompt "\n")
 370       (widget-create 'link
 371                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 372                      :help-echo
 373                      (substitute-command-keys
 374                       "Click here or \\[abort-recursive-edit] to cancel")
 375                      "Cancel")
 376       (widget-create 'link
 377                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 378                      :help-echo
 379                      (substitute-command-keys
 380                       "Click here or \\[exit-recursive-edit] to finish")
 381                      "OK")
 382       (insert "\n\n")
 383       (if names
 384           (while names
 385             (setq point (point))
 386             (epa-insert-keys context (car names) secret)
 387             (goto-char point)
 388             (epa-mark)
 389             (goto-char (point-max))
 390             (setq names (cdr names)))
 391         (epa-insert-keys context nil secret))
 392       (epa-keys-mode)
 393       (setq epa-exit-buffer-function #'abort-recursive-edit)
 394       (goto-char (point-min))
 395       (pop-to-buffer (current-buffer)))
 396     (unwind-protect
 397           (progn
 398             (recursive-edit)
 399             (epa-marked-keys))
 400         (if (get-buffer-window epa-keys-buffer)
 401             (delete-window (get-buffer-window epa-keys-buffer)))
 402         (kill-buffer epa-keys-buffer))))
 403
 404 (defun epa--format-seconds (seconds)
 405   (let ((number-seconds (string-to-number (concat seconds ".0"))))
 406     (format-time-string "%Y-%m-%d"
 407                         (cons (floor (/ number-seconds 65536))
 408                               (floor (mod number-seconds 65536))))))
 409
 410 (defun epa-show-key (key)
 411   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 412          (entry (assoc (epg-sub-key-id primary-sub-key)
 413                        epa-key-buffer-alist))
 414          (inhibit-read-only t)
 415          buffer-read-only
 416          pointer)
 417     (unless entry
 418       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 419             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 420     (unless (and (cdr entry)
 421                  (buffer-live-p (cdr entry)))
 422       (setcdr entry (generate-new-buffer
 423                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 424     (set-buffer (cdr entry))
 425     (make-local-variable 'epa-key)
 426     (setq epa-key key)
 427     (erase-buffer)
 428     (setq pointer (epg-key-user-id-list key))
 429     (while pointer
 430       (insert " "
 431               (if (epg-user-id-validity (car pointer))
 432                   (char-to-string
 433                    (car (rassq (epg-user-id-validity (car pointer))
 434                                epg-key-validity-alist)))
 435                 " ")
 436               " "
 437               (if (stringp (epg-user-id-string (car pointer)))
 438                   (epg-user-id-string (car pointer))
 439                 (epg-decode-dn (epg-user-id-string (car pointer))))
 440               "\n")
 441       (setq pointer (cdr pointer)))
 442     (setq pointer (epg-key-sub-key-list key))
 443     (while pointer
 444       (insert " "
 445               (if (epg-sub-key-validity (car pointer))
 446                   (char-to-string
 447                    (car (rassq (epg-sub-key-validity (car pointer))
 448                                epg-key-validity-alist)))
 449                 " ")
 450               " "
 451               (epg-sub-key-id (car pointer))
 452               " "
 453               (format "%dbits"
 454                       (epg-sub-key-length (car pointer)))
 455               " "
 456               (cdr (assq (epg-sub-key-algorithm (car pointer))
 457                          epg-pubkey-algorithm-alist))
 458               "\n\tCreated: "
 459               (epa--format-seconds (epg-sub-key-creation-time (car pointer)))
 460               (if (epg-sub-key-expiration-time (car pointer))
 461                   (format "\n\tExpires: %s"
 462                           (epa--format-seconds (epg-sub-key-expiration-time
 463                                                 (car pointer))))
 464                 "")
 465               "\n\tCapabilities: "
 466               (mapconcat #'symbol-name
 467                          (epg-sub-key-capability (car pointer))
 468                          " ")
 469               "\n\tFingerprint: "
 470               (epg-sub-key-fingerprint (car pointer))
 471               "\n")
 472       (setq pointer (cdr pointer)))
 473     (goto-char (point-min))
 474     (pop-to-buffer (current-buffer))
 475     (epa-key-mode)))
 476
 477 (defun epa-show-key-notify (widget &rest ignore)
 478   (epa-show-key (widget-get widget :value)))
 479
 480 (defun epa-mark (&optional arg)
 481   "Mark the current line.
 482 If ARG is non-nil, unmark the current line."
 483   (interactive "P")
 484   (let ((inhibit-read-only t)
 485         buffer-read-only
 486         properties)
 487     (beginning-of-line)
 488     (setq properties (text-properties-at (point)))
 489     (delete-char 1)
 490     (insert (if arg " " "*"))
 491     (set-text-properties (1- (point)) (point) properties)
 492     (forward-line)))
 493
 494 (defun epa-unmark (&optional arg)
 495   "Unmark the current line.
 496 If ARG is non-nil, mark the current line."
 497   (interactive "P")
 498   (epa-mark (not arg)))
 499
 500 (defun epa-exit-buffer ()
 501   "Exit the current buffer.
 502 `epa-exit-buffer-function' is called if it is set."
 503   (interactive)
 504   (funcall epa-exit-buffer-function))
 505
 506 (defun epa-display-verify-result (verify-result)
 507   (if epa-popup-info-window
 508       (progn
 509         (unless epa-info-buffer
 510           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 511         (save-excursion
 512           (set-buffer epa-info-buffer)
 513           (let ((inhibit-read-only t)
 514                 buffer-read-only)
 515             (erase-buffer)
 516             (insert (epg-verify-result-to-string verify-result)))
 517           (epa-info-mode))
 518         (pop-to-buffer epa-info-buffer)
 519         (if (> (window-height) epa-info-window-height)
 520             (shrink-window (- (window-height) epa-info-window-height)))
 521         (goto-char (point-min)))
 522     (message "%s" (epg-verify-result-to-string verify-result))))
 523
 524 (defun epa-info-mode ()
 525   "Major mode for `epa-info-buffer'."
 526   (kill-all-local-variables)
 527   (buffer-disable-undo)
 528   (setq major-mode 'epa-info-mode
 529         mode-name "Info"
 530         truncate-lines t
 531         buffer-read-only t)
 532   (use-local-map epa-info-mode-map)
 533   (run-hooks 'epa-info-mode-hook))
 534
 535 ;;;###autoload
 536 (defun epa-decrypt-file (file)
 537   "Decrypt FILE."
 538   (interactive "fFile: ")
 539   (let* ((default-name (file-name-sans-extension file))
 540          (plain (expand-file-name
 541                  (read-file-name
 542                   (concat "To file (default "
 543                           (file-name-nondirectory default-name)
 544                           ") ")
 545                   (file-name-directory default-name)
 546                   default-name)))
 547          (context (epg-make-context)))
 548     (message "Decrypting %s..." (file-name-nondirectory file))
 549     (epg-decrypt-file context file plain)
 550     (message "Decrypting %s...done" (file-name-nondirectory file))
 551     (if (epg-context-result-for context 'verify)
 552         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 553
 554 ;;;###autoload
 555 (defun epa-verify-file (file)
 556   "Verify FILE."
 557   (interactive "fFile: ")
 558   (let* ((context (epg-make-context))
 559          (plain (if (equal (file-name-extension file) "sig")
 560                     (file-name-sans-extension file))))
 561     (message "Verifying %s..." (file-name-nondirectory file))
 562     (epg-verify-file context file plain)
 563     (message "Verifying %s...done" (file-name-nondirectory file))
 564     (if (epg-context-result-for context 'verify)
 565         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 566
 567 ;;;###autoload
 568 (defun epa-sign-file (file signers mode)
 569   "Sign FILE by SIGNERS keys selected."
 570   (interactive
 571    (list (expand-file-name (read-file-name "File: "))
 572          (epa-select-keys (epg-make-context) "Select keys for signing.
 573 If no one is selected, default secret key is used.  "
 574                           nil t)
 575          (if (y-or-n-p "Make a detached signature? ")
 576              'detached
 577            (if (y-or-n-p "Make a cleartext signature? ")
 578                'clear))))
 579   (let ((signature (concat file
 580                            (if (or epa-armor
 581                                    (not (memq mode '(nil t normal detached))))
 582                                ".asc"
 583                              (if (memq mode '(t detached))
 584                                  ".sig"
 585                                ".gpg"))))
 586         (context (epg-make-context)))
 587     (epg-context-set-armor context epa-armor)
 588     (epg-context-set-textmode context epa-textmode)
 589     (epg-context-set-signers context signers)
 590     (message "Signing %s..." (file-name-nondirectory file))
 591     (epg-sign-file context file signature mode)
 592     (message "Signing %s...done" (file-name-nondirectory file))))
 593
 594 ;;;###autoload
 595 (defun epa-encrypt-file (file recipients)
 596   "Encrypt FILE for RECIPIENTS."
 597   (interactive
 598    (list (expand-file-name (read-file-name "File: "))
 599          (epa-select-keys (epg-make-context) "Select recipents for encryption.
 600 If no one is selected, symmetric encryption will be performed.  ")))
 601   (let ((cipher (concat file (if epa-armor ".asc" ".gpg")))
 602         (context (epg-make-context)))
 603     (epg-context-set-armor context epa-armor)
 604     (epg-context-set-textmode context epa-textmode)
 605     (message "Encrypting %s..." (file-name-nondirectory file))
 606     (epg-encrypt-file context file recipients cipher)
 607     (message "Encrypting %s...done" (file-name-nondirectory file))))
 608
 609 ;;;###autoload
 610 (defun epa-decrypt-region (start end)
 611   "Decrypt the current region between START and END.
 612
 613 Don't use this command in Lisp programs!"
 614   (interactive "r")
 615   (save-excursion
 616     (let ((context (epg-make-context))
 617           plain)
 618       (message "Decrypting...")
 619       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 620       (message "Decrypting...done")
 621       (delete-region start end)
 622       (goto-char start)
 623       (insert (decode-coding-string plain coding-system-for-read))
 624       (if (epg-context-result-for context 'verify)
 625           (epa-display-verify-result (epg-context-result-for context 'verify))))))
 626
 627 ;;;###autoload
 628 (defun epa-decrypt-armor-in-region (start end)
 629   "Decrypt OpenPGP armors in the current region between START and END.
 630
 631 Don't use this command in Lisp programs!"
 632   (interactive "r")
 633   (save-excursion
 634     (save-restriction
 635       (narrow-to-region start end)
 636       (goto-char start)
 637       (let (armor-start armor-end charset coding-system)
 638         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 639           (setq armor-start (match-beginning 0)
 640                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 641                                              nil t))
 642           (unless armor-end
 643             (error "No armor tail"))
 644           (goto-char armor-start)
 645           (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 646               (setq charset (match-string 1)))
 647           (if coding-system-for-read
 648               (setq coding-system coding-system-for-read)
 649             (if charset
 650                 (setq coding-system (intern (downcase charset)))
 651               (setq coding-system 'utf-8)))
 652           (let ((coding-system-for-read coding-system))
 653             (epa-decrypt-region start end)))))))
 654
 655 ;;;###autoload
 656 (defun epa-verify-region (start end)
 657   "Verify the current region between START and END.
 658
 659 Don't use this command in Lisp programs!"
 660   (interactive "r")
 661   (let ((context (epg-make-context)))
 662     (epg-verify-string context
 663                        (encode-coding-string
 664                         (buffer-substring start end)
 665                         coding-system-for-write))
 666     (if (epg-context-result-for context 'verify)
 667         (epa-display-verify-result (epg-context-result-for context 'verify)))))
 668
 669 ;;;###autoload
 670 (defun epa-verify-armor-in-region (start end)
 671   "Verify OpenPGP armors in the current region between START and END.
 672
 673 Don't use this command in Lisp programs!"
 674   (interactive "r")
 675   (save-excursion
 676     (save-restriction
 677       (narrow-to-region start end)
 678       (goto-char start)
 679       (let (armor-start armor-end)
 680         (while (re-search-forward "-----BEGIN PGP\\( SIGNED\\)? MESSAGE-----$"
 681                                   nil t)
 682           (setq armor-start (match-beginning 0))
 683           (if (match-beginning 1)       ;cleartext signed message
 684               (progn
 685                 (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 686                                            nil t)
 687                   (error "Invalid cleartext signed message"))
 688                 (setq armor-end (re-search-forward
 689                                  "^-----END PGP SIGNATURE-----$"
 690                                  nil t)))
 691             (setq armor-end (re-search-forward
 692                              "^-----END PGP MESSAGE-----$"
 693                              nil t)))
 694           (unless armor-end
 695             (error "No armor tail"))
 696           (epa-verify-region armor-start armor-end))))))
 697
 698 ;;;###autoload
 699 (defun epa-sign-region (start end signers mode)
 700   "Sign the current region between START and END by SIGNERS keys selected.
 701
 702 Don't use this command in Lisp programs!"
 703   (interactive
 704    (list (region-beginning) (region-end)
 705          (epa-select-keys (epg-make-context) "Select keys for signing.
 706 If no one is selected, default secret key is used.  "
 707                           nil t)
 708          (if (y-or-n-p "Make a detached signature? ")
 709              'detached
 710            (if (y-or-n-p "Make a cleartext signature? ")
 711                'clear))))
 712   (save-excursion
 713     (let ((context (epg-make-context))
 714           signature)
 715       (epg-context-set-armor context epa-armor)
 716       (epg-context-set-textmode context epa-textmode)
 717       (epg-context-set-signers context signers)
 718       (message "Signing...")
 719       (setq signature (epg-sign-string context
 720                                        (encode-coding-string
 721                                         (buffer-substring start end)
 722                                         coding-system-for-write)
 723                                        mode))
 724       (message "Signing...done")
 725       (delete-region start end)
 726       (insert (decode-coding-string signature coding-system-for-read)))))
 727
 728 ;;;###autoload
 729 (defun epa-encrypt-region (start end recipients)
 730   "Encrypt the current region between START and END for RECIPIENTS.
 731
 732 Don't use this command in Lisp programs!"
 733   (interactive
 734    (list (region-beginning) (region-end)
 735          (epa-select-keys (epg-make-context) "Select recipents for encryption.
 736 If no one is selected, symmetric encryption will be performed.  ")))
 737   (save-excursion
 738     (let ((context (epg-make-context))
 739           cipher)
 740       (epg-context-set-armor context epa-armor)
 741       (epg-context-set-textmode context epa-textmode)
 742       (message "Encrypting...")
 743       (setq cipher (epg-encrypt-string context
 744                                        (encode-coding-string
 745                                         (buffer-substring start end)
 746                                         coding-system-for-write)
 747                                        recipients))
 748       (message "Encrypting...done")
 749       (delete-region start end)
 750       (insert cipher))))
 751
 752 ;;;###autoload
 753 (defun epa-delete-keys (keys &optional allow-secret)
 754   "Delete selected KEYS."
 755   (interactive
 756    (let ((keys (epa-marked-keys)))
 757      (unless keys
 758        (error "No keys selected"))
 759      (list keys
 760            (eq (nth 1 epa-list-keys-arguments) t))))
 761   (let ((context (epg-make-context)))
 762     (message "Deleting...")
 763     (epg-delete-keys context keys allow-secret)
 764     (message "Deleting...done")
 765     (apply #'epa-list-keys epa-list-keys-arguments)))
 766
 767 ;;;###autoload
 768 (defun epa-import-keys (file)
 769   "Import keys from FILE."
 770   (interactive "fFile: ")
 771   (let ((context (epg-make-context)))
 772     (message "Importing %s..." (file-name-nondirectory file))
 773     (epg-import-keys-from-file context (expand-file-name file))
 774     (message "Importing %s...done" (file-name-nondirectory file))
 775     (apply #'epa-list-keys epa-list-keys-arguments)))
 776
 777 ;;;###autoload
 778 (defun epa-export-keys (keys file)
 779   "Export selected KEYS to FILE."
 780   (interactive
 781    (let ((keys (epa-marked-keys))
 782          default-name)
 783      (unless keys
 784        (error "No keys selected"))
 785      (setq default-name
 786            (expand-file-name
 787             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
 788                     (if epa-armor ".asc" ".gpg"))
 789             default-directory))
 790      (list keys
 791            (expand-file-name
 792             (read-file-name
 793              (concat "To file (default "
 794                      (file-name-nondirectory default-name)
 795                      ") ")
 796              (file-name-directory default-name)
 797              default-name)))))
 798   (let ((context (epg-make-context)))
 799     (epg-context-set-armor context epa-armor)
 800     (message "Exporting to %s..." (file-name-nondirectory file))
 801     (epg-export-keys-to-file context keys file)
 802     (message "Exporting to %s...done" (file-name-nondirectory file))))
 803
 804 ;;;###autoload
 805 (defun epa-sign-keys (keys &optional local)
 806   "Sign selected KEYS.
 807 If LOCAL is non-nil, the signature is marked as non exportable."
 808   (interactive
 809    (let ((keys (epa-marked-keys)))
 810      (unless keys
 811        (error "No keys selected"))
 812      (list keys current-prefix-arg)))
 813   (let ((context (epg-make-context)))
 814     (message "Signing keys...")
 815     (epg-sign-keys context keys local)
 816     (message "Signing keys...done")))
 817
 818 (provide 'epa)
 819
 820 ;;; epa.el ends here