git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   7 ;; Keywords: mail, news, MIME, offline
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "De" gnus-draft-edit-message
  51     "Ds" gnus-draft-send-message
  52     "DS" gnus-draft-send-all-messages))
  53
  54 (defun gnus-draft-make-menu-bar ()
  55   (unless (boundp 'gnus-draft-menu)
  56     (easy-menu-define
  57      gnus-draft-menu gnus-draft-mode-map ""
  58      '("Drafts"
  59        ["Toggle whether to send" gnus-draft-toggle-sending t]
  60        ["Edit" gnus-draft-edit-message t]
  61        ["Send selected message(s)" gnus-draft-send-message t]
  62        ["Send all messages" gnus-draft-send-all-messages t]
  63        ["Delete draft" gnus-summary-delete-article t]))))
  64
  65 (defun gnus-draft-mode (&optional arg)
  66   "Minor mode for providing a draft summary buffers.
  67
  68 \\{gnus-draft-mode-map}"
  69   (interactive "P")
  70   (when (eq major-mode 'gnus-summary-mode)
  71     (when (set (make-local-variable 'gnus-draft-mode)
  72                   (if (null arg) (not gnus-draft-mode)
  73                     (> (prefix-numeric-value arg) 0)))
  74       ;; Set up the menu.
  75       (when (gnus-visual-p 'draft-menu 'menu)
  76         (gnus-draft-make-menu-bar))
  77       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number)))
  98     (gnus-summary-mark-as-read article gnus-canceled-mark)
  99     (gnus-draft-setup-for-editing article gnus-newsgroup-name)
 100     (set-buffer-modified-p t)
 101     (save-buffer)
 102     (let ((gnus-verbose-backends nil))
 103       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 104     (push
 105      `((lambda ()
 106          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 107            (save-excursion
 108              (set-buffer ,gnus-summary-buffer)
 109              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 110      message-send-actions)))
 111
 112 (defun gnus-draft-send-message (&optional n)
 113   "Send the current draft."
 114   (interactive "P")
 115   (let ((articles (gnus-summary-work-articles n))
 116         article)
 117     (while (setq article (pop articles))
 118       (gnus-summary-remove-process-mark article)
 119       (unless (memq article gnus-newsgroup-unsendable)
 120         (gnus-draft-send article gnus-newsgroup-name)
 121         (gnus-summary-mark-article article gnus-canceled-mark)))))
 122
 123 (defun gnus-draft-send (article &optional group)
 124   "Send message ARTICLE."
 125   (gnus-draft-setup-for-sending article (or group "nndraft:queue"))
 126   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 127         message-send-hook type method)
 128     ;; We read the meta-information that says how and where
 129     ;; this message is to be sent.
 130     (save-restriction
 131       (message-narrow-to-head)
 132       (when (re-search-forward
 133              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 134              nil t)
 135         (setq type (ignore-errors (read (current-buffer)))
 136               method (ignore-errors (read (current-buffer))))
 137         (message-remove-header gnus-agent-meta-information-header)))
 138     ;; Then we send it.  If we have no meta-information, we just send
 139     ;; it and let Message figure out how.
 140     (when (let ((mail-header-separator ""))
 141             (cond ((eq type 'news)
 142                    (mime-edit-maybe-split-and-send
 143                     (function
 144                      (lambda ()
 145                        (interactive)
 146                        (funcall message-send-news-function method)
 147                        )))
 148                    (funcall message-send-news-function method)
 149                    )
 150                   ((eq type 'mail)
 151                    (mime-edit-maybe-split-and-send
 152                     (function
 153                      (lambda ()
 154                        (interactive)
 155                        (funcall message-send-mail-function)
 156                        )))
 157                    (funcall message-send-mail-function)
 158                    t)))
 159       (let ((gnus-verbose-backends nil))
 160         (gnus-request-expire-articles
 161          (list article) (or group "nndraft:queue") t)))))
 162
 163 (defun gnus-draft-send-all-messages ()
 164   "Send all the sendable drafts."
 165   (interactive)
 166   (gnus-uu-mark-buffer)
 167   (gnus-draft-send-message))
 168
 169 (defun gnus-group-send-drafts ()
 170   "Send all sendable articles from the queue group."
 171   (interactive)
 172   (gnus-activate-group "nndraft:queue")
 173   (save-excursion
 174     (let ((articles (nndraft-articles))
 175           (unsendable (gnus-uncompress-range
 176                        (cdr (assq 'unsend
 177                                   (gnus-info-marks
 178                                    (gnus-get-info "nndraft:queue"))))))
 179           article)
 180       (while (setq article (pop articles))
 181         (unless (memq article unsendable)
 182           (gnus-draft-send article))))))
 183
 184 ;;; Utility functions
 185
 186 (defcustom gnus-draft-decoding-function
 187   #'mime-edit-decode-message-in-buffer
 188   "*Function called to decode the message from network representation."
 189   :group 'gnus-agent
 190   :type 'function)
 191
 192 ;;;!!!If this is byte-compiled, it fails miserably.
 193 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 194 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 195 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 196
 197 (defun gnus-draft-setup-for-editing (narticle group)
 198   (gnus-setup-message 'forward
 199     (let ((article narticle))
 200       (message-mail)
 201       (erase-buffer)
 202       (if (not (gnus-request-restore-buffer article group))
 203           (error "Couldn't restore the article")
 204         ;; Insert the separator.
 205         (funcall gnus-draft-decoding-function)
 206         (goto-char (point-min))
 207         (search-forward "\n\n")
 208         (forward-char -1)
 209         (insert mail-header-separator)
 210         (forward-line 1)
 211         (message-set-auto-save-file-name)))))
 212
 213 (defvar gnus-draft-send-draft-buffer " *send draft*")
 214 (defun gnus-draft-setup-for-sending (narticle group)
 215   (let ((article narticle))
 216     (if (not (get-buffer gnus-draft-send-draft-buffer))
 217         (get-buffer-create gnus-draft-send-draft-buffer))
 218     (set-buffer gnus-draft-send-draft-buffer)
 219     (erase-buffer)
 220     (if (not (gnus-request-restore-buffer article group))
 221         (error "Couldn't restore the article")
 222       )))
 223
 224 (defun gnus-draft-article-sendable-p (article)
 225   "Say whether ARTICLE is sendable."
 226   (not (memq article gnus-newsgroup-unsendable)))
 227
 228 (provide 'gnus-draft)
 229
 230 ;;; gnus-draft.el ends here