git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Keywords: mail, news, MIME, offline
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                   (if (null arg) (not gnus-draft-mode)
  72                     (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (gnus-run-hooks 'gnus-draft-mode-hook))))
  78
  79 ;;; Commands
  80
  81 (defun gnus-draft-toggle-sending (article)
  82   "Toggle whether to send an article or not."
  83   (interactive (list (gnus-summary-article-number)))
  84   (if (gnus-draft-article-sendable-p article)
  85       (progn
  86         (push article gnus-newsgroup-unsendable)
  87         (gnus-summary-mark-article article gnus-unsendable-mark))
  88     (setq gnus-newsgroup-unsendable
  89           (delq article gnus-newsgroup-unsendable))
  90     (gnus-summary-mark-article article gnus-unread-mark))
  91   (gnus-summary-position-point))
  92
  93 (defun gnus-draft-edit-message ()
  94   "Enter a mail/post buffer to edit and send the draft."
  95   (interactive)
  96   (let ((article (gnus-summary-article-number)))
  97     (gnus-summary-mark-as-read article gnus-canceled-mark)
  98     (gnus-draft-setup article gnus-newsgroup-name)
  99     (push
 100      `((lambda ()
 101          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 102            (save-excursion
 103              (set-buffer ,gnus-summary-buffer)
 104              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 105      message-send-actions)))
 106
 107 (defun gnus-draft-send-message (&optional n)
 108   "Send the current draft."
 109   (interactive "P")
 110   (let ((articles (gnus-summary-work-articles n))
 111         article)
 112     (while (setq article (pop articles))
 113       (gnus-summary-remove-process-mark article)
 114       (unless (memq article gnus-newsgroup-unsendable)
 115         (gnus-draft-send article gnus-newsgroup-name)
 116         (gnus-summary-mark-article article gnus-canceled-mark)))))
 117
 118 (defun gnus-draft-send (article &optional group)
 119   "Send message ARTICLE."
 120   (gnus-draft-setup article (or group "nndraft:queue"))
 121   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 122         message-send-hook type method)
 123     ;; We read the meta-information that says how and where
 124     ;; this message is to be sent.
 125     (save-restriction
 126       (message-narrow-to-head)
 127       (when (re-search-forward
 128              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 129              nil t)
 130         (setq type (ignore-errors (read (current-buffer)))
 131               method (ignore-errors (read (current-buffer))))
 132         (message-remove-header gnus-agent-meta-information-header)))
 133     ;; Then we send it.  If we have no meta-information, we just send
 134     ;; it and let Message figure out how.
 135     (if type
 136         (let ((message-this-is-news (eq type 'news))
 137               (message-this-is-mail (eq type 'mail))
 138               (gnus-post-method method)
 139               (message-post-method method))
 140           (message-send-and-exit))
 141       (message-send-and-exit))))
 142
 143 (defun gnus-draft-send-all-messages ()
 144   "Send all the sendable drafts."
 145   (interactive)
 146   (gnus-uu-mark-buffer)
 147   (gnus-draft-send-message))
 148
 149 (defun gnus-group-send-drafts ()
 150   "Send all sendable articles from the queue group."
 151   (interactive)
 152   (gnus-activate-group "nndraft:queue")
 153   (save-excursion
 154     (let ((articles (nndraft-articles))
 155           (unsendable (gnus-uncompress-range
 156                        (cdr (assq 'unsend
 157                                   (gnus-info-marks
 158                                    (gnus-get-info "nndraft:queue"))))))
 159           article)
 160       (while (setq article (pop articles))
 161         (unless (memq article unsendable)
 162           (gnus-draft-send article))))))
 163
 164 ;;; Utility functions
 165
 166 (defcustom gnus-draft-decoding-function
 167   (function
 168    (lambda ()
 169      (mime-edit-decode-buffer nil)
 170      (eword-decode-header)
 171      ))
 172   "*Function called to decode the message from network representation."
 173   :group 'gnus-agent
 174   :type 'function)
 175
 176 ;;;!!!If this is byte-compiled, it fails miserably.
 177 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 178 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 179 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 180
 181 (progn
 182 (defun gnus-draft-setup (narticle group)
 183   (gnus-setup-message 'forward
 184     (let ((article narticle))
 185       (message-mail)
 186       (erase-buffer)
 187       (if (not (gnus-request-restore-buffer article group))
 188           (error "Couldn't restore the article")
 189         ;; Insert the separator.
 190         (funcall gnus-draft-decoding-function)
 191         (goto-char (point-min))
 192         (search-forward "\n\n")
 193         (forward-char -1)
 194         (insert mail-header-separator)
 195         (forward-line 1)
 196         (message-set-auto-save-file-name))))))
 197
 198 (defun gnus-draft-article-sendable-p (article)
 199   "Say whether ARTICLE is sendable."
 200   (not (memq article gnus-newsgroup-unsendable)))
 201
 202 (provide 'gnus-draft)
 203
 204 ;;; gnus-draft.el ends here