epg.el

   1 ;;; epg.el --- EasyPG, yet another GnuPG interface.
   2 ;; Copyright (C) 1999, 2000, 2002, 2003, 2004,
   3 ;;   2005, 2006 Free Software Foundation, Inc.
   4 ;; Copyright (C) 2006 Daiki Ueno
   5
   6 ;; Author: Daiki Ueno <ueno@unixuser.org>
   7 ;; Keywords: PGP, GnuPG
   8
   9 ;; This file is part of EasyPG.
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Code:
  27
  28 (defgroup epg ()
  29   "EasyPG, yet another GnuPG interface.")
  30
  31 (defcustom epg-gpg-program "gpg"
  32   "The `gpg' executable."
  33   :group 'epg
  34   :type 'string)
  35
  36 (defvar epg-user-id nil
  37   "GnuPG ID of your default identity.")
  38
  39 (defvar epg-user-id-alist nil
  40   "An alist mapping from key ID to user ID.")
  41
  42 (defvar epg-read-point nil)
  43 (defvar epg-pending-status-list nil)
  44 (defvar epg-key-id nil)
  45 (defvar epg-context nil)
  46 (defvar epg-debug nil)
  47
  48 (defvar epg-colons-pub-spec
  49   '((trust "[^:]")
  50     (length "[0-9]+" 0 string-to-number)
  51     (algorithm "[0-9]+" 0 string-to-number)
  52     (key-id "[^:]+")
  53     (creation-date "[0-9]+")
  54     (expiration-date "[0-9]+")
  55     nil
  56     (ownertrust "[^:]")
  57     nil
  58     nil
  59     (capability "[escaESCA]*"))
  60   "The schema of keylisting output whose type is \"pub\".
  61 This is used by `epg-list-keys'.")
  62
  63 (defvar epg-colons-sec-spec
  64   '((trust "[^:]")
  65     (length "[0-9]+" 0 string-to-number)
  66     (algorithm "[0-9]+" 0 string-to-number)
  67     (key-id "[^:]+")
  68     (creation-date "[0-9]+")
  69     (expiration-date "[0-9]+")
  70     nil
  71     (ownertrust "[^:]"))
  72 "The schema of keylisting output whose type is \"sec\".
  73 This is used by `epg-list-keys'.")
  74
  75 (defvar epg-colons-uid-spec
  76   '((trust "[^:]")
  77     nil
  78     nil
  79     nil
  80     (creation-date "[0-9]+")
  81     (expiration-date "[0-9]+")
  82     (hash "[^:]+")
  83     nil
  84     (user-id "[^:]+"))
  85   "The schema of keylisting output whose type is \"uid\".
  86 This is used by `epg-list-keys'.")
  87
  88 (defconst epg-cipher-algorithm-alist
  89   '((0 . "NONE")
  90     (1 . "IDEA")
  91     (2 . "3DES")
  92     (3 . "CAST5")
  93     (4 . "BLOWFISH")
  94     (7 . "AES")
  95     (8 . "AES192")
  96     (9 . "AES256")
  97     (10 . "TWOFISH")
  98     (110 . "DUMMY")))
  99
 100 (defconst epg-pubkey-algorithm-alist
 101   '((1 . "RSA")
 102     (2 . "RSA_E")
 103     (3 . "RSA_S")
 104     (16 . "ELGAMAL_E")
 105     (17 . "DSA")
 106     (20 . "ELGAMAL")))
 107
 108 (defconst epg-digest-algorithm-alist
 109   '((1 . "MD5")
 110     (2 . "SHA1")
 111     (3 . "RMD160")
 112     (8 . "SHA256")
 113     (9 . "SHA384")
 114     (10 . "SHA512")))
 115
 116 (defconst epg-compress-algorithm-alist
 117   '((0 . "NONE")
 118     (1 . "ZIP")
 119     (2 . "ZLIB")
 120     (3 . "BZIP2")))
 121
 122 (defvar epg-prompt-alist nil)
 123
 124 (defun epg-make-data-from-file (file)
 125   "Make a data object from FILE."
 126   (vector file nil))
 127
 128 (defun epg-make-data-from-string (string)
 129   "Make a data object from STRING."
 130   (vector nil string))
 131
 132 (defun epg-data-file (data)
 133   "Return the file of DATA."
 134   (aref data 0))
 135
 136 (defun epg-data-string (data)
 137   "Return the string of DATA."
 138   (aref data 1))
 139
 140 (defun epg-make-context (&optional protocol armor textmode include-certs)
 141   "Return a context object."
 142   (vector protocol armor textmode include-certs
 143           #'epg-passphrase-callback-function
 144           #'epg-progress-callback-function
 145           nil nil nil nil))
 146
 147 (defun epg-context-protocol (context)
 148   "Return the protocol used within the context."
 149   (aref context 0))
 150
 151 (defun epg-context-armor (context)
 152   "Return t if the output shouled be ASCII armored in the CONTEXT context."
 153   (aref context 1))
 154
 155 (defun epg-context-textmode (context)
 156   "Return t if canonical text mode should be used in the CONTEXT context."
 157   (aref context 2))
 158
 159 (defun epg-context-include-certs (context)
 160   "Return how many certificates should be included in an S/MIME signed
 161 message."
 162   (aref context 3))
 163
 164 (defun epg-context-passphrase-callback (context)
 165   "Return the function used to query passphrase."
 166   (aref context 4))
 167
 168 (defun epg-context-progress-callback (context)
 169   "Return the function which handles progress update."
 170   (aref context 5))
 171
 172 (defun epg-context-signers (context)
 173   "Return the list of key-id for singning."
 174   (aref context 6))
 175
 176 (defun epg-context-process (context)
 177   "Return the process object of `epg-gpg-program'.
 178 This function is for internal use only."
 179   (aref context 7))
 180
 181 (defun epg-context-output-file (context)
 182   "Return the output file of `epg-gpg-program'.
 183 This function is for internal use only."
 184   (aref context 8))
 185
 186 (defun epg-context-result (context)
 187   "Return the result of the previous cryptographic operation."
 188   (aref context 9))
 189
 190 (defun epg-context-set-protocol (context protocol)
 191   "Set the protocol used within the context."
 192   (aset context 0 protocol))
 193
 194 (defun epg-context-set-armor (context armor)
 195   "Specify if the output shouled be ASCII armored in the CONTEXT context."
 196   (aset context 1 armor))
 197
 198 (defun epg-context-set-textmode (context textmode)
 199   "Specify if canonical text mode should be used in the CONTEXT context."
 200   (aset context 2 textmode))
 201
 202 (defun epg-context-set-include-certs (context include-certs)
 203  "Set how many certificates should be included in an S/MIME signed message."
 204   (aset context 3 include-certs))
 205
 206 (defun epg-context-set-passphrase-callback (context
 207                                                  passphrase-callback)
 208   "Set the function used to query passphrase."
 209   (aset context 4 passphrase-callback))
 210
 211 (defun epg-context-set-progress-callback (context progress-callback)
 212   "Set the function which handles progress update."
 213   (aset context 5 progress-callback))
 214
 215 (defun epg-context-set-signers (context signers)
 216  "Set the list of key-id for singning."
 217   (aset context 6 signers))
 218
 219 (defun epg-context-set-process (context process)
 220   "Set the process object of `epg-gpg-program'.
 221 This function is for internal use only."
 222   (aset context 7 process))
 223
 224 (defun epg-context-set-output-file (context output-file)
 225   "Set the output file of `epg-gpg-program'.
 226 This function is for internal use only."
 227   (aset context 8 output-file))
 228
 229 (defun epg-context-set-result (context result)
 230   "Set the result of the previous cryptographic operation."
 231   (aset context 9 result))
 232
 233 (defun epg-make-signature (status key-id user-id)
 234   "Return a signature object."
 235   (vector status key-id user-id nil nil))
 236
 237 (defun epg-signature-status (signature)
 238   "Return the status code of SIGNATURE."
 239   (aref signature 0))
 240
 241 (defun epg-signature-key-id (signature)
 242   "Return the key-id of SIGNATURE."
 243   (aref signature 1))
 244
 245 (defun epg-signature-user-id (signature)
 246   "Return the user-id of SIGNATURE."
 247   (aref signature 2))
 248
 249 (defun epg-signature-validity (signature)
 250   "Return the validity of SIGNATURE."
 251   (aref signature 3))
 252
 253 (defun epg-signature-fingerprint (signature)
 254   "Return the fingerprint of SIGNATURE."
 255   (aref signature 4))
 256
 257 (defun epg-signature-set-status (signature status)
 258  "Set the status code of SIGNATURE."
 259   (aset signature 0 status))
 260
 261 (defun epg-signature-set-key-id (signature key-id)
 262  "Set the key-id of SIGNATURE."
 263   (aset signature 1 key-id))
 264
 265 (defun epg-signature-set-user-id (signature user-id)
 266  "Set the user-id of SIGNATURE."
 267   (aset signature 2 user-id))
 268
 269 (defun epg-signature-set-validity (signature validity)
 270  "Set the validity of SIGNATURE."
 271   (aset signature 3 validity))
 272
 273 (defun epg-signature-set-fingerprint (signature fingerprint)
 274  "Set the fingerprint of SIGNATURE."
 275   (aset signature 4 fingerprint))
 276
 277 (defun epg-context-result-for (context name)
 278   (cdr (assq name (epg-context-result context))))
 279
 280 (defun epg-context-set-result-for (context name value)
 281   (let* ((result (epg-context-result context))
 282          (entry (assq name result)))
 283     (if entry
 284         (setcdr entry value)
 285       (epg-context-set-result context (cons (cons name value) result)))))
 286
 287 (defun epg-start (context args)
 288   "Start `epg-gpg-program' in a subprocess with given ARGS."
 289   (let* ((args (append (list "--no-tty"
 290                              "--status-fd" "1"
 291                              "--command-fd" "0")
 292                        (if (epg-context-armor context) '("--armor"))
 293                        (if (epg-context-textmode context) '("--textmode"))
 294                        (if (epg-context-output-file context)
 295                            (list "--output" (epg-context-output-file context)))
 296                        args))
 297          (coding-system-for-write 'binary)
 298          process-connection-type
 299          (orig-mode (default-file-modes))
 300          (buffer (generate-new-buffer " *epg*"))
 301          process)
 302     (with-current-buffer buffer
 303       (make-local-variable 'epg-read-point)
 304       (setq epg-read-point (point-min))
 305       (make-local-variable 'epg-pending-status-list)
 306       (setq epg-pending-status-list nil)
 307       (make-local-variable 'epg-key-id)
 308       (setq epg-key-id nil)
 309       (make-local-variable 'epg-context)
 310       (setq epg-context context))
 311     (unwind-protect
 312         (progn
 313           (set-default-file-modes 448)
 314           (setq process
 315                 (apply #'start-process "epg" buffer epg-gpg-program args)))
 316       (set-default-file-modes orig-mode))
 317     (set-process-filter process #'epg-process-filter)
 318     (epg-context-set-process context process)))
 319
 320 (defun epg-process-filter (process input)
 321   (if epg-debug
 322       (save-excursion
 323         (set-buffer (get-buffer-create  " *epg-debug*"))
 324         (goto-char (point-max))
 325         (insert input)))
 326   (if (buffer-live-p (process-buffer process))
 327       (save-excursion
 328         (set-buffer (process-buffer process))
 329         (goto-char (point-max))
 330         (insert input)
 331         (goto-char epg-read-point)
 332         (beginning-of-line)
 333         (while (looking-at ".*\n")      ;the input line is finished
 334           (save-excursion
 335             (if (looking-at "\\[GNUPG:] \\([A-Z_]+\\) ?\\(.*\\)")
 336                 (let* ((status (match-string 1))
 337                        (string (match-string 2))
 338                        (symbol (intern-soft (concat "epg-status-" status))))
 339                   (if (member status epg-pending-status-list)
 340                       (setq epg-pending-status-list nil))
 341                   (if (and symbol
 342                            (fboundp symbol))
 343                       (funcall symbol process string)))))
 344           (forward-line))
 345         (setq epg-read-point (point)))))
 346
 347 (defun epg-read-output (context)
 348   (with-temp-buffer
 349     (if (fboundp 'set-buffer-multibyte)
 350         (set-buffer-multibyte nil))
 351     (if (file-exists-p (epg-context-output-file context))
 352         (let ((coding-system-for-read (if (epg-context-textmode context)
 353                                           'raw-text
 354                                         'binary)))
 355           (insert-file-contents (epg-context-output-file context))
 356           (buffer-string)))))
 357
 358 (defun epg-wait-for-status (context status-list)
 359   (with-current-buffer (process-buffer (epg-context-process context))
 360     (setq epg-pending-status-list status-list)
 361     (while (and (eq (process-status (epg-context-process context)) 'run)
 362                 epg-pending-status-list)
 363       (accept-process-output (epg-context-process context) 1))))
 364
 365 (defun epg-wait-for-completion (context)
 366   (if (eq (process-status (epg-context-process context)) 'run)
 367       (process-send-eof (epg-context-process context)))
 368   (while (eq (process-status (epg-context-process context)) 'run)
 369     ;; We can't use accept-process-output instead of sit-for here
 370     ;; because it may cause an interrupt during the sentinel execution.
 371     (sit-for 0.1)))
 372
 373 (defun epg-reset (context)
 374   (if (and (epg-context-process context)
 375            (buffer-live-p (process-buffer (epg-context-process context))))
 376       (kill-buffer (process-buffer (epg-context-process context))))
 377   (epg-context-set-process context nil))
 378
 379 (defun epg-delete-output-file (context)
 380   (if (and (epg-context-output-file context)
 381            (file-exists-p (epg-context-output-file context)))
 382       (delete-file (epg-context-output-file context))))
 383
 384 (defun epg-status-USERID_HINT (process string)
 385   (if (string-match "\\`\\([^ ]+\\) \\(.*\\)" string)
 386       (let* ((key-id (match-string 1 string))
 387              (user-id (match-string 2 string))
 388              (entry (assoc key-id epg-user-id-alist)))
 389         (if entry
 390             (setcdr entry user-id)
 391           (setq epg-user-id-alist (cons (cons key-id user-id)
 392                                         epg-user-id-alist))))))
 393
 394 (defun epg-status-NEED_PASSPHRASE (process string)
 395   (if (string-match "\\`\\([^ ]+\\)" string)
 396       (setq epg-key-id (match-string 1 string))))
 397
 398 (defun epg-status-NEED_PASSPHRASE_SYM (process string)
 399   (setq epg-key-id 'SYM))
 400
 401 (defun epg-status-NEED_PASSPHRASE_PIN (process string)
 402   (setq epg-key-id 'PIN))
 403
 404 (defun epg-status-GET_HIDDEN (process string)
 405   (let ((passphrase
 406          (funcall (if (consp (epg-context-passphrase-callback epg-context))
 407                       (car (epg-context-passphrase-callback epg-context))
 408                     (epg-context-passphrase-callback epg-context))
 409                   epg-key-id
 410                   (if (consp (epg-context-passphrase-callback epg-context))
 411                       (cdr (epg-context-passphrase-callback epg-context)))))
 412         string)
 413     (if passphrase
 414         (unwind-protect
 415             (progn
 416               (setq string (concat passphrase "\n"))
 417               (fillarray passphrase 0)
 418               (setq passphrase nil)
 419               (process-send-string process string))
 420           (if string
 421               (fillarray string 0))))))
 422
 423 (defun epg-status-GET_BOOL (process string)
 424   (let ((entry (assoc string epg-prompt-alist)))
 425     (if (y-or-n-p (if entry (cdr entry) (concat string "? ")))
 426         (process-send-string process "y\n")
 427       (process-send-string process "n\n"))))
 428
 429 (defun epg-status-GET_LINE (process string)
 430   (let* ((entry (assoc string epg-prompt-alist))
 431          (string (read-string (if entry (cdr entry) (concat string ": ")))))
 432     (process-send-string process (concat string "\n"))))
 433
 434 (defun epg-status-GOODSIG (process string)
 435   (if (string-match "\\`\\([^ ]+\\) \\(.*\\)" string)
 436       (epg-context-set-result-for
 437        epg-context
 438        'verify
 439        (cons (epg-make-signature 'good
 440                                  (match-string 1 string)
 441                                  (match-string 2 string))
 442              (epg-context-result-for epg-context 'verify)))))
 443
 444 (defun epg-status-EXPSIG (process string)
 445   (if (string-match "\\`\\([^ ]+\\) \\(.*\\)" string)
 446       (epg-context-set-result-for
 447        epg-context
 448        'verify
 449        (cons (epg-make-signature 'expired
 450                                  (match-string 1 string)
 451                                  (match-string 2 string))
 452              (epg-context-result-for epg-context 'verify)))))
 453
 454 (defun epg-status-EXPKEYSIG (process string)
 455   (if (string-match "\\`\\([^ ]+\\) \\(.*\\)" string)
 456       (epg-context-set-result-for
 457        epg-context
 458        'verify
 459        (cons (epg-make-signature 'expired-key
 460                                  (match-string 1 string)
 461                                  (match-string 2 string))
 462              (epg-context-result-for epg-context 'verify)))))
 463
 464 (defun epg-status-REVKEYSIG (process string)
 465   (if (string-match "\\`\\([^ ]+\\) \\(.*\\)" string)
 466       (epg-context-set-result-for
 467        epg-context
 468        'verify
 469        (cons (epg-make-signature 'revoked-key
 470                                  (match-string 1 string)
 471                                  (match-string 2 string))
 472              (epg-context-result-for epg-context 'verify)))))
 473
 474 (defun epg-status-BADSIG (process string)
 475   (if (string-match "\\`\\([^ ]+\\) \\(.*\\)" string)
 476       (epg-context-set-result-for
 477        epg-context
 478        'verify
 479        (cons (epg-make-signature 'bad
 480                                  (match-string 1 string)
 481                                  (match-string 2 string))
 482              (epg-context-result-for epg-context 'verify)))))
 483
 484 (defun epg-status-VALIDSIG (process string)
 485   (let ((signature (car (epg-context-result-for epg-context 'verify))))
 486     (if (and signature
 487              (eq (epg-signature-status signature) 'good)
 488              (string-match "\\`\\([^ ]+\\) " string))
 489         (epg-signature-set-fingerprint signature (match-string 1 string)))))
 490
 491 (defun epg-status-TRUST_UNDEFINED (process string)
 492   (let ((signature (car (epg-context-result-for epg-context 'verify))))
 493     (if (and signature
 494              (eq (epg-signature-status signature) 'good))
 495         (epg-signature-set-validity signature 'undefined))))
 496
 497 (defun epg-status-TRUST_NEVER (process string)
 498   (let ((signature (car (epg-context-result-for epg-context 'verify))))
 499     (if (and signature
 500              (eq (epg-signature-status signature) 'good))
 501         (epg-signature-set-validity signature 'never))))
 502
 503 (defun epg-status-TRUST_MARGINAL (process string)
 504   (let ((signature (car (epg-context-result-for epg-context 'verify))))
 505     (if (and signature
 506              (eq (epg-signature-status signature) 'marginal))
 507         (epg-signature-set-validity signature 'marginal))))
 508
 509 (defun epg-status-TRUST_FULLY (process string)
 510   (let ((signature (car (epg-context-result-for epg-context 'verify))))
 511     (if (and signature
 512              (eq (epg-signature-status signature) 'good))
 513         (epg-signature-set-validity signature 'fully))))
 514
 515 (defun epg-status-TRUST_ULTIMATE (process string)
 516   (let ((signature (car (epg-context-result-for epg-context 'verify))))
 517     (if (and signature
 518              (eq (epg-signature-status signature) 'good))
 519         (epg-signature-set-validity signature 'ultimate))))
 520
 521 (defun epg-status-PROGRESS (process string)
 522   (if (string-match "\\`\\([^ ]+\\) \\([^ ]\\) \\([0-9]+\\) \\([0-9]+\\)"
 523                     string)
 524       (funcall (if (consp (epg-context-progress-callback epg-context))
 525                    (car (epg-context-progress-callback epg-context))
 526                  (epg-context-progress-callback epg-context))
 527                (match-string 1 string)
 528                (match-string 2 string)
 529                (string-to-number (match-string 3 string))
 530                (string-to-number (match-string 4 string))
 531                (if (consp (epg-context-progress-callback epg-context))
 532                    (cdr (epg-context-progress-callback epg-context))))))
 533
 534 (defun epg-status-DECRYPTION_FAILED (process string)
 535   (epg-context-set-result-for
 536    epg-context 'error
 537    (cons 'decryption-failed
 538          (epg-context-result-for epg-context 'error))))
 539
 540 (defun epg-status-NODATA (process string)
 541   (epg-context-set-result-for
 542    epg-context 'error
 543    (cons (cons 'no-data (string-to-number string))
 544          (epg-context-result-for epg-context 'error))))
 545
 546 (defun epg-status-UNEXPECTED (process string)
 547   (epg-context-set-result-for
 548    epg-context 'error
 549    (cons (cons 'unexpected (string-to-number string))
 550          (epg-context-result-for epg-context 'error))))
 551
 552 (defun epg-status-KEYEXPIRED (process string)
 553   (epg-context-set-result-for
 554    epg-context 'error
 555    (cons (cons 'key-expired string)
 556          (epg-context-result-for epg-context 'error))))
 557
 558 (defun epg-status-KEYREVOKED (process string)
 559   (epg-context-set-result-for
 560    epg-context 'error
 561    (cons 'key-revoked
 562          (epg-context-result-for epg-context 'error))))
 563
 564 (defun epg-status-BADARMOR (process string)
 565   (epg-context-set-result-for
 566    epg-context 'error
 567    (cons 'bad-armor
 568          (epg-context-result-for epg-context 'error))))
 569
 570 (defun epg-passphrase-callback-function (key-id handback)
 571   (read-passwd
 572    (if (eq key-id 'SYM)
 573        "Passphrase for symmetric encryption: "
 574      (if (eq key-id 'PIN)
 575          "Passphrase for PIN: "
 576        (let ((entry (assoc key-id epg-user-id-alist)))
 577          (if entry
 578              (format "Passphrase for %s %s: " key-id (cdr entry))
 579            (format "Passphrase for %s: " key-id)))))))
 580
 581 (defun epg-progress-callback-function (what char current total handback)
 582   (message "%s: %d%%/%d%%" what current total))
 583
 584 (defun epg-configuration ()
 585   "Return a list of internal configuration parameters of `epg-gpg-program'."
 586   (let (config type)
 587     (with-temp-buffer
 588       (apply #'call-process epg-gpg-program nil (list t nil) nil
 589              '("--with-colons" "--list-config"))
 590       (goto-char (point-min))
 591       (while (re-search-forward "^cfg:\\([^:]+\\):\\(.*\\)" nil t)
 592         (setq type (intern (match-string 1))
 593               config (cons (cons type
 594                                  (if (memq type
 595                                            '(pubkey cipher digest compress))
 596                                      (mapcar #'string-to-number
 597                                              (delete "" (split-string
 598                                                          (match-string 2)
 599                                                          ";")))
 600                                    (match-string 2)))
 601                            config))))
 602     config))
 603
 604 (defun epg-list-keys (name &optional secret)
 605   "List keys associated with STRING."
 606   (let ((args (append (list "--with-colons" "--no-greeting" "--batch"
 607                             "--fixed-list-mode"
 608                             (if secret "--list-secret-keys" "--list-keys"))
 609                       (if name (list name))))
 610         keys type symbol pointer)
 611     (with-temp-buffer
 612       (apply #'call-process epg-gpg-program nil (list t nil) nil args)
 613       (goto-char (point-min))
 614       (while (re-search-forward "^\\([a-z][a-z][a-z]\\):\\(.*\\)" nil t)
 615         (setq type (match-string 1)
 616               symbol (intern-soft (format "epg-colons-%s-spec" type)))
 617         (if (member type '("pub" "sec"))
 618             (setq keys (cons nil keys)))
 619         (if (and symbol
 620                  (boundp symbol))
 621             (setcar keys (cons (cons (intern type)
 622                                      (epg-parse-colons
 623                                       (symbol-value symbol)
 624                                       (match-string 2)))
 625                                (car keys))))
 626         (forward-line)))
 627     (setq pointer keys)
 628     (while pointer
 629       (setcar pointer (nreverse (car pointer)))
 630       (setq pointer (cdr pointer)))
 631     (nreverse keys)))
 632
 633 (defun epg-parse-colons (alist string)
 634   (let ((index 0)
 635         result)
 636     (while (and alist
 637                 (or (null (car alist))
 638                     (eq index
 639                         (string-match
 640                          (concat "\\(" (nth 1 (car alist)) "\\)?:")
 641                          string index))))
 642       (if (car alist)
 643           (progn
 644             (setq index (match-end 0))
 645             (if (match-beginning 1)
 646                 (setq result
 647                       (cons (cons (car (car alist))
 648                                   (funcall (or (nth 3 (car alist)) #'identity)
 649                                            (match-string
 650                                             (1+ (or (nth 2 (car alist)) 0))
 651                                             string)))
 652                             result))))
 653         (setq index (1+ index)))
 654       (setq alist (cdr alist)))
 655     (nreverse result)))
 656
 657 (if (fboundp 'make-temp-file)
 658     (defalias 'epg-make-temp-file 'make-temp-file)
 659   ;; stolen from poe.el.
 660   (defun epg-make-temp-file (prefix)
 661     "Create a temporary file.
 662 The returned file name (created by appending some random characters at the end
 663 of PREFIX, and expanding against `temporary-file-directory' if necessary),
 664 is guaranteed to point to a newly created empty file.
 665 You can then use `write-region' to write new data into the file."
 666     (let (tempdir tempfile)
 667       (unwind-protect
 668           (let (file)
 669             ;; First, create a temporary directory.
 670             (while (condition-case ()
 671                        (progn
 672                          (setq tempdir (make-temp-name
 673                                         (concat
 674                                          (file-name-directory prefix)
 675                                          "DIR")))
 676                          ;; return nil or signal an error.
 677                          (make-directory tempdir))
 678                      ;; let's try again.
 679                      (file-already-exists t)))
 680             (set-file-modes tempdir 448)
 681             ;; Second, create a temporary file in the tempdir.
 682             ;; There *is* a race condition between `make-temp-name'
 683             ;; and `write-region', but we don't care it since we are
 684             ;; in a private directory now.
 685             (setq tempfile (make-temp-name (concat tempdir "/EMU")))
 686             (write-region "" nil tempfile nil 'silent)
 687             (set-file-modes tempfile 384)
 688             ;; Finally, make a hard-link from the tempfile.
 689             (while (condition-case ()
 690                        (progn
 691                          (setq file (make-temp-name prefix))
 692                          ;; return nil or signal an error.
 693                          (add-name-to-file tempfile file))
 694                      ;; let's try again.
 695                      (file-already-exists t)))
 696             file)
 697         ;; Cleanup the tempfile.
 698         (and tempfile
 699              (file-exists-p tempfile)
 700              (delete-file tempfile))
 701         ;; Cleanup the tempdir.
 702         (and tempdir
 703              (file-directory-p tempdir)
 704              (delete-directory tempdir))))))
 705
 706 ;;;###autoload
 707 (defun epg-start-decrypt (context cipher)
 708   "Initiate a decrypt operation on CIPHER.
 709 CIPHER is a data object.
 710
 711 If you use this function, you will need to wait for the completion of
 712 `epg-gpg-program' by using `epg-wait-for-completion' and call
 713 `epg-reset' to clear a temporaly output file.
 714 If you are unsure, use synchronous version of this function
 715 `epg-decrypt-file' or `epg-decrypt-string' instead."
 716   (unless (epg-data-file cipher)
 717     (error "Not a file"))
 718   (epg-context-set-result context nil)
 719   (epg-start context (list "--decrypt" (epg-data-file cipher)))
 720   (epg-wait-for-status context '("BEGIN_DECRYPTION")))
 721
 722 ;;;###autoload
 723 (defun epg-decrypt-file (context cipher plain)
 724   "Decrypt a file CIPHER and store the result to a file PLAIN.
 725 If PLAIN is nil, it returns the result as a string."
 726   (unwind-protect
 727       (progn
 728         (if plain
 729             (epg-context-set-output-file context plain)
 730           (epg-context-set-output-file context
 731                                        (epg-make-temp-file "epg-output")))
 732         (epg-start-decrypt context (epg-make-data-from-file cipher))
 733         (epg-wait-for-completion context)
 734         (if (epg-context-result-for context 'error)
 735             (error "Decryption failed"))
 736         (unless plain
 737           (epg-read-output context)))
 738     (unless plain
 739       (epg-delete-output-file context))
 740     (epg-reset context)))
 741
 742 ;;;###autoload
 743 (defun epg-decrypt-string (context cipher)
 744   "Decrypt a string CIPHER and return the plain text."
 745   (let ((input-file (epg-make-temp-file "epg-input"))
 746         (coding-system-for-write 'binary))
 747     (unwind-protect
 748         (progn
 749           (write-region cipher nil input-file)
 750           (epg-context-set-output-file context
 751                                        (epg-make-temp-file "epg-output"))
 752           (epg-start-decrypt context (epg-make-data-from-file input-file))
 753           (epg-wait-for-completion context)
 754           (if (epg-context-result-for context 'error)
 755               (error "Decryption failed"))
 756           (epg-read-output context))
 757       (epg-delete-output-file context)
 758       (if (file-exists-p input-file)
 759           (delete-file input-file))
 760       (epg-reset context))))
 761
 762 ;;;###autoload
 763 (defun epg-start-verify (context signature &optional signed-text)
 764   "Initiate a verify operation on SIGNATURE.
 765 SIGNATURE and SIGNED-TEXT are a data object if they are specified.
 766
 767 For a detached signature, both SIGNATURE and SIGNED-TEXT should be set.
 768 For a normal or a clear text signature, SIGNED-TEXT should be nil.
 769
 770 If you use this function, you will need to wait for the completion of
 771 `epg-gpg-program' by using `epg-wait-for-completion' and call
 772 `epg-reset' to clear a temporaly output file.
 773 If you are unsure, use synchronous version of this function
 774 `epg-verify-file' or `epg-verify-string' instead."
 775   (epg-context-set-result context nil)
 776   (if signed-text
 777       ;; Detached signature.
 778       (if (epg-data-file signed-text)
 779           (epg-start context (list "--verify" (epg-data-file signature)
 780                                    (epg-data-file signed-text)))
 781         (epg-start context (list "--verify" (epg-data-file signature) "-"))
 782         (if (eq (process-status (epg-context-process context)) 'run)
 783             (process-send-string (epg-context-process context)
 784                                  (epg-data-string signed-text))))
 785     ;; Normal (or cleartext) signature.
 786     (if (epg-data-file signature)
 787         (epg-start context (list "--verify" (epg-data-file signature)))
 788       (epg-start context (list "--verify"))
 789       (if (eq (process-status (epg-context-process context)) 'run)
 790           (process-send-string (epg-context-process context)
 791                                (epg-data-string signature))))))
 792
 793 ;;;###autoload
 794 (defun epg-verify-file (context signature &optional signed-text plain)
 795   "Verify a file SIGNATURE.
 796 SIGNED-TEXT and PLAIN are also a file if they are specified.
 797
 798 For a detached signature, both SIGNATURE and SIGNED-TEXT should be string.
 799 For a normal or a clear text signature, SIGNED-TEXT should be nil."
 800   (unwind-protect
 801       (progn
 802         (if plain
 803             (epg-context-set-output-file context plain)
 804           (epg-context-set-output-file context
 805                                        (epg-make-temp-file "epg-output")))
 806         (if signed-text
 807             (epg-start-verify context
 808                               (epg-make-data-from-file signature)
 809                               (epg-make-data-from-file signed-text))
 810           (epg-start-verify context
 811                             (epg-make-data-from-file signature)))
 812         (epg-wait-for-completion context)
 813         (unless plain
 814           (epg-read-output context)))
 815     (unless plain
 816       (epg-delete-output-file context))
 817     (epg-reset context)))
 818
 819 ;;;###autoload
 820 (defun epg-verify-string (context signature &optional signed-text)
 821   "Verify a string SIGNATURE.
 822 SIGNED-TEXT is a string if it is specified.
 823
 824 For a detached signature, both SIGNATURE and SIGNED-TEXT should be string.
 825 For a normal or a clear text signature, SIGNED-TEXT should be nil."
 826   (let ((coding-system-for-write 'binary)
 827         input-file)
 828     (unwind-protect
 829         (progn
 830           (epg-context-set-output-file context
 831                                        (epg-make-temp-file "epg-output"))
 832           (if signed-text
 833               (progn
 834                 (setq input-file (epg-make-temp-file "epg-signature"))
 835                 (write-region signature nil input-file)
 836                 (epg-start-verify context
 837                                   (epg-make-data-from-file input-file)
 838                                   (epg-make-data-from-string signed-text)))
 839             (epg-start-verify context (epg-make-data-from-string signature)))
 840           (epg-wait-for-completion context)
 841           (epg-read-output context))
 842       (epg-delete-output-file context)
 843       (if (and input-file
 844                (file-exists-p input-file))
 845           (delete-file input-file))
 846       (epg-reset context))))
 847
 848 ;;;###autoload
 849 (defun epg-start-sign (context plain &optional mode)
 850   "Initiate a sign operation on PLAIN.
 851 PLAIN is a data object.
 852
 853 If optional 3rd argument MODE is 'clearsign, it makes a clear text signature.
 854 If MODE is t or 'detached, it makes a detached signature.
 855 Otherwise, it makes a normal signature.
 856
 857 If you use this function, you will need to wait for the completion of
 858 `epg-gpg-program' by using `epg-wait-for-completion' and call
 859 `epg-reset' to clear a temporaly output file.
 860 If you are unsure, use synchronous version of this function
 861 `epg-sign-file' or `epg-sign-string' instead."
 862   (epg-context-set-result context nil)
 863   (epg-start context
 864              (append (list (if (eq mode 'clearsign)
 865                                "--clearsign"
 866                              (if (or (eq mode t) (eq mode 'detached))
 867                                  "--detach-sign"
 868                                "--sign")))
 869                      (apply #'nconc
 870                             (mapcar (lambda (signer)
 871                                       (list "-u" signer))
 872                                     (epg-context-signers context)))
 873                      (if (epg-data-file plain)
 874                          (list (epg-data-file plain)))))
 875   (epg-wait-for-status context '("BEGIN_SIGNING"))
 876   (if (and (epg-data-string plain)
 877            (eq (process-status (epg-context-process context)) 'run))
 878       (process-send-string (epg-context-process context)
 879                            (epg-data-string plain))))
 880
 881 ;;;###autoload
 882 (defun epg-sign-file (context plain signature &optional mode)
 883   "Sign a file PLAIN and store the result to a file SIGNATURE.
 884 If SIGNATURE is nil, it returns the result as a string.
 885 If optional 3rd argument MODE is 'clearsign, it makes a clear text signature.
 886 If MODE is t or 'detached, it makes a detached signature.
 887 Otherwise, it makes a normal signature."
 888   (unwind-protect
 889       (progn
 890         (if signature
 891             (epg-context-set-output-file context signature)
 892           (epg-context-set-output-file context
 893                                        (epg-make-temp-file "epg-output")))
 894         (epg-start-sign context (epg-make-data-from-file plain) mode)
 895         (epg-wait-for-completion context)
 896         (if (epg-context-result-for context 'error)
 897             (error "Sign failed"))
 898         (unless signature
 899           (epg-read-output context)))
 900     (unless signature
 901       (epg-delete-output-file context))
 902     (epg-reset context)))
 903
 904 ;;;###autoload
 905 (defun epg-sign-string (context plain &optional mode)
 906   "Sign a string PLAIN and return the output as string.
 907 If optional 3rd argument MODE is 'clearsign, it makes a clear text signature.
 908 If MODE is t or 'detached, it makes a detached signature.
 909 Otherwise, it makes a normal signature."
 910   (unwind-protect
 911       (progn
 912         (epg-context-set-output-file context
 913                                      (epg-make-temp-file "epg-output"))
 914         (epg-start-sign context (epg-make-data-from-string plain) mode)
 915         (epg-wait-for-completion context)
 916         (if (epg-context-result-for context 'error)
 917             (error "Sign failed"))
 918         (epg-read-output context))
 919     (epg-delete-output-file context)
 920     (epg-reset context)))
 921
 922 ;;;###autoload
 923 (defun epg-start-encrypt (context plain recipients
 924                                   &optional sign always-trust)
 925   "Initiate an encrypt operation on PLAIN.
 926 PLAIN is a data object.
 927 If RECIPIENTS is nil, it performs symmetric encryption.
 928
 929 If you use this function, you will need to wait for the completion of
 930 `epg-gpg-program' by using `epg-wait-for-completion' and call
 931 `epg-reset' to clear a temporaly output file.
 932 If you are unsure, use synchronous version of this function
 933 `epg-encrypt-file' or `epg-encrypt-string' instead."
 934   (epg-context-set-result context nil)
 935   (epg-start context
 936              (append (if always-trust '("--always-trust"))
 937                      (if recipients '("--encrypt") '("--symmetric"))
 938                      (if sign
 939                          (cons "--sign"
 940                                (apply #'nconc
 941                                       (mapcar (lambda (signer)
 942                                                 (list "-u" signer))
 943                                               (epg-context-signers context)))))
 944                      (apply #'nconc
 945                             (mapcar (lambda (recipient)
 946                                       (list "-r" recipient))
 947                                     recipients))
 948                      (if (epg-data-file plain)
 949                          (list (epg-data-file plain)))))
 950   (if sign
 951       (epg-wait-for-status context '("BEGIN_SIGNING"))
 952     (if (null recipients)
 953         (epg-wait-for-status context '("BEGIN_ENCRYPTION"))))
 954   (if (and (epg-data-string plain)
 955            (eq (process-status (epg-context-process context)) 'run))
 956       (process-send-string (epg-context-process context)
 957                            (epg-data-string plain))))
 958
 959 ;;;###autoload
 960 (defun epg-encrypt-file (context plain recipients
 961                                  cipher &optional sign always-trust)
 962   "Encrypt a file PLAIN and store the result to a file CIPHER.
 963 If CIPHER is nil, it returns the result as a string.
 964 If RECIPIENTS is nil, it performs symmetric encryption."
 965   (unwind-protect
 966       (progn
 967         (if cipher
 968             (epg-context-set-output-file context cipher)
 969           (epg-context-set-output-file context
 970                                        (epg-make-temp-file "epg-output")))
 971         (epg-start-encrypt context (epg-make-data-from-file plain)
 972                            recipients sign always-trust)
 973         (epg-wait-for-completion context)
 974         (if (epg-context-result-for context 'error)
 975             (error "Encrypt failed"))
 976         (unless cipher
 977           (epg-read-output context)))
 978     (unless cipher
 979       (epg-delete-output-file context))
 980     (epg-reset context)))
 981
 982 ;;;###autoload
 983 (defun epg-encrypt-string (context plain recipients
 984                                    &optional sign always-trust)
 985   "Encrypt a string PLAIN.
 986 If RECIPIENTS is nil, it performs symmetric encryption."
 987   (unwind-protect
 988       (progn
 989         (epg-context-set-output-file context
 990                                      (epg-make-temp-file "epg-output"))
 991         (epg-start-encrypt context (epg-make-data-from-string plain)
 992                            recipients sign always-trust)
 993         (epg-wait-for-completion context)
 994         (if (epg-context-result-for context 'error)
 995             (error "Encrypt failed"))
 996         (epg-read-output context))
 997     (epg-delete-output-file context)
 998     (epg-reset context)))
 999
1000 ;;;###autoload
1001 (defun epg-start-export-keys (context pattern)
1002   "Initiate an export keys operation.
1003
1004 If you use this function, you will need to wait for the completion of
1005 `epg-gpg-program' by using `epg-wait-for-completion' and call
1006 `epg-reset' to clear a temporaly output file.
1007 If you are unsure, use synchronous version of this function
1008 `epg-export-keys' instead."
1009   (epg-context-set-result context nil)
1010   (epg-context-set-output-file context (epg-make-temp-file "epg-output"))
1011   (epg-start context (list "--export" pattern)))
1012
1013 ;;;###autoload
1014 (defun epg-export-keys (context pattern)
1015   "Extract public keys matched with PATTERN and return them."
1016   (unwind-protect
1017       (progn
1018         (epg-start-export-keys context pattern)
1019         (epg-wait-for-completion context)
1020         (if (epg-context-result-for context 'error)
1021             (error "Export keys failed"))
1022         (epg-read-output context))
1023     (epg-reset context)))
1024
1025 ;;;###autoload
1026 (defun epg-start-import-keys (context keys)
1027   "Initiate an import keys operation.
1028 KEYS is a data object.
1029
1030 If you use this function, you will need to wait for the completion of
1031 `epg-gpg-program' by using `epg-wait-for-completion' and call
1032 `epg-reset' to clear a temporaly output file.
1033 If you are unsure, use synchronous version of this function
1034 `epg-import-keys-from-file' or `epg-import-keys-from-string' instead."
1035   (epg-context-set-result context nil)
1036   (epg-context-set-output-file context (epg-make-temp-file "epg-output"))
1037   (epg-start context (append (list "--import") (epg-data-file keys)))
1038   (if (and (epg-data-string keys)
1039            (eq (process-status (epg-context-process context)) 'run))
1040       (process-send-string (epg-context-process context)
1041                            (epg-data-string keys))))
1042
1043 (defun epg-import-keys-1 (context keys)
1044   (unwind-protect
1045       (progn
1046         (epg-start-import-keys context keys)
1047         (epg-wait-for-completion context)
1048         (if (epg-context-result-for context 'error)
1049             (error "Import keys failed"))
1050         (epg-read-output context))
1051     (epg-reset context)))
1052
1053 ;;;###autoload
1054 (defun epg-import-keys-from-file (context keys)
1055   "Add keys from a file KEYS."
1056   (epg-import-keys-1 context (epg-make-data-from-file keys)))
1057
1058 ;;;###autoload
1059 (defun epg-import-keys-from-string (context keys)
1060   "Add keys from a string KEYS."
1061   (epg-import-keys-1 context (epg-make-data-from-string keys)))
1062
1063 (provide 'epg)
1064
1065 ;;; epg.el ends here