git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-fun.el

   1 ;;; gnus-fun.el --- various frivoluos extension functions to Gnus
   2 ;; Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defcustom gnus-x-face-directory (expand-file-name "x-faces" gnus-directory)
  29   "*Directory where X-Face PBM files are stored."
  30   :group 'gnus-fun
  31   :type 'directory)
  32
  33 (defcustom gnus-convert-pbm-to-x-face-command "pbmtoxbm %s | compface"
  34   "Command for converting a PBM to an X-Face."
  35   :group 'gnus-fun
  36   :type 'string)
  37
  38 (defcustom gnus-convert-image-to-x-face-command "giftopnm %s | ppmnorm | pnmscale -width 48 -height 48 | ppmtopgm | pgmtopbm | pbmtoxbm | compface"
  39   "Command for converting a GIF to an X-Face."
  40   :group 'gnus-fun
  41   :type 'string)
  42
  43 (defun gnus-shell-command-to-string (command)
  44   "Like `shell-command-to-string' except not mingling ERROR."
  45   (with-output-to-string
  46     (call-process shell-file-name nil (list standard-output nil)
  47                   nil shell-command-switch command)))
  48
  49 (defun gnus-shell-command-on-region (start end command)
  50   "A simplified `shell-command-on-region'.
  51 Output to the current buffer, replace text, and don't mingle error."
  52   (call-process-region start end shell-file-name t
  53                        (list (current-buffer) nil)
  54                        nil shell-command-switch command))
  55
  56 ;;;###autoload
  57 (defun gnus-random-x-face ()
  58   "Insert a random X-Face header from `gnus-x-face-directory'."
  59   (interactive)
  60   (when (file-exists-p gnus-x-face-directory)
  61     (let* ((files (directory-files gnus-x-face-directory t "\\.pbm$"))
  62            (file (nth (random (length files)) files)))
  63       (when file
  64         (gnus-shell-command-to-string
  65          (format gnus-convert-pbm-to-x-face-command
  66                  (shell-quote-argument file)))))))
  67
  68 ;;;###autoload
  69 (defun gnus-x-face-from-file (file)
  70   "Insert an X-Face header based on an image file."
  71   (interactive "fImage file name:" )
  72   (when (file-exists-p file)
  73     (gnus-shell-command-to-string
  74      (format gnus-convert-image-to-x-face-command
  75              (shell-quote-argument file)))))
  76
  77 (defun gnus-convert-image-to-gray-x-face (file depth)
  78   (let* ((mapfile (make-temp-name (expand-file-name "gnus." mm-tmp-directory)))
  79          (levels (expt 2 depth))
  80          (step (/ 255 (1- levels)))
  81          color-alist bits bits-list mask pixel x-faces)
  82     (with-temp-file mapfile
  83       (insert "P3\n")
  84       (insert (format "%d 1\n" levels))
  85       (insert "255\n")
  86       (dotimes (i levels)
  87         (insert (format "%d %d %d\n"
  88                         (* step i) (* step i) (* step i)))
  89         (push (cons (* step i) i) color-alist)))
  90     (when (file-exists-p file)
  91       (with-temp-buffer
  92         (insert (gnus-shell-command-to-string
  93                  (format "giftopnm %s | ppmnorm | pnmscale -width 48 -height 48 | ppmquant -fs -map %s | ppmtopgm | pnmnoraw"
  94                          (shell-quote-argument file)
  95                          mapfile)))
  96         (goto-char (point-min))
  97         (forward-line 3)
  98         (while (setq pixel (ignore-errors (read (current-buffer))))
  99           (push (cdr (assq pixel color-alist)) bits-list))
 100         (setq bits-list (nreverse bits-list))
 101         (dotimes (bit-number depth)
 102           (setq mask (expt 2 bit-number))
 103           (with-temp-buffer
 104             (insert "P1\n48 48\n")
 105             (dolist (bits bits-list)
 106               (insert (if (zerop (logand bits mask)) "0 " "1 ")))
 107             (gnus-shell-command-on-region
 108              (point-min) (point-max)
 109              ;; the following is taken from xbmtoikon:
 110              "pbmtoicon | sed '/^[      ]*[*\\\\/]/d; s/[       ]//g; s/,$//' | tr , '\\012' | sed 's/^0x//; s/^/0x/' | pr -l1 -t -w22 -3 -s, | sed 's/,*$/,/' | compface")
 111             (push (buffer-string) x-faces))))
 112       (dotimes (i (length x-faces))
 113         (insert (if (zerop i) "X-Face:" (format "X-Face-%s:" i))
 114                 (nth i x-faces))))
 115     (delete-file mapfile)))
 116
 117 ;;;###autoload
 118 (defun gnus-convert-gray-x-face-to-xpm (faces)
 119   (let* ((depth (length faces))
 120          (scale (/ 255 (1- (expt 2 depth))))
 121          (ok-p t)
 122          bit-list bit-lists pixels pixel)
 123     (dolist (face faces)
 124       (setq bit-list nil)
 125       (with-temp-buffer
 126         (insert (uncompface face))
 127         (gnus-shell-command-on-region
 128          (point-min) (point-max)
 129          "pnmnoraw")
 130         (goto-char (point-min))
 131         (forward-line 2)
 132         (while (not (eobp))
 133           (cond
 134            ((eq (following-char) ?0)
 135             (push 0 bit-list))
 136            ((eq (following-char) ?1)
 137             (push 1 bit-list)))
 138           (forward-char 1)))
 139       (unless (= (length bit-list) (* 48 48))
 140         (setq ok-p nil))
 141       (push bit-list bit-lists))
 142     (when ok-p
 143       (dotimes (i (* 48 48))
 144         (setq pixel 0)
 145         (dotimes (plane depth)
 146           (setq pixel (+ (* pixel 2) (nth i (nth plane bit-lists)))))
 147         (push pixel pixels))
 148       (with-temp-buffer
 149         (insert "P2\n48 48\n255\n")
 150         (dolist (pixel pixels)
 151           (insert (number-to-string (* scale pixel)) " "))
 152         (gnus-shell-command-on-region
 153          (point-min) (point-max)
 154          "ppmtoxpm")
 155         (buffer-string)))))
 156
 157 ;;;###autoload
 158 (defun gnus-convert-gray-x-face-region (beg end)
 159   "Convert the X-Faces in region to a PPM file."
 160   (interactive "r")
 161   (let ((input (buffer-substring beg end))
 162         faces)
 163     (with-temp-buffer
 164       (insert input)
 165       (goto-char (point-min))
 166       (while (not (eobp))
 167         (save-restriction
 168           (mail-header-narrow-to-field)
 169           (push (mail-header-field-value) faces)
 170           (goto-char (point-max)))))
 171     (gnus-convert-gray-x-face-to-xpm faces)))
 172
 173 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 174   "Face to show X-Face.
 175 The colors from this face are used as the foreground and background
 176 colors of the displayed X-Faces."
 177   :group 'gnus-article-headers)
 178
 179 (defun gnus-display-x-face-in-from (data)
 180   "Display the X-Face DATA in the From header."
 181   (let ((default-enable-multibyte-characters nil)
 182         pbm)
 183     (when (or (gnus-image-type-available-p 'xface)
 184               (and (gnus-image-type-available-p 'pbm)
 185                    (setq pbm (uncompface data))))
 186       (save-excursion
 187         (save-restriction
 188           (article-narrow-to-head)
 189           (gnus-article-goto-header "from")
 190           (when (bobp)
 191             (insert "From: [no `from' set]\n")
 192             (forward-char -17))
 193           (gnus-add-image
 194            'xface
 195            (gnus-put-image
 196             (if (gnus-image-type-available-p 'xface)
 197                 (gnus-create-image
 198                  (concat "X-Face: " data)
 199                  'xface t :ascent 'center :face 'gnus-x-face)
 200               (gnus-create-image
 201                pbm 'pbm t :ascent 'center :face 'gnus-x-face))))
 202           (gnus-add-wash-type 'xface))))))
 203
 204 (defun gnus-grab-cam-x-face ()
 205   "Grab a picture off the camera and make it into an X-Face."
 206   (interactive)
 207   (shell-command "xawtv-remote snap ppm")
 208   (let ((file nil))
 209     (while (null (setq file (directory-files "/tftpboot/sparky/tmp"
 210                                              t "snap.*ppm")))
 211       (sleep-for 1))
 212     (setq file (car file))
 213     (with-temp-buffer
 214       (shell-command
 215        (format "pnmcut -left 110 -top 30 -width 144 -height 144 '%s' | ppmnorm 2>/dev/null | pnmscale -width 48 | ppmtopgm | pgmtopbm -threshold -value 0.92 | pbmtoxbm | compface"
 216                file)
 217        (current-buffer))
 218       ;;(sleep-for 3)
 219       (delete-file file)
 220       (buffer-string))))
 221
 222 (defun gnus-grab-gray-x-face ()
 223   "Grab a picture off the camera and make it into an X-Face."
 224   (interactive)
 225   (shell-command "xawtv-remote snap ppm")
 226   (let ((file nil))
 227     (while (null (setq file (directory-files "/tftpboot/sparky/tmp"
 228                                              t "snap.*ppm")))
 229       (sleep-for 1))
 230     (setq file (car file))
 231     (with-temp-buffer
 232       (shell-command
 233        (format "pnmcut -left 70 -top 100 -width 144 -height 144 '%s' | ppmquant 256 2>/dev/null | ppmtogif > '%s.gif'"
 234                file file)
 235        (current-buffer))
 236       (delete-file file))
 237     (gnus-convert-image-to-gray-x-face (concat file ".gif") 3)
 238     (delete-file (concat file ".gif"))))
 239
 240 (provide 'gnus-fun)
 241
 242 ;;; gnus-fun.el ends here