git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-logic.el

   1 ;;; gnus-logic.el --- advanced scoring code for Gnus
   2 ;; Copyright (C) 1996,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'gnus)
  30 (require 'gnus-score)
  31 (require 'gnus-util)
  32
  33 ;;; Internal variables.
  34
  35 (defvar gnus-advanced-headers nil)
  36
  37 ;; To avoid having 8-bit characters in the source file.
  38 (defvar gnus-advanced-not (intern (format "%c" 172)))
  39
  40 (defconst gnus-advanced-index
  41   ;; Name to index alist.
  42   '(("number" 0 gnus-advanced-integer)
  43     ("subject" 1 gnus-advanced-string)
  44     ("from" 2 gnus-advanced-string)
  45     ("date" 3 gnus-advanced-date)
  46     ("message-id" 4 gnus-advanced-string)
  47     ("references" 5 gnus-advanced-string)
  48     ("chars" 6 gnus-advanced-integer)
  49     ("lines" 7 gnus-advanced-integer)
  50     ("xref" 8 gnus-advanced-string)
  51     ("head" nil gnus-advanced-body)
  52     ("body" nil gnus-advanced-body)
  53     ("all" nil gnus-advanced-body)))
  54
  55 (eval-and-compile
  56   (autoload 'parse-time-string "parse-time"))
  57
  58 (defun gnus-score-advanced (rule &optional trace)
  59   "Apply advanced scoring RULE to all the articles in the current group."
  60   (let ((headers gnus-newsgroup-headers)
  61         gnus-advanced-headers score)
  62     (while (setq gnus-advanced-headers (pop headers))
  63       (when (gnus-advanced-score-rule (car rule))
  64         ;; This rule was successful, so we add the score to
  65         ;; this article.
  66         (if (setq score (assq (mail-header-number gnus-advanced-headers)
  67                               gnus-newsgroup-scored))
  68             (setcdr score
  69                     (+ (cdr score)
  70                        (or (nth 1 rule)
  71                            gnus-score-interactive-default-score)))
  72           (push (cons (mail-header-number gnus-advanced-headers)
  73                       (or (nth 1 rule)
  74                           gnus-score-interactive-default-score))
  75                 gnus-newsgroup-scored)
  76           (when trace
  77             (push (cons "A file" rule)
  78                   gnus-score-trace)))))))
  79
  80 (defun gnus-advanced-score-rule (rule)
  81   "Apply RULE to `gnus-advanced-headers'."
  82   (let ((type (car rule)))
  83     (cond
  84      ;; "And" rule.
  85      ((or (eq type '&) (eq type 'and))
  86       (pop rule)
  87       (if (not rule)
  88           t                             ; Empty rule is true.
  89         (while (and rule
  90                     (gnus-advanced-score-rule (car rule)))
  91           (pop rule))
  92         ;; If all the rules were true, then `rule' should be nil.
  93         (not rule)))
  94      ;; "Or" rule.
  95      ((or (eq type '|) (eq type 'or))
  96       (pop rule)
  97       (if (not rule)
  98           nil
  99         (while (and rule
 100                     (not (gnus-advanced-score-rule (car rule))))
 101           (pop rule))
 102         ;; If one of the rules returned true, then `rule' should be non-nil.
 103         rule))
 104      ;; "Not" rule.
 105      ((or (eq type '!) (eq type 'not) (eq type gnus-advanced-not))
 106       (not (gnus-advanced-score-rule (nth 1 rule))))
 107      ;; This is a `1-'-type redirection rule.
 108      ((and (symbolp type)
 109            (string-match "^[0-9]+-$\\|^\\^+$" (symbol-name type)))
 110       (let ((gnus-advanced-headers
 111              (gnus-parent-headers
 112               gnus-advanced-headers
 113               (if (string-match "^\\([0-9]+\\)-$" (symbol-name type))
 114                   ;; 1- type redirection.
 115                   (string-to-number
 116                    (substring (symbol-name type)
 117                               (match-beginning 0) (match-end 0)))
 118                 ;; ^^^ type redirection.
 119                 (length (symbol-name type))))))
 120         (when gnus-advanced-headers
 121           (gnus-advanced-score-rule (nth 1 rule)))))
 122      ;; Plain scoring rule.
 123      ((stringp type)
 124       (gnus-advanced-score-article rule))
 125      ;; Bug-out time!
 126      (t
 127       (error "Unknown advanced score type: %s" rule)))))
 128
 129 (defun gnus-advanced-score-article (rule)
 130   ;; `rule' is a semi-normal score rule, so we find out
 131   ;; what function that's supposed to do the actual
 132   ;; processing.
 133   (let* ((header (car rule))
 134          (func (assoc (downcase header) gnus-advanced-index)))
 135     (if (not func)
 136         (error "No such header: %s" rule)
 137       ;; Call the score function.
 138       (funcall (caddr func) (or (cadr func) header)
 139                (cadr rule) (caddr rule)))))
 140
 141 (defun gnus-advanced-string (index match type)
 142   "See whether string MATCH of TYPE matches `gnus-advanced-headers' in INDEX."
 143   (let* ((type (or type 's))
 144          (case-fold-search (not (eq (downcase (symbol-name type))
 145                                     (symbol-name type))))
 146          (header (aref gnus-advanced-headers index)))
 147     (cond
 148      ((memq type '(r R regexp Regexp))
 149       (string-match match header))
 150      ((memq type '(s S string String))
 151       (string-match (regexp-quote match) header))
 152      ((memq type '(e E exact Exact))
 153       (string= match header))
 154      ((memq type '(f F fuzzy Fuzzy))
 155       (string-match (regexp-quote (gnus-simplify-subject-fuzzy match))
 156                     header))
 157      (t
 158       (error "No such string match type: %s" type)))))
 159
 160 (defun gnus-advanced-integer (index match type)
 161   (if (not (memq type '(< > <= >= =)))
 162       (error "No such integer score type: %s" type)
 163     (funcall type match (or (aref gnus-advanced-headers index) 0))))
 164
 165 (defun gnus-advanced-date (index match type)
 166   (let ((date (apply 'encode-time (parse-time-string
 167                                    (aref gnus-advanced-headers index))))
 168         (match (apply 'encode-time (parse-time-string match))))
 169     (cond
 170      ((eq type 'at)
 171       (equal date match))
 172      ((eq type 'before)
 173       (time-less-p match date))
 174      ((eq type 'after)
 175       (time-less-p date match))
 176      (t
 177       (error "No such date score type: %s" type)))))
 178
 179 (defun gnus-advanced-body (header match type)
 180   (when (string= header "all")
 181     (setq header "article"))
 182   (save-excursion
 183     (set-buffer nntp-server-buffer)
 184     (let* ((request-func (cond ((string= "head" header)
 185                                 'gnus-request-head)
 186                                ((string= "body" header)
 187                                 'gnus-request-body)
 188                                (t 'gnus-request-article)))
 189            ofunc article)
 190       ;; Not all backends support partial fetching.  In that case,
 191       ;; we just fetch the entire article.
 192       (unless (gnus-check-backend-function
 193                (intern (concat "request-" header))
 194                gnus-newsgroup-name)
 195         (setq ofunc request-func)
 196         (setq request-func 'gnus-request-article))
 197       (setq article (mail-header-number gnus-advanced-headers))
 198       (gnus-message 7 "Scoring article %s..." article)
 199       (when (funcall request-func article gnus-newsgroup-name)
 200         (goto-char (point-min))
 201         ;; If just parts of the article is to be searched and the
 202         ;; backend didn't support partial fetching, we just narrow
 203         ;; to the relevant parts.
 204         (when ofunc
 205           (if (eq ofunc 'gnus-request-head)
 206               (narrow-to-region
 207                (point)
 208                (or (search-forward "\n\n" nil t) (point-max)))
 209             (narrow-to-region
 210              (or (search-forward "\n\n" nil t) (point))
 211              (point-max))))
 212         (let* ((case-fold-search (not (eq (downcase (symbol-name type))
 213                                           (symbol-name type))))
 214                (search-func
 215                 (cond ((memq type '(r R regexp Regexp))
 216                        're-search-forward)
 217                       ((memq type '(s S string String))
 218                        'search-forward)
 219                       (t
 220                        (error "Invalid match type: %s" type)))))
 221           (goto-char (point-min))
 222           (prog1
 223               (funcall search-func match nil t)
 224             (widen)))))))
 225
 226 (provide 'gnus-logic)
 227
 228 ;;; gnus-logic.el ends here.