lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999, 2003 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: XEmacs Development Team
   8 ;; Keywords: extensions, dumped
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  24 ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  25 ;; 02111-1307, USA.
  26
  27 ;;; Synched up with: FSF 21.3.
  28
  29 ;;; Commentary:
  30
  31 ;; This file is dumped with XEmacs.
  32
  33 ;; XEmacs is already, in a sense, object oriented -- each object
  34 ;; (buffer) belongs to a class (major mode), and that class defines
  35 ;; the relationship between messages (input events) and methods
  36 ;; (commands) by means of a keymap.
  37 ;;
  38 ;; The only thing missing is a good scheme of inheritance.  It is
  39 ;; possible to simulate a single level of inheritance with generous
  40 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  41 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  42 ;; -- but generally, each major mode ends up reinventing the wheel.
  43 ;; Ideally, someone should redesign all of Emacs's major modes to
  44 ;; follow a more conventional object-oriented system: when defining a
  45 ;; new major mode, the user should need only to name the existing mode
  46 ;; it is most similar to, then list the (few) differences.
  47 ;;
  48 ;; In the mean time, this package offers most of the advantages of
  49 ;; full inheritance with the existing major modes.  The macro
  50 ;; `define-derived-mode' allows the user to make a variant of an existing
  51 ;; major mode, with its own keymap.  The new mode will inherit the key
  52 ;; bindings of its parent, and will, in fact, run its parent first
  53 ;; every time it is called.  For example, the commands
  54 ;;
  55 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  56 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  57 ;;    (setq case-fold-search nil))
  58 ;;
  59 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  60 ;;
  61 ;; will create a function `hypertext-mode' with its own (sparse)
  62 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  63 ;; perform the following actions:
  64 ;;
  65 ;; - run the command (text-mode) to get its default setup
  66 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  67 ;;   inherit from 'text-mode-map'.
  68 ;; - replace the current syntax table with
  69 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  70 ;;   from the current text-mode-syntax-table.
  71 ;; - replace the current abbrev table with
  72 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  73 ;;   from the current text-mode-abbrev table
  74 ;; - change the mode line to read "Hypertext"
  75 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  76 ;; - run the body of commands provided in the macro -- in this case,
  77 ;;   set the local variable `case-fold-search' to nil.
  78 ;;
  79 ;; The advantages of this system are threefold.  First, text mode is
  80 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  81 ;; possibly using hooks, you would have added it to all text buffers
  82 ;; -- here, it appears only in hypertext buffers, where it makes
  83 ;; sense.  Second, it is possible to build even further, and make
  84 ;; a derived mode from a derived mode.  The commands
  85 ;;
  86 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  87 ;;   [various key definitions]
  88 ;;
  89 ;; will add a new major mode for HTML with very little fuss.
  90 ;;
  91 ;; Note also the function `derived-mode-p' which can tell if the current
  92 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  93 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  94 ;; be used in place of (eq major-mode 'text-mode).
  95 \f
  96 ;;; Code:
  97
  98 ;;; PRIVATE: defsubst must be defined before they are first used
  99
 100 (defsubst derived-mode-hook-name (mode)
 101   "Construct the mode hook name based on mode name MODE."
 102   (intern (concat (symbol-name mode) "-hook")))
 103
 104 (defsubst derived-mode-map-name (mode)
 105   "Construct a map name based on a MODE name."
 106   (intern (concat (symbol-name mode) "-map")))
 107
 108 (defsubst derived-mode-syntax-table-name (mode)
 109   "Construct a syntax-table name based on a MODE name."
 110   (intern (concat (symbol-name mode) "-syntax-table")))
 111
 112 (defsubst derived-mode-abbrev-table-name (mode)
 113   "Construct an abbrev-table name based on a MODE name."
 114   (intern (concat (symbol-name mode) "-abbrev-table")))
 115
 116 ;; PUBLIC: define a new major mode which inherits from an existing one.
 117
 118 ;; XEmacs -- no autoload
 119 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 120   "Create a new mode as a variant of an existing mode.
 121
 122 The arguments to this command are as follow:
 123
 124 CHILD:     the name of the command for the derived mode.
 125 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 126            or nil if there is no parent.
 127 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 128 DOCSTRING: an optional documentation string--if you do not supply one,
 129            the function will attempt to invent something useful.
 130 BODY:      forms to execute just before running the
 131            hooks for the new mode.  Do not use `interactive' here.
 132
 133 BODY can start with a bunch of keyword arguments.  The following keyword
 134   arguments are currently understood:
 135 :group GROUP
 136         Declare the customization group that corresponds to this mode.
 137 :syntax-table TABLE
 138         Use TABLE instead of the default.
 139         A nil value means to simply use the same syntax-table as the parent.
 140 :abbrev-table TABLE
 141         Use TABLE instead of the default.
 142         A nil value means to simply use the same abbrev-table as the parent.
 143
 144 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 145
 146   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 147
 148 You could then make new key bindings for `LaTeX-thesis-mode-map'
 149 without changing regular LaTeX mode.  In this example, BODY is empty,
 150 and DOCSTRING is generated by default.
 151
 152 On a more complicated level, the following command uses `sgml-mode' as
 153 the parent, and then sets the variable `case-fold-search' to nil:
 154
 155   (define-derived-mode article-mode sgml-mode \"Article\"
 156     \"Major mode for editing technical articles.\"
 157     (setq case-fold-search nil))
 158
 159 Note that if the documentation string had been left out, it would have
 160 been generated automatically, with a reference to the keymap.
 161
 162 The new mode runs the hook constructed by the function
 163 `derived-mode-hook-name'."
 164   (declare (debug (&define name symbolp sexp [&optional stringp]
 165                            [&rest keywordp sexp] def-body)))
 166
 167   (when (and docstring (not (stringp docstring)))
 168     ;; Some trickiness, since what appears to be the docstring may really be
 169     ;; the first element of the body.
 170     (push docstring body)
 171     (setq docstring nil))
 172
 173   (when (eq parent 'fundamental-mode) (setq parent nil))
 174
 175   (let ((map (derived-mode-map-name child))
 176         (syntax (derived-mode-syntax-table-name child))
 177         (abbrev (derived-mode-abbrev-table-name child))
 178         (declare-abbrev t)
 179         (declare-syntax t)
 180         (hook (derived-mode-hook-name child))
 181         (group nil))
 182
 183     ;; Process the keyword args.
 184     (while (keywordp (car body))
 185       (case (pop body)
 186         (:group (setq group (pop body)))
 187         (:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 188         (:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 189         (t (pop body))))
 190
 191     (setq docstring (derived-mode-make-docstring
 192                      parent child docstring syntax abbrev))
 193
 194     `(progn
 195        (defvar ,hook nil ,(format "Hook run when entering %s mode." name))
 196        (defvar ,map (make-sparse-keymap))
 197        ,(if declare-syntax
 198             `(defvar ,syntax (make-syntax-table)))
 199        ,(if declare-abbrev
 200             `(defvar ,abbrev
 201                (progn (define-abbrev-table ',abbrev nil) ,abbrev)))
 202        (put ',child 'derived-mode-parent ',parent)
 203        ,(if group `(put ',child 'custom-mode-group ,group))
 204
 205        (defun ,child ()
 206          ,docstring
 207          (interactive)
 208                                         ; Run the parent.
 209          (delay-mode-hooks
 210
 211           (,(or parent 'kill-all-local-variables))
 212                                         ; Identify the child mode.
 213           (setq major-mode (quote ,child))
 214           (setq mode-name ,name)
 215                                         ; Identify special modes.
 216           ,(when parent
 217              `(progn
 218                 (if (get (quote ,parent) 'mode-class)
 219                     (put (quote ,child) 'mode-class
 220                          (get (quote ,parent) 'mode-class)))
 221                                         ; Set up maps and tables.
 222                 (unless (keymap-parent ,map)
 223                   (set-keymap-parents ,map (list (current-local-map))))
 224                 ,(when declare-syntax
 225                    ;; XEmacs change: we do not have char-table-parent
 226                    `(derived-mode-merge-syntax-tables
 227                      (syntax-table) ,syntax))))
 228
 229           (use-local-map ,map)
 230           ,(when syntax `(set-syntax-table ,syntax))
 231           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 232                                         ; Splice in the body (if any).
 233           ,@body
 234           )
 235          ;; Run the hooks, if any.
 236          ;; Make the generated code work in older Emacs versions
 237          ;; that do not yet have run-mode-hooks.
 238          (if (fboundp 'run-mode-hooks)
 239              (run-mode-hooks ',hook)
 240            (run-hooks ',hook))))))
 241
 242 ;; PUBLIC: find the ultimate class of a derived mode.
 243
 244 (defun derived-mode-class (mode)
 245   "Find the class of a major MODE.
 246 A mode's class is the first ancestor which is NOT a derived mode.
 247 Use the `derived-mode-parent' property of the symbol to trace backwards.
 248 Since major-modes might all derive from `fundamental-mode', this function
 249 is not very useful."
 250   (while (get mode 'derived-mode-parent)
 251     (setq mode (get mode 'derived-mode-parent)))
 252   mode)
 253 (make-obsolete 'derived-mode-class 'derived-mode-p)
 254
 255 ;; PUBLIC: find if the current mode derives from another.
 256 ;; from GNU Emacs 21 subr.el
 257
 258 (defun derived-mode-p (&rest modes)
 259   "Non-nil if the current major mode is derived from one of MODES.
 260 Uses the `derived-mode-parent' property of the symbol to trace backwards."
 261   (let ((parent major-mode))
 262     (while (and (not (memq parent modes))
 263                 (setq parent (get parent 'derived-mode-parent))))
 264     parent))
 265
 266 \f
 267 ;;; PRIVATE
 268
 269 (defun derived-mode-make-docstring (parent child &optional
 270                                            docstring syntax abbrev)
 271   "Construct a docstring for a new mode if none is provided."
 272
 273   (let ((map (derived-mode-map-name child))
 274         (hook (derived-mode-hook-name child)))
 275
 276     (unless (stringp docstring)
 277       ;; Use a default docstring.
 278       (setq docstring
 279             (if (null parent)
 280                 (format "Major-mode.
 281 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 282               (format "Major mode derived from `%s' by `define-derived-mode'.
 283 It inherits all of the parent's attributes, but has its own keymap,
 284 abbrev table and syntax table:
 285
 286   `%s', `%s' and `%s'
 287
 288 which more-or-less shadow %s's corresponding tables."
 289                       parent map abbrev syntax parent))))
 290
 291     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 292       ;; Make sure the docstring mentions the mode's hook.
 293       (setq docstring
 294             (concat docstring
 295                     (if (null parent)
 296                         "\n\nThis mode "
 297                       (concat
 298                        "\n\nIn addition to any hooks its parent mode "
 299                        (if (string-match (regexp-quote (format "`%s'" parent))
 300                                          docstring) nil
 301                          (format "`%s' " parent))
 302                        "might have run,\nthis mode "))
 303                     (format "runs the hook `%s'" hook)
 304                     ", as the final step\nduring initialization.")))
 305
 306     (unless (string-match "\\\\[{[]" docstring)
 307       ;; And don't forget to put the mode's keymap.
 308       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 309
 310     docstring))
 311
 312 \f
 313 ;;; OBSOLETE
 314 ;; The functions below are only provided for backward compatibility with
 315 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 316
 317 (defsubst derived-mode-setup-function-name (mode)
 318   "Construct a setup-function name based on a MODE name."
 319   (intern (concat (symbol-name mode) "-setup")))
 320
 321 \f
 322 ;; Utility functions for defining a derived mode.
 323
 324 ;; XEmacs -- don't autoload
 325 (defun derived-mode-init-mode-variables (mode)
 326   "Initialise variables for a new MODE.
 327 Right now, if they don't already exist, set up a blank keymap, an
 328 empty syntax table, and an empty abbrev table -- these will be merged
 329 the first time the mode is used."
 330
 331   (if (boundp (derived-mode-map-name mode))
 332       t
 333     (eval `(defvar ,(derived-mode-map-name mode)
 334              ;; XEmacs change
 335              (make-sparse-keymap (derived-mode-map-name mode))
 336              ,(format "Keymap for %s." mode)))
 337     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 338
 339   (if (boundp (derived-mode-syntax-table-name mode))
 340       t
 341     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 342              ;; XEmacs change
 343              ;; Make a syntax table which doesn't specify anything
 344              ;; for any char.  Valid data will be merged in by
 345              ;; derived-mode-merge-syntax-tables.
 346              ;; (make-char-table 'syntax-table nil)
 347              (make-syntax-table)
 348              ,(format "Syntax table for %s." mode)))
 349     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 350
 351   (if (boundp (derived-mode-abbrev-table-name mode))
 352       t
 353     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 354              (progn
 355                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 356                (make-abbrev-table))
 357              ,(format "Abbrev table for %s." mode)))))
 358 \f
 359 ;; Utility functions for running a derived mode.
 360
 361 (defun derived-mode-set-keymap (mode)
 362   "Set the keymap of the new MODE, maybe merging with the parent."
 363   (let* ((map-name (derived-mode-map-name mode))
 364          (new-map (eval map-name))
 365          (old-map (current-local-map)))
 366     (and old-map
 367          (get map-name 'derived-mode-unmerged)
 368          (derived-mode-merge-keymaps old-map new-map))
 369     (put map-name 'derived-mode-unmerged nil)
 370     (use-local-map new-map)))
 371
 372 (defun derived-mode-set-syntax-table (mode)
 373   "Set the syntax table of the new MODE, maybe merging with the parent."
 374   (let* ((table-name (derived-mode-syntax-table-name mode))
 375          (old-table (syntax-table))
 376          (new-table (eval table-name)))
 377     (if (get table-name 'derived-mode-unmerged)
 378         (derived-mode-merge-syntax-tables old-table new-table))
 379     (put table-name 'derived-mode-unmerged nil)
 380     (set-syntax-table new-table)))
 381
 382 (defun derived-mode-set-abbrev-table (mode)
 383   "Set the abbrev table for MODE if it exists.
 384 Always merge its parent into it, since the merge is non-destructive."
 385   (let* ((table-name (derived-mode-abbrev-table-name mode))
 386          (old-table local-abbrev-table)
 387          (new-table (eval table-name)))
 388     (derived-mode-merge-abbrev-tables old-table new-table)
 389     (setq local-abbrev-table new-table)))
 390
 391 ;;;(defun derived-mode-run-setup-function (mode)
 392 ;;;  "Run the setup function if it exists."
 393
 394 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 395 ;;;    (if (fboundp fname)
 396 ;;;     (funcall fname))))
 397
 398 (defun derived-mode-run-hooks (mode)
 399   "Run the mode hook for MODE."
 400   (let ((hooks-name (derived-mode-hook-name mode)))
 401     (if (boundp hooks-name)
 402         (run-hooks hooks-name))))
 403
 404 ;; Functions to merge maps and tables.
 405
 406 (defun derived-mode-merge-keymaps (old new)
 407   "Merge an OLD keymap into a NEW one.
 408 The old keymap is set to be the last cdr of the new one, so that there will
 409 be automatic inheritance."
 410   ;; XEmacs change.  FSF 19.30 to 21.3 has a whole bunch of weird crap here
 411   ;; for merging prefix keys and such.  Hopefully none of this is
 412   ;; necessary in XEmacs.
 413   (set-keymap-parents new (list old)))
 414
 415 (defun derived-mode-merge-syntax-tables (old new)
 416   "Merge an OLD syntax table into a NEW one.
 417 Where the new table already has an entry, nothing is copied from the old one."
 418   ;; XEmacs change: on the other hand, Emacs 21.3 just has
 419   ;; (set-char-table-parent new old) here.
 420   ;; We use map-char-table, not map-syntax-table, so we can explicitly
 421   ;; check for inheritance.
 422   (map-char-table
 423    #'(lambda (key value)
 424        (if (eq ?@ (char-syntax-from-code value))
 425            (map-char-table #'(lambda (key1 value1)
 426                                (put-char-table key1 value1 new))
 427                            old
 428                            key)))
 429    new))
 430
 431 ;; Merge an old abbrev table into a new one.
 432 ;; This function requires internal knowledge of how abbrev tables work,
 433 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 434 ;; as the value of the symbol, and the hook as the function definition.
 435 (defun derived-mode-merge-abbrev-tables (old new)
 436   (if old
 437       (mapatoms
 438        #'(lambda (symbol)
 439            (or (intern-soft (symbol-name symbol) new)
 440                (define-abbrev new (symbol-name symbol)
 441                  (symbol-value symbol) (symbol-function symbol))))
 442        old)))
 443
 444 (provide 'derived)
 445
 446 ;;; arch-tag: 630be248-47d1-4f02-afa0-8207de0ebea0
 447 ;;; derived.el ends here