git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-int)
  32 (require 'gnus-range)
  33 (require 'gnus-start)
  34 (eval-when-compile
  35   (require 'gnus-sum))
  36
  37 (defcustom gnus-cache-active-file
  38   (concat (file-name-as-directory gnus-cache-directory) "active")
  39   "*The cache active file."
  40   :group 'gnus-cache
  41   :type 'file)
  42
  43 (defcustom gnus-cache-enter-articles '(ticked dormant)
  44   "Classes of articles to enter into the cache."
  45   :group 'gnus-cache
  46   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  47
  48 (defcustom gnus-cache-remove-articles '(read)
  49   "Classes of articles to remove from the cache."
  50   :group 'gnus-cache
  51   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  52
  53 (defcustom gnus-cacheable-groups nil
  54   "*Groups that match this regexp will be cached.
  55
  56 If you only want to cache your nntp groups, you could set this
  57 variable to \"^nntp\".
  58
  59 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  60 it's not cached."
  61   :group 'gnus-cache
  62   :type '(choice (const :tag "off" nil)
  63                 regexp))
  64
  65 (defcustom gnus-uncacheable-groups nil
  66   "*Groups that match this regexp will not be cached.
  67
  68 If you want to avoid caching your nnml groups, you could set this
  69 variable to \"^nnml\".
  70
  71 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  72 it's not cached."
  73   :group 'gnus-cache
  74   :type '(choice (const :tag "off" nil)
  75                  regexp))
  76
  77 \f
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-cache-removable-articles nil)
  82 (defvar gnus-cache-buffer nil)
  83 (defvar gnus-cache-active-hashtb nil)
  84 (defvar gnus-cache-active-altered nil)
  85
  86 (eval-and-compile
  87   (autoload 'nnml-generate-nov-databases-1 "nnml")
  88   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  89
  90 \f
  91
  92 ;;; Functions called from Gnus.
  93
  94 (defun gnus-cache-open ()
  95   "Initialize the cache."
  96   (when (or (file-exists-p gnus-cache-directory)
  97             (and gnus-use-cache
  98                  (not (eq gnus-use-cache 'passive))))
  99     (gnus-cache-read-active)))
 100
 101 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
 102 (ignore-errors
 103   (gnus-add-shutdown 'gnus-cache-close 'gnus))
 104
 105 (defun gnus-cache-close ()
 106   "Shut down the cache."
 107   (gnus-cache-write-active)
 108   (gnus-cache-save-buffers)
 109   (setq gnus-cache-active-hashtb nil))
 110
 111 (defun gnus-cache-save-buffers ()
 112   ;; save the overview buffer if it exists and has been modified
 113   ;; delete empty cache subdirectories
 114   (when gnus-cache-buffer
 115     (let ((buffer (cdr gnus-cache-buffer))
 116           (overview-file (gnus-cache-file-name
 117                           (car gnus-cache-buffer) ".overview")))
 118       ;; write the overview only if it was modified
 119       (when (buffer-modified-p buffer)
 120         (save-excursion
 121           (set-buffer buffer)
 122           (if (> (buffer-size) 0)
 123               ;; Non-empty overview, write it to a file.
 124               (gnus-write-buffer overview-file)
 125             ;; Empty overview file, remove it
 126             (when (file-exists-p overview-file)
 127               (delete-file overview-file))
 128             ;; If possible, remove group's cache subdirectory.
 129             (condition-case nil
 130                 ;; FIXME: we can detect the error type and warn the user
 131                 ;; of any inconsistencies (articles w/o nov entries?).
 132                 ;; for now, just be conservative...delete only if safe -- sj
 133                 (delete-directory (file-name-directory overview-file))
 134               (error nil)))))
 135       ;; Kill the buffer -- it's either unmodified or saved.
 136       (gnus-kill-buffer buffer)
 137       (setq gnus-cache-buffer nil))))
 138
 139 (defun gnus-cache-possibly-enter-article
 140   (group article headers ticked dormant unread &optional force)
 141   (when (and (or force (not (eq gnus-use-cache 'passive)))
 142              (numberp article)
 143              (> article 0)
 144              (vectorp headers))         ; This might be a dummy article.
 145     ;; If this is a virtual group, we find the real group.
 146     (when (gnus-virtual-group-p group)
 147       (let ((result (nnvirtual-find-group-art
 148                      (gnus-group-real-name group) article)))
 149         (setq group (car result)
 150               headers (copy-sequence headers))
 151         (mail-header-set-number headers (cdr result))))
 152     (let ((number (mail-header-number headers))
 153           file dir)
 154       (when (and number
 155                  (> number 0)           ; Reffed article.
 156                  (or force
 157                      (and (or (not gnus-cacheable-groups)
 158                               (string-match gnus-cacheable-groups group))
 159                           (or (not gnus-uncacheable-groups)
 160                               (not (string-match
 161                                     gnus-uncacheable-groups group)))
 162                           (gnus-cache-member-of-class
 163                            gnus-cache-enter-articles ticked dormant unread)))
 164                  (not (file-exists-p (setq file (gnus-cache-file-name
 165                                                  group number)))))
 166         ;; Possibly create the cache directory.
 167         (gnus-make-directory (setq dir (file-name-directory file)))
 168         ;; Save the article in the cache.
 169         (if (file-exists-p file)
 170             t                           ; The article already is saved.
 171           (save-excursion
 172             (set-buffer nntp-server-buffer)
 173             (let ((gnus-use-cache nil))
 174               (gnus-request-article-this-buffer number group))
 175             (when (> (buffer-size) 0)
 176               (gnus-write-buffer file)
 177               (gnus-cache-change-buffer group)
 178               (set-buffer (cdr gnus-cache-buffer))
 179               (goto-char (point-max))
 180               (forward-line -1)
 181               (while (condition-case ()
 182                          (when (not (bobp))
 183                            (> (read (current-buffer)) number))
 184                        (error
 185                         ;; The line was malformed, so we just remove it!!
 186                         (gnus-delete-line)
 187                         t))
 188                 (forward-line -1))
 189               (if (bobp)
 190                   (if (not (eobp))
 191                       (progn
 192                         (beginning-of-line)
 193                         (when (< (read (current-buffer)) number)
 194                           (forward-line 1)))
 195                     (beginning-of-line))
 196                 (forward-line 1))
 197               (beginning-of-line)
 198               ;; [number subject from date id references chars lines xref]
 199               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 200                               (mail-header-number headers)
 201                               (let ((subject (mail-header-subject headers)))
 202                                 (or (get-text-property 0 'raw-text subject)
 203                                     subject))
 204                               (let ((from (mail-header-from headers)))
 205                                 (or (get-text-property 0 'raw-text from)
 206                                     from))
 207                               (mail-header-date headers)
 208                               (mail-header-id headers)
 209                               (or (mail-header-references headers) "")
 210                               (or (mail-header-chars headers) "")
 211                               (or (mail-header-lines headers) "")
 212                               (or (mail-header-xref headers) "")))
 213               ;; Update the active info.
 214               (set-buffer gnus-summary-buffer)
 215               (gnus-cache-update-active group number)
 216               (push article gnus-newsgroup-cached)
 217               (gnus-summary-update-secondary-mark article))
 218             t))))))
 219
 220 (defun gnus-cache-enter-remove-article (article)
 221   "Mark ARTICLE for later possible removal."
 222   (when article
 223     (push article gnus-cache-removable-articles)))
 224
 225 (defun gnus-cache-possibly-remove-articles ()
 226   "Possibly remove some of the removable articles."
 227   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 228       (gnus-cache-possibly-remove-articles-1)
 229     (let ((arts gnus-cache-removable-articles)
 230           ga)
 231       (while arts
 232         (when (setq ga (nnvirtual-find-group-art
 233                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 234           (let ((gnus-cache-removable-articles (list (cdr ga)))
 235                 (gnus-newsgroup-name (car ga)))
 236             (gnus-cache-possibly-remove-articles-1)))))
 237     (setq gnus-cache-removable-articles nil)))
 238
 239 (defun gnus-cache-possibly-remove-articles-1 ()
 240   "Possibly remove some of the removable articles."
 241   (unless (eq gnus-use-cache 'passive)
 242     (let ((articles gnus-cache-removable-articles)
 243           (cache-articles gnus-newsgroup-cached)
 244           article)
 245       (gnus-cache-change-buffer gnus-newsgroup-name)
 246       (while articles
 247         (when (memq (setq article (pop articles)) cache-articles)
 248           ;; The article was in the cache, so we see whether we are
 249           ;; supposed to remove it from the cache.
 250           (gnus-cache-possibly-remove-article
 251            article (memq article gnus-newsgroup-marked)
 252            (memq article gnus-newsgroup-dormant)
 253            (or (memq article gnus-newsgroup-unreads)
 254                (memq article gnus-newsgroup-unselected))))))
 255     ;; The overview file might have been modified, save it
 256     ;; safe because we're only called at group exit anyway.
 257     (gnus-cache-save-buffers)))
 258
 259 (defun gnus-cache-request-article (article group)
 260   "Retrieve ARTICLE in GROUP from the cache."
 261   (let ((file (gnus-cache-file-name group article))
 262         (buffer-read-only nil))
 263     (when (file-exists-p file)
 264       (erase-buffer)
 265       (gnus-kill-all-overlays)
 266       (nnheader-insert-file-contents file)
 267       t)))
 268
 269 (defun gnus-cache-possibly-alter-active (group active)
 270   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 271   (when gnus-cache-active-hashtb
 272     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 273       (when cache-active
 274         (when (< (car cache-active) (car active))
 275           (setcar active (car cache-active)))
 276         (when (> (cdr cache-active) (cdr active))
 277           (setcdr active (cdr cache-active)))))))
 278
 279 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 280   "Retrieve the headers for ARTICLES in GROUP."
 281   (let ((cached
 282          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 283     (if (not cached)
 284         ;; No cached articles here, so we just retrieve them
 285         ;; the normal way.
 286         (let ((gnus-use-cache nil))
 287           (gnus-retrieve-headers articles group fetch-old))
 288       (let ((uncached-articles (gnus-sorted-intersection
 289                                 (gnus-sorted-complement articles cached)
 290                                 articles))
 291             (cache-file (gnus-cache-file-name group ".overview"))
 292             type)
 293         ;; We first retrieve all the headers that we don't have in
 294         ;; the cache.
 295         (let ((gnus-use-cache nil))
 296           (when uncached-articles
 297             (setq type (and articles
 298                             (gnus-retrieve-headers
 299                              uncached-articles group fetch-old)))))
 300         (gnus-cache-save-buffers)
 301         ;; Then we insert the cached headers.
 302         (save-excursion
 303           (cond
 304            ((not (file-exists-p cache-file))
 305             ;; There are no cached headers.
 306             type)
 307            ((null type)
 308             ;; There were no uncached headers (or retrieval was
 309             ;; unsuccessful), so we use the cached headers exclusively.
 310             (set-buffer nntp-server-buffer)
 311             (erase-buffer)
 312             (nnheader-insert-file-contents cache-file)
 313             'nov)
 314            ((eq type 'nov)
 315             ;; We have both cached and uncached NOV headers, so we
 316             ;; braid them.
 317             (gnus-cache-braid-nov group cached)
 318             type)
 319            (t
 320             ;; We braid HEADs.
 321             (gnus-cache-braid-heads group (gnus-sorted-intersection
 322                                            cached articles))
 323             type)))))))
 324
 325 (defun gnus-cache-enter-article (&optional n)
 326   "Enter the next N articles into the cache.
 327 If not given a prefix, use the process marked articles instead.
 328 Returns the list of articles entered."
 329   (interactive "P")
 330   (let ((articles (gnus-summary-work-articles n))
 331         article out)
 332     (while (setq article (pop articles))
 333       (gnus-summary-remove-process-mark article)
 334       (if (natnump article)
 335           (when (gnus-cache-possibly-enter-article
 336                  gnus-newsgroup-name article
 337                  (gnus-summary-article-header article)
 338                  nil nil nil t)
 339             (push article out))
 340         (gnus-message 2 "Can't cache article %d" article))
 341       (gnus-summary-update-secondary-mark article))
 342     (gnus-summary-next-subject 1)
 343     (gnus-summary-position-point)
 344     (nreverse out)))
 345
 346 (defun gnus-cache-remove-article (n)
 347   "Remove the next N articles from the cache.
 348 If not given a prefix, use the process marked articles instead.
 349 Returns the list of articles removed."
 350   (interactive "P")
 351   (gnus-cache-change-buffer gnus-newsgroup-name)
 352   (let ((articles (gnus-summary-work-articles n))
 353         article out)
 354     (while articles
 355       (setq article (pop articles))
 356       (gnus-summary-remove-process-mark article)
 357       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 358         (push article out))
 359       (gnus-summary-update-secondary-mark article))
 360     (gnus-summary-next-subject 1)
 361     (gnus-summary-position-point)
 362     (nreverse out)))
 363
 364 (defun gnus-cached-article-p (article)
 365   "Say whether ARTICLE is cached in the current group."
 366   (memq article gnus-newsgroup-cached))
 367
 368 (defun gnus-summary-insert-cached-articles ()
 369   "Insert all the articles cached for this group into the current buffer."
 370   (interactive)
 371   (let ((cached (sort (copy-sequence gnus-newsgroup-cached) '<))
 372         (gnus-verbose (max 6 gnus-verbose)))
 373     (unless cached
 374       (gnus-message 3 "No cached articles for this group"))
 375     (while cached
 376       (gnus-summary-goto-subject (pop cached) t))))
 377
 378 (defalias 'gnus-summary-limit-include-cached
 379   'gnus-summary-insert-cached-articles)
 380
 381 ;;; Internal functions.
 382
 383 (defun gnus-cache-change-buffer (group)
 384   (and gnus-cache-buffer
 385        ;; See if the current group's overview cache has been loaded.
 386        (or (string= group (car gnus-cache-buffer))
 387            ;; Another overview cache is current, save it.
 388            (gnus-cache-save-buffers)))
 389   ;; if gnus-cache buffer is nil, create it
 390   (unless gnus-cache-buffer
 391     ;; Create cache buffer
 392     (save-excursion
 393       (setq gnus-cache-buffer
 394             (cons group
 395                   (set-buffer (gnus-get-buffer-create " *gnus-cache-overview*"))))
 396       (buffer-disable-undo (current-buffer))
 397       ;; Insert the contents of this group's cache overview.
 398       (erase-buffer)
 399       (let ((file (gnus-cache-file-name group ".overview")))
 400         (when (file-exists-p file)
 401           (nnheader-insert-file-contents file)))
 402       ;; We have a fresh (empty/just loaded) buffer,
 403       ;; mark it as unmodified to save a redundant write later.
 404       (set-buffer-modified-p nil))))
 405
 406 ;; Return whether an article is a member of a class.
 407 (defun gnus-cache-member-of-class (class ticked dormant unread)
 408   (or (and ticked (memq 'ticked class))
 409       (and dormant (memq 'dormant class))
 410       (and unread (memq 'unread class))
 411       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 412
 413 (defun gnus-cache-file-name (group article)
 414   (concat (file-name-as-directory gnus-cache-directory)
 415           (file-name-as-directory
 416            (nnheader-translate-file-chars
 417             (if (gnus-use-long-file-name 'not-cache)
 418                 group
 419               (let ((group (nnheader-replace-chars-in-string group ?/ ?_)))
 420                 ;; Translate the first colon into a slash.
 421                 (when (string-match ":" group)
 422                   (aset group (match-beginning 0) ?/))
 423                 (nnheader-replace-chars-in-string group ?. ?/)))
 424             t))
 425           (if (stringp article) article (int-to-string article))))
 426
 427 (defun gnus-cache-update-article (group article)
 428   "If ARTICLE is in the cache, remove it and re-enter it."
 429   (gnus-cache-change-buffer group)
 430   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 431     (let ((gnus-use-cache nil))
 432       (gnus-cache-possibly-enter-article
 433        gnus-newsgroup-name article (gnus-summary-article-header article)
 434        nil nil nil t))))
 435
 436 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 437                                                    &optional force)
 438   "Possibly remove ARTICLE from the cache."
 439   (let ((group gnus-newsgroup-name)
 440         (number article)
 441         file)
 442     ;; If this is a virtual group, we find the real group.
 443     (when (gnus-virtual-group-p group)
 444       (let ((result (nnvirtual-find-group-art
 445                      (gnus-group-real-name group) article)))
 446         (setq group (car result)
 447               number (cdr result))))
 448     (setq file (gnus-cache-file-name group number))
 449     (when (and (file-exists-p file)
 450                (or force
 451                    (gnus-cache-member-of-class
 452                     gnus-cache-remove-articles ticked dormant unread)))
 453       (save-excursion
 454         (delete-file file)
 455         (set-buffer (cdr gnus-cache-buffer))
 456         (goto-char (point-min))
 457         (when (or (looking-at (concat (int-to-string number) "\t"))
 458                   (search-forward (concat "\n" (int-to-string number) "\t")
 459                                   (point-max) t))
 460           (delete-region (progn (beginning-of-line) (point))
 461                          (progn (forward-line 1) (point)))))
 462       (setq gnus-newsgroup-cached
 463             (delq article gnus-newsgroup-cached))
 464       (gnus-summary-update-secondary-mark article)
 465       t)))
 466
 467 (defun gnus-cache-articles-in-group (group)
 468   "Return a sorted list of cached articles in GROUP."
 469   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 470         articles)
 471     (when (file-exists-p dir)
 472       (setq articles
 473             (sort (mapcar (lambda (name) (string-to-int name))
 474                           (directory-files dir nil "^[0-9]+$" t))
 475                   '<))
 476       ;; Update the cache active file, just to synch more.
 477       (when articles
 478         (gnus-cache-update-active group (car articles) t)
 479         (gnus-cache-update-active group (car (last articles))))
 480       articles)))
 481
 482 (defun gnus-cache-braid-nov (group cached &optional file)
 483   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
 484         beg end)
 485     (gnus-cache-save-buffers)
 486     (save-excursion
 487       (set-buffer cache-buf)
 488       (buffer-disable-undo (current-buffer))
 489       (erase-buffer)
 490       (nnheader-insert-file-contents (or file (gnus-cache-file-name group ".overview")))
 491       (goto-char (point-min))
 492       (insert "\n")
 493       (goto-char (point-min)))
 494     (set-buffer nntp-server-buffer)
 495     (goto-char (point-min))
 496     (while cached
 497       (while (and (not (eobp))
 498                   (< (read (current-buffer)) (car cached)))
 499         (forward-line 1))
 500       (beginning-of-line)
 501       (save-excursion
 502         (set-buffer cache-buf)
 503         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 504                             nil t)
 505             (setq beg (progn (beginning-of-line) (point))
 506                   end (progn (end-of-line) (point)))
 507           (setq beg nil)))
 508       (when beg
 509         (insert-buffer-substring cache-buf beg end)
 510         (insert "\n"))
 511       (setq cached (cdr cached)))
 512     (kill-buffer cache-buf)))
 513
 514 (defun gnus-cache-braid-heads (group cached)
 515   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
 516     (save-excursion
 517       (set-buffer cache-buf)
 518       (buffer-disable-undo (current-buffer))
 519       (erase-buffer))
 520     (set-buffer nntp-server-buffer)
 521     (goto-char (point-min))
 522     (while cached
 523       (while (and (not (eobp))
 524                   (looking-at "2.. +\\([0-9]+\\) ")
 525                   (< (progn (goto-char (match-beginning 1))
 526                             (read (current-buffer)))
 527                      (car cached)))
 528         (search-forward "\n.\n" nil 'move))
 529       (beginning-of-line)
 530       (save-excursion
 531         (set-buffer cache-buf)
 532         (erase-buffer)
 533         (nnheader-insert-file-contents (gnus-cache-file-name group (car cached)))
 534         (goto-char (point-min))
 535         (insert "220 ")
 536         (princ (car cached) (current-buffer))
 537         (insert " Article retrieved.\n")
 538         (search-forward "\n\n" nil 'move)
 539         (delete-region (point) (point-max))
 540         (forward-char -1)
 541         (insert "."))
 542       (insert-buffer-substring cache-buf)
 543       (setq cached (cdr cached)))
 544     (kill-buffer cache-buf)))
 545
 546 ;;;###autoload
 547 (defun gnus-jog-cache ()
 548   "Go through all groups and put the articles into the cache.
 549
 550 Usage:
 551 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 552   (interactive)
 553   (let ((gnus-mark-article-hook nil)
 554         (gnus-expert-user t)
 555         (nnmail-spool-file nil)
 556         (gnus-use-dribble-file nil)
 557         (gnus-novice-user nil)
 558         (gnus-large-newsgroup nil))
 559     ;; Start Gnus.
 560     (gnus)
 561     ;; Go through all groups...
 562     (gnus-group-mark-buffer)
 563     (gnus-group-iterate nil
 564       (lambda (group)
 565         (let (gnus-auto-select-next)
 566           (gnus-summary-read-group group nil t)
 567           ;; ... and enter the articles into the cache.
 568           (when (eq major-mode 'gnus-summary-mode)
 569             (gnus-uu-mark-buffer)
 570             (gnus-cache-enter-article)
 571             (kill-buffer (current-buffer))))))))
 572
 573 (defun gnus-cache-read-active (&optional force)
 574   "Read the cache active file."
 575   (gnus-make-directory gnus-cache-directory)
 576   (if (or (not (file-exists-p gnus-cache-active-file))
 577           (not (zerop (nth 7 (file-attributes gnus-cache-active-file))))
 578           force)
 579       ;; There is no active file, so we generate one.
 580       (gnus-cache-generate-active)
 581     ;; We simply read the active file.
 582     (save-excursion
 583       (gnus-set-work-buffer)
 584       (nnheader-insert-file-contents gnus-cache-active-file)
 585       (gnus-active-to-gnus-format
 586        nil (setq gnus-cache-active-hashtb
 587                  (gnus-make-hashtable
 588                   (count-lines (point-min) (point-max)))))
 589       (setq gnus-cache-active-altered nil))))
 590
 591 (defun gnus-cache-write-active (&optional force)
 592   "Write the active hashtb to the active file."
 593   (when (or force
 594             (and gnus-cache-active-hashtb
 595                  gnus-cache-active-altered))
 596     (nnheader-temp-write gnus-cache-active-file
 597       (mapatoms
 598        (lambda (sym)
 599          (when (and sym (boundp sym))
 600            (insert (format "%s %d %d y\n"
 601                            (symbol-name sym) (cdr (symbol-value sym))
 602                            (car (symbol-value sym))))))
 603        gnus-cache-active-hashtb))
 604     ;; Mark the active hashtb as unaltered.
 605     (setq gnus-cache-active-altered nil)))
 606
 607 (defun gnus-cache-update-active (group number &optional low)
 608   "Update the upper bound of the active info of GROUP to NUMBER.
 609 If LOW, update the lower bound instead."
 610   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 611     (if (null active)
 612         ;; We just create a new active entry for this group.
 613         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 614       ;; Update the lower or upper bound.
 615       (if low
 616           (setcar active number)
 617         (setcdr active number)))
 618     ;; Mark the active hashtb as altered.
 619     (setq gnus-cache-active-altered t)))
 620
 621 ;;;###autoload
 622 (defun gnus-cache-generate-active (&optional directory)
 623   "Generate the cache active file."
 624   (interactive)
 625   (let* ((top (null directory))
 626          (directory (expand-file-name (or directory gnus-cache-directory)))
 627          (files (directory-files directory 'full))
 628          (group
 629           (if top
 630               ""
 631             (string-match
 632              (concat "^" (regexp-quote
 633                           (file-name-as-directory
 634                            (expand-file-name gnus-cache-directory))))
 635              (directory-file-name directory))
 636             (nnheader-replace-chars-in-string
 637              (substring (directory-file-name directory) (match-end 0))
 638              ?/ ?.)))
 639          nums alphs)
 640     (when top
 641       (gnus-message 5 "Generating the cache active file...")
 642       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 643     ;; Separate articles from all other files and directories.
 644     (while files
 645       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 646           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 647         (push (pop files) alphs)))
 648     ;; If we have nums, then this is probably a valid group.
 649     (when (setq nums (sort nums '<))
 650       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 651                     gnus-cache-active-hashtb))
 652     ;; Go through all the other files.
 653     (while alphs
 654       (when (and (file-directory-p (car alphs))
 655                  (not (string-match "^\\.\\.?$"
 656                                     (file-name-nondirectory (car alphs)))))
 657         ;; We descend directories.
 658         (gnus-cache-generate-active (car alphs)))
 659       (setq alphs (cdr alphs)))
 660     ;; Write the new active file.
 661     (when top
 662       (gnus-cache-write-active t)
 663       (gnus-message 5 "Generating the cache active file...done"))))
 664
 665 ;;;###autoload
 666 (defun gnus-cache-generate-nov-databases (dir)
 667   "Generate NOV files recursively starting in DIR."
 668   (interactive (list gnus-cache-directory))
 669   (gnus-cache-close)
 670   (let ((nnml-generate-active-function 'identity))
 671     (nnml-generate-nov-databases-1 dir)))
 672
 673 (defun gnus-cache-move-cache (dir)
 674   "Move the cache tree to somewhere else."
 675   (interactive "FMove the cache tree to: ")
 676   (rename-file gnus-cache-directory dir))
 677
 678 (provide 'gnus-cache)
 679
 680 ;;; gnus-cache.el ends here