git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-agent.el

   1 ;;; gnus-agent.el --- unplugged support for Semi-gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-cache)
  29 (require 'nnvirtual)
  30 (require 'gnus-sum)
  31 (eval-when-compile
  32   (require 'cl)
  33   (require 'gnus-score))
  34
  35 (defcustom gnus-agent-directory (nnheader-concat gnus-directory "agent/")
  36   "Where the Gnus agent will store its files."
  37   :group 'gnus-agent
  38   :type 'directory)
  39
  40 (defcustom gnus-agent-plugged-hook nil
  41   "Hook run when plugging into the network."
  42   :group 'gnus-agent
  43   :type 'hook)
  44
  45 (defcustom gnus-agent-unplugged-hook nil
  46   "Hook run when unplugging from the network."
  47   :group 'gnus-agent
  48   :type 'hook)
  49
  50 (defcustom gnus-agent-handle-level gnus-level-subscribed
  51   "Groups on levels higher than this variable will be ignored by the Agent."
  52   :group 'gnus-agent
  53   :type 'integer)
  54
  55 (defcustom gnus-agent-expire-days 7
  56   "Read articles older than this will be expired."
  57   :group 'gnus-agent
  58   :type 'integer)
  59
  60 (defcustom gnus-agent-expire-all nil
  61   "If non-nil, also expire unread, ticked and dormant articles.
  62 If nil, only read articles will be expired."
  63   :group 'gnus-agent
  64   :type 'boolean)
  65
  66 (defcustom gnus-agent-group-mode-hook nil
  67   "Hook run in Agent group minor modes."
  68   :group 'gnus-agent
  69   :type 'hook)
  70
  71 (defcustom gnus-agent-summary-mode-hook nil
  72   "Hook run in Agent summary minor modes."
  73   :group 'gnus-agent
  74   :type 'hook)
  75
  76 (defcustom gnus-agent-server-mode-hook nil
  77   "Hook run in Agent summary minor modes."
  78   :group 'gnus-agent
  79   :type 'hook)
  80
  81 ;;; Internal variables
  82
  83 (defvar gnus-agent-history-buffers nil)
  84 (defvar gnus-agent-buffer-alist nil)
  85 (defvar gnus-agent-article-alist nil)
  86 (defvar gnus-agent-group-alist nil)
  87 (defvar gnus-agent-covered-methods nil)
  88 (defvar gnus-category-alist nil)
  89 (defvar gnus-agent-current-history nil)
  90 (defvar gnus-agent-overview-buffer nil)
  91 (defvar gnus-category-predicate-cache nil)
  92 (defvar gnus-category-group-cache nil)
  93 (defvar gnus-agent-spam-hashtb nil)
  94 (defvar gnus-agent-file-name nil)
  95 (defvar gnus-agent-send-mail-function nil)
  96 (defvar gnus-agent-file-coding-system 'no-conversion)
  97
  98 (defconst gnus-agent-scoreable-headers
  99   (list
 100    "subject" "from" "date" "message-id"
 101    "references" "chars" "lines" "xref")
 102   "Headers that are considered when scoring articles
 103 for download via the Agent.")
 104
 105 ;; Dynamic variables
 106 (defvar gnus-headers)
 107 (defvar gnus-score)
 108
 109 ;;;
 110 ;;; Setup
 111 ;;;
 112
 113 (defun gnus-open-agent ()
 114   (setq gnus-agent t)
 115   (gnus-agent-read-servers)
 116   (gnus-category-read)
 117   (setq gnus-agent-overview-buffer
 118         (gnus-get-buffer-create " *Gnus agent overview*"))
 119   (add-hook 'gnus-group-mode-hook 'gnus-agent-mode)
 120   (add-hook 'gnus-summary-mode-hook 'gnus-agent-mode)
 121   (add-hook 'gnus-server-mode-hook 'gnus-agent-mode))
 122
 123 (gnus-add-shutdown 'gnus-close-agent 'gnus)
 124
 125 (defun gnus-close-agent ()
 126   (setq gnus-agent-covered-methods nil
 127         gnus-category-predicate-cache nil
 128         gnus-category-group-cache nil
 129         gnus-agent-spam-hashtb nil)
 130   (gnus-kill-buffer gnus-agent-overview-buffer))
 131
 132 ;;;
 133 ;;; Utility functions
 134 ;;;
 135
 136 (defun gnus-agent-read-file (file)
 137   "Load FILE and do a `read' there."
 138   (with-temp-buffer
 139     (ignore-errors
 140       (nnheader-insert-file-contents file)
 141       (goto-char (point-min))
 142       (read (current-buffer)))))
 143
 144 (defsubst gnus-agent-method ()
 145   (concat (symbol-name (car gnus-command-method)) "/"
 146           (if (equal (cadr gnus-command-method) "")
 147               "unnamed"
 148             (cadr gnus-command-method))))
 149
 150 (defsubst gnus-agent-directory ()
 151   "Path of the Gnus agent directory."
 152   (nnheader-concat gnus-agent-directory
 153                    (nnheader-translate-file-chars (gnus-agent-method)) "/"))
 154
 155 (defun gnus-agent-lib-file (file)
 156   "The full path of the Gnus agent library FILE."
 157   (concat (gnus-agent-directory) "agent.lib/" file))
 158
 159 ;;; Fetching setup functions.
 160
 161 (defun gnus-agent-start-fetch ()
 162   "Initialize data structures for efficient fetching."
 163   (gnus-agent-open-history)
 164   (setq gnus-agent-current-history (gnus-agent-history-buffer)))
 165
 166 (defun gnus-agent-stop-fetch ()
 167   "Save all data structures and clean up."
 168   (gnus-agent-save-history)
 169   (gnus-agent-close-history)
 170   (setq gnus-agent-spam-hashtb nil)
 171   (save-excursion
 172     (set-buffer nntp-server-buffer)
 173     (widen)))
 174
 175 (defmacro gnus-agent-with-fetch (&rest forms)
 176   "Do FORMS safely."
 177   `(unwind-protect
 178        (progn
 179          (gnus-agent-start-fetch)
 180          ,@forms)
 181      (gnus-agent-stop-fetch)))
 182
 183 (put 'gnus-agent-with-fetch 'lisp-indent-function 0)
 184 (put 'gnus-agent-with-fetch 'edebug-form-spec '(body))
 185
 186 ;;;
 187 ;;; Mode infestation
 188 ;;;
 189
 190 (defvar gnus-agent-mode-hook nil
 191   "Hook run when installing agent mode.")
 192
 193 (defvar gnus-agent-mode nil)
 194 (defvar gnus-agent-mode-status '(gnus-agent-mode " Plugged"))
 195
 196 (defun gnus-agent-mode ()
 197   "Minor mode for providing a agent support in Gnus buffers."
 198   (let* ((buffer (progn (string-match "^gnus-\\(.*\\)-mode$"
 199                                       (symbol-name major-mode))
 200                         (match-string 1 (symbol-name major-mode))))
 201          (mode (intern (format "gnus-agent-%s-mode" buffer))))
 202     (set (make-local-variable 'gnus-agent-mode) t)
 203     (set mode nil)
 204     (set (make-local-variable mode) t)
 205     ;; Set up the menu.
 206     (when (gnus-visual-p 'agent-menu 'menu)
 207       (funcall (intern (format "gnus-agent-%s-make-menu-bar" buffer))))
 208     (unless (assq 'gnus-agent-mode minor-mode-alist)
 209       (push gnus-agent-mode-status minor-mode-alist))
 210     (unless (assq mode minor-mode-map-alist)
 211       (push (cons mode (symbol-value (intern (format "gnus-agent-%s-mode-map"
 212                                                      buffer))))
 213             minor-mode-map-alist))
 214     (when (eq major-mode 'gnus-group-mode)
 215       (gnus-agent-toggle-plugged gnus-plugged))
 216     (gnus-run-hooks 'gnus-agent-mode-hook
 217                     (intern (format "gnus-agent-%s-mode-hook" buffer)))))
 218
 219 (defvar gnus-agent-group-mode-map (make-sparse-keymap))
 220 (gnus-define-keys gnus-agent-group-mode-map
 221   "Ju" gnus-agent-fetch-groups
 222   "Jc" gnus-enter-category-buffer
 223   "Jj" gnus-agent-toggle-plugged
 224   "Js" gnus-agent-fetch-session
 225   "JS" gnus-group-send-drafts
 226   "Ja" gnus-agent-add-group)
 227
 228 (defun gnus-agent-group-make-menu-bar ()
 229   (unless (boundp 'gnus-agent-group-menu)
 230     (easy-menu-define
 231      gnus-agent-group-menu gnus-agent-group-mode-map ""
 232      '("Agent"
 233        ["Toggle plugged" gnus-agent-toggle-plugged t]
 234        ["List categories" gnus-enter-category-buffer t]
 235        ["Send drafts" gnus-group-send-drafts gnus-plugged]
 236        ("Fetch"
 237         ["All" gnus-agent-fetch-session gnus-plugged]
 238         ["Group" gnus-agent-fetch-group gnus-plugged])))))
 239
 240 (defvar gnus-agent-summary-mode-map (make-sparse-keymap))
 241 (gnus-define-keys gnus-agent-summary-mode-map
 242   "Jj" gnus-agent-toggle-plugged
 243   "J#" gnus-agent-mark-article
 244   "J\M-#" gnus-agent-unmark-article
 245   "@" gnus-agent-toggle-mark
 246   "Jc" gnus-agent-catchup)
 247
 248 (defun gnus-agent-summary-make-menu-bar ()
 249   (unless (boundp 'gnus-agent-summary-menu)
 250     (easy-menu-define
 251      gnus-agent-summary-menu gnus-agent-summary-mode-map ""
 252      '("Agent"
 253        ["Toggle plugged" gnus-agent-toggle-plugged t]
 254        ["Mark as downloadable" gnus-agent-mark-article t]
 255        ["Unmark as downloadable" gnus-agent-unmark-article t]
 256        ["Toggle mark" gnus-agent-toggle-mark t]
 257        ["Catchup undownloaded" gnus-agent-catchup t]))))
 258
 259 (defvar gnus-agent-server-mode-map (make-sparse-keymap))
 260 (gnus-define-keys gnus-agent-server-mode-map
 261   "Jj" gnus-agent-toggle-plugged
 262   "Ja" gnus-agent-add-server
 263   "Jr" gnus-agent-remove-server)
 264
 265 (defun gnus-agent-server-make-menu-bar ()
 266   (unless (boundp 'gnus-agent-server-menu)
 267     (easy-menu-define
 268      gnus-agent-server-menu gnus-agent-server-mode-map ""
 269      '("Agent"
 270        ["Toggle plugged" gnus-agent-toggle-plugged t]
 271        ["Add" gnus-agent-add-server t]
 272        ["Remove" gnus-agent-remove-server t]))))
 273
 274 (defun gnus-agent-toggle-plugged (plugged)
 275   "Toggle whether Gnus is unplugged or not."
 276   (interactive (list (not gnus-plugged)))
 277   (if plugged
 278       (progn
 279         (setq gnus-plugged plugged)
 280         (gnus-run-hooks 'gnus-agent-plugged-hook)
 281         (setcar (cdr gnus-agent-mode-status) " Plugged"))
 282     (gnus-agent-close-connections)
 283     (setq gnus-plugged plugged)
 284     (gnus-run-hooks 'gnus-agent-unplugged-hook)
 285     (setcar (cdr gnus-agent-mode-status) " Unplugged"))
 286   (set-buffer-modified-p t))
 287
 288 (defun gnus-agent-close-connections ()
 289   "Close all methods covered by the Gnus agent."
 290   (let ((methods gnus-agent-covered-methods))
 291     (while methods
 292       (gnus-close-server (pop methods)))))
 293
 294 ;;;###autoload
 295 (defun gnus-unplugged ()
 296   "Start Gnus unplugged."
 297   (interactive)
 298   (setq gnus-plugged nil)
 299   (gnus))
 300
 301 ;;;###autoload
 302 (defun gnus-plugged ()
 303   "Start Gnus plugged."
 304   (interactive)
 305   (setq gnus-plugged t)
 306   (gnus))
 307
 308 ;;;###autoload
 309 (defun gnus-agentize ()
 310   "Allow Gnus to be an offline newsreader.
 311 The normal usage of this command is to put the following as the
 312 last form in your `.gnus.el' file:
 313
 314 \(gnus-agentize)
 315
 316 This will modify the `gnus-before-startup-hook', `gnus-post-method',
 317 and `message-send-mail-function' variables, and install the Gnus
 318 agent minor mode in all Gnus buffers."
 319   (interactive)
 320   (gnus-open-agent)
 321   (add-hook 'gnus-setup-news-hook 'gnus-agent-queue-setup)
 322   (unless gnus-agent-send-mail-function
 323     (setq gnus-agent-send-mail-function message-send-mail-function
 324           message-send-mail-function 'gnus-agent-send-mail))
 325   (unless gnus-agent-covered-methods
 326     (setq gnus-agent-covered-methods (list gnus-select-method))))
 327
 328 (defun gnus-agent-queue-setup ()
 329   "Make sure the queue group exists."
 330   (unless (gnus-gethash "nndraft:queue" gnus-newsrc-hashtb)
 331     (gnus-request-create-group "queue" '(nndraft ""))
 332     (let ((gnus-level-default-subscribed 1))
 333       (gnus-subscribe-group "nndraft:queue" nil '(nndraft "")))
 334     (gnus-group-set-parameter
 335      "nndraft:queue" 'gnus-dummy '((gnus-draft-mode)))))
 336
 337 (defun gnus-agent-send-mail ()
 338   (if gnus-plugged
 339       (funcall gnus-agent-send-mail-function)
 340     (goto-char (point-min))
 341     (re-search-forward
 342      (concat "^" (regexp-quote mail-header-separator) "\n"))
 343     (replace-match "\n")
 344     (gnus-agent-insert-meta-information 'mail)
 345     (gnus-request-accept-article "nndraft:queue" nil t t)))
 346
 347 (defun gnus-agent-insert-meta-information (type &optional method)
 348   "Insert meta-information into the message that says how it's to be posted.
 349 TYPE can be either `mail' or `news'.  If the latter METHOD can
 350 be a select method."
 351   (save-excursion
 352     (message-remove-header gnus-agent-meta-information-header)
 353     (goto-char (point-min))
 354     (insert gnus-agent-meta-information-header ": "
 355             (symbol-name type) " " (format "%S" method)
 356             "\n")
 357     (forward-char -1)
 358     (while (search-backward "\n" nil t)
 359       (replace-match "\\n" t t))))
 360
 361 ;;;
 362 ;;; Group mode commands
 363 ;;;
 364
 365 (defun gnus-agent-fetch-groups (n)
 366   "Put all new articles in the current groups into the Agent."
 367   (interactive "P")
 368   (gnus-group-iterate n 'gnus-agent-fetch-group))
 369
 370 (defun gnus-agent-fetch-group (group)
 371   "Put all new articles in GROUP into the Agent."
 372   (interactive (list (gnus-group-group-name)))
 373   (unless group
 374     (error "No group on the current line"))
 375   (let ((gnus-command-method (gnus-find-method-for-group group)))
 376     (gnus-agent-with-fetch
 377       (gnus-agent-fetch-group-1 group gnus-command-method)
 378       (gnus-message 5 "Fetching %s...done" group))))
 379
 380 (defun gnus-agent-add-group (category arg)
 381   "Add the current group to an agent category."
 382   (interactive
 383    (list
 384     (intern
 385      (completing-read
 386       "Add to category: "
 387       (mapcar (lambda (cat) (list (symbol-name (car cat))))
 388               gnus-category-alist)
 389       nil t))
 390     current-prefix-arg))
 391   (let ((cat (assq category gnus-category-alist))
 392         c groups)
 393     (gnus-group-iterate arg
 394       (lambda (group)
 395         (when (cadddr (setq c (gnus-group-category group)))
 396           (setf (cadddr c) (delete group (cadddr c))))
 397         (push group groups)))
 398     (setf (cadddr cat) (nconc (cadddr cat) groups))
 399     (gnus-category-write)))
 400
 401 ;;;
 402 ;;; Server mode commands
 403 ;;;
 404
 405 (defun gnus-agent-add-server (server)
 406   "Enroll SERVER in the agent program."
 407   (interactive (list (gnus-server-server-name)))
 408   (unless server
 409     (error "No server on the current line"))
 410   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 411     (when (member method gnus-agent-covered-methods)
 412       (error "Server already in the agent program"))
 413     (push method gnus-agent-covered-methods)
 414     (gnus-agent-write-servers)
 415     (message "Entered %s into the Agent" server)))
 416
 417 (defun gnus-agent-remove-server (server)
 418   "Remove SERVER from the agent program."
 419   (interactive (list (gnus-server-server-name)))
 420   (unless server
 421     (error "No server on the current line"))
 422   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 423     (unless (member method gnus-agent-covered-methods)
 424       (error "Server not in the agent program"))
 425     (setq gnus-agent-covered-methods
 426           (delete method gnus-agent-covered-methods))
 427     (gnus-agent-write-servers)
 428     (message "Removed %s from the agent" server)))
 429
 430 (defun gnus-agent-read-servers ()
 431   "Read the alist of covered servers."
 432   (setq gnus-agent-covered-methods
 433         (gnus-agent-read-file
 434          (nnheader-concat gnus-agent-directory "lib/servers"))))
 435
 436 (defun gnus-agent-write-servers ()
 437   "Write the alist of covered servers."
 438   (with-temp-file (nnheader-concat gnus-agent-directory "lib/servers")
 439     (prin1 gnus-agent-covered-methods (current-buffer))))
 440
 441 ;;;
 442 ;;; Summary commands
 443 ;;;
 444
 445 (defun gnus-agent-mark-article (n &optional unmark)
 446   "Mark the next N articles as downloadable.
 447 If N is negative, mark backward instead.  If UNMARK is non-nil, remove
 448 the mark instead.  The difference between N and the actual number of
 449 articles marked is returned."
 450   (interactive "p")
 451   (let ((backward (< n 0))
 452         (n (abs n)))
 453     (while (and
 454             (> n 0)
 455             (progn
 456               (gnus-summary-set-agent-mark
 457                (gnus-summary-article-number) unmark)
 458               (zerop (gnus-summary-next-subject (if backward -1 1) nil t))))
 459       (setq n (1- n)))
 460     (when (/= 0 n)
 461       (gnus-message 7 "No more articles"))
 462     (gnus-summary-recenter)
 463     (gnus-summary-position-point)
 464     n))
 465
 466 (defun gnus-agent-unmark-article (n)
 467   "Remove the downloadable mark from the next N articles.
 468 If N is negative, unmark backward instead.  The difference between N and
 469 the actual number of articles unmarked is returned."
 470   (interactive "p")
 471   (gnus-agent-mark-article n t))
 472
 473 (defun gnus-agent-toggle-mark (n)
 474   "Toggle the downloadable mark from the next N articles.
 475 If N is negative, toggle backward instead.  The difference between N and
 476 the actual number of articles toggled is returned."
 477   (interactive "p")
 478   (gnus-agent-mark-article n 'toggle))
 479
 480 (defun gnus-summary-set-agent-mark (article &optional unmark)
 481   "Mark ARTICLE as downloadable."
 482   (let ((unmark (if (and (not (null unmark)) (not (eq t unmark)))
 483                     (memq article gnus-newsgroup-downloadable)
 484                   unmark)))
 485     (if unmark
 486         (progn
 487           (setq gnus-newsgroup-downloadable
 488                 (delq article gnus-newsgroup-downloadable))
 489           (push article gnus-newsgroup-undownloaded))
 490       (setq gnus-newsgroup-undownloaded
 491             (delq article gnus-newsgroup-undownloaded))
 492       (push article gnus-newsgroup-downloadable))
 493     (gnus-summary-update-mark
 494      (if unmark gnus-undownloaded-mark gnus-downloadable-mark)
 495      'unread)))
 496
 497 (defun gnus-agent-get-undownloaded-list ()
 498   "Mark all unfetched articles as read."
 499   (let ((gnus-command-method (gnus-find-method-for-group gnus-newsgroup-name)))
 500     (when (and (not gnus-plugged)
 501                (gnus-agent-method-p gnus-command-method))
 502       (gnus-agent-load-alist gnus-newsgroup-name)
 503       (let ((articles gnus-newsgroup-unreads)
 504             article)
 505         (while (setq article (pop articles))
 506           (unless (or (cdr (assq article gnus-agent-article-alist))
 507                   (memq article gnus-newsgroup-downloadable))
 508             (push article gnus-newsgroup-undownloaded)))))))
 509
 510 (defun gnus-agent-catchup ()
 511   "Mark all undownloaded articles as read."
 512   (interactive)
 513   (save-excursion
 514     (while gnus-newsgroup-undownloaded
 515       (gnus-summary-mark-article
 516        (pop gnus-newsgroup-undownloaded) gnus-catchup-mark)))
 517   (gnus-summary-position-point))
 518
 519 ;;;
 520 ;;; Internal functions
 521 ;;;
 522
 523 (defun gnus-agent-save-active (method)
 524   (when (gnus-agent-method-p method)
 525     (let* ((gnus-command-method method)
 526            (file (gnus-agent-lib-file "active")))
 527       (gnus-make-directory (file-name-directory file))
 528       (let ((coding-system-for-write gnus-agent-file-coding-system))
 529         (write-region (point-min) (point-max) file nil 'silent))
 530       (when (file-exists-p (gnus-agent-lib-file "groups"))
 531         (delete-file (gnus-agent-lib-file "groups"))))))
 532
 533 (defun gnus-agent-save-groups (method)
 534   (let* ((gnus-command-method method)
 535          (file (gnus-agent-lib-file "groups")))
 536     (gnus-make-directory (file-name-directory file))
 537     (let ((coding-system-for-write gnus-agent-file-coding-system))
 538       (write-region (point-min) (point-max) file nil 'silent))
 539     (when (file-exists-p (gnus-agent-lib-file "active"))
 540       (delete-file (gnus-agent-lib-file "active")))))
 541
 542 (defun gnus-agent-save-group-info (method group active)
 543   (when (gnus-agent-method-p method)
 544     (let* ((gnus-command-method method)
 545            (file (if nntp-server-list-active-group
 546                      (gnus-agent-lib-file "active")
 547                    (gnus-agent-lib-file "groups"))))
 548       (gnus-make-directory (file-name-directory file))
 549       (with-temp-file file
 550         (when (file-exists-p file)
 551           (nnheader-insert-file-contents file))
 552         (goto-char (point-min))
 553         (if nntp-server-list-active-group
 554             (progn
 555               (when (re-search-forward
 556                      (concat "^" (regexp-quote group) " ") nil t)
 557                 (gnus-delete-line))
 558               (insert group " " (number-to-string (cdr active)) " "
 559                       (number-to-string (car active)) " y\n"))
 560           (when (re-search-forward (concat (regexp-quote group) " ") nil t)
 561             (gnus-delete-line))
 562           (insert-buffer-substring nntp-server-buffer))))))
 563
 564 (defun gnus-agent-group-path (group)
 565   "Translate GROUP into a path."
 566   (if nnmail-use-long-file-names
 567       (gnus-group-real-name group)
 568     (nnheader-replace-chars-in-string
 569      (nnheader-translate-file-chars (gnus-group-real-name group))
 570      ?. ?/)))
 571
 572 \f
 573
 574 (defun gnus-agent-method-p (method)
 575   "Say whether METHOD is covered by the agent."
 576   (member method gnus-agent-covered-methods))
 577
 578 (defun gnus-agent-get-function (method)
 579   (if (and (not gnus-plugged)
 580            (gnus-agent-method-p method))
 581       (progn
 582         (require 'nnagent)
 583         'nnagent)
 584     (car method)))
 585
 586 ;;; History functions
 587
 588 (defun gnus-agent-history-buffer ()
 589   (cdr (assoc (gnus-agent-method) gnus-agent-history-buffers)))
 590
 591 (defun gnus-agent-open-history ()
 592   (save-excursion
 593     (push (cons (gnus-agent-method)
 594                 (set-buffer (gnus-get-buffer-create
 595                              (format " *Gnus agent %s history*"
 596                                      (gnus-agent-method)))))
 597           gnus-agent-history-buffers)
 598     (erase-buffer)
 599     (insert "\n")
 600     (let ((file (gnus-agent-lib-file "history")))
 601       (when (file-exists-p file)
 602         (insert-file file))
 603       (set (make-local-variable 'gnus-agent-file-name) file))))
 604
 605 (defun gnus-agent-save-history ()
 606   (save-excursion
 607     (set-buffer gnus-agent-current-history)
 608     (gnus-make-directory (file-name-directory gnus-agent-file-name))
 609     (let ((coding-system-for-write gnus-agent-file-coding-system))
 610       (write-region (1+ (point-min)) (point-max)
 611                     gnus-agent-file-name nil 'silent))))
 612
 613 (defun gnus-agent-close-history ()
 614   (when (gnus-buffer-live-p gnus-agent-current-history)
 615     (kill-buffer gnus-agent-current-history)
 616     (setq gnus-agent-history-buffers
 617           (delq (assoc (gnus-agent-method) gnus-agent-history-buffers)
 618                 gnus-agent-history-buffers))))
 619
 620 (defun gnus-agent-enter-history (id group-arts date)
 621   (save-excursion
 622     (set-buffer gnus-agent-current-history)
 623     (goto-char (point-max))
 624     (insert id "\t" (number-to-string date) "\t")
 625     (while group-arts
 626       (insert (caar group-arts) " " (number-to-string (cdr (pop group-arts)))
 627               " "))
 628     (insert "\n")))
 629
 630 (defun gnus-agent-article-in-history-p (id)
 631   (save-excursion
 632     (set-buffer (gnus-agent-history-buffer))
 633     (goto-char (point-min))
 634     (search-forward (concat "\n" id "\t") nil t)))
 635
 636 (defun gnus-agent-history-path (id)
 637   (save-excursion
 638     (set-buffer (gnus-agent-history-buffer))
 639     (goto-char (point-min))
 640     (when (search-forward (concat "\n" id "\t") nil t)
 641       (let ((method (gnus-agent-method)))
 642         (let (paths group)
 643           (while (not (numberp (setq group (read (current-buffer)))))
 644             (push (concat method "/" group) paths))
 645           (nreverse paths))))))
 646
 647 ;;;
 648 ;;; Fetching
 649 ;;;
 650
 651 (defun gnus-agent-fetch-articles (group articles)
 652   "Fetch ARTICLES from GROUP and put them into the Agent."
 653   (when articles
 654     ;; Prune off articles that we have already fetched.
 655     (while (and articles
 656                 (cdr (assq (car articles) gnus-agent-article-alist)))
 657      (pop articles))
 658     (let ((arts articles))
 659       (while (cdr arts)
 660         (if (cdr (assq (cadr arts) gnus-agent-article-alist))
 661             (setcdr arts (cddr arts))
 662           (setq arts (cdr arts)))))
 663     (when articles
 664       (let ((dir (concat
 665                   (gnus-agent-directory)
 666                   (gnus-agent-group-path group) "/"))
 667             (date (time-to-days (current-time)))
 668             (case-fold-search t)
 669             pos crosses id elem)
 670         (gnus-make-directory dir)
 671         (gnus-message 7 "Fetching articles for %s..." group)
 672         ;; Fetch the articles from the backend.
 673         (if (gnus-check-backend-function 'retrieve-articles group)
 674             (setq pos (gnus-retrieve-articles articles group))
 675           (with-temp-file nil
 676             (let (article)
 677               (while (setq article (pop articles))
 678                 (when (gnus-request-article article group)
 679                   (goto-char (point-max))
 680                   (push (cons article (point)) pos)
 681                   (insert-buffer-substring nntp-server-buffer)))
 682               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 683               (setq pos (nreverse pos)))))
 684         ;; Then save these articles into the Agent.
 685         (save-excursion
 686           (set-buffer nntp-server-buffer)
 687           (while pos
 688             (narrow-to-region (cdar pos) (or (cdadr pos) (point-max)))
 689             (goto-char (point-min))
 690             (when (search-forward "\n\n" nil t)
 691               (when (search-backward "\nXrefs: " nil t)
 692                 ;; Handle crossposting.
 693                 (skip-chars-forward "^ ")
 694                 (skip-chars-forward " ")
 695                 (setq crosses nil)
 696                 (while (looking-at "\\([^: \n]+\\):\\([0-9]+\\) +")
 697                   (push (cons (buffer-substring (match-beginning 1)
 698                                                 (match-end 1))
 699                               (buffer-substring (match-beginning 2)
 700                                                 (match-end 2)))
 701                         crosses)
 702                   (goto-char (match-end 0)))
 703                 (gnus-agent-crosspost crosses (caar pos))))
 704             (goto-char (point-min))
 705             (if (not (re-search-forward "^Message-ID: *<\\([^>\n]+\\)>" nil t))
 706                 (setq id "No-Message-ID-in-article")
 707               (setq id (buffer-substring (match-beginning 1) (match-end 1))))
 708             (let ((coding-system-for-write
 709                    gnus-agent-file-coding-system))
 710               (write-region (point-min) (point-max)
 711                             (concat dir (number-to-string (caar pos)))
 712                             nil 'silent))
 713             (when (setq elem (assq (caar pos) gnus-agent-article-alist))
 714               (setcdr elem t))
 715             (gnus-agent-enter-history
 716              id (or crosses (list (cons group (caar pos)))) date)
 717             (widen)
 718             (pop pos)))
 719         (gnus-agent-save-alist group)))))
 720
 721 (defun gnus-agent-crosspost (crosses article)
 722   (let (gnus-agent-article-alist group alist beg end)
 723     (save-excursion
 724       (set-buffer gnus-agent-overview-buffer)
 725       (when (nnheader-find-nov-line article)
 726         (forward-word 1)
 727         (setq beg (point))
 728         (setq end (progn (forward-line 1) (point)))))
 729     (while crosses
 730       (setq group (caar crosses))
 731       (unless (setq alist (assoc group gnus-agent-group-alist))
 732         (push (setq alist (list group (gnus-agent-load-alist (caar crosses))))
 733               gnus-agent-group-alist))
 734       (setcdr alist (cons (cons (cdar crosses) t) (cdr alist)))
 735       (save-excursion
 736         (set-buffer (gnus-get-buffer-create (format " *Gnus agent overview %s*"
 737                                                group)))
 738         (when (= (point-max) (point-min))
 739           (push (cons group (current-buffer)) gnus-agent-buffer-alist)
 740           (ignore-errors
 741             (nnheader-insert-file-contents
 742              (gnus-agent-article-name ".overview" group))))
 743         (nnheader-find-nov-line (string-to-number (cdar crosses)))
 744         (insert (string-to-number (cdar crosses)))
 745         (insert-buffer-substring gnus-agent-overview-buffer beg end))
 746       (pop crosses))))
 747
 748 (defun gnus-agent-flush-cache ()
 749   (save-excursion
 750     (while gnus-agent-buffer-alist
 751       (set-buffer (cdar gnus-agent-buffer-alist))
 752       (let ((coding-system-for-write
 753              gnus-agent-file-coding-system))
 754         (write-region (point-min) (point-max)
 755                       (gnus-agent-article-name ".overview"
 756                                                (caar gnus-agent-buffer-alist))
 757                       nil 'silent))
 758       (pop gnus-agent-buffer-alist))
 759     (while gnus-agent-group-alist
 760       (with-temp-file (caar gnus-agent-group-alist)
 761         (princ (cdar gnus-agent-group-alist))
 762         (insert "\n"))
 763       (pop gnus-agent-group-alist))))
 764
 765 (defun gnus-agent-fetch-headers (group &optional force)
 766   (let ((articles (if (gnus-agent-load-alist group)
 767                       (gnus-sorted-intersection
 768                        (gnus-list-of-unread-articles group)
 769                        (gnus-uncompress-range
 770                         (cons (1+ (caar (last gnus-agent-article-alist)))
 771                               (cdr (gnus-active group)))))
 772                     (gnus-list-of-unread-articles group)))
 773         (gnus-decode-encoded-word-function 'identity))
 774     ;; Fetch them.
 775     (when articles
 776       (gnus-message 7 "Fetching headers for %s..." group)
 777       (save-excursion
 778         (set-buffer nntp-server-buffer)
 779         (unless (eq 'nov (gnus-retrieve-headers articles group))
 780           (nnvirtual-convert-headers))
 781         ;; Save these headers for later processing.
 782         (copy-to-buffer gnus-agent-overview-buffer (point-min) (point-max))
 783         (let (file)
 784           (when (file-exists-p
 785                  (setq file (gnus-agent-article-name ".overview" group)))
 786             (gnus-agent-braid-nov group articles file))
 787           (gnus-make-directory (nnheader-translate-file-chars
 788                                 (file-name-directory file)))
 789           (let ((coding-system-for-write
 790                  gnus-agent-file-coding-system))
 791             (write-region (point-min) (point-max) file nil 'silent))
 792           (gnus-agent-save-alist group articles nil)
 793           (gnus-agent-enter-history
 794            "last-header-fetched-for-session"
 795            (list (cons group (nth (- (length  articles) 1) articles)))
 796            (time-to-days (current-time)))
 797           articles)))))
 798
 799 (defsubst gnus-agent-copy-nov-line (article)
 800   (let (b e)
 801     (set-buffer gnus-agent-overview-buffer)
 802     (setq b (point))
 803     (if (eq article (read (current-buffer)))
 804         (setq e (progn (forward-line 1) (point)))
 805       (progn
 806         (beginning-of-line)
 807         (setq e b)))
 808     (set-buffer nntp-server-buffer)
 809     (insert-buffer-substring gnus-agent-overview-buffer b e)))
 810
 811 (defun gnus-agent-braid-nov (group articles file)
 812   (set-buffer gnus-agent-overview-buffer)
 813   (goto-char (point-min))
 814   (set-buffer nntp-server-buffer)
 815   (erase-buffer)
 816   (nnheader-insert-file-contents file)
 817   (goto-char (point-max))
 818   (if (or (= (point-min) (point-max))
 819           (progn
 820             (forward-line -1)
 821             (< (read (current-buffer)) (car articles))))
 822       ;; We have only headers that are after the older headers,
 823       ;; so we just append them.
 824       (progn
 825         (goto-char (point-max))
 826         (insert-buffer-substring gnus-agent-overview-buffer))
 827     ;; We do it the hard way.
 828     (nnheader-find-nov-line (car articles))
 829     (gnus-agent-copy-nov-line (car articles))
 830     (pop articles)
 831     (while (and articles
 832                 (not (eobp)))
 833       (while (and (not (eobp))
 834                   (< (read (current-buffer)) (car articles)))
 835         (forward-line 1))
 836       (beginning-of-line)
 837       (unless (eobp)
 838         (gnus-agent-copy-nov-line (car articles))
 839         (setq articles (cdr articles))))
 840     (when articles
 841       (let (b e)
 842         (set-buffer gnus-agent-overview-buffer)
 843         (setq b (point)
 844               e (point-max))
 845         (set-buffer nntp-server-buffer)
 846         (insert-buffer-substring gnus-agent-overview-buffer b e)))))
 847
 848 (defun gnus-agent-load-alist (group &optional dir)
 849   "Load the article-state alist for GROUP."
 850   (setq gnus-agent-article-alist
 851         (gnus-agent-read-file
 852          (if dir
 853              (concat dir ".agentview")
 854            (gnus-agent-article-name ".agentview" group)))))
 855
 856 (defun gnus-agent-save-alist (group &optional articles state dir)
 857   "Save the article-state alist for GROUP."
 858   (with-temp-file (if dir
 859                       (concat dir ".agentview")
 860                     (gnus-agent-article-name ".agentview" group))
 861     (princ (setq gnus-agent-article-alist
 862                  (nconc gnus-agent-article-alist
 863                         (mapcar (lambda (article) (cons article state))
 864                                 articles)))
 865            (current-buffer))
 866     (insert "\n")))
 867
 868 (defun gnus-agent-article-name (article group)
 869   (concat (gnus-agent-directory) (gnus-agent-group-path group) "/"
 870           (if (stringp article) article (string-to-number article))))
 871
 872 ;;;###autoload
 873 (defun gnus-agent-batch-fetch ()
 874   "Start Gnus and fetch session."
 875   (interactive)
 876   (gnus)
 877   (gnus-agent-fetch-session)
 878   (gnus-group-exit))
 879
 880 (defun gnus-agent-fetch-session ()
 881   "Fetch all articles and headers that are eligible for fetching."
 882   (interactive)
 883   (unless gnus-agent-covered-methods
 884     (error "No servers are covered by the Gnus agent"))
 885   (unless gnus-plugged
 886     (error "Can't fetch articles while Gnus is unplugged"))
 887   (let ((methods gnus-agent-covered-methods)
 888         groups group gnus-command-method)
 889     (save-excursion
 890       (while methods
 891         (setq gnus-command-method (car methods))
 892         (when (or (gnus-server-opened gnus-command-method)
 893                   (gnus-open-server gnus-command-method))
 894           (setq groups (gnus-groups-from-server (car methods)))
 895           (gnus-agent-with-fetch
 896             (while (setq group (pop groups))
 897               (when (<= (gnus-group-level group) gnus-agent-handle-level)
 898                 (gnus-agent-fetch-group-1 group gnus-command-method)))))
 899         (pop methods))
 900       (gnus-message 6 "Finished fetching articles into the Gnus agent"))))
 901
 902 (defun gnus-agent-fetch-group-1 (group method)
 903   "Fetch GROUP."
 904   (let ((gnus-command-method method)
 905         gnus-newsgroup-dependencies gnus-newsgroup-headers
 906         gnus-newsgroup-scored gnus-headers gnus-score
 907         gnus-use-cache articles arts
 908         category predicate info marks score-param)
 909     ;; Fetch headers.
 910     (when (and (or (gnus-active group) (gnus-activate-group group))
 911                (setq articles (gnus-agent-fetch-headers group)))
 912       ;; Parse them and see which articles we want to fetch.
 913       (setq gnus-newsgroup-dependencies
 914             (make-vector (length articles) 0))
 915       ;; No need to call `gnus-get-newsgroup-headers-xover' with
 916       ;; the entire .overview for group as we still have the just
 917       ;; downloaded headers in `gnus-agent-overview-buffer'.
 918       (let ((nntp-server-buffer gnus-agent-overview-buffer))
 919         (setq gnus-newsgroup-headers
 920               (gnus-get-newsgroup-headers-xover articles nil nil group)))
 921       (setq category (gnus-group-category group))
 922       (setq predicate
 923             (gnus-get-predicate
 924              (or (gnus-group-get-parameter group 'agent-predicate t)
 925                  (cadr category))))
 926       ;; Do we want to download everything, or nothing?
 927       (if (or (eq (caaddr predicate) 'gnus-agent-true)
 928               (eq (caaddr predicate) 'gnus-agent-false))
 929           ;; Yes.
 930           (setq arts (symbol-value
 931                       (cadr (assoc (caaddr predicate)
 932                                    '((gnus-agent-true articles)
 933                                      (gnus-agent-false nil))))))
 934         ;; No, we need to decide what we want.
 935         (setq score-param
 936               (let ((score-method
 937                      (or
 938                       (gnus-group-get-parameter group 'agent-score t)
 939                       (caddr category))))
 940                 (when score-method
 941                   (require 'gnus-score)
 942                   (if (eq score-method 'file)
 943                       (let ((entries
 944                              (gnus-score-load-files
 945                               (gnus-all-score-files group)))
 946                             list score-file)
 947                         (while (setq list (car entries))
 948                           (push (car list) score-file)
 949                           (setq list (cdr list))
 950                           (while list
 951                             (when (member (caar list)
 952                                           gnus-agent-scoreable-headers)
 953                               (push (car list) score-file))
 954                             (setq list (cdr list)))
 955                           (setq score-param
 956                                 (append score-param (list (nreverse score-file)))
 957                                 score-file nil entries (cdr entries)))
 958                         (list score-param))
 959                     (if (stringp (car score-method))
 960                         score-method
 961                       (list (list score-method)))))))
 962         (when score-param
 963           (gnus-score-headers score-param))
 964         (setq arts nil)
 965         (while (setq gnus-headers (pop gnus-newsgroup-headers))
 966           (setq gnus-score
 967                 (or (cdr (assq (mail-header-number gnus-headers)
 968                                gnus-newsgroup-scored))
 969                     gnus-summary-default-score))
 970           (when (funcall predicate)
 971             (push (mail-header-number gnus-headers)
 972                   arts))))
 973       ;; Fetch the articles.
 974       (when arts
 975         (gnus-agent-fetch-articles group arts)))
 976     ;; Perhaps we have some additional articles to fetch.
 977     (setq arts (assq 'download (gnus-info-marks
 978                                 (setq info (gnus-get-info group)))))
 979     (when (cdr arts)
 980       (gnus-agent-fetch-articles
 981        group (gnus-uncompress-range (cdr arts)))
 982       (setq marks (delq arts (gnus-info-marks info)))
 983       (gnus-info-set-marks info marks))))
 984
 985 ;;;
 986 ;;; Agent Category Mode
 987 ;;;
 988
 989 (defvar gnus-category-mode-hook nil
 990   "Hook run in `gnus-category-mode' buffers.")
 991
 992 (defvar gnus-category-line-format "     %(%20c%): %g\n"
 993   "Format of category lines.")
 994
 995 (defvar gnus-category-mode-line-format "Gnus: %%b"
 996   "The format specification for the category mode line.")
 997
 998 (defvar gnus-agent-short-article 100
 999   "Articles that have fewer lines than this are short.")
1000
1001 (defvar gnus-agent-long-article 200
1002   "Articles that have more lines than this are long.")
1003
1004 (defvar gnus-agent-low-score 0
1005   "Articles that have a score lower than this have a low score.")
1006
1007 (defvar gnus-agent-high-score 0
1008   "Articles that have a score higher than this have a high score.")
1009
1010
1011 ;;; Internal variables.
1012
1013 (defvar gnus-category-buffer "*Agent Category*")
1014
1015 (defvar gnus-category-line-format-alist
1016   `((?c gnus-tmp-name ?s)
1017     (?g gnus-tmp-groups ?d)))
1018
1019 (defvar gnus-category-mode-line-format-alist
1020   `((?u user-defined ?s)))
1021
1022 (defvar gnus-category-line-format-spec nil)
1023 (defvar gnus-category-mode-line-format-spec nil)
1024
1025 (defvar gnus-category-mode-map nil)
1026 (put 'gnus-category-mode 'mode-class 'special)
1027
1028 (unless gnus-category-mode-map
1029   (setq gnus-category-mode-map (make-sparse-keymap))
1030   (suppress-keymap gnus-category-mode-map)
1031
1032   (gnus-define-keys gnus-category-mode-map
1033     "q" gnus-category-exit
1034     "k" gnus-category-kill
1035     "c" gnus-category-copy
1036     "a" gnus-category-add
1037     "p" gnus-category-edit-predicate
1038     "g" gnus-category-edit-groups
1039     "s" gnus-category-edit-score
1040     "l" gnus-category-list
1041
1042     "\C-c\C-i" gnus-info-find-node
1043     "\C-c\C-b" gnus-bug))
1044
1045 (defvar gnus-category-menu-hook nil
1046   "*Hook run after the creation of the menu.")
1047
1048 (defun gnus-category-make-menu-bar ()
1049   (gnus-turn-off-edit-menu 'category)
1050   (unless (boundp 'gnus-category-menu)
1051     (easy-menu-define
1052      gnus-category-menu gnus-category-mode-map ""
1053      '("Categories"
1054        ["Add" gnus-category-add t]
1055        ["Kill" gnus-category-kill t]
1056        ["Copy" gnus-category-copy t]
1057        ["Edit predicate" gnus-category-edit-predicate t]
1058        ["Edit score" gnus-category-edit-score t]
1059        ["Edit groups" gnus-category-edit-groups t]
1060        ["Exit" gnus-category-exit t]))
1061
1062     (gnus-run-hooks 'gnus-category-menu-hook)))
1063
1064 (defun gnus-category-mode ()
1065   "Major mode for listing and editing agent categories.
1066
1067 All normal editing commands are switched off.
1068 \\<gnus-category-mode-map>
1069 For more in-depth information on this mode, read the manual
1070 (`\\[gnus-info-find-node]').
1071
1072 The following commands are available:
1073
1074 \\{gnus-category-mode-map}"
1075   (interactive)
1076   (when (gnus-visual-p 'category-menu 'menu)
1077     (gnus-category-make-menu-bar))
1078   (kill-all-local-variables)
1079   (gnus-simplify-mode-line)
1080   (setq major-mode 'gnus-category-mode)
1081   (setq mode-name "Category")
1082   (gnus-set-default-directory)
1083   (setq mode-line-process nil)
1084   (use-local-map gnus-category-mode-map)
1085   (buffer-disable-undo)
1086   (setq truncate-lines t)
1087   (setq buffer-read-only t)
1088   (gnus-run-hooks 'gnus-category-mode-hook))
1089
1090 (defalias 'gnus-category-position-point 'gnus-goto-colon)
1091
1092 (defun gnus-category-insert-line (category)
1093   (let* ((gnus-tmp-name (car category))
1094          (gnus-tmp-groups (length (cadddr category))))
1095     (beginning-of-line)
1096     (gnus-add-text-properties
1097      (point)
1098      (prog1 (1+ (point))
1099        ;; Insert the text.
1100        (eval gnus-category-line-format-spec))
1101      (list 'gnus-category gnus-tmp-name))))
1102
1103 (defun gnus-enter-category-buffer ()
1104   "Go to the Category buffer."
1105   (interactive)
1106   (gnus-category-setup-buffer)
1107   (gnus-configure-windows 'category)
1108   (gnus-category-prepare))
1109
1110 (defun gnus-category-setup-buffer ()
1111   (unless (get-buffer gnus-category-buffer)
1112     (save-excursion
1113       (set-buffer (gnus-get-buffer-create gnus-category-buffer))
1114       (gnus-category-mode))))
1115
1116 (defun gnus-category-prepare ()
1117   (gnus-set-format 'category-mode)
1118   (gnus-set-format 'category t)
1119   (let ((alist gnus-category-alist)
1120         (buffer-read-only nil))
1121     (erase-buffer)
1122     (while alist
1123       (gnus-category-insert-line (pop alist)))
1124     (goto-char (point-min))
1125     (gnus-category-position-point)))
1126
1127 (defun gnus-category-name ()
1128   (or (get-text-property (gnus-point-at-bol) 'gnus-category)
1129       (error "No category on the current line")))
1130
1131 (defun gnus-category-read ()
1132   "Read the category alist."
1133   (setq gnus-category-alist
1134         (or (gnus-agent-read-file
1135              (nnheader-concat gnus-agent-directory "lib/categories"))
1136             (list (list 'default 'short nil nil)))))
1137
1138 (defun gnus-category-write ()
1139   "Write the category alist."
1140   (setq gnus-category-predicate-cache nil
1141         gnus-category-group-cache nil)
1142   (with-temp-file (nnheader-concat gnus-agent-directory "lib/categories")
1143     (prin1 gnus-category-alist (current-buffer))))
1144
1145 (defun gnus-category-edit-predicate (category)
1146   "Edit the predicate for CATEGORY."
1147   (interactive (list (gnus-category-name)))
1148   (let ((info (assq category gnus-category-alist)))
1149     (gnus-edit-form
1150      (cadr info) (format "Editing the predicate for category %s" category)
1151      `(lambda (predicate)
1152         (setf (cadr (assq ',category gnus-category-alist)) predicate)
1153         (gnus-category-write)
1154         (gnus-category-list)))))
1155
1156 (defun gnus-category-edit-score (category)
1157   "Edit the score expression for CATEGORY."
1158   (interactive (list (gnus-category-name)))
1159   (let ((info (assq category gnus-category-alist)))
1160     (gnus-edit-form
1161      (caddr info)
1162      (format "Editing the score expression for category %s" category)
1163      `(lambda (groups)
1164         (setf (caddr (assq ',category gnus-category-alist)) groups)
1165         (gnus-category-write)
1166         (gnus-category-list)))))
1167
1168 (defun gnus-category-edit-groups (category)
1169   "Edit the group list for CATEGORY."
1170   (interactive (list (gnus-category-name)))
1171   (let ((info (assq category gnus-category-alist)))
1172     (gnus-edit-form
1173      (cadddr info) (format "Editing the group list for category %s" category)
1174      `(lambda (groups)
1175         (setf (cadddr (assq ',category gnus-category-alist)) groups)
1176         (gnus-category-write)
1177         (gnus-category-list)))))
1178
1179 (defun gnus-category-kill (category)
1180   "Kill the current category."
1181   (interactive (list (gnus-category-name)))
1182   (let ((info (assq category gnus-category-alist))
1183         (buffer-read-only nil))
1184     (gnus-delete-line)
1185     (gnus-category-write)
1186     (setq gnus-category-alist (delq info gnus-category-alist))))
1187
1188 (defun gnus-category-copy (category to)
1189   "Copy the current category."
1190   (interactive (list (gnus-category-name) (intern (read-string "New name: "))))
1191   (let ((info (assq category gnus-category-alist)))
1192     (push (list to (gnus-copy-sequence (cadr info))
1193                 (gnus-copy-sequence (caddr info)) nil)
1194           gnus-category-alist)
1195     (gnus-category-write)
1196     (gnus-category-list)))
1197
1198 (defun gnus-category-add (category)
1199   "Create a new category."
1200   (interactive "SCategory name: ")
1201   (when (assq category gnus-category-alist)
1202     (error "Category %s already exists" category))
1203   (push (list category 'false nil nil)
1204         gnus-category-alist)
1205   (gnus-category-write)
1206   (gnus-category-list))
1207
1208 (defun gnus-category-list ()
1209   "List all categories."
1210   (interactive)
1211   (gnus-category-prepare))
1212
1213 (defun gnus-category-exit ()
1214   "Return to the group buffer."
1215   (interactive)
1216   (kill-buffer (current-buffer))
1217   (gnus-configure-windows 'group t))
1218
1219 ;; To avoid having 8-bit characters in the source file.
1220 (defvar gnus-category-not (list '! 'not (intern (format "%c" 172))))
1221
1222 (defvar gnus-category-predicate-alist
1223   '((spam . gnus-agent-spam-p)
1224     (short . gnus-agent-short-p)
1225     (long . gnus-agent-long-p)
1226     (low . gnus-agent-low-scored-p)
1227     (high . gnus-agent-high-scored-p)
1228     (true . gnus-agent-true)
1229     (false . gnus-agent-false))
1230   "Mapping from short score predicate symbols to predicate functions.")
1231
1232 (defun gnus-agent-spam-p ()
1233   "Say whether an article is spam or not."
1234   (unless gnus-agent-spam-hashtb
1235     (setq gnus-agent-spam-hashtb (gnus-make-hashtable 1000)))
1236   (if (not (equal (mail-header-references gnus-headers) ""))
1237       nil
1238     (let ((string (gnus-simplify-subject (mail-header-subject gnus-headers))))
1239       (prog1
1240           (gnus-gethash string gnus-agent-spam-hashtb)
1241         (gnus-sethash string t gnus-agent-spam-hashtb)))))
1242
1243 (defun gnus-agent-short-p ()
1244   "Say whether an article is short or not."
1245   (< (mail-header-lines gnus-headers) gnus-agent-short-article))
1246
1247 (defun gnus-agent-long-p ()
1248   "Say whether an article is long or not."
1249   (> (mail-header-lines gnus-headers) gnus-agent-long-article))
1250
1251 (defun gnus-agent-low-scored-p ()
1252   "Say whether an article has a low score or not."
1253   (< gnus-score gnus-agent-low-score))
1254
1255 (defun gnus-agent-high-scored-p ()
1256   "Say whether an article has a high score or not."
1257   (> gnus-score gnus-agent-high-score))
1258
1259 (defun gnus-category-make-function (cat)
1260   "Make a function from category CAT."
1261   `(lambda () ,(gnus-category-make-function-1 cat)))
1262
1263 (defun gnus-agent-true ()
1264   "Return t."
1265   t)
1266
1267 (defun gnus-agent-false ()
1268   "Return nil."
1269   nil)
1270
1271 (defun gnus-category-make-function-1 (cat)
1272   "Make a function from category CAT."
1273   (cond
1274    ;; Functions are just returned as is.
1275    ((or (symbolp cat)
1276         (gnus-functionp cat))
1277     `(,(or (cdr (assq cat gnus-category-predicate-alist))
1278            cat)))
1279    ;; More complex category.
1280    ((consp cat)
1281     `(,(cond
1282         ((memq (car cat) '(& and))
1283          'and)
1284         ((memq (car cat) '(| or))
1285          'or)
1286         ((memq (car cat) gnus-category-not)
1287          'not))
1288       ,@(mapcar 'gnus-category-make-function-1 (cdr cat))))
1289    (t
1290     (error "Unknown category type: %s" cat))))
1291
1292 (defun gnus-get-predicate (predicate)
1293   "Return the predicate for CATEGORY."
1294   (or (cdr (assoc predicate gnus-category-predicate-cache))
1295       (cdar (push (cons predicate
1296                         (gnus-category-make-function predicate))
1297                   gnus-category-predicate-cache))))
1298
1299 (defun gnus-group-category (group)
1300   "Return the category GROUP belongs to."
1301   (unless gnus-category-group-cache
1302     (setq gnus-category-group-cache (gnus-make-hashtable 1000))
1303     (let ((cs gnus-category-alist)
1304           groups cat)
1305       (while (setq cat (pop cs))
1306         (setq groups (cadddr cat))
1307         (while groups
1308           (gnus-sethash (pop groups) cat gnus-category-group-cache)))))
1309   (or (gnus-gethash group gnus-category-group-cache)
1310       (assq 'default gnus-category-alist)))
1311
1312 (defun gnus-agent-expire ()
1313   "Expire all old articles."
1314   (interactive)
1315   (let ((methods gnus-agent-covered-methods)
1316         (day (- (time-to-days (current-time)) gnus-agent-expire-days))
1317         gnus-command-method sym group articles
1318         history overview file histories elem art nov-file low info
1319         unreads marked article)
1320     (save-excursion
1321       (setq overview (gnus-get-buffer-create " *expire overview*"))
1322       (while (setq gnus-command-method (pop methods))
1323         (let ((expiry-hashtb (gnus-make-hashtable 1023)))
1324         (gnus-agent-open-history)
1325         (set-buffer
1326          (setq gnus-agent-current-history
1327                (setq history (gnus-agent-history-buffer))))
1328         (goto-char (point-min))
1329         (when (> (buffer-size) 1)
1330           (goto-char (point-min))
1331           (while (not (eobp))
1332             (skip-chars-forward "^\t")
1333             (if (> (read (current-buffer)) day)
1334                 ;; New article; we don't expire it.
1335                 (forward-line 1)
1336               ;; Old article.  Schedule it for possible nuking.
1337               (while (not (eolp))
1338                 (setq sym (let ((obarray expiry-hashtb))
1339                             (read (current-buffer))))
1340                 (if (boundp sym)
1341                     (set sym (cons (cons (read (current-buffer)) (point))
1342                                    (symbol-value sym)))
1343                   (set sym (list (cons (read (current-buffer)) (point)))))
1344                 (skip-chars-forward " "))
1345               (forward-line 1)))
1346           ;; We now have all articles that can possibly be expired.
1347           (mapatoms
1348            (lambda (sym)
1349              (setq group (symbol-name sym)
1350                    articles (sort (symbol-value sym) 'car-less-than-car)
1351                    low (car (gnus-active group))
1352                    info (gnus-get-info group)
1353                    unreads (ignore-errors (gnus-list-of-unread-articles group))
1354                    marked (nconc (gnus-uncompress-range
1355                                   (cdr (assq 'tick (gnus-info-marks info))))
1356                                  (gnus-uncompress-range
1357                                   (cdr (assq 'dormant
1358                                              (gnus-info-marks info)))))
1359                    nov-file (gnus-agent-article-name ".overview" group))
1360              (gnus-agent-load-alist group)
1361              (gnus-message 5 "Expiring articles in %s" group)
1362              (set-buffer overview)
1363              (erase-buffer)
1364              (when (file-exists-p nov-file)
1365                (nnheader-insert-file-contents nov-file))
1366              (goto-char (point-min))
1367              (setq article 0)
1368              (while (setq elem (pop articles))
1369                (setq article (car elem))
1370                (when (or (null low)
1371                          (< article low)
1372                          gnus-agent-expire-all
1373                          (and (not (memq article unreads))
1374                               (not (memq article marked))))
1375                  ;; Find and nuke the NOV line.
1376                  (while (and (not (eobp))
1377                              (or (not (numberp
1378                                        (setq art (read (current-buffer)))))
1379                                  (< art article)))
1380                    (if (file-exists-p
1381                         (gnus-agent-article-name
1382                          (number-to-string art) group))
1383                        (forward-line 1)
1384                      ;; Remove old NOV lines that have no articles.
1385                      (gnus-delete-line)))
1386                  (if (or (eobp)
1387                          (/= art article))
1388                      (beginning-of-line)
1389                    (gnus-delete-line))
1390                  ;; Nuke the article.
1391                  (when (file-exists-p (setq file (gnus-agent-article-name
1392                                                   (number-to-string article)
1393                                                   group)))
1394                    (delete-file file))
1395                  ;; Schedule the history line for nuking.
1396                  (push (cdr elem) histories)))
1397              (gnus-make-directory (file-name-directory nov-file))
1398              (let ((coding-system-for-write
1399                     gnus-agent-file-coding-system))
1400                (write-region (point-min) (point-max) nov-file nil 'silent))
1401              ;; Delete the unwanted entries in the alist.
1402              (setq gnus-agent-article-alist
1403                    (sort gnus-agent-article-alist 'car-less-than-car))
1404              (let* ((alist gnus-agent-article-alist)
1405                     (prev (cons nil alist))
1406                     (first prev)
1407                     expired)
1408                (while (and alist
1409                            (<= (caar alist) article))
1410                  (if (or (not (cdar alist))
1411                          (not (file-exists-p
1412                                (gnus-agent-article-name
1413                                 (number-to-string
1414                                  (caar alist))
1415                                 group))))
1416                      (progn
1417                        (push (caar alist) expired)
1418                        (setcdr prev (setq alist (cdr alist))))
1419                    (setq prev alist
1420                          alist (cdr alist))))
1421                (setq gnus-agent-article-alist (cdr first))
1422                (gnus-agent-save-alist group)
1423                ;; Mark all articles up to the first article
1424                ;; in `gnus-article-alist' as read.
1425                (when (and info (caar gnus-agent-article-alist))
1426                  (setcar (nthcdr 2 info)
1427                          (gnus-range-add
1428                           (nth 2 info)
1429                           (cons 1 (- (caar gnus-agent-article-alist) 1)))))
1430                ;; Maybe everything has been expired from `gnus-article-alist'
1431                ;; and so the above marking as read could not be conducted,
1432                ;; or there are expired article within the range of the alist.
1433                (when (and info
1434                           expired
1435                           (or (not (caar gnus-agent-article-alist))
1436                               (> (car expired)
1437                                  (caar gnus-agent-article-alist))))
1438                  (setcar (nthcdr 2 info)
1439                          (gnus-add-to-range
1440                           (nth 2 info)
1441                           (nreverse expired))))
1442                (gnus-dribble-enter
1443                 (concat "(gnus-group-set-info '"
1444                         (gnus-prin1-to-string info)
1445                         ")"))))
1446            expiry-hashtb)
1447           (set-buffer history)
1448           (setq histories (nreverse (sort histories '<)))
1449           (while histories
1450             (goto-char (pop histories))
1451             (gnus-delete-line))
1452           (gnus-agent-save-history)
1453           (gnus-agent-close-history))
1454         (gnus-message 4 "Expiry...done"))))))
1455
1456 ;;;###autoload
1457 (defun gnus-agent-batch ()
1458   (interactive)
1459   (let ((init-file-user "")
1460         (gnus-always-read-dribble-file t))
1461     (gnus))
1462   (gnus-group-send-drafts)
1463   (gnus-agent-fetch-session))
1464
1465 (provide 'gnus-agent)
1466
1467 ;;; gnus-agent.el ends here