git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-diary.el

   1 ;;; gnus-diary.el --- Wrapper around the NNDiary Gnus backend
   2
   3 ;; Copyright (C) 1999-2001 Didier Verna.
   4
   5 ;; Author:        Didier Verna <didier@xemacs.org>
   6 ;; Maintainer:    Didier Verna <didier@xemacs.org>
   7 ;; Created:       Tue Jul 20 10:42:55 1999 under XEmacs 21.2 (beta 18)
   8 ;; Last Revision: Wed Sep 12 12:31:09 2001
   9 ;; Keywords:      calendar mail news
  10
  11 ;; This file is part of NNDiary.
  12
  13 ;; NNDiary is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; NNDiary is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program; if not, write to the Free Software
  25 ;; Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  26
  27
  28 ;;; Commentary:
  29
  30 ;; Contents management by FCM version 0.1.
  31
  32 ;; Description:
  33 ;; ===========
  34
  35 ;; Gnus-Diary is a wrapper around the NNDiary Gnus backend.  It is here to
  36 ;; make your nndiary-user life easier in different ways.  So, you don't have
  37 ;; to use it if you don't want to.  But, really, you should.
  38
  39 ;; Gnus-Diary offers the following features on top of the NNDiary backend:
  40
  41 ;;  - A nice summary line format:
  42 ;;    Displaying diary messages in standard summary line format (usually
  43 ;;    something like "<From Joe>: <Subject>") is pretty useless.  Most of the
  44 ;;    time, you're the one who wrote the message, and you mostly want to see
  45 ;;    the event's date.  Gnus-Diary offers you a nice summary line format
  46 ;;    which will do this.  By default, a summary line will appear like this:
  47 ;;
  48 ;;     <Event Date>: <Subject> <Remaining time>
  49 ;;
  50 ;;   for example, here's how Joe's birthday is displayed in my
  51 ;;   "nndiary:birhdays" summary buffer (the message is expirable, but will
  52 ;;   never be deleted, as it specifies a regular event):
  53 ;;
  54 ;;   E  Sat, Sep 22 01, 12:00: Joe's birthday (in 6 months, 1 week)
  55
  56 ;;  - More article sorting functions:
  57 ;;    Gnus-Diary adds a new sorting function called
  58 ;;    `gnus-summary-sort-by-schedule'.  This function lets you organize your
  59 ;;    diary summary buffers from the closest event to the farthest one.
  60
  61 ;;  - Automatic generation of diary group parameters:
  62 ;;    When you create a new diary group, or visit one, Gnus-Diary checks your
  63 ;;    group parameters, and if needed, sets the summary line format to the
  64 ;;    diary-specific value, adds the diary-specific sorting functions, and
  65 ;;    also adds the different `X-Diary-*' headers to the group's
  66 ;;    posting-style.  It is then easier to send a diary message, because if
  67 ;;    you use `C-u a' or `C-u m' on a diary group to prepare a message, these
  68 ;;    headers will be inserted automatically (but not filled with proper
  69 ;;    values yet).
  70
  71 ;;  - An interactive mail-to-diary convertion function:
  72 ;;    The function `gnus-diary-check-message' ensures that the current message
  73 ;;    contains all the required diary headers, and prompts you for values /
  74 ;;    correction if needed.  This function is hooked in the nndiary backend so
  75 ;;    that moving an article to an nndiary group will trigger it
  76 ;;    automatically.  It is also bound to `C-c D c' in message-mode and
  77 ;;    article-edit-mode in order to ease the process of converting a usual
  78 ;;    mail to a diary one.  This function takes a prefix argument which will
  79 ;;    force prompting of all diary headers, regardless of their
  80 ;;    presence/validity.  That way, you can very easily reschedule a diary
  81 ;;    message for instance.
  82
  83
  84 ;; Usage:
  85 ;; =====
  86
  87 ;; 0/ Don't use any `gnus-user-format-function-[d|D]'.  Gnus-Diary provides
  88 ;;    both of these (sorry if you used them before).
  89 ;; 1/ Add '(require 'gnus-diary) to your gnusrc file.
  90 ;; 2/ Customize your gnus-diary options to suit your needs.
  91
  92
  93
  94 ;; Bugs / Todo:
  95 ;; ===========
  96
  97
  98 ;;; Code:
  99
 100 (require 'nndiary)
 101 (require 'message)
 102 (require 'gnus-art)
 103
 104 (defgroup gnus-diary nil
 105   "Utilities on top of the nndiary backend for Gnus.")
 106
 107 (defcustom gnus-diary-summary-line-format "%U%R%z %uD: %(%s%) (%ud)\n"
 108   "*Summary line format for nndiary groups."
 109   :type 'string
 110   :group 'gnus-diary
 111   :group 'gnus-summary-format)
 112
 113 (defcustom gnus-diary-time-format "%a, %b %e %y, %H:%M"
 114   "*Time format to display appointements in nndiary summary buffers.
 115 Please refer to `format-time-string' for information on possible values."
 116   :type 'string
 117   :group 'gnus-diary)
 118
 119 (defcustom gnus-diary-delay-format-function 'gnus-diary-delay-format-english
 120   "*Function called to format a diary delay string.
 121 It is passed two arguments.  The first one is non nil if the delay is in
 122 the past.  The second one is of the form ((NUM . UNIT) ...) where NUM is
 123 an integer and UNIT is one of 'year 'month 'week 'day 'hour or 'minute.
 124 It should return strings like \"In 2 months, 3 weeks\", \"3 hours,
 125 1 minute ago\" and so on.
 126
 127 There are currently two built-in format functions:
 128 `gnus-diary-delay-format-english' (the default)
 129 `gnus-diary-delay-format-french'"
 130   :type '(choice (const  :tag "english" gnus-diary-delay-format-english)
 131                  (const  :tag "french"  gnus-diary-delay-format-french)
 132                  (symbol :tag "other"))
 133   :group 'gnus-diary)
 134
 135 (defconst gnus-diary-version nndiary-version
 136   "Current Diary backend version.")
 137
 138
 139 ;; Summary line format ======================================================
 140
 141 (defun gnus-diary-delay-format-french (past delay)
 142   (if (null delay)
 143       "maintenant!"
 144     ;; Keep only a precision of two degrees
 145     (and (> (length delay) 1) (setf (nthcdr 2 delay) nil))
 146     (concat (if past "il y a " "dans ")
 147             (let ((str "")
 148                   del)
 149               (while (setq del (pop delay))
 150                 (setq str (concat str
 151                                   (int-to-string (car del)) " "
 152                                   (cond ((eq (cdr del) 'year)
 153                                          "an")
 154                                         ((eq (cdr del) 'month)
 155                                          "mois")
 156                                         ((eq (cdr del) 'week)
 157                                          "semaine")
 158                                         ((eq (cdr del) 'day)
 159                                          "jour")
 160                                         ((eq (cdr del) 'hour)
 161                                          "heure")
 162                                         ((eq (cdr del) 'minute)
 163                                          "minute"))
 164                                   (unless (or (eq (cdr del) 'month)
 165                                               (= (car del) 1))
 166                                     "s")
 167                                   (if delay ", "))))
 168               str))))
 169
 170
 171 (defun gnus-diary-delay-format-english (past delay)
 172   (if (null delay)
 173       "now!"
 174     ;; Keep only a precision of two degrees
 175     (and (> (length delay) 1) (setf (nthcdr 2 delay) nil))
 176     (concat (unless past "in ")
 177             (let ((str "")
 178                   del)
 179               (while (setq del (pop delay))
 180                 (setq str (concat str
 181                                   (int-to-string (car del)) " "
 182                                   (symbol-name (cdr del))
 183                                   (and (> (car del) 1) "s")
 184                                   (if delay ", "))))
 185               str)
 186             (and past " ago"))))
 187
 188
 189 (defun gnus-diary-header-schedule (headers)
 190   ;; Same as `nndiary-schedule', but given a set of headers HEADERS
 191   (mapcar
 192    (lambda (elt)
 193      (let ((head (cdr (assoc (intern (format "X-Diary-%s" (car elt)))
 194                              headers))))
 195        (when head
 196          (nndiary-parse-schedule-value head (cadr elt) (caddr elt)))))
 197    nndiary-headers))
 198
 199 ;; #### NOTE: Gnus sometimes gives me a HEADER not corresponding to any
 200 ;; message, with all fields set to nil here. I don't know what it is for, and
 201 ;; I just ignore it.
 202 (defun gnus-user-format-function-d (header)
 203   ;; Returns an aproximative delay string for the next occurence of this
 204   ;; message. The delay is given only in the first non zero unit.
 205   ;; Code partly stolen from article-make-date-line
 206   (let* ((extras (mail-header-extra header))
 207          (sched (gnus-diary-header-schedule extras))
 208          (occur (nndiary-next-occurence sched (current-time)))
 209          (now (current-time))
 210          (real-time (subtract-time occur now)))
 211     (if (null real-time)
 212         "?????"
 213       (let* ((sec (+ (* (float (car real-time)) 65536) (cadr real-time)))
 214              (past (< sec 0))
 215              delay)
 216         (and past (setq sec (- sec)))
 217         (unless (zerop sec)
 218           ;; This is a bit convoluted, but basically we go through the time
 219           ;; units for years, weeks, etc, and divide things to see whether
 220           ;; that results in positive answers.
 221           (let ((units `((year . ,(* 365.25 24 3600))
 222                          (month . ,(* 31 24 3600))
 223                          (week . ,(* 7 24 3600))
 224                          (day . ,(* 24 3600))
 225                          (hour . 3600)
 226                          (minute . 60)))
 227                 unit num)
 228             (while (setq unit (pop units))
 229               (unless (zerop (setq num (ffloor (/ sec (cdr unit)))))
 230                 (setq delay (append delay `((,(floor num) . ,(car unit))))))
 231               (setq sec (- sec (* num (cdr unit)))))))
 232         (funcall gnus-diary-delay-format-function past delay)))
 233     ))
 234
 235 ;; #### NOTE: Gnus sometimes gives me a HEADER not corresponding to any
 236 ;; message, with all fields set to nil here. I don't know what it is for, and
 237 ;; I just ignore it.
 238 (defun gnus-user-format-function-D (header)
 239   ;; Returns a formatted time string for the next occurence of this message.
 240   (let* ((extras (mail-header-extra header))
 241          (sched (gnus-diary-header-schedule extras))
 242          (occur (nndiary-next-occurence sched (current-time))))
 243     (format-time-string gnus-diary-time-format occur)))
 244
 245
 246 ;; Article sorting functions ================================================
 247
 248 (defun gnus-article-sort-by-schedule (h1 h2)
 249   (let* ((now (current-time))
 250          (e1 (mail-header-extra h1))
 251          (e2 (mail-header-extra h2))
 252          (s1 (gnus-diary-header-schedule e1))
 253          (s2 (gnus-diary-header-schedule e2))
 254          (o1 (nndiary-next-occurence s1 now))
 255          (o2 (nndiary-next-occurence s2 now)))
 256     (if (and (= (car o1) (car o2)) (= (cadr o1) (cadr o2)))
 257         (< (mail-header-number h1) (mail-header-number h2))
 258       (time-less-p o1 o2))))
 259
 260
 261 (defun gnus-thread-sort-by-schedule (h1 h2)
 262   (gnus-article-sort-by-schedule (gnus-thread-header h1)
 263                                  (gnus-thread-header h2)))
 264
 265 (defun gnus-summary-sort-by-schedule (&optional reverse)
 266   "Sort nndiary summary buffers by schedule of appointements.
 267 Optional prefix (or REVERSE argument) means sort in reverse order."
 268   (interactive "P")
 269   (gnus-summary-sort 'schedule reverse))
 270
 271 (defvar gnus-summary-misc-menu)
 272
 273 (add-hook 'gnus-summary-menu-hook
 274           (lambda ()
 275             (easy-menu-add-item gnus-summary-misc-menu
 276                                 '("Sort")
 277                                 ["Sort by schedule"
 278                                  gnus-summary-sort-by-schedule
 279                                  (eq (car (gnus-find-method-for-group
 280                                            gnus-newsgroup-name))
 281                                      'nndiary)]
 282                                 "Sort by number")))
 283
 284
 285
 286 ;; Group parameters autosetting =============================================
 287
 288 (defun gnus-diary-update-group-parameters (group)
 289   ;; Ensure that nndiary groups have convenient group parameters:
 290   ;; - a posting style containing X-Diary headers
 291   ;; - a nice summary line format
 292   ;; - NNDiary specific sorting by schedule functions
 293   ;; In general, try not to mess with what the user might have modified.
 294   (let ((posting-style (gnus-group-get-parameter group 'posting-style t)))
 295     ;; Posting style:
 296     (mapcar (lambda (elt)
 297               (let ((header (format "X-Diary-%s" (car elt))))
 298                 (unless (assoc header posting-style)
 299                   (setq posting-style (append posting-style
 300                                               `((,header "*")))))
 301                 ))
 302             nndiary-headers)
 303     (gnus-group-set-parameter group 'posting-style posting-style)
 304     ;; Summary line format:
 305     (unless (gnus-group-get-parameter group 'gnus-summary-line-format t)
 306       (gnus-group-set-parameter group 'gnus-summary-line-format
 307                                 `(,gnus-diary-summary-line-format)))
 308     ;; Sorting by schedule:
 309     (unless (gnus-group-get-parameter group 'gnus-article-sort-functions)
 310       (gnus-group-set-parameter group 'gnus-article-sort-functions
 311                                 '((append gnus-article-sort-functions
 312                                           (list
 313                                            'gnus-article-sort-by-schedule)))))
 314     (unless (gnus-group-get-parameter group 'gnus-thread-sort-functions)
 315       (gnus-group-set-parameter group 'gnus-thread-sort-functions
 316                                 '((append gnus-thread-sort-functions
 317                                           (list
 318                                            'gnus-thread-sort-by-schedule)))))
 319     ))
 320
 321 ;; Called when a group is subscribed. This is needed because groups created
 322 ;; because of mail splitting are *not* created with the backend function.
 323 ;; Thus, `nndiary-request-create-group-hooks' is inoperative.
 324 (defun gnus-diary-maybe-update-group-parameters (group)
 325   (when (eq (car (gnus-find-method-for-group group)) 'nndiary)
 326     (gnus-diary-update-group-parameters group)))
 327
 328 (add-hook 'nndiary-request-create-group-hooks
 329           'gnus-diary-update-group-parameters)
 330 ;; Now that we have `gnus-subscribe-newsgroup-hooks', this is not needed
 331 ;; anymore. Maybe I should remove this completely.
 332 (add-hook 'nndiary-request-update-info-hooks
 333           'gnus-diary-update-group-parameters)
 334 (add-hook 'gnus-subscribe-newsgroup-hooks
 335           'gnus-diary-maybe-update-group-parameters)
 336
 337
 338 ;; Diary Message Checking ===================================================
 339
 340 (eval-and-compile
 341   (if (fboundp 'kill-entire-line)
 342       (defalias 'gnus-diary-kill-entire-line 'kill-entire-line)
 343     (defun gnus-diary-kill-entire-line ()
 344       (beginning-of-line)
 345       (let ((kill-whole-line t))
 346         (kill-line)))))
 347
 348 (defvar gnus-diary-header-value-history nil
 349   ;; History variable for header value prompting
 350   )
 351
 352 (defun gnus-diary-narrow-to-headers ()
 353   "Narrow the current buffer to the header part.
 354 Point is left at the beginning of the region.
 355 The buffer is assumed to contain a message, but the format is unknown."
 356   (cond ((eq major-mode 'message-mode)
 357          (message-narrow-to-headers))
 358         (t
 359          (goto-char (point-min))
 360          (when (search-forward "\n\n" nil t)
 361            (narrow-to-region (point-min) (- (point) 1))
 362            (goto-char (point-min))))
 363         ))
 364
 365 (defun gnus-diary-add-header (str)
 366   "Add a header to the current buffer.
 367 The buffer is assumed to contain a message, but the format is unknown."
 368   (cond ((eq major-mode 'message-mode)
 369          (message-add-header str))
 370         (t
 371          (save-restriction
 372            (gnus-diary-narrow-to-headers)
 373            (goto-char (point-max))
 374            (if (string-match "\n$" str)
 375                (insert str)
 376              (insert str ?\n))))
 377         ))
 378
 379 (defun gnus-diary-check-message (arg)
 380   "Ensure that the current message is a valid for NNDiary.
 381 This function checks that all NNDiary required headers are present and
 382 valid, and prompts for values / correction otherwise.
 383
 384 If ARG (or prefix) is non-nil, force prompting for all fields."
 385   (interactive "P")
 386   (save-excursion
 387     (mapcar
 388      (lambda (head)
 389        (let ((header (concat "X-Diary-" (car head)))
 390              (ask arg)
 391              value invalid)
 392          ;; First, try to find the header, and checks for validity:
 393          (save-restriction
 394            (gnus-diary-narrow-to-headers)
 395            (when (re-search-forward (concat "^" header ":") nil t)
 396              (unless (eq (char-after) ? )
 397                (insert " "))
 398              (setq value (buffer-substring (point) (gnus-point-at-eol)))
 399              (and (string-match "[ \t]*\\([^ \t]+\\)[ \t]*" value)
 400                   (setq value (match-string 1 value)))
 401              (condition-case ()
 402                  (nndiary-parse-schedule-value value
 403                                                (nth 1 head) (nth 2 head))
 404                (t
 405                 (setq invalid t)))
 406              ;; #### NOTE: this (along with the `gnus-diary-add-header'
 407              ;; function) could be rewritten in a better way, in particular
 408              ;; not to blindly remove an already present header and reinsert
 409              ;; it somewhere else afterwards.
 410              (when (or ask invalid)
 411                (gnus-diary-kill-entire-line))
 412              ))
 413          ;; Now, loop until a valid value is provided:
 414          (while (or ask (not value) invalid)
 415            (let ((prompt (concat (and invalid
 416                                       (prog1 "(current value invalid) "
 417                                         (beep)))
 418                                  header
 419                                  (and (not value) " (defaults to `*')")
 420                                  ": ")))
 421              (setq value
 422                    (if (listp (nth 1 head))
 423                        (completing-read prompt (cons '("*" nil) (nth 1 head))
 424                                         nil t value
 425                                         gnus-diary-header-value-history "*")
 426                      (read-string prompt value
 427                                   gnus-diary-header-value-history "*"))))
 428            (setq ask nil)
 429            (setq invalid nil)
 430            (condition-case ()
 431                (nndiary-parse-schedule-value value
 432                                              (nth 1 head) (nth 2 head))
 433              (t
 434               (setq invalid t))))
 435          (gnus-diary-add-header (concat header ": " value))
 436          ))
 437      nndiary-headers)
 438     ))
 439
 440 (add-hook 'nndiary-request-accept-article-hooks
 441           (lambda () (gnus-diary-check-message nil)))
 442
 443 (define-key message-mode-map "\C-cDc" 'gnus-diary-check-message)
 444 (define-key gnus-article-edit-mode-map "\C-cDc" 'gnus-diary-check-message)
 445
 446
 447 ;; The end ==================================================================
 448
 449 (defun gnus-diary-version ()
 450   "Current Diary backend version."
 451   (interactive)
 452   (message "NNDiary version %s" nndiary-version))
 453
 454 (define-key message-mode-map "\C-cDv" 'gnus-diary-version)
 455 (define-key gnus-article-edit-mode-map "\C-cDv" 'gnus-diary-version)
 456
 457
 458 (provide 'gnus-diary)
 459
 460 ;;; gnus-diary.el ends here