git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-sum)
  30 (require 'message)
  31 (require 'gnus-msg)
  32 (require 'nndraft)
  33 (eval-when-compile (require 'cl))
  34
  35 ;;; Draft minor mode
  36
  37 (defvar gnus-draft-mode nil
  38   "Minor mode for providing a draft summary buffers.")
  39
  40 (defvar gnus-draft-mode-map nil)
  41
  42 (unless gnus-draft-mode-map
  43   (setq gnus-draft-mode-map (make-sparse-keymap))
  44
  45   (gnus-define-keys gnus-draft-mode-map
  46     "Dt" gnus-draft-toggle-sending
  47     "De" gnus-draft-edit-message
  48     "Ds" gnus-draft-send-message
  49     "DS" gnus-draft-send-all-messages))
  50
  51 (defun gnus-draft-make-menu-bar ()
  52   (unless (boundp 'gnus-draft-menu)
  53     (easy-menu-define
  54      gnus-draft-menu gnus-draft-mode-map ""
  55      '("Drafts"
  56        ["Toggle whether to send" gnus-draft-toggle-sending t]))))
  57
  58 (defun gnus-draft-mode (&optional arg)
  59   "Minor mode for providing a draft summary buffers.
  60
  61 \\{gnus-draft-mode-map}"
  62   (interactive "P")
  63   (when (eq major-mode 'gnus-summary-mode)
  64     (when (set (make-local-variable 'gnus-draft-mode)
  65                   (if (null arg) (not gnus-draft-mode)
  66                     (> (prefix-numeric-value arg) 0)))
  67       ;; Set up the menu.
  68       (when (gnus-visual-p 'draft-menu 'menu)
  69         (gnus-draft-make-menu-bar))
  70       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  71       (run-hooks 'gnus-draft-mode-hook))))
  72
  73 ;;; Commands
  74
  75 (defun gnus-draft-toggle-sending (article)
  76   "Toggle whether to send an article or not."
  77   (interactive (list (gnus-summary-article-number)))
  78   (if (gnus-draft-article-sendable-p article)
  79       (progn
  80         (push article gnus-newsgroup-unsendable)
  81         (gnus-summary-mark-article article gnus-unsendable-mark))
  82     (setq gnus-newsgroup-unsendable
  83           (delq article gnus-newsgroup-unsendable))
  84     (gnus-summary-mark-article article gnus-unread-mark))
  85   (gnus-summary-position-point))
  86
  87 (defun gnus-draft-edit-message ()
  88   "Enter a mail/post buffer to edit and send the draft."
  89   (interactive)
  90   (let ((article (gnus-summary-article-number)))
  91     (gnus-summary-mark-as-read article gnus-canceled-mark)
  92     (gnus-draft-setup article gnus-newsgroup-name)
  93     (push
  94      `((lambda ()
  95          (when (buffer-name (get-buffer ,gnus-summary-buffer))
  96            (save-excursion
  97              (set-buffer (get-buffer ,gnus-summary-buffer))
  98              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
  99      message-send-actions)))
 100
 101 (defun gnus-draft-send-message (&optional n)
 102   "Send the current draft."
 103   (interactive "P")
 104   (let ((articles (gnus-summary-work-articles n))
 105         article)
 106     (while (setq article (pop articles))
 107       (gnus-summary-remove-process-mark article)
 108       (unless (memq article gnus-newsgroup-unsendable)
 109         (gnus-draft-send article gnus-newsgroup-name)
 110         (gnus-summary-mark-article article gnus-canceled-mark)))))
 111
 112 (defun gnus-draft-send (article &optional group)
 113   "Send message ARTICLE."
 114   (gnus-draft-setup article (or group "nndraft:queue"))
 115   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 116         message-send-hook)
 117     (message-send-and-exit)))
 118
 119 (defun gnus-draft-send-all-messages ()
 120   "Send all the sendable drafts."
 121   (interactive)
 122   (gnus-uu-mark-buffer)
 123   (gnus-draft-send-message))
 124
 125 (defun gnus-group-send-drafts ()
 126   "Send all sendable articles from the queue group."
 127   (interactive)
 128   (gnus-activate-group "nndraft:queue")
 129   (save-excursion
 130     (let ((articles (nndraft-articles))
 131           (unsendable (gnus-uncompress-range
 132                        (cdr (assq 'unsend
 133                                   (gnus-info-marks
 134                                    (gnus-get-info "nndraft:queue"))))))
 135           article)
 136       (while (setq article (pop articles))
 137         (unless (memq article unsendable)
 138           (gnus-draft-send article))))))
 139
 140 ;;; Utility functions
 141
 142 ;;;!!!If this is byte-compiled, it fails miserably.
 143 ;;;!!!I have no idea why.
 144
 145 (progn
 146 (defun gnus-draft-setup (narticle group)
 147   (gnus-setup-message 'forward
 148     (let ((article narticle))
 149       (message-mail)
 150       (erase-buffer)
 151       (if (not (gnus-request-restore-buffer article group))
 152           (error "Couldn't restore the article")
 153         ;; Insert the separator.
 154         (goto-char (point-min))
 155         (search-forward "\n\n")
 156         (forward-char -1)
 157         (insert mail-header-separator)
 158         (forward-line 1)
 159         (message-set-auto-save-file-name))))))
 160
 161 (defun gnus-draft-article-sendable-p (article)
 162   "Say whether ARTICLE is sendable."
 163   (not (memq article gnus-newsgroup-unsendable)))
 164
 165 (provide 'gnus-draft)
 166
 167 ;;; gnus-draft.el ends here