git.chise.org Git - chise/xemacs-chise.git-/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp interface to the C "face" structure
   2
   3 ;; Copyright (C) 1992-4, 1997 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995 Board of Trustees, University of Illinois
   5 ;; Copyright (C) 1995, 1996 Ben Wing
   6
   7 ;; Author: Ben Wing <ben@xemacs.org>
   8 ;; Keywords: faces, internal, dumped
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Synched up with: Not synched with FSF.  Almost completely divergent.
  28
  29 ;;; Commentary:
  30
  31 ;; This file is dumped with XEmacs.
  32
  33 ;; face implementation #1 (used Lisp vectors and parallel C vectors;
  34 ;; FSFmacs still uses this) authored by Jamie Zawinski <jwz@jwz.org>
  35 ;; pre Lucid-Emacs 19.0.
  36
  37 ;; face implementation #2 (used one face object per frame per face)
  38 ;; authored by Jamie Zawinski for 19.9.
  39
  40 ;; face implementation #3 (use one face object per face) originally
  41 ;; authored for 19.12 by Chuck Thompson <cthomp@cs.uiuc.edu>,
  42 ;; rewritten by Ben Wing with the advent of specifiers.
  43
  44
  45 ;;; Some stuff in FSF's faces.el is in our x-faces.el.
  46
  47 ;;; Code:
  48
  49 (defgroup faces nil
  50   "Support for multiple text attributes (fonts, colors, ...)
  51 Such a collection of attributes is called a \"face\"."
  52   :group 'emacs)
  53
  54
  55 (defun read-face-name (prompt)
  56   (let (face)
  57     (while (= (length face) 0) ; nil or ""
  58       (setq face (completing-read prompt
  59                                   (mapcar (lambda (x) (list (symbol-name x)))
  60                                           (face-list))
  61                                   nil t)))
  62     (intern face)))
  63
  64 (defun face-interactive (what &optional bool)
  65   (let* ((fn (intern (concat "face-" what "-instance")))
  66          (face (read-face-name (format "Set %s of face: " what)))
  67          (default (if (fboundp fn)
  68                       ;; #### we should distinguish here between
  69                       ;; explicitly setting the value to be the
  70                       ;; same as the default face's value, and
  71                       ;; not setting a value at all.
  72                       (funcall fn face)))
  73          (value (if bool
  74                     (y-or-n-p (format "Should face %s be %s? "
  75                                       (symbol-name face) bool))
  76                   (read-string (format "Set %s of face %s to: "
  77                                        what (symbol-name face))
  78                    (cond ((font-instance-p default)
  79                           (font-instance-name default))
  80                          ((color-instance-p default)
  81                           (color-instance-name default))
  82                          ((image-instance-p default)
  83                           (image-instance-file-name default))
  84                          (t default))))))
  85     (list face (if (equal value "") nil value))))
  86
  87 (defconst built-in-face-specifiers
  88   (built-in-face-specifiers)
  89   "A list of the built-in face properties that are specifiers.")
  90
  91 (defun face-property (face property &optional locale tag-set exact-p)
  92   "Return FACE's value of the given PROPERTY.
  93
  94 If LOCALE is omitted, the FACE's actual value for PROPERTY will be
  95   returned.  For built-in properties, this will be a specifier object
  96   of a type appropriate to the property (e.g. a font or color
  97   specifier).  For other properties, this could be anything.
  98
  99 If LOCALE is supplied, then instead of returning the actual value,
 100   the specification(s) for the given locale or locale type will
 101   be returned.  This will only work if the actual value of
 102   PROPERTY is a specifier (this will always be the case for built-in
 103   properties, but not or not may apply to user-defined properties).
 104   If the actual value of PROPERTY is not a specifier, this value
 105   will simply be returned regardless of LOCALE.
 106
 107 The return value will be a list of instantiators (e.g. strings
 108   specifying a font or color name), or a list of specifications, each
 109   of which is a cons of a locale and a list of instantiators.
 110   Specifically, if LOCALE is a particular locale (a buffer, window,
 111   frame, device, or 'global), a list of instantiators for that locale
 112   will be returned.  Otherwise, if LOCALE is a locale type (one of
 113   the symbols 'buffer, 'window, 'frame, or 'device), the specifications
 114   for all locales of that type will be returned.  Finally, if LOCALE is
 115   'all, the specifications for all locales of all types will be returned.
 116
 117 The specifications in a specifier determine what the value of
 118   PROPERTY will be in a particular \"domain\" or set of circumstances,
 119   which is typically a particular Emacs window along with the buffer
 120   it contains and the frame and device it lies within.  The value is
 121   derived from the instantiator associated with the most specific
 122   locale (in the order buffer, window, frame, device, and 'global)
 123   that matches the domain in question.  In other words, given a domain
 124   (i.e. an Emacs window, usually), the specifier for PROPERTY will
 125   first be searched for a specification whose locale is the buffer
 126   contained within that window; then for a specification whose locale
 127   is the window itself; then for a specification whose locale is the
 128   frame that the window is contained within; etc.  The first
 129   instantiator that is valid for the domain (usually this means that
 130   the instantiator is recognized by the device [i.e. MS Windows, the X
 131   server or TTY device] that the domain is on.  The function
 132   `face-property-instance' actually does all this, and is used to
 133   determine how to display the face.
 134
 135 See `set-face-property' for the built-in property-names."
 136
 137   (setq face (get-face face))
 138   (let ((value (get face property)))
 139     (if (and locale
 140              (or (memq property built-in-face-specifiers)
 141                  (specifierp value)))
 142         (setq value (specifier-specs value locale tag-set exact-p)))
 143     value))
 144
 145 (defun convert-face-property-into-specifier (face property)
 146   "Convert PROPERTY on FACE into a specifier, if it's not already."
 147   (setq face (get-face face))
 148   (let ((specifier (get face property)))
 149     ;; if a user-property does not have a specifier but a
 150     ;; locale was specified, put a specifier there.
 151     ;; If there was already a value there, convert it to a
 152     ;; specifier with the value as its 'global instantiator.
 153     (unless (specifierp specifier)
 154       (let ((new-specifier (make-specifier 'generic)))
 155         (if (or (not (null specifier))
 156                 ;; make sure the nil returned from `get' wasn't
 157                 ;; actually the value of the property
 158                 (null (get face property t)))
 159             (add-spec-to-specifier new-specifier specifier))
 160         (setq specifier new-specifier)
 161         (put face property specifier)))))
 162
 163 (defun face-property-instance (face property
 164                                     &optional domain default no-fallback)
 165   "Return the instance of FACE's PROPERTY in the specified DOMAIN.
 166
 167 Under most circumstances, DOMAIN will be a particular window,
 168   and the returned instance describes how the specified property
 169   actually is displayed for that window and the particular buffer
 170   in it.  Note that this may not be the same as how the property
 171   appears when the buffer is displayed in a different window or
 172   frame, or how the property appears in the same window if you
 173   switch to another buffer in that window; and in those cases,
 174   the returned instance would be different.
 175
 176 The returned instance will typically be a color-instance,
 177   font-instance, or pixmap-instance object, and you can query
 178   it using the appropriate object-specific functions.  For example,
 179   you could use `color-instance-rgb-components' to find out the
 180   RGB (red, green, and blue) components of how the 'background
 181   property of the 'highlight face is displayed in a particular
 182   window.  The results might be different from the results
 183   you would get for another window (perhaps the user
 184   specified a different color for the frame that window is on;
 185   or perhaps the same color was specified but the window is
 186   on a different X server, and that X server has different RGB
 187   values for the color from this one).
 188
 189 DOMAIN defaults to the selected window if omitted.
 190
 191 DOMAIN can be a frame or device, instead of a window.  The value
 192   returned for a such a domain is used in special circumstances
 193   when a more specific domain does not apply; for example, a frame
 194   value might be used for coloring a toolbar, which is conceptually
 195   attached to a frame rather than a particular window.  The value
 196   is also useful in determining what the value would be for a
 197   particular window within the frame or device, if it is not
 198   overridden by a more specific specification.
 199
 200 If PROPERTY does not name a built-in property, its value will
 201   simply be returned unless it is a specifier object, in which case
 202   it will be instanced using `specifier-instance'.
 203
 204 Optional arguments DEFAULT and NO-FALLBACK are the same as in
 205   `specifier-instance'."
 206
 207   (setq face (get-face face))
 208   (let ((value (get face property)))
 209     (if (specifierp value)
 210         (setq value (specifier-instance value domain default no-fallback)))
 211     value))
 212
 213 (defun face-property-matching-instance (face property matchspec
 214                                              &optional domain default
 215                                              no-fallback)
 216   "Return the instance of FACE's PROPERTY matching MATCHSPEC in DOMAIN.
 217 Currently the only useful value for MATCHSPEC is a charset, when used
 218 in conjunction with the face's font; this allows you to retrieve a
 219 font that can be used to display a particular charset, rather than just
 220 any font.
 221
 222 Other than MATCHSPEC, this function is identical to `face-property-instance'.
 223 See also `specifier-matching-instance' for a fuller description of the
 224 matching process."
 225
 226   (setq face (get-face face))
 227   (let ((value (get face property)))
 228     (if (specifierp value)
 229         (setq value (specifier-matching-instance value matchspec domain
 230                                                  default no-fallback)))
 231     value))
 232
 233 (defun set-face-property (face property value &optional locale tag-set
 234                                how-to-add)
 235   "Change a property of FACE.
 236
 237 NOTE: If you want to remove a property from a face, use `remove-face-property'
 238   rather than attempting to set a value of nil for the property.
 239
 240 For built-in properties, the actual value of the property is a
 241   specifier and you cannot change this; but you can change the
 242   specifications within the specifier, and that is what this function
 243   will do.  For user-defined properties, you can use this function
 244   to either change the actual value of the property or, if this value
 245   is a specifier, change the specifications within it.
 246
 247 If PROPERTY is a built-in property, the specifications to be added to
 248   this property can be supplied in many different ways:
 249
 250   -- If VALUE is a simple instantiator (e.g. a string naming a font or
 251      color) or a list of instantiators, then the instantiator(s) will
 252      be added as a specification of the property for the given LOCALE
 253      (which defaults to 'global if omitted).
 254   -- If VALUE is a list of specifications (each of which is a cons of
 255      a locale and a list of instantiators), then LOCALE must be nil
 256      (it does not make sense to explicitly specify a locale in this
 257      case), and specifications will be added as given.
 258   -- If VALUE is a specifier (as would be returned by `face-property'
 259      if no LOCALE argument is given), then some or all of the
 260      specifications in the specifier will be added to the property.
 261      In this case, the function is really equivalent to
 262      `copy-specifier' and LOCALE has the same semantics (if it is
 263      a particular locale, the specification for the locale will be
 264      copied; if a locale type, specifications for all locales of
 265      that type will be copied; if nil or 'all, then all
 266      specifications will be copied).
 267
 268 HOW-TO-ADD should be either nil or one of the symbols 'prepend,
 269   'append, 'remove-tag-set-prepend, 'remove-tag-set-append, 'remove-locale,
 270   'remove-locale-type, or 'remove-all.  See `copy-specifier' and
 271   `add-spec-to-specifier' for a description of what each of
 272   these means.  Most of the time, you do not need to worry about
 273   this argument; the default behavior usually is fine.
 274
 275 In general, it is OK to pass an instance object (e.g. as returned
 276   by `face-property-instance') as an instantiator in place of
 277   an actual instantiator.  In such a case, the instantiator used
 278   to create that instance object will be used (for example, if
 279   you set a font-instance object as the value of the 'font
 280   property, then the font name used to create that object will
 281   be used instead).  If some cases, however, doing this
 282   conversion does not make sense, and this will be noted in
 283   the documentation for particular types of instance objects.
 284
 285 If PROPERTY is not a built-in property, then this function will
 286   simply set its value if LOCALE is nil.  However, if LOCALE is
 287   given, then this function will attempt to add VALUE as the
 288   instantiator for the given LOCALE, using `add-spec-to-specifier'.
 289   If the value of the property is not a specifier, it will
 290   automatically be converted into a 'generic specifier.
 291
 292
 293 The following symbols have predefined meanings:
 294
 295  foreground         The foreground color of the face.
 296                     For valid instantiators, see `make-color-specifier'.
 297
 298  background         The background color of the face.
 299                     For valid instantiators, see `make-color-specifier'.
 300
 301  font               The font used to display text covered by this face.
 302                     For valid instantiators, see `make-font-specifier'.
 303
 304  display-table      The display table of the face.
 305                     This should be a vector of 256 elements.
 306
 307  background-pixmap  The pixmap displayed in the background of the face.
 308                     Only used by faces on X and MS Windows devices.
 309                     For valid instantiators, see `make-image-specifier'.
 310
 311  underline          Underline all text covered by this face.
 312                     For valid instantiators, see `make-face-boolean-specifier'.
 313
 314  strikethru         Draw a line through all text covered by this face.
 315                     For valid instantiators, see `make-face-boolean-specifier'.
 316
 317  highlight          Highlight all text covered by this face.
 318                     Only used by faces on TTY devices.
 319                     For valid instantiators, see `make-face-boolean-specifier'.
 320
 321  dim                Dim all text covered by this face.
 322                     For valid instantiators, see `make-face-boolean-specifier'.
 323
 324  blinking           Blink all text covered by this face.
 325                     Only used by faces on TTY devices.
 326                     For valid instantiators, see `make-face-boolean-specifier'.
 327
 328  reverse            Reverse the foreground and background colors.
 329                     Only used by faces on TTY devices.
 330                     For valid instantiators, see `make-face-boolean-specifier'.
 331
 332  doc-string         Description of what the face's normal use is.
 333                     NOTE: This is not a specifier, unlike all
 334                     the other built-in properties, and cannot
 335                     contain locale-specific values."
 336
 337   (setq face (get-face face))
 338   (if (memq property built-in-face-specifiers)
 339       (set-specifier (get face property) value locale tag-set how-to-add)
 340
 341     ;; This section adds user defined properties.
 342     (if (not locale)
 343         (put face property value)
 344       (convert-face-property-into-specifier face property)
 345       (add-spec-to-specifier (get face property) value locale tag-set
 346                              how-to-add)))
 347   value)
 348
 349 (defun remove-face-property (face property &optional locale tag-set exact-p)
 350   "Remove a property from FACE.
 351 For built-in properties, this is analogous to `remove-specifier'.
 352 See `remove-specifier' for the meaning of the LOCALE, TAG-SET, and EXACT-P
 353 arguments."
 354   (or locale (setq locale 'all))
 355   (if (memq property built-in-face-specifiers)
 356       (remove-specifier (face-property face property) locale tag-set exact-p)
 357     (if (eq locale 'all)
 358         (remprop (get-face face) property)
 359       (convert-face-property-into-specifier face property)
 360       (remove-specifier (face-property face property) locale tag-set
 361                         exact-p))))
 362
 363 (defun reset-face (face &optional locale tag-set exact-p)
 364   "Clear all existing built-in specifications from FACE.
 365 This makes FACE inherit all its display properties from 'default.
 366 WARNING: Be absolutely sure you want to do this!!!  It is a dangerous
 367 operation and is not undoable.
 368
 369 The arguments LOCALE, TAG-SET and EXACT-P are the same as for
 370 `remove-specifier'."
 371   (mapc (lambda (x)
 372           (remove-specifier (face-property face x) locale tag-set exact-p))
 373         built-in-face-specifiers)
 374   nil)
 375
 376 (defun set-face-parent (face parent &optional locale tag-set how-to-add)
 377   "Set the parent of FACE to PARENT, for all properties.
 378 This makes all properties of FACE inherit from PARENT."
 379   (setq parent (get-face parent))
 380   (mapcar (lambda (x)
 381             (set-face-property face x (vector parent) locale tag-set
 382                                how-to-add))
 383           (delq 'display-table
 384                 (delq 'background-pixmap
 385                       (copy-sequence built-in-face-specifiers))))
 386   (set-face-background-pixmap face (vector 'inherit ':face parent)
 387                               locale tag-set how-to-add)
 388   nil)
 389
 390 (defun face-doc-string (face)
 391   "Return the documentation string for FACE."
 392   (face-property face 'doc-string))
 393
 394 (defun set-face-doc-string (face doc-string)
 395   "Change the documentation string of FACE to DOC-STRING."
 396   (interactive (face-interactive "doc-string"))
 397   (set-face-property face 'doc-string doc-string))
 398
 399 (defun face-font-name (face &optional domain charset)
 400   "Return the font name of FACE in DOMAIN, or nil if it is unspecified.
 401 DOMAIN is as in `face-font-instance'."
 402   (let ((f (face-font-instance face domain charset)))
 403     (and f (font-instance-name f))))
 404
 405 (defun face-font (face &optional locale tag-set exact-p)
 406   "Return the font of FACE in LOCALE, or nil if it is unspecified.
 407
 408 FACE may be either a face object or a symbol representing a face.
 409
 410 LOCALE may be a locale (the instantiators for that particular locale
 411   will be returned), a locale type (the specifications for all locales
 412   of that type will be returned), 'all (all specifications will be
 413   returned), or nil (the actual specifier object will be returned).
 414
 415 See `face-property' for more information."
 416   (face-property face 'font locale tag-set exact-p))
 417
 418 (defun face-font-instance (face &optional domain charset)
 419   "Return the instance of FACE's font in DOMAIN.
 420
 421 FACE may be either a face object or a symbol representing a face.
 422
 423 Normally DOMAIN will be a window or nil (meaning the selected window),
 424   and an instance object describing how the font appears in that
 425   particular window and buffer will be returned.
 426
 427 See `face-property-instance' for more information."
 428   (if charset
 429       (face-property-matching-instance face 'font charset domain)
 430     (face-property-instance face 'font domain)))
 431
 432 (defun set-face-font (face font &optional locale tag-set how-to-add)
 433   "Change the font of FACE to FONT in LOCALE.
 434
 435 FACE may be either a face object or a symbol representing a face.
 436
 437 FONT should be an instantiator (see `make-font-specifier'), a list of
 438   instantiators, an alist of specifications (each mapping a
 439   locale to an instantiator list), or a font specifier object.
 440
 441 If FONT is an alist, LOCALE must be omitted.  If FONT is a
 442   specifier object, LOCALE can be a locale, a locale type, 'all,
 443   or nil; see `copy-specifier' for its semantics.  Otherwise LOCALE
 444   specifies the locale under which the specified instantiator(s)
 445   will be added, and defaults to 'global.
 446
 447 See `set-face-property' for more information."
 448   (interactive (face-interactive "font"))
 449   (set-face-property face 'font font locale tag-set how-to-add))
 450
 451 (defun face-foreground (face &optional locale tag-set exact-p)
 452   "Return the foreground of FACE in LOCALE, or nil if it is unspecified.
 453
 454 FACE may be either a face object or a symbol representing a face.
 455
 456 LOCALE may be a locale (the instantiators for that particular locale
 457   will be returned), a locale type (the specifications for all locales
 458   of that type will be returned), 'all (all specifications will be
 459   returned), or nil (the actual specifier object will be returned).
 460
 461 See `face-property' for more information."
 462   (face-property face 'foreground locale tag-set exact-p))
 463
 464 (defun face-foreground-instance (face &optional domain default no-fallback)
 465   "Return the instance of FACE's foreground in DOMAIN.
 466
 467 FACE may be either a face object or a symbol representing a face.
 468
 469 Normally DOMAIN will be a window or nil (meaning the selected window),
 470   and an instance object describing how the foreground appears in that
 471   particular window and buffer will be returned.
 472
 473 See `face-property-instance' for more information."
 474   (face-property-instance face 'foreground domain default no-fallback))
 475
 476 (defun face-foreground-name (face &optional domain default no-fallback)
 477   "Return the name of FACE's foreground color in DOMAIN.
 478
 479 FACE may be either a face object or a symbol representing a face.
 480
 481 Normally DOMAIN will be a window or nil (meaning the selected window),
 482   and an instance object describing how the background appears in that
 483   particular window and buffer will be returned.
 484
 485 See `face-property-instance' for more information."
 486   (color-instance-name (face-foreground-instance
 487                         face domain default no-fallback)))
 488
 489 (defun set-face-foreground (face color &optional locale tag-set how-to-add)
 490   "Change the foreground color of FACE to COLOR in LOCALE.
 491
 492 FACE may be either a face object or a symbol representing a face.
 493
 494 COLOR should be an instantiator (see `make-color-specifier'), a list of
 495   instantiators, an alist of specifications (each mapping a locale to
 496   an instantiator list), or a color specifier object.
 497
 498 If COLOR is an alist, LOCALE must be omitted.  If COLOR is a
 499   specifier object, LOCALE can be a locale, a locale type, 'all,
 500   or nil; see `copy-specifier' for its semantics.  Otherwise LOCALE
 501   specifies the locale under which the specified instantiator(s)
 502   will be added, and defaults to 'global.
 503
 504 See `set-face-property' for more information."
 505   (interactive (face-interactive "foreground"))
 506   (set-face-property face 'foreground color locale tag-set how-to-add))
 507
 508 (defun face-background (face &optional locale tag-set exact-p)
 509   "Return the background color of FACE in LOCALE, or nil if it is unspecified.
 510
 511 FACE may be either a face object or a symbol representing a face.
 512
 513 LOCALE may be a locale (the instantiators for that particular locale
 514   will be returned), a locale type (the specifications for all locales
 515   of that type will be returned), 'all (all specifications will be
 516   returned), or nil (the actual specifier object will be returned).
 517
 518 See `face-property' for more information."
 519   (face-property face 'background locale tag-set exact-p))
 520
 521 (defun face-background-instance (face &optional domain default no-fallback)
 522   "Return the instance of FACE's background in DOMAIN.
 523
 524 FACE may be either a face object or a symbol representing a face.
 525
 526 Normally DOMAIN will be a window or nil (meaning the selected window),
 527   and an instance object describing how the background appears in that
 528   particular window and buffer will be returned.
 529
 530 See `face-property-instance' for more information."
 531   (face-property-instance face 'background domain default no-fallback))
 532
 533 (defun face-background-name (face &optional domain default no-fallback)
 534   "Return the name of FACE's background color in DOMAIN.
 535
 536 FACE may be either a face object or a symbol representing a face.
 537
 538 Normally DOMAIN will be a window or nil (meaning the selected window),
 539   and an instance object describing how the background appears in that
 540   particular window and buffer will be returned.
 541
 542 See `face-property-instance' for more information."
 543   (color-instance-name (face-background-instance
 544                         face domain default no-fallback)))
 545
 546 (defun set-face-background (face color &optional locale tag-set how-to-add)
 547   "Change the background color of FACE to COLOR in LOCALE.
 548
 549 FACE may be either a face object or a symbol representing a face.
 550
 551 COLOR should be an instantiator (see `make-color-specifier'), a list of
 552   instantiators, an alist of specifications (each mapping a locale to
 553   an instantiator list), or a color specifier object.
 554
 555 If COLOR is an alist, LOCALE must be omitted.  If COLOR is a
 556   specifier object, LOCALE can be a locale, a locale type, 'all,
 557   or nil; see `copy-specifier' for its semantics.  Otherwise LOCALE
 558   specifies the locale under which the specified instantiator(s)
 559   will be added, and defaults to 'global.
 560
 561 See `set-face-property' for more information."
 562   (interactive (face-interactive "background"))
 563   (set-face-property face 'background color locale tag-set how-to-add))
 564
 565 (defun face-background-pixmap (face &optional locale tag-set exact-p)
 566   "Return the background pixmap of FACE in LOCALE, or nil if it is unspecified.
 567 This property is only used on window system devices.
 568
 569 FACE may be either a face object or a symbol representing a face.
 570
 571 LOCALE may be a locale (the instantiators for that particular locale
 572   will be returned), a locale type (the specifications for all locales
 573   of that type will be returned), 'all (all specifications will be
 574   returned), or nil (the actual specifier object will be returned).
 575
 576 See `face-property' for more information."
 577   (face-property face 'background-pixmap locale tag-set exact-p))
 578
 579 (defun face-background-pixmap-instance (face &optional domain default
 580                                              no-fallback)
 581   "Return the instance of FACE's background pixmap in DOMAIN.
 582
 583 FACE may be either a face object or a symbol representing a face.
 584
 585 Normally DOMAIN will be a window or nil (meaning the selected window),
 586   and an instance object describing how the background appears in that
 587   particular window and buffer will be returned.
 588
 589 See `face-property-instance' for more information."
 590   (face-property-instance face 'background-pixmap domain default no-fallback))
 591
 592 (defun set-face-background-pixmap (face pixmap &optional locale tag-set
 593                                         how-to-add)
 594   "Change the background pixmap of FACE to PIXMAP in LOCALE.
 595 This property is only used on window system devices.
 596
 597 FACE may be either a face object or a symbol representing a face.
 598
 599 PIXMAP should be an instantiator (see `make-image-specifier'), a list
 600   of instantiators, an alist of specifications (each mapping a locale
 601   to an instantiator list), or an image specifier object.
 602
 603 If PIXMAP is an alist, LOCALE must be omitted.  If PIXMAP is a
 604   specifier object, LOCALE can be a locale, a locale type, 'all,
 605   or nil; see `copy-specifier' for its semantics.  Otherwise LOCALE
 606   specifies the locale under which the specified instantiator(s)
 607   will be added, and defaults to 'global.
 608
 609 See `set-face-property' for more information."
 610   (interactive (face-interactive "background-pixmap"))
 611   (set-face-property face 'background-pixmap pixmap locale tag-set how-to-add))
 612
 613 (defun face-display-table (face &optional locale tag-set exact-p)
 614   "Return the display table of FACE in LOCALE.
 615
 616 A vector (as returned by `make-display-table') will be returned.
 617
 618 LOCALE may be a locale (the instantiators for that particular locale
 619   will be returned), a locale type (the specifications for all locales
 620   of that type will be returned), 'all (all specifications will be
 621   returned), or nil (the actual specifier object will be returned).
 622
 623 See `face-property' for more information."
 624   (face-property face 'display-table locale tag-set exact-p))
 625
 626 (defun face-display-table-instance (face &optional domain default no-fallback)
 627   "Return the instance of FACE's display table in DOMAIN.
 628 A vector (as returned by `make-display-table') will be returned.
 629
 630 See `face-property-instance' for the semantics of the DOMAIN argument."
 631   (face-property-instance face 'display-table domain default no-fallback))
 632
 633 (defun set-face-display-table (face display-table &optional locale tag-set
 634                                     how-to-add)
 635   "Change the display table of FACE to DISPLAY-TABLE in LOCALE.
 636 DISPLAY-TABLE should be a vector as returned by `make-display-table'.
 637
 638 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 639   HOW-TO-ADD arguments."
 640   (interactive (face-interactive "display-table"))
 641   (set-face-property face 'display-table display-table locale tag-set
 642                      how-to-add))
 643
 644 ;; The following accessors and mutators are, IMHO, good
 645 ;; implementation.  Cf. with `make-face-bold'.
 646
 647 (defun face-underline-p (face &optional domain default no-fallback)
 648   "Return t if FACE is underlined in DOMAIN.
 649 See `face-property-instance' for the semantics of the DOMAIN argument."
 650   (face-property-instance face 'underline domain default no-fallback))
 651
 652 (defun set-face-underline-p (face underline-p &optional locale tag-set
 653                                   how-to-add)
 654   "Change the underline property of FACE to UNDERLINE-P.
 655 UNDERLINE-P is normally a face-boolean instantiator; see
 656  `make-face-boolean-specifier'.
 657 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 658  HOW-TO-ADD arguments."
 659   (interactive (face-interactive "underline-p" "underlined"))
 660   (set-face-property face 'underline underline-p locale tag-set how-to-add))
 661
 662 (defun face-strikethru-p (face &optional domain default no-fallback)
 663   "Return t if FACE is strikethru-d (i.e. struck through) in DOMAIN.
 664 See `face-property-instance' for the semantics of the DOMAIN argument."
 665   (face-property-instance face 'strikethru domain default no-fallback))
 666
 667 (defun set-face-strikethru-p (face strikethru-p &optional locale tag-set
 668                                   how-to-add)
 669   "Change whether FACE is strikethru-d (i.e. struck through) in LOCALE.
 670 STRIKETHRU-P is normally a face-boolean instantiator; see
 671  `make-face-boolean-specifier'.
 672 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 673  HOW-TO-ADD arguments."
 674   (interactive (face-interactive "strikethru-p" "strikethru-d"))
 675   (set-face-property face 'strikethru strikethru-p locale tag-set how-to-add))
 676
 677 (defun face-highlight-p (face &optional domain default no-fallback)
 678   "Return t if FACE is highlighted in DOMAIN (TTY domains only).
 679 See `face-property-instance' for the semantics of the DOMAIN argument."
 680   (face-property-instance face 'highlight domain default no-fallback))
 681
 682 (defun set-face-highlight-p (face highlight-p &optional locale tag-set
 683                                   how-to-add)
 684   "Change whether FACE is highlighted in LOCALE (TTY locales only).
 685 HIGHLIGHT-P is normally a face-boolean instantiator; see
 686  `make-face-boolean-specifier'.
 687 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 688  HOW-TO-ADD arguments."
 689   (interactive (face-interactive "highlight-p" "highlighted"))
 690   (set-face-property face 'highlight highlight-p locale tag-set how-to-add))
 691
 692 (defun face-dim-p (face &optional domain default no-fallback)
 693   "Return t if FACE is dimmed in DOMAIN.
 694 See `face-property-instance' for the semantics of the DOMAIN argument."
 695   (face-property-instance face 'dim domain default no-fallback))
 696
 697 (defun set-face-dim-p (face dim-p &optional locale tag-set how-to-add)
 698   "Change whether FACE is dimmed in LOCALE.
 699 DIM-P is normally a face-boolean instantiator; see
 700  `make-face-boolean-specifier'.
 701 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 702  HOW-TO-ADD arguments."
 703   (interactive (face-interactive "dim-p" "dimmed"))
 704   (set-face-property face 'dim dim-p locale tag-set how-to-add))
 705
 706 (defun face-blinking-p (face &optional domain default no-fallback)
 707   "Return t if FACE is blinking in DOMAIN (TTY domains only).
 708 See `face-property-instance' for the semantics of the DOMAIN argument."
 709   (face-property-instance face 'blinking domain default no-fallback))
 710
 711 (defun set-face-blinking-p (face blinking-p &optional locale tag-set
 712                                  how-to-add)
 713   "Change whether FACE is blinking in LOCALE (TTY locales only).
 714 BLINKING-P is normally a face-boolean instantiator; see
 715  `make-face-boolean-specifier'.
 716 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 717  HOW-TO-ADD arguments."
 718   (interactive (face-interactive "blinking-p" "blinking"))
 719   (set-face-property face 'blinking blinking-p locale tag-set how-to-add))
 720
 721 (defun face-reverse-p (face &optional domain default no-fallback)
 722   "Return t if FACE is reversed in DOMAIN (TTY domains only).
 723 See `face-property-instance' for the semantics of the DOMAIN argument."
 724   (face-property-instance face 'reverse domain default no-fallback))
 725
 726 (defun set-face-reverse-p (face reverse-p &optional locale tag-set how-to-add)
 727   "Change whether FACE is reversed in LOCALE (TTY locales only).
 728 REVERSE-P is normally a face-boolean instantiator; see
 729  `make-face-boolean-specifier'.
 730 See `set-face-property' for the semantics of the LOCALE, TAG-SET, and
 731  HOW-TO-ADD arguments."
 732   (interactive (face-interactive "reverse-p" "reversed"))
 733   (set-face-property face 'reverse reverse-p locale tag-set how-to-add))
 734
 735 \f
 736 (defun face-property-equal (face1 face2 prop domain)
 737   (equal (face-property-instance face1 prop domain)
 738          (face-property-instance face2 prop domain)))
 739
 740 (defun face-equal-loop (props face1 face2 domain)
 741   (while (and props
 742               (face-property-equal face1 face2 (car props) domain))
 743     (setq props (cdr props)))
 744   (null props))
 745
 746 (defun face-equal (face1 face2 &optional domain)
 747   "Return t if FACE1 and FACE2 will display in the same way in DOMAIN.
 748 See `face-property-instance' for the semantics of the DOMAIN argument."
 749   (if (null domain) (setq domain (selected-window)))
 750   (if (not (valid-specifier-domain-p domain))
 751       (error "Invalid specifier domain"))
 752   (let ((device (dfw-device domain))
 753         (common-props '(foreground background font display-table underline
 754                                    dim))
 755         (win-props '(background-pixmap strikethru))
 756         (tty-props '(highlight blinking reverse)))
 757
 758     ;; First check the properties which are used in common between the
 759     ;; x and tty devices.  Then, check those properties specific to
 760     ;; the particular device type.
 761     (and (face-equal-loop common-props face1 face2 domain)
 762          (cond ((eq 'tty (device-type device))
 763                 (face-equal-loop tty-props face1 face2 domain))
 764                ((or (eq 'x (device-type device))
 765                     (eq 'mswindows (device-type device)))
 766                 (face-equal-loop win-props face1 face2 domain))
 767                (t t)))))
 768
 769 (defun face-differs-from-default-p (face &optional domain)
 770   "Return t if FACE will display differently from the default face in DOMAIN.
 771 See `face-property-instance' for the semantics of the DOMAIN argument."
 772   (not (face-equal face 'default domain)))
 773
 774 ; moved from x-faces.el
 775 (defun try-font-name (name &optional device)
 776   ;; yes, name really should be here twice.
 777   (and name (make-font-instance name device t) name))
 778
 779 \f
 780 ;; This function is a terrible, disgusting hack!!!!  Need to
 781 ;; separate out the font elements as separate face properties!
 782
 783 ;; WE DEMAND LEXICAL SCOPING!!!
 784 ;; WE DEMAND LEXICAL SCOPING!!!
 785 ;; WE DEMAND LEXICAL SCOPING!!!
 786 ;; WE DEMAND LEXICAL SCOPING!!!
 787 ;; WE DEMAND LEXICAL SCOPING!!!
 788 ;; WE DEMAND LEXICAL SCOPING!!!
 789 ;; WE DEMAND LEXICAL SCOPING!!!
 790 ;; WE DEMAND LEXICAL SCOPING!!!
 791 ;; WE DEMAND LEXICAL SCOPING!!!
 792 ;; WE DEMAND LEXICAL SCOPING!!!
 793 ;; WE DEMAND LEXICAL SCOPING!!!
 794 ;; WE DEMAND LEXICAL SCOPING!!!
 795 ;; WE DEMAND LEXICAL SCOPING!!!
 796 ;; WE DEMAND LEXICAL SCOPING!!!
 797 ;; WE DEMAND LEXICAL SCOPING!!!
 798 (defun frob-face-property (face property func device-tags &optional
 799 locale tags)
 800   "Change the specifier for FACE's PROPERTY according to FUNC, in LOCALE.
 801 This function is ugly and messy and is primarily used as an internal
 802 helper function for `make-face-bold' et al., so you probably don't
 803 want to use it or read the rest of the documentation.  But if you do ...
 804
 805 FUNC should be a function of two arguments (an instance and a device)
 806 that returns a modified name that is valid for the given device.
 807 If LOCALE specifies a valid domain (i.e. a window, frame, or device),
 808 this function instantiates the specifier over that domain, applies FUNC
 809 to the resulting instance, and adds the result back as an instantiator
 810 for that locale.  Otherwise, LOCALE should be a locale, locale type, or
 811 'all (defaults to 'all if omitted).  For each specification thusly
 812 included: if the locale given is a valid domain, FUNC will be
 813 iterated over all valid instantiators for the device of the domain
 814 until a non-nil result is found (if there is no such result, the
 815 first valid instantiator is used), and that result substituted for
 816 the specification; otherwise, the process just outlined is
 817 iterated over each existing device and the concatenated results
 818 substituted for the specification.
 819
 820 DEVICE-TAGS is a list of tags that each device must match in order for
 821 the function to be called on it."
 822   (let ((sp (face-property face property))
 823         temp-sp)
 824     (if (valid-specifier-domain-p locale)
 825         ;; this is easy.
 826         (let* ((inst (face-property-instance face property locale))
 827                (name (and inst
 828                           (device-matches-specifier-tag-set-p
 829                            (dfw-device locale) device-tags)
 830                           (funcall func inst (dfw-device locale)))))
 831           (when name
 832             (add-spec-to-specifier sp name locale tags)))
 833       ;; otherwise, map over all specifications ...
 834       ;; but first, some further kludging:
 835       ;; (1) if we're frobbing the global property, make sure
 836       ;;     that something is there (copy from the default face,
 837       ;;     if necessary).  Otherwise, something like
 838       ;;     (make-face-larger 'modeline)
 839       ;;     won't do anything at all if the modeline simply
 840       ;;     inherits its font from 'default.
 841       ;; (2) if we're frobbing a particular locale, nothing would
 842       ;;     happen if that locale has no instantiators.  So signal
 843       ;;     an error to indicate this.
 844
 845
 846       (setq temp-sp (copy-specifier sp))
 847       (if (and (or (eq locale 'global) (eq locale 'all) (not locale))
 848                (not (face-property face property 'global)))
 849           (copy-specifier (face-property 'default property)
 850                           temp-sp 'global))
 851       (if (and (valid-specifier-locale-p locale)
 852                (not (specifier-specs temp-sp locale)))
 853           (error "Property must have a specification in locale %S" locale))
 854       (map-specifier
 855        temp-sp
 856        (lambda (sp-arg locale inst-list func)
 857          (let* ((device (dfw-device locale))
 858                 ;; if a device can be derived from the locale,
 859                 ;; call frob-face-property-1 for that device.
 860                 ;; Otherwise map frob-face-property-1 over each device.
 861                 (result
 862                  (if device
 863                      (list (and (device-matches-specifier-tag-set-p
 864                                  device device-tags)
 865                                 (frob-face-property-1 sp-arg device inst-list
 866                                                       func)))
 867                    (mapcar (lambda (device)
 868                              (and (device-matches-specifier-tag-set-p
 869                                    device device-tags)
 870                                   (frob-face-property-1 sp-arg device
 871                                                         inst-list func)))
 872                            (device-list))))
 873                 new-result)
 874            ;; remove duplicates and nils from the obtained list of
 875            ;; instantiators. Also add tags amd remove 'defaults'.
 876            (mapcar (lambda (arg)
 877                      (when arg
 878                        (if (not (consp arg))
 879                            (setq arg (cons tags arg))
 880                          (setcar arg (append tags (delete 'default
 881                                                           (car arg))))))
 882                      (when (and arg (not (member arg new-result)))
 883                        (setq new-result (cons arg new-result))))
 884                    result)
 885            ;; add back in.
 886            (add-spec-list-to-specifier sp (list (cons locale new-result)))
 887            ;; tell map-specifier to keep going.
 888            nil))
 889        locale
 890        func))))
 891
 892 (defun frob-face-property-1 (sp device inst-list func)
 893   (let
 894       (first-valid result)
 895     (while (and inst-list (not result))
 896       (let* ((inst-pair (car inst-list))
 897              (tag-set (car inst-pair))
 898              (sp-inst (specifier-instance-from-inst-list
 899                        sp device (list inst-pair))))
 900         (if sp-inst
 901             (progn
 902               (if (not first-valid)
 903                   (setq first-valid inst-pair))
 904               (setq result (funcall func sp-inst device))
 905               (if result
 906                   (setq result (cons tag-set result))))))
 907       (setq inst-list (cdr inst-list)))
 908     (or result first-valid)))
 909
 910 (defcustom face-frob-from-locale-first nil
 911   "*If non nil, use kludgy way of frobbing fonts suitable for non-mule
 912 multi-charset environments."
 913   :group 'faces
 914   :type 'boolean)
 915
 916 (defun frob-face-font-2 (face locale tags unfrobbed-face frobbed-face
 917                               tty-thunk ws-thunk standard-face-mapping)
 918   ;; another kludge to make things more intuitive.  If we're
 919   ;; inheriting from a standard face in this locale, frob the
 920   ;; inheritance as appropriate.  Else, if, after the first
 921   ;; window-system frobbing pass, the face hasn't changed and still
 922   ;; looks like the standard unfrobbed face (e.g. 'default), make it
 923   ;; inherit from the standard frobbed face (e.g. 'bold).  Regardless
 924   ;; of things, do the TTY frobbing.
 925
 926   ;; yuck -- The LOCALE argument to make-face-bold is not actually a locale,
 927   ;; but is a "locale, locale-type, or nil for all".  So ...  do our extra
 928   ;; frobbing only if it's actually a locale; or for nil, do the frobbing
 929   ;; on 'global.  This specifier stuff needs some rethinking.
 930   (let* ((the-locale (cond ((null locale) 'global)
 931                            ((valid-specifier-locale-p locale) locale)
 932                            (t nil)))
 933          (spec-list
 934           (and
 935            the-locale
 936            (specifier-spec-list (get (get-face face) 'font) the-locale tags t)))
 937          (change-it
 938           (and
 939            spec-list
 940            (cdr (assoc (cdadar spec-list) standard-face-mapping)))))
 941     (if (and change-it
 942              (not (memq (face-name (find-face face))
 943                         '(default bold italic bold-italic))))
 944         (progn
 945           (or (equal change-it t)
 946               (set-face-property face 'font change-it the-locale tags))
 947           (funcall tty-thunk))
 948       (let* ((domain (cond ((null the-locale) nil)
 949                            ((valid-specifier-domain-p the-locale) the-locale)
 950                            ;; OK, this next one is truly a kludge, but
 951                            ;; it results in more intuitive behavior most
 952                            ;; of the time. (really!)
 953                            ((or (eq the-locale 'global) (eq the-locale 'all))
 954                             (selected-device))
 955                            (t nil)))
 956              (inst (and domain (face-property-instance face 'font domain))))
 957         ;; If it's reasonable to do the inherit-from-standard-face trick,
 958         ;; and it's called for, then do it now.
 959         (if (and
 960              face-frob-from-locale-first
 961              (eq the-locale 'global)
 962              domain
 963              (equal inst (face-property-instance face 'font domain))
 964              ;; don't do it for standard faces, or you'll get inheritance loops.
 965              ;; #### This makes XEmacs seg fault! fix this bug.
 966              (not (memq (face-name (find-face face))
 967                         '(default bold italic bold-italic)))
 968              (equal (face-property-instance face 'font domain)
 969                     (face-property-instance unfrobbed-face 'font domain)))
 970             (set-face-property face 'font (vector frobbed-face)
 971                                the-locale tags)
 972           ;; and only otherwise try to build new property value artificially
 973           (funcall tty-thunk)
 974           (funcall ws-thunk)
 975           (and
 976            domain
 977            (equal inst (face-property-instance face 'font domain))
 978            ;; don't do it for standard faces, or you'll get inheritance loops.
 979            ;; #### This makes XEmacs seg fault! fix this bug.
 980            (not (memq (face-name (find-face face))
 981                       '(default bold italic bold-italic)))
 982            (equal (face-property-instance face 'font domain)
 983                   (face-property-instance unfrobbed-face 'font domain))
 984            (set-face-property face 'font (vector frobbed-face) the-locale tags)))))))
 985
 986 (defun make-face-bold (face &optional locale tags)
 987   "Make FACE bold in LOCALE, if possible.
 988 This will attempt to make the font bold for X/MSW locales and will set the
 989 highlight flag for TTY locales.
 990
 991 If LOCALE is nil, omitted, or `all', this will attempt to frob all
 992 font specifications for FACE to make them appear bold.  Similarly, if
 993 LOCALE is a locale type, this frobs all font specifications for locales
 994 of that type.  If LOCALE is a particular locale, what happens depends on
 995 what sort of locale is given.  If you gave a device, frame, or window,
 996 then it's always possible to determine what the font actually will be,
 997 so this is determined and the resulting font is frobbed and added back as a
 998 specification for this locale.  If LOCALE is a buffer, however, you can't
 999 determine what the font will actually be unless there's actually a
1000 specification given for that particular buffer (otherwise, it depends
1001 on what window and frame the buffer appears in, and might not even be
1002 well-defined if the buffer appears multiple times in different places);
1003 therefore you will get an error unless there's a specification for the
1004 buffer.
1005
1006 Finally, in some cases (specifically, when LOCALE is not a locale type),
1007 if the frobbing didn't actually make the font look any different
1008 \(this happens, for example, if your font specification is already bold
1009 or has no bold equivalent), and currently looks like the font of the
1010 'default face, it is set to inherit from the 'bold face.  This is kludgy
1011 but it makes `make-face-bold' have more intuitive behavior in many
1012 circumstances."
1013   (interactive (list (read-face-name "Make which face bold: ")))
1014   (frob-face-font-2
1015    face locale tags 'default 'bold
1016    (lambda ()
1017      ;; handle TTY specific entries
1018      (when (featurep 'tty)
1019        (set-face-highlight-p face t locale (cons 'tty tags))))
1020    (lambda ()
1021      ;; handle X/MS Windows specific entries
1022      (when (featurep 'x)
1023        (frob-face-property face 'font 'x-make-font-bold
1024                            '(x) locale tags))
1025      (when (featurep 'mswindows)
1026        (frob-face-property face 'font 'mswindows-make-font-bold
1027                            '(mswindows) locale tags))
1028      )
1029    '(([default] . [bold])
1030      ([bold] . t)
1031      ([italic] . [bold-italic])
1032      ([bold-italic] . t))))
1033
1034 (defun make-face-italic (face &optional locale tags)
1035   "Make FACE italic in LOCALE, if possible.
1036 This will attempt to make the font italic for X/MS Windows locales and
1037 will set the underline flag for TTY locales.  See `make-face-bold' for
1038 the semantics of the LOCALE argument and for more specifics on exactly
1039 how this function works."
1040   (interactive (list (read-face-name "Make which face italic: ")))
1041   (frob-face-font-2
1042    face locale tags 'default 'italic
1043    (lambda ()
1044      ;; handle TTY specific entries
1045      (when (featurep 'tty)
1046        (set-face-underline-p face t locale (cons 'tty tags))))
1047    (lambda ()
1048      ;; handle X specific entries
1049      (when (featurep 'x)
1050        (frob-face-property face 'font 'x-make-font-italic
1051                            '(x) locale tags))
1052      (when (featurep 'mswindows)
1053        (frob-face-property face 'font 'mswindows-make-font-italic
1054                            '(mswindows) locale tags))
1055      )
1056    '(([default] . [italic])
1057      ([bold] . [bold-italic])
1058      ([italic] . t)
1059      ([bold-italic] . t))))
1060
1061 (defun make-face-bold-italic (face &optional locale tags)
1062   "Make FACE bold and italic in LOCALE, if possible.
1063 This will attempt to make the font bold-italic for X/MS Windows
1064 locales and will set the highlight and underline flags for TTY
1065 locales.  See `make-face-bold' for the semantics of the LOCALE
1066 argument and for more specifics on exactly how this function works."
1067   (interactive (list (read-face-name "Make which face bold-italic: ")))
1068   (frob-face-font-2
1069    face locale tags 'default 'bold-italic
1070    (lambda ()
1071      ;; handle TTY specific entries
1072      (when (featurep 'tty)
1073        (set-face-highlight-p face t locale (cons 'tty tags))
1074        (set-face-underline-p face t locale (cons 'tty tags))))
1075    (lambda ()
1076      ;; handle X specific entries
1077      (when (featurep 'x)
1078        (frob-face-property face 'font 'x-make-font-bold-italic
1079                            '(x) locale tags))
1080      (when (featurep 'mswindows)
1081        (frob-face-property face 'font 'mswindows-make-font-bold-italic
1082                            '(mswindows) locale tags))
1083      )
1084    '(([default] . [italic])
1085      ([bold] . [bold-italic])
1086      ([italic] . [bold-italic])
1087      ([bold-italic] . t))))
1088
1089 (defun make-face-unbold (face &optional locale tags)
1090   "Make FACE non-bold in LOCALE, if possible.
1091 This will attempt to make the font non-bold for X/MS Windows locales
1092 and will unset the highlight flag for TTY locales.  See
1093 `make-face-bold' for the semantics of the LOCALE argument and for more
1094 specifics on exactly how this function works."
1095   (interactive (list (read-face-name "Make which face non-bold: ")))
1096   (frob-face-font-2
1097    face locale tags 'bold 'default
1098    (lambda ()
1099      ;; handle TTY specific entries
1100      (when (featurep 'tty)
1101        (set-face-highlight-p face nil locale (cons 'tty tags))))
1102    (lambda ()
1103      ;; handle X specific entries
1104      (when (featurep 'x)
1105        (frob-face-property face 'font 'x-make-font-unbold
1106                            '(x) locale tags))
1107      (when (featurep 'mswindows)
1108        (frob-face-property face 'font 'mswindows-make-font-unbold
1109                            '(mswindows) locale tags))
1110      )
1111    '(([default] . t)
1112      ([bold] . [default])
1113      ([italic] . t)
1114      ([bold-italic] . [italic]))))
1115
1116 (defun make-face-unitalic (face &optional locale tags)
1117   "Make FACE non-italic in LOCALE, if possible.
1118 This will attempt to make the font non-italic for X/MS Windows locales
1119 and will unset the underline flag for TTY locales.  See
1120 `make-face-bold' for the semantics of the LOCALE argument and for more
1121 specifics on exactly how this function works."
1122   (interactive (list (read-face-name "Make which face non-italic: ")))
1123   (frob-face-font-2
1124    face locale tags 'italic 'default
1125    (lambda ()
1126      ;; handle TTY specific entries
1127      (when (featurep 'tty)
1128        (set-face-underline-p face nil locale (cons 'tty tags))))
1129    (lambda ()
1130      ;; handle X specific entries
1131      (when (featurep 'x)
1132        (frob-face-property face 'font 'x-make-font-unitalic
1133                            '(x) locale tags))
1134      (when (featurep 'mswindows)
1135        (frob-face-property face 'font 'mswindows-make-font-unitalic
1136                            '(mswindows) locale tags))
1137      )
1138    '(([default] . t)
1139      ([bold] . t)
1140      ([italic] . [default])
1141      ([bold-italic] . [bold]))))
1142
1143
1144 ;; Why do the following two functions lose so badly in so many
1145 ;; circumstances?
1146
1147 (defun make-face-smaller (face &optional locale)
1148   "Make the font of FACE be smaller, if possible.
1149 LOCALE works as in `make-face-bold' et al., but the ``inheriting-
1150 from-the-bold-face'' operations described there are not done
1151 because they don't make sense in this context."
1152   (interactive (list (read-face-name "Shrink which face: ")))
1153   ;; handle X specific entries
1154   (when (featurep 'x)
1155     (frob-face-property face 'font 'x-find-smaller-font
1156                         '(x) locale))
1157   (when (featurep 'mswindows)
1158     (frob-face-property face 'font 'mswindows-find-smaller-font
1159                         '(mswindows) locale)))
1160
1161 (defun make-face-larger (face &optional locale)
1162   "Make the font of FACE be larger, if possible.
1163 See `make-face-smaller' for the semantics of the LOCALE argument."
1164   (interactive (list (read-face-name "Enlarge which face: ")))
1165   ;; handle X specific entries
1166   (when (featurep 'x)
1167     (frob-face-property face 'font 'x-find-larger-font
1168                         '(x) locale))
1169   (when (featurep 'mswindows)
1170     (frob-face-property face 'font 'mswindows-find-larger-font
1171                         '(mswindows) locale)))
1172
1173 (defun invert-face (face &optional locale)
1174   "Swap the foreground and background colors of the face."
1175   (interactive (list (read-face-name "Invert face: ")))
1176   (if (valid-specifier-domain-p locale)
1177       (let ((foreface (face-foreground-instance face locale)))
1178         (set-face-foreground face (face-background-instance face locale)
1179                              locale)
1180         (set-face-background face foreface locale))
1181     (let ((forespec (copy-specifier (face-foreground face) nil locale)))
1182       (copy-specifier (face-background face) (face-foreground face) locale)
1183       (copy-specifier forespec (face-background face) locale))))
1184
1185 \f
1186 ;;; Convenience functions
1187
1188 (defun face-ascent (face &optional domain charset)
1189   "Return the ascent of FACE in DOMAIN.
1190 See `face-property-instance' for the semantics of the DOMAIN argument."
1191   (font-ascent (face-font face) domain charset))
1192
1193 (defun face-descent (face &optional domain charset)
1194   "Return the descent of FACE in DOMAIN.
1195 See `face-property-instance' for the semantics of the DOMAIN argument."
1196   (font-descent (face-font face) domain charset))
1197
1198 (defun face-width (face &optional domain charset)
1199   "Return the width of FACE in DOMAIN.
1200 See `face-property-instance' for the semantics of the DOMAIN argument."
1201   (font-width (face-font face) domain charset))
1202
1203 (defun face-height (face &optional domain charset)
1204   "Return the height of FACE in DOMAIN.
1205 See `face-property-instance' for the semantics of the DOMAIN argument."
1206   (+ (face-ascent face domain charset) (face-descent face domain charset)))
1207
1208 (defun face-proportional-p (face &optional domain charset)
1209   "Return t if FACE is proportional in DOMAIN.
1210 See `face-property-instance' for the semantics of the DOMAIN argument."
1211   (font-proportional-p (face-font face) domain charset))
1212
1213 \f
1214 ;; Functions that used to be in cus-face.el, but logically go here.
1215
1216 (defcustom frame-background-mode nil
1217   "*The brightness of the background.
1218 Set this to the symbol dark if your background color is dark, light if
1219 your background is light, or nil (default) if you want Emacs to
1220 examine the brightness for you."
1221   :group 'faces
1222   :type '(choice (choice-item dark)
1223                  (choice-item light)
1224                  (choice-item :tag "Auto" nil)))
1225
1226 ;; The old variable that many people still have in .emacs files.
1227 (define-obsolete-variable-alias 'custom-background-mode
1228   'frame-background-mode)
1229
1230 (defun get-frame-background-mode (frame)
1231   "Detect background mode for FRAME."
1232   (let* ((color-instance (face-background-instance 'default frame))
1233          (mode (condition-case nil
1234                    (if (< (apply '+ (color-instance-rgb-components
1235                                      color-instance)) 65536)
1236                        'dark 'light)
1237                  ;; Here, we get an error on a TTY.  As we don't have
1238                  ;; a good way of detecting whether a TTY is light or
1239                  ;; dark, we'll guess it's dark.
1240                  (error 'dark))))
1241     (set-frame-property frame 'background-mode mode)
1242     mode))
1243
1244 (defun extract-custom-frame-properties (frame)
1245   "Return a plist with the frame properties of FRAME used by custom."
1246   (list 'type (or (frame-property frame 'display-type)
1247                   (device-type (frame-device frame)))
1248         'class (device-class (frame-device frame))
1249         'background (or frame-background-mode
1250                         (frame-property frame 'background-mode)
1251                         (get-frame-background-mode frame))))
1252
1253 (defcustom init-face-from-resources t
1254   "If non nil, attempt to initialize faces from the resource database."
1255   :group 'faces
1256   :type 'boolean)
1257
1258 ;; Old name, used by custom.  Also, FSFmacs name.
1259 (defvaralias 'initialize-face-resources 'init-face-from-resources)
1260
1261 ;; Make sure all custom setting are added with this tag so we can
1262 ;; identify-them
1263 (define-specifier-tag 'custom)
1264
1265 (defun face-spec-set (face spec &optional frame tags)
1266   "Set FACE's face attributes according to the first matching entry in SPEC.
1267 If optional FRAME is non-nil, set it for that frame only.
1268 If it is nil, then apply SPEC to each frame individually.
1269 See `defface' for information about SPEC."
1270   (if frame
1271       (progn
1272         (reset-face face frame tags)
1273         (face-display-set face spec frame tags)
1274         (init-face-from-resources face frame))
1275     (let ((frames (relevant-custom-frames)))
1276       (reset-face face nil tags)
1277       ;; This should not be needed. We only remove our own specifiers
1278       ;; (if (and (eq 'default face) (featurep 'x))
1279       ;;          (x-init-global-faces))
1280       (face-display-set face spec nil tags)
1281       (while frames
1282         (face-display-set face spec (car frames) tags)
1283         (pop frames))
1284       (init-face-from-resources face))))
1285
1286 (defun face-display-set (face spec &optional frame tags)
1287   "Set FACE to the attributes to the first matching entry in SPEC.
1288 Iff optional FRAME is non-nil, set it for that frame only.
1289 See `defface' for information about SPEC."
1290   (while spec
1291     (let ((display (caar spec))
1292           (atts (cadar spec)))
1293       (pop spec)
1294       (when (face-spec-set-match-display display frame)
1295         ;; Avoid creating frame local duplicates of the global face.
1296         (unless (and frame (eq display (get face 'custom-face-display)))
1297           (apply 'face-custom-attributes-set face frame tags atts))
1298         (unless frame
1299           (put face 'custom-face-display display))
1300         (setq spec nil)))))
1301
1302 (defvar default-custom-frame-properties nil
1303   "The frame properties used for the global faces.
1304 Frames not matching these properties should have frame local faces.
1305 The value should be nil, if uninitialized, or a plist otherwise.
1306 See `defface' for a list of valid keys and values for the plist.")
1307
1308 (defun get-custom-frame-properties (&optional frame)
1309   "Return a plist with the frame properties of FRAME used by custom.
1310 If FRAME is nil, return the default frame properties."
1311   (cond (frame
1312          ;; Try to get from cache.
1313          (let ((cache (frame-property frame 'custom-properties)))
1314            (unless cache
1315              ;; Oh well, get it then.
1316              (setq cache (extract-custom-frame-properties frame))
1317              ;; and cache it...
1318              (set-frame-property frame 'custom-properties cache))
1319            cache))
1320         (default-custom-frame-properties)
1321         (t
1322          (setq default-custom-frame-properties
1323                (extract-custom-frame-properties (selected-frame))))))
1324
1325 (defun face-spec-update-all-matching (spec display plist)
1326   "Update all entries in the face spec that could match display to
1327 have the entries from the new plist and return the new spec."
1328   (mapcar
1329    (lambda (e)
1330      (let ((entries (car e))
1331            (options (cadr e))
1332            (match t)
1333            dplist
1334            (new-options plist)
1335            )
1336        (unless (eq display t)
1337          (mapc (lambda (arg)
1338                  (setq dplist (plist-put dplist (car arg) (cadr arg))))
1339                display))
1340        (unless (eq entries t)
1341          (mapc (lambda (arg)
1342                  (setq match (and match (eq (cadr arg)
1343                                             (plist-get
1344                                               dplist (car arg)
1345                                               (cadr arg))))))
1346                entries))
1347        (if (not match)
1348            e
1349          (while new-options
1350            (setq options
1351                  (plist-put options (car new-options) (cadr new-options)))
1352            (setq new-options (cddr new-options)))
1353          (list entries options))))
1354    (copy-sequence spec)))
1355
1356
1357
1358 (defun face-spec-set-match-display (display &optional frame)
1359   "Return non-nil if DISPLAY matches FRAME.
1360 DISPLAY is part of a spec such as can be used in `defface'.
1361 If FRAME is nil or omitted, the selected frame is used."
1362   (if (eq display t)
1363       t
1364     (let* ((props (get-custom-frame-properties frame))
1365            (type (plist-get props 'type))
1366            (class (plist-get props 'class))
1367            (background (plist-get props 'background))
1368            (match t)
1369            (entries display)
1370            entry req options)
1371       (while (and entries match)
1372         (setq entry (car entries)
1373               entries (cdr entries)
1374               req (car entry)
1375               options (cdr entry)
1376               match (case req
1377                       (type       (memq type options))
1378                       (class      (memq class options))
1379                       (background (memq background options))
1380                       (t (warn "Unknown req `%S' with options `%S'"
1381                                req options)
1382                          nil))))
1383       match)))
1384
1385 (defun relevant-custom-frames ()
1386   "List of frames whose custom properties differ from the default."
1387   (let ((relevant nil)
1388         (default (get-custom-frame-properties))
1389         (frames (frame-list))
1390         frame)
1391     (while frames
1392       (setq frame (car frames)
1393             frames (cdr frames))
1394       (unless (equal default (get-custom-frame-properties frame))
1395         (push frame relevant)))
1396     relevant))
1397
1398 (defun initialize-custom-faces (&optional frame)
1399   "Initialize all custom faces for FRAME.
1400 If FRAME is nil or omitted, initialize them for all frames."
1401   (mapc (lambda (symbol)
1402           (let ((spec (or (get symbol 'saved-face)
1403                           (get symbol 'face-defface-spec))))
1404             (when spec
1405               ;; No need to init-face-from-resources -- code in
1406               ;; `init-frame-faces' does it already.
1407               (face-display-set symbol spec frame))))
1408         (face-list)))
1409
1410 (defun custom-initialize-frame (frame)
1411   "Initialize frame-local custom faces for FRAME if necessary."
1412   (unless (equal (get-custom-frame-properties)
1413                  (get-custom-frame-properties frame))
1414     (initialize-custom-faces frame)))
1415
1416 (defun startup-initialize-custom-faces ()
1417   "Reset faces created by defface.  Only called at startup.
1418 Don't use this function in your program."
1419   (when default-custom-frame-properties
1420     ;; Reset default value to the actual frame, not stream.
1421     (setq default-custom-frame-properties
1422           (extract-custom-frame-properties (selected-frame)))
1423     ;; like initialize-custom-faces but removes property first.
1424     (mapc (lambda (symbol)
1425             (let ((spec (or (get symbol 'saved-face)
1426                             (get symbol 'face-defface-spec))))
1427               (when spec
1428                 ;; Reset faces created during auto-autoloads loading.
1429                 (reset-face symbol)
1430                 ;; And set it according to the spec.
1431                 (face-display-set symbol spec nil))))
1432           (face-list))))
1433
1434 \f
1435 (defun make-empty-face (name &optional doc-string temporary)
1436   "Like `make-face', but doesn't query the resource database."
1437   (let ((init-face-from-resources nil))
1438     (make-face name doc-string temporary)))
1439
1440 (defun init-face-from-resources (face &optional locale)
1441   "Initialize FACE from the resource database.
1442 If LOCALE is specified, it should be a frame, device, or 'global, and
1443 the face will be resourced over that locale.  Otherwise, the face will
1444 be resourced over all possible locales (i.e. all frames, all devices,
1445 and 'global)."
1446   (cond ((null init-face-from-resources)
1447          ;; Do nothing.
1448          )
1449         ((not locale)
1450          ;; Global, set for all frames.
1451          (progn
1452            (init-face-from-resources face 'global)
1453            (let ((devices (device-list)))
1454              (while devices
1455                (init-face-from-resources face (car devices))
1456                (setq devices (cdr devices))))
1457            (let ((frames (frame-list)))
1458              (while frames
1459                (init-face-from-resources face (car frames))
1460                (setq frames (cdr frames))))))
1461         (t
1462          ;; Specific.
1463          (let ((devtype (cond ((devicep locale) (device-type locale))
1464                               ((framep locale) (frame-type locale))
1465                               (t nil))))
1466            (cond ((or (and (not devtype) (featurep 'x)) (eq 'x devtype))
1467                   (x-init-face-from-resources face locale))
1468                  ((or (not devtype) (eq 'tty devtype))
1469                   ;; Nothing to do for TTYs?
1470                   ))))))
1471
1472 (defun init-device-faces (device)
1473   ;; First, add any device-local face resources.
1474   (when init-face-from-resources
1475     (loop for face in (face-list) do
1476           (init-face-from-resources face device))
1477     ;; Then do any device-specific initialization.
1478     (cond ((eq 'x (device-type device))
1479            (x-init-device-faces device))
1480           ((eq 'mswindows (device-type device))
1481            (mswindows-init-device-faces device))
1482           ;; Nothing to do for TTYs?
1483           )
1484     (or (eq 'stream (device-type device))
1485         (init-other-random-faces device))))
1486
1487 (defun init-frame-faces (frame)
1488   (when init-face-from-resources
1489     ;; First, add any frame-local face resources.
1490     (loop for face in (face-list) do
1491           (init-face-from-resources face frame))
1492     ;; Then do any frame-specific initialization.
1493     (cond ((eq 'x (frame-type frame))
1494            (x-init-frame-faces frame))
1495           ((eq 'mswindows (frame-type frame))
1496            (mswindows-init-frame-faces frame))
1497           ;; Is there anything which should be done for TTY's?
1498           )))
1499
1500 ;; #### This is somewhat X-specific, and is called when the first
1501 ;; X device is created (even if there were TTY devices created
1502 ;; beforehand).  The concept of resources has not been generalized
1503 ;; outside of X-specificness, so we have to live with this
1504 ;; breach of device-independence.
1505
1506 (defun init-global-faces ()
1507   ;; Look for global face resources.
1508   (loop for face in (face-list) do
1509         (init-face-from-resources face 'global))
1510   ;; Further X frobbing.
1511   (x-init-global-faces)
1512   ;; for bold and the like, make the global specification be bold etc.
1513   ;; if the user didn't already specify a value.  These will also be
1514   ;; frobbed further in init-other-random-faces.
1515   (unless (face-font 'bold 'global)
1516     (make-face-bold 'bold 'global))
1517   ;;
1518   (unless (face-font 'italic 'global)
1519     (make-face-italic 'italic 'global))
1520   ;;
1521   (unless (face-font 'bold-italic 'global)
1522     (make-face-bold-italic 'bold-italic 'global)
1523     (unless (face-font 'bold-italic 'global)
1524       (copy-face 'bold 'bold-italic)
1525       (make-face-italic 'bold-italic)))
1526
1527   (when (face-equal 'bold 'bold-italic)
1528     (copy-face 'italic 'bold-italic)
1529     (make-face-bold 'bold-italic))
1530   ;;
1531   ;; Nothing more to be done for X or TTY's?
1532   )
1533
1534
1535 ;; These warnings are there for a reason.  Just specify your fonts
1536 ;; correctly.  Deal with it.  Additionally, one can use
1537 ;; `log-warning-minimum-level' instead of this.
1538 ;(defvar inhibit-font-complaints nil
1539 ;  "Whether to suppress complaints about incomplete sets of fonts.")
1540
1541 (defun face-complain-about-font (face device)
1542   (if (symbolp face) (setq face (symbol-name face)))
1543 ;;  (if (not inhibit-font-complaints)
1544   (display-warning
1545    'font
1546    (let ((default-name (face-font-name 'default device)))
1547      (format "%s: couldn't deduce %s %s version of the font
1548 %S.
1549
1550 Please specify X resources to make the %s face
1551 visually distinguishable from the default face.
1552 For example, you could add one of the following to $HOME/Emacs:
1553
1554 Emacs.%s.attributeFont: -dt-*-medium-i-*
1555 or
1556 Emacs.%s.attributeForeground: hotpink\n"
1557              invocation-name
1558              (if (string-match "\\`[aeiouAEIOU]" face) "an" "a")
1559              face
1560              default-name
1561              face
1562              face
1563              face
1564              ))))
1565
1566
1567 ;; #### This is quite a mess.  We should use the custom mechanism for
1568 ;; most of this stuff.  Currently we don't do it, because Custom
1569 ;; doesn't use specifiers (yet.)  FSF does it the Right Way.
1570
1571 ;; For instance, the definition of `bold' should be something like
1572 ;; (defface bold ((t (:bold t))) "Bold text.") -- and `:bold t' should
1573 ;; make sure that everything works properly.
1574
1575 (defun init-other-random-faces (device)
1576   "Initialize the colors and fonts of the bold, italic, bold-italic,
1577 zmacs-region, list-mode-item-selected, highlight, primary-selection,
1578 secondary-selection, and isearch faces when each device is created.  If
1579 you want to add code to do stuff like this, use the create-device-hook."
1580
1581   ;; try to make 'bold look different from the default on this device.
1582   ;; If that doesn't work at all, then issue a warning.
1583   (unless (face-differs-from-default-p 'bold device)
1584     (make-face-bold 'bold device)
1585     (unless (face-differs-from-default-p 'bold device)
1586       (make-face-unbold 'bold device)
1587       (unless (face-differs-from-default-p 'bold device)
1588         ;; the luser specified one of the bogus font names
1589         (face-complain-about-font 'bold device))))
1590
1591   ;; Similar for italic.
1592   ;; It's unreasonable to expect to be able to make a font italic all
1593   ;; the time.  For many languages, italic is an alien concept.
1594   ;; Basically, because italic is not a globally meaningful concept,
1595   ;; the use of the italic face should really be obsoleted.
1596
1597   ;; I disagree with above.  In many languages, the concept of capital
1598   ;; letters is just as alien, and yet we use them.  Italic is here to
1599   ;; stay.  -hniksic
1600
1601   ;; In a Solaris Japanese environment, there just aren't any italic
1602   ;; fonts - period.  CDE recognizes this reality, and fonts
1603   ;; -dt-interface user-medium-r-normal-*-*-*-*-*-*-*-*-* don't come
1604   ;; in italic versions.  So we first try to make the font bold before
1605   ;; complaining.
1606   (unless (face-differs-from-default-p 'italic device)
1607     (make-face-italic 'italic device)
1608     (unless (face-differs-from-default-p 'italic device)
1609       (make-face-bold 'italic device)
1610       (unless (face-differs-from-default-p 'italic device)
1611         (face-complain-about-font 'italic device))))
1612
1613   ;; similar for bold-italic.
1614   (unless (face-differs-from-default-p 'bold-italic device)
1615     (make-face-bold-italic 'bold-italic device)
1616     ;; if we couldn't get a bold-italic version, try just bold.
1617     (unless (face-differs-from-default-p 'bold-italic device)
1618       (make-face-bold 'bold-italic device)
1619       ;; if we couldn't get bold or bold-italic, then that's probably because
1620       ;; the default font is bold, so make the `bold-italic' face be unbold.
1621       (unless (face-differs-from-default-p 'bold-italic device)
1622         (make-face-unbold 'bold-italic device)
1623         (make-face-italic 'bold-italic device)
1624         (unless (face-differs-from-default-p 'bold-italic device)
1625           ;; if that didn't work, try plain italic
1626           ;; (can this ever happen? what the hell.)
1627           (make-face-italic 'bold-italic device)
1628           (unless (face-differs-from-default-p 'bold-italic device)
1629             ;; then bitch and moan.
1630             (face-complain-about-font 'bold-italic device))))))
1631
1632   ;; Set the text-cursor colors unless already specified.
1633   (when (and (not (eq 'tty (device-type device)))
1634              (not (face-background 'text-cursor 'global))
1635              (face-property-equal 'text-cursor 'default 'background device))
1636     (set-face-background 'text-cursor [default foreground] 'global
1637                          nil 'append))
1638   (when (and (not (eq 'tty (device-type device)))
1639              (not (face-foreground 'text-cursor 'global))
1640              (face-property-equal 'text-cursor 'default 'foreground device))
1641     (set-face-foreground 'text-cursor [default background] 'global
1642                          nil 'append))
1643   )
1644
1645 ;; New function with 20.1, suggested by Per Abrahamsen, coded by Kyle
1646 ;; Jones and Hrvoje Niksic.
1647 (defun set-face-stipple (face pixmap &optional frame)
1648   "Change the stipple pixmap of FACE to PIXMAP.
1649 This is an Emacs compatibility function; consider using
1650 set-face-background-pixmap instead.
1651
1652 PIXMAP should be a string, the name of a file of pixmap data.
1653 The directories listed in the variables `x-bitmap-file-path' and
1654 `mswindows-bitmap-file-path' under X and MS Windows respectively
1655 are searched.
1656
1657 Alternatively, PIXMAP may be a list of the form (WIDTH HEIGHT
1658 DATA) where WIDTH and HEIGHT are the size in pixels, and DATA is
1659 a string, containing the raw bits of the bitmap.  XBM data is
1660 expected in this case, other types of image data will not work.
1661
1662 If the optional FRAME argument is provided, change only
1663 in that frame; otherwise change each frame."
1664   (while (not (find-face face))
1665     (setq face (wrong-type-argument 'facep face)))
1666   (let ((bitmap-path (ecase (console-type)
1667                        (x         x-bitmap-file-path)
1668                        (mswindows mswindows-bitmap-file-path)))
1669         instantiator)
1670     (while
1671         (null
1672          (setq instantiator
1673                (cond ((stringp pixmap)
1674                       (let ((file (if (file-name-absolute-p pixmap)
1675                                       pixmap
1676                                     (locate-file pixmap bitmap-path
1677                                                  '(".xbm" "")))))
1678                         (and file
1679                              `[xbm :file ,file])))
1680                      ((and (listp pixmap) (= (length pixmap) 3))
1681                       `[xbm :data ,pixmap])
1682                      (t nil))))
1683       ;; We're signaling a continuable error; let's make sure the
1684       ;; function `stipple-pixmap-p' at least exists.
1685       (flet ((stipple-pixmap-p (pixmap)
1686                (or (stringp pixmap)
1687                    (and (listp pixmap) (= (length pixmap) 3)))))
1688         (setq pixmap (signal 'wrong-type-argument
1689                              (list 'stipple-pixmap-p pixmap)))))
1690     (check-type frame (or null frame))
1691     (set-face-background-pixmap face instantiator frame)))
1692
1693 \f
1694 ;; Create the remaining standard faces now.  This way, packages that we dump
1695 ;; can reference these faces as parents.
1696 ;;
1697 ;; The default, modeline, left-margin, right-margin, text-cursor,
1698 ;; and pointer faces are created in C.
1699
1700 (make-face 'bold "Bold text.")
1701 (make-face 'italic "Italic text.")
1702 (make-face 'bold-italic "Bold-italic text.")
1703 (make-face 'underline "Underlined text.")
1704 (or (face-differs-from-default-p 'underline)
1705     (set-face-underline-p 'underline t 'global '(default)))
1706 (make-face 'zmacs-region "Used on highlightes region between point and mark.")
1707 (make-face 'isearch "Used on region matched by isearch.")
1708 (make-face 'isearch-secondary "Face to use for highlighting all matches.")
1709 (make-face 'list-mode-item-selected
1710            "Face for the selected list item in list-mode.")
1711 (make-face 'highlight "Highlight face.")
1712 (make-face 'primary-selection "Primary selection face.")
1713 (make-face 'secondary-selection "Secondary selection face.")
1714
1715 ;; Several useful color faces.
1716 (eval-when-compile (load "cl-macs"))
1717 (dolist (color '(red green blue yellow))
1718   (make-face color (concat (symbol-name color) " text."))
1719   (set-face-foreground color (symbol-name color) nil 'color))
1720
1721 ;; Make some useful faces.  This happens very early, before creating
1722 ;; the first non-stream device.
1723
1724 (set-face-background 'text-cursor
1725                      '(((x default) . "Red3")
1726                        ((mswindows default) . "Red3"))
1727                      'global)
1728
1729 ;; some older X servers don't recognize "darkseagreen2"
1730 (set-face-background 'highlight
1731                      '(((x default color) . "darkseagreen2")
1732                        ((x default color) . "green")
1733                        ((x default grayscale) . "gray53")
1734                        ((mswindows default color) . "darkseagreen2")
1735                        ((mswindows default color) . "green")
1736                        ((mswindows default grayscale) . "gray53"))
1737                      'global)
1738 (set-face-background-pixmap 'highlight
1739                             '(((x default mono) . "gray1")
1740                               ((mswindows default mono) . "gray1"))
1741                             'global)
1742
1743 (set-face-background 'zmacs-region
1744                      '(((x default color) . "gray65")
1745                        ((x default grayscale) . "gray65")
1746                        ((mswindows default color) . "gray65")
1747                        ((mswindows default grayscale) . "gray65"))
1748                      'global)
1749 (set-face-background-pixmap 'zmacs-region
1750                             '(((x default mono) . "gray3")
1751                               ((mswindows default mono) . "gray3"))
1752                             'global)
1753
1754 (set-face-background 'list-mode-item-selected
1755                      '(((x default color) . "gray68")
1756                        ((x default grayscale) . "gray68")
1757                        ((x default mono) . [default foreground])
1758                        ((mswindows default color) . "gray68")
1759                        ((mswindows default grayscale) . "gray68")
1760                        ((mswindows default mono) . [default foreground]))
1761                      'global)
1762 (set-face-foreground 'list-mode-item-selected
1763                      '(((x default mono) . [default background])
1764                        ((mswindows default mono) . [default background]))
1765                      'global)
1766
1767 (set-face-background 'primary-selection
1768                      '(((x default color) . "gray65")
1769                        ((x default grayscale) . "gray65")
1770                        ((mswindows default color) . "gray65")
1771                        ((mswindows default grayscale) . "gray65"))
1772                      'global)
1773 (set-face-background-pixmap 'primary-selection
1774                             '(((x default mono) . "gray3")
1775                               ((mswindows default mono) . "gray3"))
1776                             'global)
1777
1778 (set-face-background 'secondary-selection
1779                      '(((x default color) . "paleturquoise")
1780                        ((x default color) . "green")
1781                        ((x default grayscale) . "gray53")
1782                        ((mswindows default color) . "paleturquoise")
1783                        ((mswindows default color) . "green")
1784                        ((mswindows default grayscale) . "gray53"))
1785                      'global)
1786 (set-face-background-pixmap 'secondary-selection
1787                             '(((x default mono) . "gray1")
1788                               ((mswindows default mono) . "gray1"))
1789                             'global)
1790
1791 (set-face-background 'isearch
1792                      '(((x default color) . "paleturquoise")
1793                        ((x default color) . "green")
1794                        ((mswindows default color) . "paleturquoise")
1795                        ((mswindows default color) . "green"))
1796                      'global)
1797
1798 ;; #### This should really, I mean *really*, be converted to some form
1799 ;; of `defface' one day.
1800 (set-face-foreground 'isearch-secondary
1801                      '(((x default color) . "red3")
1802                        ((mswindows default color) . "red3"))
1803                      'global)
1804
1805 ;; Define some logical color names to be used when reading the pixmap files.
1806 (if (featurep 'xpm)
1807     (setq xpm-color-symbols
1808           (list
1809            '("foreground" (face-foreground 'default))
1810            '("background" (face-background 'default))
1811            '("backgroundToolBarColor"
1812              (or
1813               (and
1814                (featurep 'x)
1815                (x-get-resource "backgroundToolBarColor"
1816                                "BackgroundToolBarColor" 'string
1817                                nil nil 'warn))
1818
1819               (face-background 'toolbar)))
1820            '("foregroundToolBarColor"
1821              (or
1822               (and
1823                (featurep 'x)
1824                (x-get-resource "foregroundToolBarColor"
1825                                "ForegroundToolBarColor" 'string
1826                                nil nil 'warn))
1827               (face-foreground 'toolbar)))
1828            )))
1829
1830 (when (featurep 'tty)
1831   (set-face-highlight-p 'bold                    t 'global '(default tty))
1832   (set-face-underline-p 'italic                  t 'global '(default tty))
1833   (set-face-highlight-p 'bold-italic             t 'global '(default tty))
1834   (set-face-underline-p 'bold-italic             t 'global '(default tty))
1835   (set-face-highlight-p 'highlight               t 'global '(default tty))
1836   (set-face-reverse-p   'text-cursor             t 'global '(default tty))
1837   (set-face-reverse-p   'modeline                t 'global '(default tty))
1838   (set-face-reverse-p   'zmacs-region            t 'global '(default tty))
1839   (set-face-reverse-p   'primary-selection       t 'global '(default tty))
1840   (set-face-underline-p 'secondary-selection     t 'global '(default tty))
1841   (set-face-reverse-p   'list-mode-item-selected t 'global '(default tty))
1842   (set-face-reverse-p   'isearch                 t 'global '(default tty))
1843   )
1844
1845 ;;; faces.el ends here