git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   8 ;; Keywords: mail, news, MIME, offline
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'message)
  34 (require 'gnus-msg)
  35 (require 'nndraft)
  36 (require 'gnus-agent)
  37 (eval-when-compile (require 'cl))
  38
  39 ;;; Draft minor mode
  40
  41 (defvar gnus-draft-mode nil
  42   "Minor mode for providing a draft summary buffers.")
  43
  44 (defvar gnus-draft-mode-map nil)
  45
  46 (unless gnus-draft-mode-map
  47   (setq gnus-draft-mode-map (make-sparse-keymap))
  48
  49   (gnus-define-keys gnus-draft-mode-map
  50     "Dt" gnus-draft-toggle-sending
  51     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  52     "De" gnus-draft-edit-message
  53     "Ds" gnus-draft-send-message
  54     "DS" gnus-draft-send-all-messages))
  55
  56 (defun gnus-draft-make-menu-bar ()
  57   (unless (boundp 'gnus-draft-menu)
  58     (easy-menu-define
  59      gnus-draft-menu gnus-draft-mode-map ""
  60      '("Drafts"
  61        ["Toggle whether to send" gnus-draft-toggle-sending t]
  62        ["Edit" gnus-draft-edit-message t]
  63        ["Send selected message(s)" gnus-draft-send-message t]
  64        ["Send all messages" gnus-draft-send-all-messages t]
  65        ["Delete draft" gnus-summary-delete-article t]))))
  66
  67 (defun gnus-draft-mode (&optional arg)
  68   "Minor mode for providing a draft summary buffers.
  69
  70 \\{gnus-draft-mode-map}"
  71   (interactive "P")
  72   (when (eq major-mode 'gnus-summary-mode)
  73     (when (set (make-local-variable 'gnus-draft-mode)
  74                (if (null arg) (not gnus-draft-mode)
  75                  (> (prefix-numeric-value arg) 0)))
  76       ;; Set up the menu.
  77       (when (gnus-visual-p 'draft-menu 'menu)
  78         (gnus-draft-make-menu-bar))
  79       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  80       (gnus-run-hooks 'gnus-draft-mode-hook))))
  81
  82 ;;; Commands
  83
  84 (defun gnus-draft-toggle-sending (article)
  85   "Toggle whether to send an article or not."
  86   (interactive (list (gnus-summary-article-number)))
  87   (if (gnus-draft-article-sendable-p article)
  88       (progn
  89         (push article gnus-newsgroup-unsendable)
  90         (gnus-summary-mark-article article gnus-unsendable-mark))
  91     (setq gnus-newsgroup-unsendable
  92           (delq article gnus-newsgroup-unsendable))
  93     (gnus-summary-mark-article article gnus-unread-mark))
  94   (gnus-summary-position-point))
  95
  96 (defun gnus-draft-edit-message ()
  97   "Enter a mail/post buffer to edit and send the draft."
  98   (interactive)
  99   (let ((article (gnus-summary-article-number))
 100         (group gnus-newsgroup-name))
 101     (gnus-summary-mark-as-read article gnus-canceled-mark)
 102     (gnus-draft-setup article group t)
 103     (set-buffer-modified-p t)
 104     (save-excursion
 105       (save-restriction
 106         (message-narrow-to-headers)
 107         (message-remove-header "date")))
 108     (save-buffer)
 109     (let ((gnus-verbose-backends nil))
 110       (gnus-request-expire-articles (list article) group t))
 111     (push
 112      `((lambda ()
 113          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 114            (save-excursion
 115              (set-buffer ,gnus-summary-buffer)
 116              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 117      message-send-actions)))
 118
 119 (defun gnus-draft-send-message (&optional n)
 120   "Send the current draft."
 121   (interactive "P")
 122   (let* ((articles (gnus-summary-work-articles n))
 123          (total (length articles))
 124          article)
 125     (while (setq article (pop articles))
 126       (gnus-summary-remove-process-mark article)
 127       (unless (memq article gnus-newsgroup-unsendable)
 128         (let ((message-sending-message
 129                (format "Sending message %d of %d..."
 130                        (- total (length articles)) total)))
 131           (gnus-draft-send article gnus-newsgroup-name t))
 132         (gnus-summary-mark-article article gnus-canceled-mark)))))
 133
 134 (defun gnus-draft-send (article &optional group interactive)
 135   "Send message ARTICLE."
 136   (let* ((is-queue (or (not group)
 137                        (equal group "nndraft:queue")))
 138          (message-syntax-checks (if interactive message-syntax-checks
 139                                   'dont-check-for-anything-just-trust-me))
 140          (message-hidden-headers nil)
 141          (message-inhibit-body-encoding (or is-queue
 142                                             message-inhibit-body-encoding))
 143          (message-send-hook (and (not is-queue)
 144                                  message-send-hook))
 145          (message-setup-hook (and (not is-queue)
 146                                   message-setup-hook))
 147          (gnus-agent-queue-mail (and (not is-queue)
 148                                      gnus-agent-queue-mail))
 149          (rfc2047-encode-encoded-words nil)
 150          type method move-to)
 151     (gnus-draft-setup article (or group "nndraft:queue"))
 152     ;; We read the meta-information that says how and where
 153     ;; this message is to be sent.
 154     (save-restriction
 155       (message-narrow-to-head)
 156       (when (re-search-forward
 157              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 158                      ":") nil t)
 159         (skip-syntax-forward "-")
 160         (setq move-to (buffer-substring (point) (point-at-eol)))
 161         (message-remove-header gnus-agent-target-move-group-header))
 162       (goto-char (point-min))
 163       (when (re-search-forward
 164              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 165              nil t)
 166         (setq type (ignore-errors (read (current-buffer)))
 167               method (ignore-errors (read (current-buffer))))
 168         (message-remove-header gnus-agent-meta-information-header)))
 169     ;; Let Agent restore any GCC lines and have message.el perform them.
 170     (gnus-agent-restore-gcc)
 171     ;; Then we send it.  If we have no meta-information, we just send
 172     ;; it and let Message figure out how.
 173     (when (and (or (null method)
 174                    (gnus-server-opened method)
 175                    (gnus-open-server method))
 176                (if type
 177                    (let ((message-this-is-news (eq type 'news))
 178                          (message-this-is-mail (eq type 'mail))
 179                          (gnus-post-method method)
 180                          (message-post-method method))
 181                      (if move-to
 182                          (gnus-inews-do-gcc move-to)
 183                        (message-send-and-exit)))
 184                  (if move-to
 185                      (gnus-inews-do-gcc move-to)
 186                    (message-send-and-exit))))
 187       (let ((gnus-verbose-backends nil))
 188         (gnus-request-expire-articles
 189          (list article) (or group "nndraft:queue") t)))))
 190
 191 (defun gnus-draft-send-all-messages ()
 192   "Send all the sendable drafts."
 193   (interactive)
 194   (when (or
 195          gnus-expert-user
 196          (gnus-y-or-n-p
 197           "Send all drafts? "))
 198     (gnus-uu-mark-buffer)
 199     (gnus-draft-send-message)))
 200
 201 (defun gnus-group-send-queue ()
 202   "Send all sendable articles from the queue group."
 203   (interactive)
 204   (when (or gnus-plugged
 205             (not gnus-agent-prompt-send-queue)
 206             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 207     (gnus-activate-group "nndraft:queue")
 208     (save-excursion
 209       (let* ((articles (nndraft-articles))
 210              (unsendable (gnus-uncompress-range
 211                           (cdr (assq 'unsend
 212                                      (gnus-info-marks
 213                                       (gnus-get-info "nndraft:queue"))))))
 214              (gnus-posting-styles nil)
 215              (total (length articles))
 216              article)
 217         (while (setq article (pop articles))
 218           (unless (memq article unsendable)
 219             (let ((message-sending-message
 220                    (format "Sending message %d of %d..."
 221                            (- total (length articles)) total)))
 222               (gnus-draft-send article))))))))
 223
 224 ;;;###autoload
 225 (defun gnus-draft-reminder ()
 226   "Reminder user if there are unsent drafts."
 227   (interactive)
 228   (if (gnus-alive-p)
 229       (let (active)
 230         (catch 'continue
 231           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 232             (setq active (gnus-activate-group group))
 233             (if (and active (>= (cdr active) (car active)))
 234                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 235                     (throw 'continue t)
 236                   (error "Stop!"))))))))
 237
 238 ;;; Utility functions
 239
 240 (defcustom gnus-draft-decoding-function
 241   #'mime-edit-decode-message-in-buffer
 242   "*Function called to decode the message from network representation."
 243   :group 'gnus-agent
 244   :type 'function)
 245
 246 ;;;!!!If this is byte-compiled, it fails miserably.
 247 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 248 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 249 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 250
 251 (defun gnus-draft-setup (narticle group &optional restore)
 252   (let (ga)
 253     (gnus-setup-message 'forward
 254       (let ((article narticle))
 255         (message-mail)
 256         (erase-buffer)
 257         (if (not (gnus-request-restore-buffer article group))
 258             (error "Couldn't restore the article")
 259           (when (and restore
 260                      (equal group "nndraft:queue"))
 261             (funcall gnus-draft-decoding-function))
 262           ;; Insert the separator.
 263           (goto-char (point-min))
 264           (search-forward "\n\n")
 265           (forward-char -1)
 266           (insert mail-header-separator)
 267           (forward-line 1)
 268           (setq ga (message-fetch-field gnus-draft-meta-information-header))
 269           (message-set-auto-save-file-name))))
 270     (gnus-backlog-remove-article group narticle)
 271     (when (and ga
 272                (ignore-errors (setq ga (car (read-from-string ga)))))
 273       (setq gnus-newsgroup-name
 274             (if (equal (car ga) "") nil (car ga)))
 275       (gnus-configure-posting-styles)
 276       (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 277       (setq message-post-method
 278             `(lambda (arg)
 279                (gnus-post-method arg ,(car ga))))
 280       (unless (equal (cadr ga) "")
 281         (dolist (article (cdr ga))
 282           (message-add-action
 283            `(progn
 284               (gnus-add-mark ,(car ga) 'replied ,article)
 285               (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 286                                                            'add '(reply)))))
 287            'send))))))
 288
 289 (defun gnus-draft-article-sendable-p (article)
 290   "Say whether ARTICLE is sendable."
 291   (not (memq article gnus-newsgroup-unsendable)))
 292
 293 (provide 'gnus-draft)
 294
 295 ;;; gnus-draft.el ends here