epg-config.el

   1 ;;; epg-config.el --- configuration of the EasyPG Library
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (defgroup epg ()
  27   "The EasyPG Library"
  28   :group 'emacs)
  29
  30 (defcustom epg-gpg-program "gpg"
  31   "The `gpg' executable."
  32   :group 'epg
  33   :type 'string)
  34
  35 (defcustom epg-gpgsm-program "gpgsm"
  36   "The `gpgsm' executable."
  37   :group 'epg
  38   :type 'string)
  39
  40 (defcustom epg-gpg-home-directory nil
  41   "The directory which contains the configuration files of `epg-gpg-program'."
  42   :group 'epg
  43   :type '(choice (const :tag "Default" nil) directory))
  44
  45 (defcustom epg-locale-coding-system (if (boundp 'locale-coding-system)
  46                                         locale-coding-system)
  47   "Coding system to use with messages from `epg-gpg-program'."
  48   :group 'epg
  49   :type 'symbol)
  50
  51 (defconst epg-version-number "0.0.4")
  52
  53 (defconst epg-gpg-minimum-version "1.4.3")
  54
  55 ;;;###autoload
  56 (defun epg-configuration ()
  57   "Return a list of internal configuration parameters of `epg-gpg-program'."
  58   (let (config type)
  59     (with-temp-buffer
  60       (apply #'call-process epg-gpg-program nil (list t nil) nil
  61              (append (if epg-gpg-home-directory
  62                          (list "--homedir" epg-gpg-home-directory))
  63                      '("--with-colons" "--list-config")))
  64       (goto-char (point-min))
  65       (while (re-search-forward "^cfg:\\([^:]+\\):\\(.*\\)" nil t)
  66         (setq type (intern (match-string 1))
  67               config (cons (cons type
  68                                  (if (memq type
  69                                            '(pubkey cipher digest compress))
  70                                      (mapcar #'string-to-number
  71                                              (delete "" (split-string
  72                                                          (match-string 2)
  73                                                          ";")))
  74                                    (match-string 2)))
  75                            config))))
  76     config))
  77
  78 (defun epg-config--parse-version (string)
  79   (let ((index 0)
  80         version)
  81     (while (eq index (string-match "\\([0-9]+\\)\\.?" string index))
  82       (setq version (cons (string-to-number (match-string 1 string))
  83                           version)
  84             index (match-end 0)))
  85     (nreverse version)))
  86
  87 (defun epg-config--compare-version (v1 v2)
  88   (while (and v1 v2 (= (car v1) (car v2)))
  89     (setq v1 (cdr v1) v2 (cdr v2)))
  90   (- (or (car v1) 0) (or (car v2) 0)))
  91
  92 ;;;###autoload
  93 (defun epg-check-configuration (config &optional minimum-version)
  94   "Verify that a sufficient version of GnuPG is installed."
  95   (let ((entry (assq 'version config))
  96         version)
  97     (unless (and entry
  98                  (stringp (cdr entry)))
  99       (error "Undetermined version: %S" entry))
 100     (setq version (epg-config--parse-version (cdr entry))
 101           minimum-version (epg-config--parse-version
 102                            (or minimum-version
 103                                epg-gpg-minimum-version)))
 104     (unless (>= (epg-config--compare-version version minimum-version) 0)
 105       (error "Unsupported version: %s" (cdr entry)))))
 106
 107 (provide 'epg-config)
 108
 109 ;;; epg-config.el ends here