epa.el

   1 ;;; epa.el --- the EasyPG Assistant
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epg)
  27 (require 'font-lock)
  28 (require 'widget)
  29 (eval-when-compile (require 'wid-edit))
  30
  31 (defgroup epa nil
  32   "The EasyPG Assistant"
  33   :group 'epg)
  34
  35 (defcustom epa-armor nil
  36   "If non-nil, epa commands create ASCII armored output."
  37   :type 'boolean
  38   :group 'epa)
  39
  40 (defcustom epa-textmode nil
  41   "If non-nil, epa commands treat input files as text."
  42   :type 'boolean
  43   :group 'epa)
  44
  45 (defcustom epa-popup-info-window t
  46   "If non-nil, status information from epa commands is displayed on
  47 the separate window."
  48   :type 'boolean
  49   :group 'epa)
  50
  51 (defcustom epa-info-window-height 5
  52   "Number of lines used to display status information."
  53   :type 'integer
  54   :group 'epa)
  55
  56 (defgroup epa-faces nil
  57   "Faces for epa-mode."
  58   :group 'epa)
  59
  60 (defface epa-validity-high-face
  61   '((((class color) (background dark))
  62      (:foreground "PaleTurquoise" :bold t))
  63     (t
  64      (:bold t)))
  65   "Face used for displaying the high validity."
  66   :group 'epa-faces)
  67 (defvar epa-validity-high-face 'epa-validity-high-face)
  68
  69 (defface epa-validity-medium-face
  70   '((((class color) (background dark))
  71      (:foreground "PaleTurquoise" :italic t))
  72     (t
  73      ()))
  74   "Face used for displaying the medium validity."
  75   :group 'epa-faces)
  76 (defvar epa-validity-medium-face 'epa-validity-medium-face)
  77
  78 (defface epa-validity-low-face
  79   '((t
  80      (:italic t)))
  81   "Face used for displaying the low validity."
  82   :group 'epa-faces)
  83 (defvar epa-validity-low-face 'epa-validity-low-face)
  84
  85 (defface epa-validity-disabled-face
  86   '((t
  87      (:italic t :inverse-video t)))
  88   "Face used for displaying the disabled validity."
  89   :group 'epa-faces)
  90 (defvar epa-validity-disabled-face 'epa-validity-disabled-face)
  91
  92 (defface epa-string-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "lightyellow"))
  96     (((class color)
  97       (background light))
  98      (:foreground "blue4"))
  99     (t
 100      ()))
 101   "Face used for displaying the string."
 102   :group 'epa-faces)
 103 (defvar epa-string-face 'epa-string-face)
 104
 105 (defface epa-mark-face
 106   '((((class color) (background dark))
 107      (:foreground "orange" :bold t))
 108     (t
 109      (:foreground "red" :bold t)))
 110   "Face used for displaying the high validity."
 111   :group 'epa-faces)
 112 (defvar epa-mark-face 'epa-mark-face)
 113
 114 (defface epa-field-name-face
 115   '((((class color) (background dark))
 116      (:foreground "PaleTurquoise" :bold t))
 117     (t (:bold t)))
 118   "Face for the name of the attribute field."
 119   :group 'epa)
 120 (defvar epa-field-name-face 'epa-field-name-face)
 121
 122 (defface epa-field-body-face
 123   '((((class color) (background dark))
 124      (:foreground "turquoise" :italic t))
 125     (t (:italic t)))
 126   "Face for the body of the attribute field."
 127   :group 'epa)
 128 (defvar epa-field-body-face 'epa-field-body-face)
 129
 130 (defcustom epa-validity-face-alist
 131   '((unknown . epa-validity-disabled-face)
 132     (invalid . epa-validity-disabled-face)
 133     (disabled . epa-validity-disabled-face)
 134     (revoked . epa-validity-disabled-face)
 135     (expired . epa-validity-disabled-face)
 136     (none . epa-validity-low-face)
 137     (undefined . epa-validity-low-face)
 138     (never . epa-validity-low-face)
 139     (marginal . epa-validity-medium-face)
 140     (full . epa-validity-high-face)
 141     (ultimate . epa-validity-high-face))
 142   "An alist mapping validity values to faces."
 143   :type 'list
 144   :group 'epa)
 145
 146 (defcustom epa-font-lock-keywords
 147   '(("^\\*"
 148      (0 epa-mark-face))
 149     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 150      (1 epa-field-name-face)
 151      (2 epa-field-body-face)))
 152   "Default expressions to addon in epa-mode."
 153   :type '(repeat (list string))
 154   :group 'epa)
 155
 156 (defconst epa-pubkey-algorithm-letter-alist
 157   '((1 . ?R)
 158     (2 . ?r)
 159     (3 . ?s)
 160     (16 . ?g)
 161     (17 . ?D)
 162     (20 . ?G)))
 163
 164 (defvar epa-keys-buffer nil)
 165 (defvar epa-key-buffer-alist nil)
 166 (defvar epa-key nil)
 167 (defvar epa-list-keys-arguments nil)
 168 (defvar epa-info-buffer nil)
 169
 170 (defvar epa-keys-mode-map
 171   (let ((keymap (make-sparse-keymap)))
 172     (define-key keymap "m" 'epa-mark)
 173     (define-key keymap "u" 'epa-unmark)
 174     (define-key keymap "d" 'epa-decrypt-file)
 175     (define-key keymap "v" 'epa-verify-file)
 176     (define-key keymap "s" 'epa-sign-file)
 177     (define-key keymap "e" 'epa-encrypt-file)
 178     (define-key keymap "r" 'epa-delete-keys)
 179     (define-key keymap "i" 'epa-import-keys)
 180     (define-key keymap "o" 'epa-export-keys)
 181     (define-key keymap "g" 'epa-list-keys)
 182     (define-key keymap "n" 'next-line)
 183     (define-key keymap "p" 'previous-line)
 184     (define-key keymap " " 'scroll-up)
 185     (define-key keymap [delete] 'scroll-down)
 186     (define-key keymap "q" 'epa-exit-buffer)
 187     keymap))
 188
 189 (defvar epa-key-mode-map
 190   (let ((keymap (make-sparse-keymap)))
 191     (define-key keymap "q" 'bury-buffer)
 192     keymap))
 193
 194 (defvar epa-info-mode-map
 195   (let ((keymap (make-sparse-keymap)))
 196     (define-key keymap "q" 'delete-window)
 197     keymap))
 198
 199 (defvar epa-exit-buffer-function #'bury-buffer)
 200
 201 (define-widget 'epa-key 'push-button
 202   "Button for representing a epg-key object."
 203   :format "%[%v%]"
 204   :button-face-get 'epa--key-widget-button-face-get
 205   :value-create 'epa--key-widget-value-create
 206   :action 'epa--key-widget-action
 207   :help-echo 'epa--key-widget-help-echo)
 208
 209 (defun epa--key-widget-action (widget &optional event)
 210   (epa--show-key (widget-get widget :value)))
 211
 212 (defun epa--key-widget-value-create (widget)
 213   (let* ((key (widget-get widget :value))
 214          (primary-sub-key (car (epg-key-sub-key-list key)))
 215          (primary-user-id (car (epg-key-user-id-list key))))
 216     (insert (format "%c "
 217                     (if (epg-sub-key-validity primary-sub-key)
 218                         (car (rassq (epg-sub-key-validity primary-sub-key)
 219                                     epg-key-validity-alist))
 220                       ? ))
 221             (epg-sub-key-id primary-sub-key)
 222             " "
 223             (if primary-user-id
 224                 (if (stringp (epg-user-id-string primary-user-id))
 225                     (epg-user-id-string primary-user-id)
 226                   (epg-decode-dn (epg-user-id-string primary-user-id)))
 227               ""))))
 228
 229 (defun epa--key-widget-button-face-get (widget)
 230   (let ((validity (epg-sub-key-validity (car (epg-key-sub-key-list
 231                                               (widget-get widget :value))))))
 232     (if validity
 233         (cdr (assq validity epa-validity-face-alist))
 234       'default)))
 235
 236 (defun epa--key-widget-help-echo (widget)
 237   (format "Show %s"
 238           (epg-sub-key-id (car (epg-key-sub-key-list
 239                                 (widget-get widget :value))))))
 240
 241 (defun epa-keys-mode ()
 242   "Major mode for `epa-list-keys'."
 243   (kill-all-local-variables)
 244   (buffer-disable-undo)
 245   (setq major-mode 'epa-keys-mode
 246         mode-name "Keys"
 247         truncate-lines t
 248         buffer-read-only t)
 249   (use-local-map epa-keys-mode-map)
 250   (make-local-variable 'font-lock-defaults)
 251   (setq font-lock-defaults '(epa-font-lock-keywords t))
 252   ;; In XEmacs, auto-initialization of font-lock is not effective
 253   ;; if buffer-file-name is not set.
 254   (font-lock-set-defaults)
 255   (make-local-variable 'epa-exit-buffer-function)
 256   (run-hooks 'epa-keys-mode-hook))
 257
 258 (defun epa-key-mode ()
 259   "Major mode for a key description."
 260   (kill-all-local-variables)
 261   (buffer-disable-undo)
 262   (setq major-mode 'epa-key-mode
 263         mode-name "Key"
 264         truncate-lines t
 265         buffer-read-only t)
 266   (use-local-map epa-key-mode-map)
 267   (make-local-variable 'font-lock-defaults)
 268   (setq font-lock-defaults '(epa-font-lock-keywords t))
 269   ;; In XEmacs, auto-initialization of font-lock is not effective
 270   ;; if buffer-file-name is not set.
 271   (font-lock-set-defaults)
 272   (make-local-variable 'epa-exit-buffer-function)
 273   (run-hooks 'epa-key-mode-hook))
 274
 275 (defun epa-info-mode ()
 276   "Major mode for `epa-info-buffer'."
 277   (kill-all-local-variables)
 278   (buffer-disable-undo)
 279   (setq major-mode 'epa-info-mode
 280         mode-name "Info"
 281         truncate-lines t
 282         buffer-read-only t)
 283   (use-local-map epa-info-mode-map)
 284   (run-hooks 'epa-info-mode-hook))
 285
 286 (defun epa-mark (&optional arg)
 287   "Mark the current line.
 288 If ARG is non-nil, unmark the current line."
 289   (interactive "P")
 290   (let ((inhibit-read-only t)
 291         buffer-read-only
 292         properties)
 293     (beginning-of-line)
 294     (setq properties (text-properties-at (point)))
 295     (delete-char 1)
 296     (insert (if arg " " "*"))
 297     (set-text-properties (1- (point)) (point) properties)
 298     (forward-line)))
 299
 300 (defun epa-unmark (&optional arg)
 301   "Unmark the current line.
 302 If ARG is non-nil, mark the current line."
 303   (interactive "P")
 304   (epa-mark (not arg)))
 305
 306 (defun epa-toggle-mark ()
 307   "Toggle the mark the current line."
 308   (interactive)
 309   (epa-mark (eq (char-after (save-excursion (beginning-of-line) (point))) ?*)))
 310
 311 (defun epa-exit-buffer ()
 312   "Exit the current buffer.
 313 `epa-exit-buffer-function' is called if it is set."
 314   (interactive)
 315   (funcall epa-exit-buffer-function))
 316
 317 ;;;###autoload
 318 (defun epa-list-keys (&optional name mode protocol)
 319   (interactive
 320    (if current-prefix-arg
 321        (let ((name (read-string "Pattern: "
 322                                 (if epa-list-keys-arguments
 323                                     (car epa-list-keys-arguments)))))
 324          (list (if (equal name "") nil name)
 325                (y-or-n-p "Secret keys? ")
 326                (intern (completing-read "Protocol? "
 327                                         '(("OpenPGP") ("CMS"))
 328                                         nil t))))
 329      (or epa-list-keys-arguments (list nil nil nil))))
 330   (unless (and epa-keys-buffer
 331                (buffer-live-p epa-keys-buffer))
 332     (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 333   (set-buffer epa-keys-buffer)
 334   (let ((inhibit-read-only t)
 335         buffer-read-only
 336         (point (point-min))
 337         (context (epg-make-context protocol)))
 338     (unless (get-text-property point 'epa-list-keys)
 339       (setq point (next-single-property-change point 'epa-list-keys)))
 340     (when point
 341       (delete-region point
 342                      (or (next-single-property-change point 'epa-list-keys)
 343                          (point-max)))
 344       (goto-char point))
 345     (epa-insert-keys context name mode)
 346     (epa-keys-mode)
 347     (widget-setup)
 348     (set-keymap-parent (current-local-map) widget-keymap))
 349   (make-local-variable 'epa-list-keys-arguments)
 350   (setq epa-list-keys-arguments (list name mode protocol))
 351   (goto-char (point-min))
 352   (pop-to-buffer (current-buffer)))
 353
 354 (defun epa-insert-keys (context name mode)
 355   (save-excursion
 356     (save-restriction
 357       (narrow-to-region (point) (point))
 358       (let ((keys (epg-list-keys context name mode))
 359             point)
 360         (while keys
 361           (setq point (point))
 362           (insert "  ")
 363           (add-text-properties point (point)
 364                                (list 'epa-key (car keys)
 365                                      'front-sticky nil
 366                                      'rear-nonsticky t
 367                                      'start-open t
 368                                      'end-open t))
 369           (widget-create 'epa-key :value (car keys))
 370           (insert "\n")
 371           (setq keys (cdr keys))))
 372       (add-text-properties (point-min) (point-max)
 373                            (list 'epa-list-keys t
 374                                  'front-sticky nil
 375                                  'rear-nonsticky t
 376                                  'start-open t
 377                                  'end-open t)))))
 378
 379 (defun epa--marked-keys ()
 380   (or (save-excursion
 381         (set-buffer epa-keys-buffer)
 382         (goto-char (point-min))
 383         (let (keys key)
 384           (while (re-search-forward "^\\*" nil t)
 385             (if (setq key (get-text-property (match-beginning 0)
 386                                              'epa-key))
 387                 (setq keys (cons key keys))))
 388           (nreverse keys)))
 389       (save-excursion
 390         (beginning-of-line)
 391         (let ((key (get-text-property (point) 'epa-key)))
 392           (if key
 393               (list key))))))
 394
 395 ;;;###autoload
 396 (defun epa-select-keys (context prompt &optional names secret)
 397   "Display a user's keyring and ask him to select keys.
 398 CONTEXT is an epg-context.
 399 PROMPT is a string to prompt with.
 400 NAMES is a list of strings to be matched with keys.  If it is nil, all
 401 the keys are listed.
 402 If SECRET is non-nil, list secret keys instead of public keys."
 403   (save-excursion
 404     (unless (and epa-keys-buffer
 405                  (buffer-live-p epa-keys-buffer))
 406       (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
 407     (let ((inhibit-read-only t)
 408           buffer-read-only)
 409       (set-buffer epa-keys-buffer)
 410       (erase-buffer)
 411       (insert prompt "\n")
 412       (widget-create 'link
 413                      :notify (lambda (&rest ignore) (abort-recursive-edit))
 414                      :help-echo
 415                      (substitute-command-keys
 416                       "Click here or \\[abort-recursive-edit] to cancel")
 417                      "Cancel")
 418       (widget-create 'link
 419                      :notify (lambda (&rest ignore) (exit-recursive-edit))
 420                      :help-echo
 421                      (substitute-command-keys
 422                       "Click here or \\[exit-recursive-edit] to finish")
 423                      "OK")
 424       (insert "\n\n")
 425       (if names
 426           (while names
 427             (epa-insert-keys context (car names) secret)
 428             (if (get-text-property (point) 'epa-list-keys)
 429                 (epa-mark))
 430             (goto-char (point-max))
 431             (setq names (cdr names)))
 432         (if secret
 433             (progn
 434               (epa-insert-keys context nil secret)
 435               (if (get-text-property (point) 'epa-list-keys)
 436                   (epa-mark)))
 437           (epa-insert-keys context nil nil)))
 438       (epa-keys-mode)
 439       (widget-setup)
 440       (set-keymap-parent (current-local-map) widget-keymap)
 441       (setq epa-exit-buffer-function #'abort-recursive-edit)
 442       (goto-char (point-min))
 443       (pop-to-buffer (current-buffer)))
 444     (unwind-protect
 445         (progn
 446           (recursive-edit)
 447           (epa--marked-keys))
 448       (if (get-buffer-window epa-keys-buffer)
 449           (delete-window (get-buffer-window epa-keys-buffer)))
 450       (kill-buffer epa-keys-buffer))))
 451
 452 (defun epa--show-key (key)
 453   (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
 454          (entry (assoc (epg-sub-key-id primary-sub-key)
 455                        epa-key-buffer-alist))
 456          (inhibit-read-only t)
 457          buffer-read-only
 458          pointer)
 459     (unless entry
 460       (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
 461             epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
 462     (unless (and (cdr entry)
 463                  (buffer-live-p (cdr entry)))
 464       (setcdr entry (generate-new-buffer
 465                      (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
 466     (set-buffer (cdr entry))
 467     (make-local-variable 'epa-key)
 468     (setq epa-key key)
 469     (erase-buffer)
 470     (setq pointer (epg-key-user-id-list key))
 471     (while pointer
 472       (if (car pointer)
 473           (insert " "
 474                   (if (epg-user-id-validity (car pointer))
 475                       (char-to-string
 476                        (car (rassq (epg-user-id-validity (car pointer))
 477                                    epg-key-validity-alist)))
 478                     " ")
 479                   " "
 480                   (if (stringp (epg-user-id-string (car pointer)))
 481                       (epg-user-id-string (car pointer))
 482                     (epg-decode-dn (epg-user-id-string (car pointer))))
 483                   "\n"))
 484       (setq pointer (cdr pointer)))
 485     (setq pointer (epg-key-sub-key-list key))
 486     (while pointer
 487       (insert " "
 488               (if (epg-sub-key-validity (car pointer))
 489                   (char-to-string
 490                    (car (rassq (epg-sub-key-validity (car pointer))
 491                                epg-key-validity-alist)))
 492                 " ")
 493               " "
 494               (epg-sub-key-id (car pointer))
 495               " "
 496               (format "%dbits"
 497                       (epg-sub-key-length (car pointer)))
 498               " "
 499               (cdr (assq (epg-sub-key-algorithm (car pointer))
 500                          epg-pubkey-algorithm-alist))
 501               "\n\tCreated: "
 502               (format-time-string "%Y-%m-%d"
 503                                   (epg-sub-key-creation-time (car pointer)))
 504               (if (epg-sub-key-expiration-time (car pointer))
 505                   (format "\n\tExpires: %s"
 506                           (format-time-string "%Y-%m-%d"
 507                                               (epg-sub-key-expiration-time
 508                                                (car pointer))))
 509                 "")
 510               "\n\tCapabilities: "
 511               (mapconcat #'symbol-name
 512                          (epg-sub-key-capability (car pointer))
 513                          " ")
 514               "\n\tFingerprint: "
 515               (epg-sub-key-fingerprint (car pointer))
 516               "\n")
 517       (setq pointer (cdr pointer)))
 518     (goto-char (point-min))
 519     (pop-to-buffer (current-buffer))
 520     (epa-key-mode)))
 521
 522 (defun epa-display-info (info)
 523   (if epa-popup-info-window
 524       (save-selected-window
 525         (unless epa-info-buffer
 526           (setq epa-info-buffer (generate-new-buffer "*Info*")))
 527         (save-excursion
 528           (set-buffer epa-info-buffer)
 529           (let ((inhibit-read-only t)
 530                 buffer-read-only)
 531             (erase-buffer)
 532             (insert info))
 533           (epa-info-mode)
 534           (goto-char (point-min)))
 535         (if (> (window-height)
 536                epa-info-window-height)
 537             (set-window-buffer (split-window nil (- (window-height)
 538                                                     epa-info-window-height))
 539                                epa-info-buffer)
 540           (pop-to-buffer epa-info-buffer)
 541           (if (> (window-height) epa-info-window-height)
 542               (shrink-window (- (window-height) epa-info-window-height)))))
 543     (message "%s" info)))
 544
 545 (defun epa-display-verify-result (verify-result)
 546   (epa-display-info (epg-verify-result-to-string verify-result)))
 547 (make-obsolete 'epa-display-verify-result 'epa-display-info)
 548
 549 (defun epa-passphrase-callback-function (context key-id handback)
 550   (if (eq key-id 'SYM)
 551       (read-passwd "Passphrase for symmetric encryption: "
 552                    (eq (epg-context-operation context) 'encrypt))
 553     (read-passwd
 554      (if (eq key-id 'PIN)
 555         "Passphrase for PIN: "
 556        (let ((entry (assoc key-id epg-user-id-alist)))
 557          (if entry
 558              (format "Passphrase for %s %s: " key-id (cdr entry))
 559            (format "Passphrase for %s: " key-id)))))))
 560
 561 (defun epa-progress-callback-function (context what char current total
 562                                                handback)
 563   (message "%s: %d%% (%d/%d)" what
 564            (if (> total 0) (floor (* (/ current (float total)) 100)) 0)
 565            current total))
 566
 567 ;;;###autoload
 568 (defun epa-decrypt-file (file)
 569   "Decrypt FILE."
 570   (interactive "fFile: ")
 571   (setq file (expand-file-name file))
 572   (let* ((default-name (file-name-sans-extension file))
 573          (plain (expand-file-name
 574                  (read-file-name
 575                   (concat "To file (default "
 576                           (file-name-nondirectory default-name)
 577                           ") ")
 578                   (file-name-directory default-name)
 579                   default-name)))
 580          (context (epg-make-context)))
 581     (epg-context-set-passphrase-callback context
 582                                          #'epa-passphrase-callback-function)
 583     (epg-context-set-progress-callback context
 584                                        #'epa-progress-callback-function)
 585     (message "Decrypting %s..." (file-name-nondirectory file))
 586     (epg-decrypt-file context file plain)
 587     (message "Decrypting %s...done" (file-name-nondirectory file))
 588     (if (epg-context-result-for context 'verify)
 589         (epa-display-info (epg-verify-result-to-string
 590                            (epg-context-result-for context 'verify))))))
 591
 592 ;;;###autoload
 593 (defun epa-verify-file (file)
 594   "Verify FILE."
 595   (interactive "fFile: ")
 596   (setq file (expand-file-name file))
 597   (let* ((context (epg-make-context))
 598          (plain (if (equal (file-name-extension file) "sig")
 599                     (file-name-sans-extension file))))
 600     (epg-context-set-progress-callback context
 601                                        #'epa-progress-callback-function)
 602     (message "Verifying %s..." (file-name-nondirectory file))
 603     (epg-verify-file context file plain)
 604     (message "Verifying %s...done" (file-name-nondirectory file))
 605     (if (epg-context-result-for context 'verify)
 606         (epa-display-info (epg-verify-result-to-string
 607                            (epg-context-result-for context 'verify))))))
 608
 609 ;;;###autoload
 610 (defun epa-sign-file (file signers mode)
 611   "Sign FILE by SIGNERS keys selected."
 612   (interactive
 613    (list (expand-file-name (read-file-name "File: "))
 614          (epa-select-keys (epg-make-context) "Select keys for signing.
 615 If no one is selected, default secret key is used.  "
 616                           nil t)
 617          (if (y-or-n-p "Make a detached signature? ")
 618              'detached
 619            (if (y-or-n-p "Make a cleartext signature? ")
 620                'clear))))
 621   (let ((signature (concat file
 622                            (if (or epa-armor
 623                                    (not (memq mode '(nil t normal detached))))
 624                                ".asc"
 625                              (if (memq mode '(t detached))
 626                                  ".sig"
 627                                ".gpg"))))
 628         (context (epg-make-context)))
 629     (epg-context-set-armor context epa-armor)
 630     (epg-context-set-textmode context epa-textmode)
 631     (epg-context-set-signers context signers)
 632     (epg-context-set-passphrase-callback context
 633                                          #'epa-passphrase-callback-function)
 634     (epg-context-set-progress-callback context
 635                                        #'epa-progress-callback-function)
 636     (message "Signing %s..." (file-name-nondirectory file))
 637     (epg-sign-file context file signature mode)
 638     (message "Signing %s...done" (file-name-nondirectory file))))
 639
 640 ;;;###autoload
 641 (defun epa-encrypt-file (file recipients)
 642   "Encrypt FILE for RECIPIENTS."
 643   (interactive
 644    (list (expand-file-name (read-file-name "File: "))
 645          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 646 If no one is selected, symmetric encryption will be performed.  ")))
 647   (let ((cipher (concat file (if epa-armor ".asc" ".gpg")))
 648         (context (epg-make-context)))
 649     (epg-context-set-armor context epa-armor)
 650     (epg-context-set-textmode context epa-textmode)
 651     (epg-context-set-passphrase-callback context
 652                                          #'epa-passphrase-callback-function)
 653     (epg-context-set-progress-callback context
 654                                        #'epa-progress-callback-function)
 655     (message "Encrypting %s..." (file-name-nondirectory file))
 656     (epg-encrypt-file context file recipients cipher)
 657     (message "Encrypting %s...done" (file-name-nondirectory file))))
 658
 659 ;;;###autoload
 660 (defun epa-decrypt-region (start end)
 661   "Decrypt the current region between START and END.
 662
 663 Don't use this command in Lisp programs!"
 664   (interactive "r")
 665   (save-excursion
 666     (let ((context (epg-make-context))
 667           plain)
 668       (epg-context-set-passphrase-callback context
 669                                            #'epa-passphrase-callback-function)
 670       (epg-context-set-progress-callback context
 671                                          #'epa-progress-callback-function)
 672       (message "Decrypting...")
 673       (setq plain (epg-decrypt-string context (buffer-substring start end)))
 674       (message "Decrypting...done")
 675       (delete-region start end)
 676       (goto-char start)
 677       (insert (decode-coding-string plain coding-system-for-read))
 678       (if (epg-context-result-for context 'verify)
 679           (epa-display-info (epg-verify-result-to-string
 680                              (epg-context-result-for context 'verify)))))))
 681
 682 ;;;###autoload
 683 (defun epa-decrypt-armor-in-region (start end)
 684   "Decrypt OpenPGP armors in the current region between START and END.
 685
 686 Don't use this command in Lisp programs!"
 687   (interactive "r")
 688   (save-excursion
 689     (save-restriction
 690       (narrow-to-region start end)
 691       (goto-char start)
 692       (let (armor-start armor-end charset coding-system)
 693         (while (re-search-forward "-----BEGIN PGP MESSAGE-----$" nil t)
 694           (setq armor-start (match-beginning 0)
 695                 armor-end (re-search-forward "^-----END PGP MESSAGE-----$"
 696                                              nil t))
 697           (unless armor-end
 698             (error "No armor tail"))
 699           (goto-char armor-start)
 700           (if (re-search-forward "^Charset: \\(.*\\)" armor-end t)
 701               (setq charset (match-string 1)))
 702           (if coding-system-for-read
 703               (setq coding-system coding-system-for-read)
 704             (if charset
 705                 (setq coding-system (intern (downcase charset)))
 706               (setq coding-system 'utf-8)))
 707           (let ((coding-system-for-read coding-system))
 708             (epa-decrypt-region start end)))))))
 709
 710 ;;;###autoload
 711 (defun epa-verify-region (start end)
 712   "Verify the current region between START and END.
 713
 714 Don't use this command in Lisp programs!"
 715   (interactive "r")
 716   (let ((context (epg-make-context)))
 717     (epg-context-set-progress-callback context
 718                                        #'epa-progress-callback-function)
 719     (epg-verify-string context
 720                        (encode-coding-string
 721                         (buffer-substring start end)
 722                         coding-system-for-write))
 723     (if (epg-context-result-for context 'verify)
 724         (epa-display-info (epg-verify-result-to-string
 725                            (epg-context-result-for context 'verify))))))
 726
 727 ;;;###autoload
 728 (defun epa-verify-cleartext-in-region (start end)
 729   "Verify OpenPGP cleartext signed messages in the current region
 730 between START and END.
 731
 732 Don't use this command in Lisp programs!"
 733   (interactive "r")
 734   (save-excursion
 735     (save-restriction
 736       (narrow-to-region start end)
 737       (goto-char start)
 738       (let (armor-start armor-end)
 739         (while (re-search-forward "-----BEGIN PGP SIGNED MESSAGE-----$"
 740                                   nil t)
 741           (setq armor-start (match-beginning 0))
 742           (unless (re-search-forward "^-----BEGIN PGP SIGNATURE-----$"
 743                                            nil t)
 744             (error "Invalid cleartext signed message"))
 745           (setq armor-end (re-search-forward
 746                            "^-----END PGP SIGNATURE-----$"
 747                            nil t))
 748           (unless armor-end
 749             (error "No armor tail"))
 750           (epa-verify-region armor-start armor-end))))))
 751
 752 ;;;###autoload
 753 (defun epa-sign-region (start end signers mode)
 754   "Sign the current region between START and END by SIGNERS keys selected.
 755
 756 Don't use this command in Lisp programs!"
 757   (interactive
 758    (list (region-beginning) (region-end)
 759          (epa-select-keys (epg-make-context) "Select keys for signing.
 760 If no one is selected, default secret key is used.  "
 761                           nil t)
 762          (catch 'done
 763            (while t
 764              (message "Signature type (n,c,d,?) ")
 765              (let ((c (read-char)))
 766                (cond ((eq c ?c)
 767                       (throw 'done 'clear))
 768                      ((eq c ?d)
 769                       (throw 'done 'detached))
 770                      ((eq c ??)
 771                       (with-output-to-temp-buffer "*Help*"
 772                         (save-excursion
 773                           (set-buffer standard-output)
 774                           (insert "\
 775 n - Create a normal signature
 776 c - Create a cleartext signature
 777 d - Create a detached signature
 778 ? - Show this help
 779 "))))
 780                      (t
 781                       (throw 'done nil))))))))
 782   (save-excursion
 783     (let ((context (epg-make-context))
 784           signature)
 785       (epg-context-set-armor context epa-armor)
 786       (epg-context-set-textmode context epa-textmode)
 787       (epg-context-set-signers context signers)
 788       (epg-context-set-passphrase-callback context
 789                                            #'epa-passphrase-callback-function)
 790       (epg-context-set-progress-callback context
 791                                          #'epa-progress-callback-function)
 792       (message "Signing...")
 793       (setq signature (epg-sign-string context
 794                                        (encode-coding-string
 795                                         (buffer-substring start end)
 796                                         coding-system-for-write)
 797                                        mode))
 798       (message "Signing...done")
 799       (delete-region start end)
 800       (insert (decode-coding-string signature coding-system-for-read)))))
 801
 802 ;;;###autoload
 803 (defun epa-encrypt-region (start end recipients)
 804   "Encrypt the current region between START and END for RECIPIENTS.
 805
 806 Don't use this command in Lisp programs!"
 807   (interactive
 808    (list (region-beginning) (region-end)
 809          (epa-select-keys (epg-make-context) "Select recipients for encryption.
 810 If no one is selected, symmetric encryption will be performed.  ")))
 811   (save-excursion
 812     (let ((context (epg-make-context))
 813           cipher)
 814       (epg-context-set-armor context epa-armor)
 815       (epg-context-set-textmode context epa-textmode)
 816       (epg-context-set-passphrase-callback context
 817                                            #'epa-passphrase-callback-function)
 818       (epg-context-set-progress-callback context
 819                                          #'epa-progress-callback-function)
 820       (message "Encrypting...")
 821       (setq cipher (epg-encrypt-string context
 822                                        (encode-coding-string
 823                                         (buffer-substring start end)
 824                                         coding-system-for-write)
 825                                        recipients))
 826       (message "Encrypting...done")
 827       (delete-region start end)
 828       (insert cipher))))
 829
 830 ;;;###autoload
 831 (defun epa-delete-keys (keys &optional allow-secret)
 832   "Delete selected KEYS.
 833
 834 Don't use this command in Lisp programs!"
 835   (interactive
 836    (let ((keys (epa--marked-keys)))
 837      (unless keys
 838        (error "No keys selected"))
 839      (list keys
 840            (eq (nth 1 epa-list-keys-arguments) t))))
 841   (let ((context (epg-make-context)))
 842     (message "Deleting...")
 843     (epg-delete-keys context keys allow-secret)
 844     (message "Deleting...done")
 845     (apply #'epa-list-keys epa-list-keys-arguments)))
 846
 847 ;;;###autoload
 848 (defun epa-import-keys (file)
 849   "Import keys from FILE.
 850
 851 Don't use this command in Lisp programs!"
 852   (interactive "fFile: ")
 853   (setq file (expand-file-name file))
 854   (let ((context (epg-make-context)))
 855     (message "Importing %s..." (file-name-nondirectory file))
 856     (condition-case nil
 857         (progn
 858           (epg-import-keys-from-file context file)
 859           (message "Importing %s...done" (file-name-nondirectory file)))
 860       (error
 861        (message "Importing %s...failed" (file-name-nondirectory file))))
 862     (if (epg-context-result-for context 'import)
 863         (epa-display-info (epg-import-result-to-string
 864                            (epg-context-result-for context 'import))))
 865     (if (eq major-mode 'epa-keys-mode)
 866         (apply #'epa-list-keys epa-list-keys-arguments))))
 867
 868 ;;;###autoload
 869 (defun epa-export-keys (keys file)
 870   "Export selected KEYS to FILE.
 871
 872 Don't use this command in Lisp programs!"
 873   (interactive
 874    (let ((keys (epa--marked-keys))
 875          default-name)
 876      (unless keys
 877        (error "No keys selected"))
 878      (setq default-name
 879            (expand-file-name
 880             (concat (epg-sub-key-id (car (epg-key-sub-key-list (car keys))))
 881                     (if epa-armor ".asc" ".gpg"))
 882             default-directory))
 883      (list keys
 884            (expand-file-name
 885             (read-file-name
 886              (concat "To file (default "
 887                      (file-name-nondirectory default-name)
 888                      ") ")
 889              (file-name-directory default-name)
 890              default-name)))))
 891   (let ((context (epg-make-context)))
 892     (epg-context-set-armor context epa-armor)
 893     (message "Exporting to %s..." (file-name-nondirectory file))
 894     (epg-export-keys-to-file context keys file)
 895     (message "Exporting to %s...done" (file-name-nondirectory file))))
 896
 897 ;;;###autoload
 898 (defun epa-sign-keys (keys &optional local)
 899   "Sign selected KEYS.
 900 If a prefix-arg is specified, the signature is marked as non exportable.
 901
 902 Don't use this command in Lisp programs!"
 903   (interactive
 904    (let ((keys (epa--marked-keys)))
 905      (unless keys
 906        (error "No keys selected"))
 907      (list keys current-prefix-arg)))
 908   (let ((context (epg-make-context)))
 909     (epg-context-set-passphrase-callback context
 910                                          #'epa-passphrase-callback-function)
 911     (epg-context-set-progress-callback context
 912                                        #'epa-progress-callback-function)
 913     (message "Signing keys...")
 914     (epg-sign-keys context keys local)
 915     (message "Signing keys...done")))
 916 (make-obsolete 'epa-sign-keys "Do not use.")
 917
 918 (provide 'epa)
 919
 920 ;;; epa.el ends here