git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   8 ;; Keywords: mail, news, MIME, offline
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'message)
  34 (require 'gnus-msg)
  35 (require 'nndraft)
  36 (require 'gnus-agent)
  37 (eval-when-compile (require 'cl))
  38
  39 ;;; Draft minor mode
  40
  41 (defvar gnus-draft-mode nil
  42   "Minor mode for providing a draft summary buffers.")
  43
  44 (defvar gnus-draft-mode-map nil)
  45
  46 (unless gnus-draft-mode-map
  47   (setq gnus-draft-mode-map (make-sparse-keymap))
  48
  49   (gnus-define-keys gnus-draft-mode-map
  50     "Dt" gnus-draft-toggle-sending
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (gnus-run-hooks 'gnus-draft-mode-hook))))
  80
  81 ;;; Commands
  82
  83 (defun gnus-draft-toggle-sending (article)
  84   "Toggle whether to send an article or not."
  85   (interactive (list (gnus-summary-article-number)))
  86   (if (gnus-draft-article-sendable-p article)
  87       (progn
  88         (push article gnus-newsgroup-unsendable)
  89         (gnus-summary-mark-article article gnus-unsendable-mark))
  90     (setq gnus-newsgroup-unsendable
  91           (delq article gnus-newsgroup-unsendable))
  92     (gnus-summary-mark-article article gnus-unread-mark))
  93   (gnus-summary-position-point))
  94
  95 (defun gnus-draft-edit-message ()
  96   "Enter a mail/post buffer to edit and send the draft."
  97   (interactive)
  98   (let ((article (gnus-summary-article-number))
  99         (group gnus-newsgroup-name))
 100     (gnus-summary-mark-as-read article gnus-canceled-mark)
 101     (gnus-draft-setup-for-editing article group)
 102     (set-buffer-modified-p t)
 103     (save-excursion
 104       (save-restriction
 105         (message-narrow-to-headers)
 106         (message-remove-header "date")
 107         (put-text-property (point-min) (point-max) 'message-field 'header)))
 108     (message-save-drafts)
 109     (let ((gnus-verbose-backends nil))
 110       (gnus-request-expire-articles (list article) group t))
 111     (push
 112      `((lambda ()
 113          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 114            (save-excursion
 115              (set-buffer ,gnus-summary-buffer)
 116              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 117      message-send-actions)))
 118
 119 (defun gnus-draft-send-message (&optional n)
 120   "Send the current draft."
 121   (interactive "P")
 122   (let* ((articles (gnus-summary-work-articles n))
 123          (total (length articles))
 124          article)
 125     (while (setq article (pop articles))
 126       (gnus-summary-remove-process-mark article)
 127       (unless (memq article gnus-newsgroup-unsendable)
 128         (let ((message-sending-message
 129                (format "Sending message %d of %d..."
 130                        (- total (length articles)) total)))
 131           (gnus-draft-send article gnus-newsgroup-name t))
 132         (gnus-summary-mark-article article gnus-canceled-mark)))))
 133
 134 (defun gnus-draft-send (article &optional group interactive)
 135   "Send message ARTICLE."
 136   (let ((message-syntax-checks (if interactive nil
 137                                  'dont-check-for-anything-just-trust-me))
 138         (message-inhibit-body-encoding (or (not group)
 139                                            (equal group "nndraft:queue")
 140                                            message-inhibit-body-encoding))
 141         (message-send-hook (and group (not (equal group "nndraft:queue"))
 142                                 message-send-hook))
 143         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 144                                  message-setup-hook))
 145         type method)
 146     (gnus-draft-setup-for-sending article (or group "nndraft:queue"))
 147     ;; We read the meta-information that says how and where
 148     ;; this message is to be sent.
 149     (save-restriction
 150       (message-narrow-to-head)
 151       (when (re-search-forward
 152              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 153              nil t)
 154         (setq type (ignore-errors (read (current-buffer)))
 155               method (ignore-errors (read (current-buffer))))
 156         (message-remove-header gnus-agent-meta-information-header)))
 157     ;; Let Agent restore any GCC lines and have message.el perform them.
 158     (gnus-agent-restore-gcc)
 159     ;; Then we send it.  If we have no meta-information, we just send
 160     ;; it and let Message figure out how.
 161     (when (let ((mail-header-separator ""))
 162             (cond ((eq type 'news)
 163                    (mime-edit-maybe-split-and-send
 164                     (function
 165                      (lambda ()
 166                        (interactive)
 167                        (funcall message-send-news-function method))))
 168                    (funcall message-send-news-function method))
 169                   ((eq type 'mail)
 170                    (mime-edit-maybe-split-and-send
 171                     (function
 172                      (lambda ()
 173                        (interactive)
 174                        (funcall message-send-mail-function))))
 175                    (funcall message-send-mail-function)
 176                    t)))
 177       (let ((gnus-verbose-backends nil))
 178         (gnus-request-expire-articles
 179          (list article) (or group "nndraft:queue") t)))))
 180
 181 (defun gnus-draft-send-all-messages ()
 182   "Send all the sendable drafts."
 183   (interactive)
 184   (gnus-uu-mark-buffer)
 185   (gnus-draft-send-message))
 186
 187 (defun gnus-group-send-drafts ()
 188   "Send all sendable articles from the queue group."
 189   (interactive)
 190   (gnus-activate-group "nndraft:queue")
 191   (save-excursion
 192     (let* ((articles (nndraft-articles))
 193            (unsendable (gnus-uncompress-range
 194                         (cdr (assq 'unsend
 195                                    (gnus-info-marks
 196                                     (gnus-get-info "nndraft:queue"))))))
 197            (total (length articles))
 198            article)
 199       (while (setq article (pop articles))
 200         (unless (memq article unsendable)
 201           (let ((message-sending-message
 202                  (format "Sending message %d of %d..."
 203                          (- total (length articles)) total)))
 204             (gnus-draft-send article)))))))
 205
 206 ;;;###autoload
 207 (defun gnus-draft-reminder ()
 208   "Reminder user if there are unsent drafts."
 209   (interactive)
 210   (if (gnus-alive-p)
 211       (let (active)
 212         (catch 'continue
 213           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 214             (setq active (gnus-activate-group group))
 215             (if (and active (>= (cdr active) (car active)))
 216                 (if (y-or-n-p "There are unsent drafts. Confirm to exit?")
 217                     (throw 'continue t)
 218                   (error "Stop!"))))))))
 219
 220 ;;; Utility functions
 221
 222 (defcustom gnus-draft-decoding-function
 223   #'mime-edit-decode-message-in-buffer
 224   "*Function called to decode the message from network representation."
 225   :group 'gnus-agent
 226   :type 'function)
 227
 228 ;;;!!!If this is byte-compiled, it fails miserably.
 229 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 230 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 231 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 232
 233 (defun gnus-draft-setup-for-editing (narticle group)
 234   (let (ga)
 235     (gnus-setup-message 'forward
 236       (let ((article narticle))
 237         (message-mail)
 238         (erase-buffer)
 239         (if (not (gnus-request-restore-buffer article group))
 240             (error "Couldn't restore the article")
 241           (funcall gnus-draft-decoding-function)
 242           ;; Insert the separator.
 243           (goto-char (point-min))
 244           (search-forward "\n\n")
 245           (forward-char -1)
 246           (insert mail-header-separator)
 247           (forward-line 1)
 248           (setq ga (message-fetch-field gnus-draft-meta-information-header))
 249           (message-set-auto-save-file-name))))
 250     (gnus-backlog-remove-article group narticle)
 251     (when (and ga
 252                (ignore-errors (setq ga (car (read-from-string ga)))))
 253       (setq gnus-newsgroup-name
 254             (if (equal (car ga) "") nil (car ga)))
 255       (setq message-post-method
 256             `(lambda (arg)
 257                (gnus-post-method arg ,(car ga))))
 258       (unless (equal (cadr ga) "")
 259         (message-add-action
 260          `(progn
 261             (gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 262             (gnus-request-set-mark ,(car ga) (list (list (list ,(cadr ga))
 263                                                          'add '(reply)))))
 264          'send)))))
 265
 266 (defvar gnus-draft-send-draft-buffer " *send draft*")
 267 (defun gnus-draft-setup-for-sending (narticle group)
 268   (let ((article narticle))
 269     (if (not (get-buffer gnus-draft-send-draft-buffer))
 270         (get-buffer-create gnus-draft-send-draft-buffer))
 271     (set-buffer gnus-draft-send-draft-buffer)
 272     (erase-buffer)
 273     (if (not (gnus-request-restore-buffer article group))
 274         (error "Couldn't restore the article"))))
 275
 276 (defun gnus-draft-article-sendable-p (article)
 277   "Say whether ARTICLE is sendable."
 278   (not (memq article gnus-newsgroup-unsendable)))
 279
 280 (provide 'gnus-draft)
 281
 282 ;;; gnus-draft.el ends here