git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Keywords: mail, news, MIME, offline
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                   (if (null arg) (not gnus-draft-mode)
  72                     (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (gnus-run-hooks 'gnus-draft-mode-hook))))
  78
  79 ;;; Commands
  80
  81 (defun gnus-draft-toggle-sending (article)
  82   "Toggle whether to send an article or not."
  83   (interactive (list (gnus-summary-article-number)))
  84   (if (gnus-draft-article-sendable-p article)
  85       (progn
  86         (push article gnus-newsgroup-unsendable)
  87         (gnus-summary-mark-article article gnus-unsendable-mark))
  88     (setq gnus-newsgroup-unsendable
  89           (delq article gnus-newsgroup-unsendable))
  90     (gnus-summary-mark-article article gnus-unread-mark))
  91   (gnus-summary-position-point))
  92
  93 (defun gnus-draft-edit-message ()
  94   "Enter a mail/post buffer to edit and send the draft."
  95   (interactive)
  96   (let ((article (gnus-summary-article-number)))
  97     (gnus-summary-mark-as-read article gnus-canceled-mark)
  98     (gnus-draft-setup article gnus-newsgroup-name)
  99     (set-buffer-modified-p t)
 100     (save-buffer)
 101     (push
 102      `((lambda ()
 103          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 104            (save-excursion
 105              (set-buffer ,gnus-summary-buffer)
 106              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 107      message-send-actions)))
 108
 109 (defun gnus-draft-send-message (&optional n)
 110   "Send the current draft."
 111   (interactive "P")
 112   (let ((articles (gnus-summary-work-articles n))
 113         article)
 114     (while (setq article (pop articles))
 115       (gnus-summary-remove-process-mark article)
 116       (unless (memq article gnus-newsgroup-unsendable)
 117         (gnus-draft-send article gnus-newsgroup-name)
 118         (gnus-summary-mark-article article gnus-canceled-mark)))))
 119
 120 (defun gnus-draft-send (article &optional group)
 121   "Send message ARTICLE."
 122   (gnus-draft-setup article (or group "nndraft:queue"))
 123   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 124         message-send-hook type method)
 125     ;; We read the meta-information that says how and where
 126     ;; this message is to be sent.
 127     (save-restriction
 128       (message-narrow-to-head)
 129       (when (re-search-forward
 130              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 131              nil t)
 132         (setq type (ignore-errors (read (current-buffer)))
 133               method (ignore-errors (read (current-buffer))))
 134         (message-remove-header gnus-agent-meta-information-header)))
 135     ;; Then we send it.  If we have no meta-information, we just send
 136     ;; it and let Message figure out how.
 137     (when (if type
 138               (let ((message-this-is-news (eq type 'news))
 139                     (message-this-is-mail (eq type 'mail))
 140                     (gnus-post-method method)
 141                     (message-post-method method))
 142                 (message-send-and-exit))
 143             (message-send-and-exit))
 144       (let ((gnus-verbose-backends nil))
 145         (gnus-request-expire-articles
 146          (list article) (or group "nndraft:queue") t)))))
 147
 148 (defun gnus-draft-send-all-messages ()
 149   "Send all the sendable drafts."
 150   (interactive)
 151   (gnus-uu-mark-buffer)
 152   (gnus-draft-send-message))
 153
 154 (defun gnus-group-send-drafts ()
 155   "Send all sendable articles from the queue group."
 156   (interactive)
 157   (gnus-activate-group "nndraft:queue")
 158   (save-excursion
 159     (let ((articles (nndraft-articles))
 160           (unsendable (gnus-uncompress-range
 161                        (cdr (assq 'unsend
 162                                   (gnus-info-marks
 163                                    (gnus-get-info "nndraft:queue"))))))
 164           article)
 165       (while (setq article (pop articles))
 166         (unless (memq article unsendable)
 167           (gnus-draft-send article))))))
 168
 169 ;;; Utility functions
 170
 171 (defcustom gnus-draft-decoding-function
 172   (function
 173    (lambda ()
 174      (mime-edit-decode-buffer nil)
 175      (eword-decode-header)
 176      ))
 177   "*Function called to decode the message from network representation."
 178   :group 'gnus-agent
 179   :type 'function)
 180
 181 ;;;!!!If this is byte-compiled, it fails miserably.
 182 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 183 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 184 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 185
 186 (progn
 187 (defun gnus-draft-setup (narticle group)
 188   (gnus-setup-message 'forward
 189     (let ((article narticle))
 190       (message-mail)
 191       (erase-buffer)
 192       (if (not (gnus-request-restore-buffer article group))
 193           (error "Couldn't restore the article")
 194         ;; Insert the separator.
 195         (funcall gnus-draft-decoding-function)
 196         (goto-char (point-min))
 197         (search-forward "\n\n")
 198         (forward-char -1)
 199         (insert mail-header-separator)
 200         (forward-line 1)
 201         (message-set-auto-save-file-name))))))
 202
 203 (defun gnus-draft-article-sendable-p (article)
 204   "Say whether ARTICLE is sendable."
 205   (not (memq article gnus-newsgroup-unsendable)))
 206
 207 (provide 'gnus-draft)
 208
 209 ;;; gnus-draft.el ends here