git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Keywords: mail, news, MIME, offline
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Draft minor mode
  37
  38 (defvar gnus-draft-mode nil
  39   "Minor mode for providing a draft summary buffers.")
  40
  41 (defvar gnus-draft-mode-map nil)
  42
  43 (unless gnus-draft-mode-map
  44   (setq gnus-draft-mode-map (make-sparse-keymap))
  45
  46   (gnus-define-keys gnus-draft-mode-map
  47     "Dt" gnus-draft-toggle-sending
  48     "De" gnus-draft-edit-message
  49     "Ds" gnus-draft-send-message
  50     "DS" gnus-draft-send-all-messages))
  51
  52 (defun gnus-draft-make-menu-bar ()
  53   (unless (boundp 'gnus-draft-menu)
  54     (easy-menu-define
  55      gnus-draft-menu gnus-draft-mode-map ""
  56      '("Drafts"
  57        ["Toggle whether to send" gnus-draft-toggle-sending t]
  58        ["Edit" gnus-draft-edit-message t]
  59        ["Send selected message(s)" gnus-draft-send-message t]
  60        ["Send all messages" gnus-draft-send-all-messages t]))))
  61
  62 (defun gnus-draft-mode (&optional arg)
  63   "Minor mode for providing a draft summary buffers.
  64
  65 \\{gnus-draft-mode-map}"
  66   (interactive "P")
  67   (when (eq major-mode 'gnus-summary-mode)
  68     (when (set (make-local-variable 'gnus-draft-mode)
  69                   (if (null arg) (not gnus-draft-mode)
  70                     (> (prefix-numeric-value arg) 0)))
  71       ;; Set up the menu.
  72       (when (gnus-visual-p 'draft-menu 'menu)
  73         (gnus-draft-make-menu-bar))
  74       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  75       (run-hooks 'gnus-draft-mode-hook))))
  76
  77 ;;; Commands
  78
  79 (defun gnus-draft-toggle-sending (article)
  80   "Toggle whether to send an article or not."
  81   (interactive (list (gnus-summary-article-number)))
  82   (if (gnus-draft-article-sendable-p article)
  83       (progn
  84         (push article gnus-newsgroup-unsendable)
  85         (gnus-summary-mark-article article gnus-unsendable-mark))
  86     (setq gnus-newsgroup-unsendable
  87           (delq article gnus-newsgroup-unsendable))
  88     (gnus-summary-mark-article article gnus-unread-mark))
  89   (gnus-summary-position-point))
  90
  91 (defun gnus-draft-edit-message ()
  92   "Enter a mail/post buffer to edit and send the draft."
  93   (interactive)
  94   (let ((article (gnus-summary-article-number)))
  95     (gnus-summary-mark-as-read article gnus-canceled-mark)
  96     (gnus-draft-setup article gnus-newsgroup-name)
  97     (push
  98      `((lambda ()
  99          (when (buffer-name (get-buffer ,gnus-summary-buffer))
 100            (save-excursion
 101              (set-buffer (get-buffer ,gnus-summary-buffer))
 102              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 103      message-send-actions)))
 104
 105 (defun gnus-draft-send-message (&optional n)
 106   "Send the current draft."
 107   (interactive "P")
 108   (let ((articles (gnus-summary-work-articles n))
 109         article)
 110     (while (setq article (pop articles))
 111       (gnus-summary-remove-process-mark article)
 112       (unless (memq article gnus-newsgroup-unsendable)
 113         (gnus-draft-send article gnus-newsgroup-name)
 114         (gnus-summary-mark-article article gnus-canceled-mark)))))
 115
 116 (defun gnus-draft-send (article &optional group)
 117   "Send message ARTICLE."
 118   (gnus-draft-setup article (or group "nndraft:queue"))
 119   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 120         message-send-hook)
 121     (message-send-and-exit)))
 122
 123 (defun gnus-draft-send-all-messages ()
 124   "Send all the sendable drafts."
 125   (interactive)
 126   (gnus-uu-mark-buffer)
 127   (gnus-draft-send-message))
 128
 129 (defun gnus-group-send-drafts ()
 130   "Send all sendable articles from the queue group."
 131   (interactive)
 132   (gnus-activate-group "nndraft:queue")
 133   (save-excursion
 134     (let ((articles (nndraft-articles))
 135           (unsendable (gnus-uncompress-range
 136                        (cdr (assq 'unsend
 137                                   (gnus-info-marks
 138                                    (gnus-get-info "nndraft:queue"))))))
 139           article)
 140       (while (setq article (pop articles))
 141         (unless (memq article unsendable)
 142           (gnus-draft-send article))))))
 143
 144 ;;; Utility functions
 145
 146 (defcustom gnus-draft-decoding-function
 147   (function
 148    (lambda ()
 149      (mime-edit-decode-buffer nil)
 150      (eword-decode-header)
 151      ))
 152   "Function called to decode the message from network representation."
 153   :group 'gnus-agent
 154   :type 'function)
 155
 156 ;;;!!!If this is byte-compiled, it fails miserably.
 157 ;;;!!!I have no idea why.
 158
 159 (progn
 160 (defun gnus-draft-setup (narticle group)
 161   (gnus-setup-message 'forward
 162     (let ((article narticle))
 163       (message-mail)
 164       (erase-buffer)
 165       (if (not (gnus-request-restore-buffer article group))
 166           (error "Couldn't restore the article")
 167         ;; Insert the separator.
 168         (funcall gnus-draft-decoding-function)
 169         (goto-char (point-min))
 170         (search-forward "\n\n")
 171         (forward-char -1)
 172         (insert mail-header-separator)
 173         (forward-line 1)
 174         (message-set-auto-save-file-name))))))
 175
 176 (defun gnus-draft-article-sendable-p (article)
 177   "Say whether ARTICLE is sendable."
 178   (not (memq article gnus-newsgroup-unsendable)))
 179
 180 (provide 'gnus-draft)
 181
 182 ;;; gnus-draft.el ends here