git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Semi-gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;;      Shuhei KOBAYASHI <shuhei-k@jaist.ac.jp>
   9 ;;      Katsumi Yamaoka  <yamaoka@jpl.org>
  10 ;;      Kiyokazu SUTO    <suto@merry.xmath.ous.ac.jp>
  11 ;; Keywords: mail, news, MIME
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  28 ;; Boston, MA 02111-1307, USA.
  29
  30 ;;; Commentary:
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl))
  35 (eval-when-compile (require 'static))
  36
  37 (require 'gnus)
  38 (require 'gnus-ems)
  39 (require 'message)
  40 (require 'gnus-art)
  41 (require 'gnus-util)
  42
  43 (defcustom gnus-post-method 'current
  44   "*Preferred method for posting USENET news.
  45
  46 If this variable is `current' (which is the default), Gnus will use
  47 the \"current\" select method when posting.  If it is `native', Gnus
  48 will use the native select method when posting.
  49
  50 This method will not be used in mail groups and the like, only in
  51 \"real\" newsgroups.
  52
  53 If not `native' nor `current', the value must be a valid method as discussed
  54 in the documentation of `gnus-select-method'.  It can also be a list of
  55 methods.  If that is the case, the user will be queried for what select
  56 method to use when posting."
  57   :group 'gnus-group-foreign
  58   :link '(custom-manual "(gnus)Posting Server")
  59   :type `(choice (const native)
  60                  (const current)
  61                  (sexp :tag "Methods" ,gnus-select-method)))
  62
  63 (defcustom gnus-outgoing-message-group nil
  64   "*All outgoing messages will be put in this group.
  65 If you want to store all your outgoing mail and articles in the group
  66 \"nnml:archive\", you set this variable to that value.  This variable
  67 can also be a list of group names.
  68
  69 If you want to have greater control over what group to put each
  70 message in, you can set this variable to a function that checks the
  71 current newsgroup name and then returns a suitable group name (or list
  72 of names)."
  73   :group 'gnus-message
  74   :type '(choice (string :tag "Group")
  75                  (function)))
  76
  77 (defcustom gnus-mailing-list-groups nil
  78   "*If non-nil a regexp matching groups that are really mailing lists.
  79 This is useful when you're reading a mailing list that has been
  80 gatewayed to a newsgroup, and you want to followup to an article in
  81 the group."
  82   :group 'gnus-message
  83   :type '(choice (regexp)
  84                  (const nil)))
  85
  86 (defcustom gnus-add-to-list nil
  87   "*If non-nil, add a `to-list' parameter automatically."
  88   :group 'gnus-message
  89   :type 'boolean)
  90
  91 (defcustom gnus-crosspost-complaint
  92   "Hi,
  93
  94 You posted the article below with the following Newsgroups header:
  95
  96 Newsgroups: %s
  97
  98 The %s group, at least, was an inappropriate recipient
  99 of this message.  Please trim your Newsgroups header to exclude this
 100 group before posting in the future.
 101
 102 Thank you.
 103
 104 "
 105   "Format string to be inserted when complaining about crossposts.
 106 The first %s will be replaced by the Newsgroups header;
 107 the second with the current group name."
 108   :group 'gnus-message
 109   :type 'string)
 110
 111 (defcustom gnus-message-setup-hook nil
 112   "Hook run after setting up a message buffer."
 113   :group 'gnus-message
 114   :type 'hook)
 115
 116 (defcustom gnus-bug-create-help-buffer t
 117   "*Should we create the *Gnus Help Bug* buffer?"
 118   :group 'gnus-message
 119   :type 'boolean)
 120
 121 (defcustom gnus-posting-styles nil
 122   "*Alist of styles to use when posting.
 123 See Info node `(gnus)Posting Styles'."
 124   :group 'gnus-message
 125   :link '(custom-manual "(gnus)Posting Styles")
 126   :type '(repeat (cons (choice (regexp)
 127                                (variable)
 128                                (list (const header)
 129                                      (string :tag "Header")
 130                                      (regexp :tag "Regexp"))
 131                                (function)
 132                                (sexp))
 133                        (repeat (list
 134                                 (choice (const signature)
 135                                         (const signature-file)
 136                                         (const organization)
 137                                         (const address)
 138                                         (const x-face-file)
 139                                         (const name)
 140                                         (const body)
 141                                         (const import)
 142                                         (symbol)
 143                                         (string :tag "Header"))
 144                                 (choice (string)
 145                                         (function)
 146                                         (variable)
 147                                         (sexp)))))))
 148
 149 (defcustom gnus-named-posting-styles nil
 150   "Alist mapping names to the user-defined posting styles."
 151   :group 'gnus-message
 152   :type '(repeat (cons string
 153                        (repeat (list
 154                                 (choice (const signature)
 155                                         (const signature-file)
 156                                         (const organization)
 157                                         (const address)
 158                                         (const x-face-file)
 159                                         (const name)
 160                                         (const body)
 161                                         (const import)
 162                                         (symbol)
 163                                         (string :tag "Header"))
 164                                 (choice (string)
 165                                         (function)
 166                                         (variable)
 167                                         (sexp)))))))
 168
 169 (defcustom gnus-gcc-mark-as-read nil
 170   "If non-nil, automatically mark Gcc articles as read."
 171   :version "22.1"
 172   :group 'gnus-message
 173   :type 'boolean)
 174
 175 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 176                         'gnus-gcc-mark-as-read)
 177
 178 (defcustom gnus-gcc-externalize-attachments nil
 179   "Should local-file attachments be included as external parts in Gcc copies?
 180 If it is `all', attach files as external parts;
 181 if a regexp and matches the Gcc group name, attach files as external parts;
 182 if nil, attach files as normal parts."
 183   :version "22.1"
 184   :group 'gnus-message
 185   :type '(choice (const nil :tag "None")
 186                  (const all :tag "Any")
 187                  (string :tag "Regexp")))
 188
 189 (gnus-define-group-parameter
 190  posting-charset-alist
 191  :type list
 192  :function-document
 193  "Return the permitted unencoded charsets for posting of GROUP."
 194  :variable gnus-group-posting-charset-alist
 195  :variable-default
 196  '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 197    ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 198    (message-this-is-mail nil nil)
 199    (message-this-is-news nil t))
 200  :variable-document
 201  "Alist of regexps and permitted unencoded charsets for posting.
 202 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 203 TEST is either a regular expression matching the newsgroup header or a
 204 variable to query,
 205 HEADER is the charset which may be left unencoded in the header (nil
 206 means encode all charsets),
 207 BODY-LIST is a list of charsets which may be encoded using 8bit
 208 content-transfer encoding in the body, or one of the special values
 209 nil (always encode using quoted-printable) or t (always use 8bit).
 210
 211 Note that any value other than nil for HEADER infringes some RFCs, so
 212 use this option with care."
 213  :variable-group gnus-charset
 214  :variable-type
 215  '(repeat (list :tag "Permitted unencoded charsets"
 216                 (choice :tag "Where"
 217                         (regexp :tag "Group")
 218                         (const :tag "Mail message" :value message-this-is-mail)
 219                         (const :tag "News article" :value message-this-is-news))
 220                 (choice :tag "Header"
 221                         (const :tag "None" nil)
 222                         (symbol :tag "Charset"))
 223                 (choice :tag "Body"
 224                         (const :tag "Any" :value t)
 225                         (const :tag "None" :value nil)
 226                         (repeat :tag "Charsets"
 227                                 (symbol :tag "Charset")))))
 228  :parameter-type '(choice :tag "Permitted unencoded charsets"
 229                           :value nil
 230                           (repeat (symbol)))
 231  :parameter-document       "\
 232 List of charsets that are permitted to be unencoded.")
 233
 234 (defcustom gnus-debug-files
 235   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 236     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 237     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 238     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 239     "mm-util.el" "mm-decode.el" "nnmail.el" "nntp.el" "message.el")
 240   "Files whose variables will be reported in `gnus-bug'."
 241   :version "22.1"
 242   :group 'gnus-message
 243   :type '(repeat (string :tag "File")))
 244
 245 (defcustom gnus-debug-exclude-variables
 246   '(mm-mime-mule-charset-alist
 247     nnmail-split-fancy message-minibuffer-local-map)
 248   "Variables that should not be reported in `gnus-bug'."
 249   :version "22.1"
 250   :group 'gnus-message
 251   :type '(repeat (symbol :tag "Variable")))
 252
 253 (defcustom gnus-discouraged-post-methods
 254   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 255   "A list of back ends that are not used in \"real\" newsgroups.
 256 This variable is used only when `gnus-post-method' is `current'."
 257   :version "22.1"
 258   :group 'gnus-group-foreign
 259   :type '(repeat (symbol :tag "Back end")))
 260
 261 (defcustom gnus-message-replysign
 262   nil
 263   "Automatically sign replies to signed messages.
 264 See also the `mml-default-sign-method' variable."
 265   :group 'gnus-message
 266   :type 'boolean)
 267
 268 (defcustom gnus-message-replyencrypt
 269   nil
 270   "Automatically encrypt replies to encrypted messages.
 271 See also the `mml-default-encrypt-method' variable."
 272   :group 'gnus-message
 273   :type 'boolean)
 274
 275 (defcustom gnus-message-replysignencrypted
 276   t
 277   "Setting this causes automatically encrypted messages to also be signed."
 278   :group 'gnus-message
 279   :type 'boolean)
 280
 281 (defcustom gnus-confirm-mail-reply-to-news (and gnus-novice-user
 282                                                 (not gnus-expert-user))
 283   "If non-nil, Gnus requests confirmation when replying to news.
 284 This is done because new users often reply by mistake when reading
 285 news.
 286 This can also be a function receiving the group name as the only
 287 parameter which should return non-nil iff a confirmation is needed, or
 288 a regexp, in which case a confirmation is asked for iff the group name
 289 matches the regexp."
 290   :version "22.1"
 291   :group 'gnus-message
 292   :type '(choice (const :tag "No" nil)
 293                  (const :tag "Yes" t)
 294                  (regexp :tag "Iff group matches regexp")
 295                  (function :tag "Iff function evaluates to non-nil")))
 296
 297 (defcustom gnus-confirm-treat-mail-like-news
 298   nil
 299   "If non-nil, Gnus will treat mail like news with regard to confirmation
 300 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 301 for fine-tuning this.
 302 If nil, Gnus will never ask for confirmation if replying to mail."
 303   :version "22.1"
 304   :group 'gnus-message
 305   :type 'boolean)
 306
 307 (defcustom gnus-summary-resend-default-address t
 308   "If non-nil, Gnus tries to suggest a default address to resend to.
 309 If nil, the address field will always be empty after invoking
 310 `gnus-summary-resend-message'."
 311   :version "22.1"
 312   :group 'gnus-message
 313   :type 'boolean)
 314
 315 ;;; Internal variables.
 316
 317 (defvar gnus-inhibit-posting-styles nil
 318   "Inhibit the use of posting styles.")
 319
 320 (defvar gnus-article-yanked-articles nil)
 321 (defvar gnus-message-buffer "*Mail Gnus*")
 322 (defvar gnus-article-copy nil)
 323 (defvar gnus-check-before-posting nil)
 324 (defvar gnus-last-posting-server nil)
 325 (defvar gnus-message-group-art nil)
 326
 327 (defvar gnus-msg-force-broken-reply-to nil)
 328
 329 (defconst gnus-bug-message
 330   (format "Sending a bug report to the Gnus Towers.
 331 ========================================
 332
 333 This gnus is the %s%s.
 334 If you think the bug is a Semi-gnus bug, send a bug report to Semi-gnus
 335 Developers. (the addresses below are mailing list addresses)
 336
 337 ========================================
 338
 339 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 340 be sent to the Gnus Bug Exterminators.
 341
 342 The thing near the bottom of the buffer is how the environment
 343 settings will be included in the mail.  Please do not delete that.
 344 They will tell the Bug People what your environment is, so that it
 345 will be easier to locate the bugs.
 346
 347 If you have found a bug that makes Emacs go \"beep\", set
 348 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 349 and include the backtrace in your bug report.
 350
 351 Please describe the bug in annoying, painstaking detail.
 352
 353 Thank you for your help in stamping out bugs.
 354 "
 355           gnus-product-name
 356           (if (string= gnus-product-name "Semi-gnus")
 357               ""
 358             ", a modified version of Semi-gnus")))
 359
 360 (eval-and-compile
 361   (autoload 'gnus-uu-post-news "gnus-uu" nil t))
 362
 363 \f
 364 ;;;
 365 ;;; Gnus Posting Functions
 366 ;;;
 367
 368 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 369   "p" gnus-summary-post-news
 370   "i" gnus-summary-news-other-window
 371   "f" gnus-summary-followup
 372   "F" gnus-summary-followup-with-original
 373   "c" gnus-summary-cancel-article
 374   "s" gnus-summary-supersede-article
 375   "r" gnus-summary-reply
 376   "y" gnus-summary-yank-message
 377   "R" gnus-summary-reply-with-original
 378   "w" gnus-summary-wide-reply
 379   "W" gnus-summary-wide-reply-with-original
 380   "v" gnus-summary-very-wide-reply
 381   "V" gnus-summary-very-wide-reply-with-original
 382   "n" gnus-summary-followup-to-mail
 383   "N" gnus-summary-followup-to-mail-with-original
 384   "m" gnus-summary-mail-other-window
 385   "u" gnus-uu-post-news
 386   "\M-c" gnus-summary-mail-crosspost-complaint
 387   "Br" gnus-summary-reply-broken-reply-to
 388   "BR" gnus-summary-reply-broken-reply-to-with-original
 389   "om" gnus-summary-mail-forward
 390   "op" gnus-summary-post-forward
 391   "Om" gnus-summary-digest-mail-forward
 392   "Op" gnus-summary-digest-post-forward
 393   "P" gnus-summary-execute-command-with-posting-style)
 394
 395 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 396   "b" gnus-summary-resend-bounced-mail
 397   ;; "c" gnus-summary-send-draft
 398   "r" gnus-summary-resend-message
 399   "e" gnus-summary-resend-message-edit)
 400
 401 ;;; Internal functions.
 402
 403 (defun gnus-inews-make-draft (articles)
 404   `(lambda ()
 405      (gnus-inews-make-draft-meta-information
 406       ,gnus-newsgroup-name ',articles)))
 407
 408 (defvar gnus-article-reply nil)
 409 (defmacro gnus-setup-message (config &rest forms)
 410   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 411         (buffer (make-symbol "gnus-setup-message-buffer"))
 412         (article (make-symbol "gnus-setup-message-article"))
 413         (yanked (make-symbol "gnus-setup-yanked-articles"))
 414         (group (make-symbol "gnus-setup-message-group")))
 415     `(let ((,winconf (current-window-configuration))
 416            (,buffer (buffer-name (current-buffer)))
 417            (,article gnus-article-reply)
 418            (,yanked gnus-article-yanked-articles)
 419            (,group gnus-newsgroup-name)
 420            (message-header-setup-hook
 421             (copy-sequence message-header-setup-hook))
 422            (message-mode-hook (copy-sequence message-mode-hook))
 423            (message-startup-parameter-alist
 424             '((reply-buffer . gnus-copy-article-buffer)
 425               (original-buffer . gnus-original-article-buffer)
 426               (user-agent . Gnus))))
 427        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 428        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 429        ;; #### FIXME: for a reason that I did not manage to identify yet,
 430        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 431        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 432        ;; After evaluation of @forms below, it gets the value we actually want
 433        ;; to override, and the posting styles are used. For that reason, I've
 434        ;; added an optional argument to `gnus-configure-posting-styles' to
 435        ;; make sure that the correct value for the group name is used. -- drv
 436        (add-hook 'message-mode-hook
 437                  (if (memq ,config '(reply-yank reply))
 438                      (lambda ()
 439                        (gnus-configure-posting-styles ,group))
 440                    (lambda ()
 441                      ;; There may be an old " *gnus article copy*" buffer.
 442                      (let (gnus-article-copy)
 443                        (gnus-configure-posting-styles ,group)))))
 444        (gnus-pull ',(intern gnus-draft-meta-information-header)
 445                   message-required-headers)
 446        (when (and ,group
 447                   (not (string= ,group "")))
 448          (push (cons
 449                 (intern gnus-draft-meta-information-header)
 450                 (gnus-inews-make-draft (or ,yanked ,article)))
 451                message-required-headers))
 452        (unwind-protect
 453            (progn
 454              ,@forms)
 455          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 456                                       ,yanked)
 457          (setq gnus-message-buffer (current-buffer))
 458          (set (make-local-variable 'gnus-message-group-art)
 459               (cons ,group ,article))
 460          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 461          (gnus-maybe-setup-default-charset)
 462          (gnus-run-hooks 'gnus-message-setup-hook))
 463        (message-hide-headers)
 464        (gnus-add-buffer)
 465        (gnus-configure-windows ,config t)
 466        (run-hooks 'post-command-hook)
 467        (set-buffer-modified-p nil))))
 468
 469 (defun gnus-inews-make-draft-meta-information (group articles)
 470   (when (numberp articles)
 471     (setq articles (list articles)))
 472   (concat "(\"" group "\""
 473           (if articles
 474               (concat " "
 475                       (mapconcat
 476                        (lambda (elem)
 477                          (number-to-string
 478                           (if (consp elem)
 479                               (car elem)
 480                             elem)))
 481                        articles " "))
 482             "")
 483           ")"))
 484
 485 ;;;###autoload
 486 (defun gnus-msg-mail (&optional to subject other-headers continue
 487                                 switch-action yank-action send-actions)
 488   "Start editing a mail message to be sent.
 489 Like `message-mail', but with Gnus paraphernalia, particularly the
 490 Gcc: header for archiving purposes."
 491   (interactive)
 492   (let ((buf (current-buffer))
 493         mail-buf)
 494     (gnus-setup-message 'message
 495       (message-mail to subject other-headers continue
 496                     nil yank-action send-actions))
 497     (when switch-action
 498       (setq mail-buf (current-buffer))
 499       (switch-to-buffer buf)
 500       (apply switch-action mail-buf nil)))
 501   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 502   t)
 503
 504 (defvar save-selected-window-window)
 505
 506 ;;;###autoload
 507 (defun gnus-button-mailto (address)
 508   "Mail to ADDRESS."
 509   (set-buffer (gnus-copy-article-buffer))
 510   (gnus-setup-message 'message
 511     (message-reply address))
 512   (and (boundp 'save-selected-window-window)
 513        (not (window-live-p save-selected-window-window))
 514        (setq save-selected-window-window (selected-window))))
 515
 516 ;;;###autoload
 517 (defun gnus-button-reply (&optional to-address wide)
 518   "Like `message-reply'."
 519   (interactive)
 520   (gnus-setup-message 'message
 521     (message-reply to-address wide))
 522   (and (boundp 'save-selected-window-window)
 523        (not (window-live-p save-selected-window-window))
 524        (setq save-selected-window-window (selected-window))))
 525
 526 ;;;###autoload
 527 (define-mail-user-agent 'gnus-user-agent
 528   'gnus-msg-mail 'message-send-and-exit
 529   'message-kill-buffer 'message-send-hook)
 530
 531 (defun gnus-setup-posting-charset (group)
 532   (let ((alist gnus-group-posting-charset-alist)
 533         (group (or group ""))
 534         elem)
 535     (when group
 536       (catch 'found
 537         (while (setq elem (pop alist))
 538           (when (or (and (stringp (car elem))
 539                          (string-match (car elem) group))
 540                     (and (functionp (car elem))
 541                          (funcall (car elem) group))
 542                     (and (symbolp (car elem))
 543                          (symbol-value (car elem))))
 544             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 545
 546 (defun gnus-inews-add-send-actions (winconf buffer article
 547                                             &optional config yanked)
 548   (gnus-make-local-hook 'message-sent-hook)
 549   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 550                                  'gnus-inews-do-gcc) nil t)
 551   (when gnus-agent
 552     (gnus-make-local-hook 'message-header-hook)
 553     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 554   (setq message-post-method
 555         `(lambda (arg)
 556            (gnus-post-method arg ,gnus-newsgroup-name)))
 557   (setq message-user-agent (gnus-message-make-user-agent))
 558   (unless message-use-multi-frames
 559     (message-add-action
 560      `(if (gnus-buffer-exists-p ,buffer)
 561           (set-window-configuration ,winconf))
 562      'exit 'postpone 'kill))
 563   (let ((to-be-marked (cond
 564                        (yanked
 565                         (mapcar
 566                          (lambda (x) (if (listp x) (car x) x)) yanked))
 567                        (article (if (listp article) article (list article)))
 568                        (t nil))))
 569     (message-add-action
 570      `(when (gnus-buffer-exists-p ,buffer)
 571         (save-excursion
 572           (set-buffer ,buffer)
 573           ,(when to-be-marked
 574              (if (eq config 'forward)
 575                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 576                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 577      'send)))
 578
 579 (put 'gnus-setup-message 'lisp-indent-function 1)
 580 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 581
 582 ;;; Post news commands of Gnus group mode and summary mode
 583
 584 (defun gnus-group-mail (&optional arg)
 585   "Start composing a mail.
 586 If ARG, use the group under the point to find a posting style.
 587 If ARG is 1, prompt for a group name to find the posting style."
 588   (interactive "P")
 589   ;; We can't `let' gnus-newsgroup-name here, since that leads
 590   ;; to local variables leaking.
 591   (let ((group gnus-newsgroup-name)
 592         ;; make sure last viewed article doesn't affect posting styles:
 593         (gnus-article-copy)
 594         (buffer (current-buffer)))
 595     (unwind-protect
 596         (progn
 597           (setq gnus-newsgroup-name
 598                 (if arg
 599                     (if (= 1 (prefix-numeric-value arg))
 600                         (completing-read "Use posting style of group: "
 601                                          gnus-active-hashtb nil
 602                                          (gnus-read-active-file-p))
 603                       (gnus-group-group-name))
 604                   ""))
 605           ;; #### see comment in gnus-setup-message -- drv
 606           (gnus-setup-message 'message (message-mail)))
 607       (save-excursion
 608         (set-buffer buffer)
 609         (setq gnus-newsgroup-name group)))))
 610
 611 (defun gnus-group-news (&optional arg)
 612   "Start composing a news.
 613 If ARG, post to group under point.
 614 If ARG is 1, prompt for group name to post to.
 615
 616 This function prepares a news even when using mail groups.  This is useful
 617 for posting messages to mail groups without actually sending them over the
 618 network.  The corresponding back end must have a 'request-post method."
 619   (interactive "P")
 620   ;; We can't `let' gnus-newsgroup-name here, since that leads
 621   ;; to local variables leaking.
 622   (let ((group gnus-newsgroup-name)
 623         ;; make sure last viewed article doesn't affect posting styles:
 624         (gnus-article-copy)
 625         (buffer (current-buffer)))
 626     (unwind-protect
 627         (progn
 628           (setq gnus-newsgroup-name
 629                 (if arg
 630                     (if (= 1 (prefix-numeric-value arg))
 631                         (completing-read "Use group: "
 632                                          gnus-active-hashtb nil
 633                                          (gnus-read-active-file-p))
 634                       (gnus-group-group-name))
 635                   ""))
 636           ;; #### see comment in gnus-setup-message -- drv
 637           (gnus-setup-message 'message
 638             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 639       (save-excursion
 640         (set-buffer buffer)
 641         (setq gnus-newsgroup-name group)))))
 642
 643 (defun gnus-group-post-news (&optional arg)
 644   "Start composing a message (a news by default).
 645 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 646 Depending on the selected group, the message might be either a mail or
 647 a news."
 648   (interactive "P")
 649   ;; Bind this variable here to make message mode hooks work ok.
 650   (let ((gnus-newsgroup-name
 651          (if arg
 652              (if (= 1 (prefix-numeric-value arg))
 653                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 654                                   (gnus-read-active-file-p))
 655                (gnus-group-group-name))
 656            ""))
 657         ;; make sure last viewed article doesn't affect posting styles:
 658         (gnus-article-copy))
 659     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 660                     (string= gnus-newsgroup-name ""))))
 661
 662 (defun gnus-summary-mail-other-window (&optional arg)
 663   "Start composing a mail in another window.
 664 Use the posting of the current group by default.
 665 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 666 posting style."
 667   (interactive "P")
 668   ;; We can't `let' gnus-newsgroup-name here, since that leads
 669   ;; to local variables leaking.
 670   (let ((group gnus-newsgroup-name)
 671         ;; make sure last viewed article doesn't affect posting styles:
 672         (gnus-article-copy)
 673         (buffer (current-buffer)))
 674     (unwind-protect
 675         (progn
 676           (setq gnus-newsgroup-name
 677                 (if arg
 678                     (if (= 1 (prefix-numeric-value arg))
 679                         (completing-read "Use group: "
 680                                          gnus-active-hashtb nil
 681                                          (gnus-read-active-file-p))
 682                       "")
 683                   gnus-newsgroup-name))
 684           ;; #### see comment in gnus-setup-message -- drv
 685           (gnus-setup-message 'message (message-mail)))
 686       (save-excursion
 687         (set-buffer buffer)
 688         (setq gnus-newsgroup-name group)))))
 689
 690 (defun gnus-summary-news-other-window (&optional arg)
 691   "Start composing a news in another window.
 692 Post to the current group by default.
 693 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 694
 695 This function prepares a news even when using mail groups.  This is useful
 696 for posting messages to mail groups without actually sending them over the
 697 network.  The corresponding back end must have a 'request-post method."
 698   (interactive "P")
 699   ;; We can't `let' gnus-newsgroup-name here, since that leads
 700   ;; to local variables leaking.
 701   (let ((group gnus-newsgroup-name)
 702         ;; make sure last viewed article doesn't affect posting styles:
 703         (gnus-article-copy)
 704         (buffer (current-buffer)))
 705     (unwind-protect
 706         (progn
 707           (setq gnus-newsgroup-name
 708                 (if arg
 709                     (if (= 1 (prefix-numeric-value arg))
 710                         (completing-read "Use group: "
 711                                          gnus-active-hashtb nil
 712                                          (gnus-read-active-file-p))
 713                       "")
 714                   gnus-newsgroup-name))
 715           ;; #### see comment in gnus-setup-message -- drv
 716           (gnus-setup-message 'message
 717             (progn
 718               (message-news (gnus-group-real-name gnus-newsgroup-name))
 719               (set (make-local-variable 'gnus-discouraged-post-methods)
 720                    (remove
 721                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 722                     gnus-discouraged-post-methods)))))
 723       (save-excursion
 724         (set-buffer buffer)
 725         (setq gnus-newsgroup-name group)))))
 726
 727 (defun gnus-summary-post-news (&optional arg)
 728   "Start composing a message.  Post to the current group by default.
 729 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 730 Depending on the selected group, the message might be either a mail or
 731 a news."
 732   (interactive "P")
 733   ;; Bind this variable here to make message mode hooks work ok.
 734   (let ((gnus-newsgroup-name
 735          (if arg
 736              (if (= 1 (prefix-numeric-value arg))
 737                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 738                                   (gnus-read-active-file-p))
 739                "")
 740            gnus-newsgroup-name))
 741         ;; make sure last viewed article doesn't affect posting styles:
 742         (gnus-article-copy))
 743     (gnus-post-news 'post gnus-newsgroup-name)))
 744
 745
 746 (defun gnus-summary-followup (yank &optional force-news)
 747   "Compose a followup to an article.
 748 If prefix argument YANK is non-nil, the original article is yanked
 749 automatically.
 750 YANK is a list of elements, where the car of each element is the
 751 article number, and the cdr is the string to be yanked."
 752   (interactive
 753    (list (and current-prefix-arg
 754               (gnus-summary-work-articles 1))))
 755   (when yank
 756     (gnus-summary-goto-subject
 757      (if (listp (car yank))
 758          (caar yank)
 759        (car yank))))
 760   (save-window-excursion
 761     (gnus-summary-select-article))
 762   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 763         (gnus-newsgroup-name gnus-newsgroup-name))
 764     ;; Send a followup.
 765     (gnus-post-news nil gnus-newsgroup-name
 766                     headers gnus-article-buffer
 767                     yank nil force-news)
 768     (gnus-summary-handle-replysign)))
 769
 770 (defun gnus-summary-followup-with-original (n &optional force-news)
 771   "Compose a followup to an article and include the original article.
 772 The text in the region will be yanked.  If the region isn't
 773 active, the entire article will be yanked."
 774   (interactive "P")
 775   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 776
 777 (defun gnus-summary-followup-to-mail (&optional arg)
 778   "Followup to the current mail message via news."
 779   (interactive
 780    (list (and current-prefix-arg
 781               (gnus-summary-work-articles 1))))
 782   (gnus-summary-followup arg t))
 783
 784 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 785   "Followup to the current mail message via news."
 786   (interactive "P")
 787   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 788
 789 (defun gnus-inews-yank-articles (articles)
 790   (let (beg article yank-string
 791             (more-than-one (cdr articles))
 792             (cur (current-buffer))
 793             refs window)
 794     (message-goto-body)
 795     (while (setq article (pop articles))
 796       (when (listp article)
 797         (setq yank-string (nth 1 article)
 798               article (nth 0 article)))
 799       (save-window-excursion
 800         (set-buffer gnus-summary-buffer)
 801         (gnus-summary-select-article nil nil nil article)
 802         (gnus-summary-remove-process-mark article))
 803
 804       ;; Gathering references.
 805       (when more-than-one
 806         (setq refs (message-list-references
 807                     refs
 808                     (mail-header-references gnus-current-headers)
 809                     (mail-header-message-id gnus-current-headers)))
 810         (when message-use-multi-frames
 811           (when (setq window (get-buffer-window cur t))
 812             (select-frame (window-frame window)))))
 813
 814       (gnus-copy-article-buffer nil yank-string)
 815       (let ((message-reply-buffer gnus-article-copy)
 816             (message-reply-headers
 817              ;; The headers are decoded.
 818              (with-current-buffer gnus-article-copy
 819                (save-restriction
 820                  (nnheader-narrow-to-headers)
 821                  (nnheader-parse-naked-head)))))
 822         (message-yank-original)
 823         (setq beg (or beg (mark t))))
 824       (when articles
 825         (insert "\n")))
 826     (push-mark)
 827
 828     ;; Replace with the gathered references.
 829     (when refs
 830       (push-mark beg)
 831       (save-restriction
 832         (message-narrow-to-headers)
 833         (let ((case-fold-search t))
 834           (if (re-search-forward "^References:\\([\t ]+.+\n\\)+" nil t)
 835               (replace-match "")
 836             (goto-char (point-max))))
 837         (mail-header-format
 838          (list (or (assq 'References message-header-format-alist)
 839                    '(References . message-shorten-references)))
 840          (list (cons 'References
 841                      (mapconcat 'identity (nreverse refs) " ")))))
 842       (setq beg (mark t))
 843       (pop-mark))
 844
 845     (goto-char beg)))
 846
 847 (defun gnus-summary-cancel-article (&optional n symp)
 848   "Cancel an article you posted.
 849 Uses the process-prefix convention.  If given the symbolic
 850 prefix `a', cancel using the standard posting method; if not
 851 post using the current select method."
 852   (interactive (gnus-interactive "P\ny"))
 853   (let ((message-post-method
 854          `(lambda (arg)
 855             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name))))
 856     (dolist (article (gnus-summary-work-articles n))
 857       (when (gnus-summary-select-article t nil nil article)
 858         (when (gnus-eval-in-buffer-window gnus-article-buffer
 859                 (save-excursion
 860                   (set-buffer gnus-original-article-buffer)
 861                   (message-cancel-news)))
 862           (gnus-summary-mark-as-read article gnus-canceled-mark)
 863           (gnus-cache-remove-article 1))
 864         (gnus-article-hide-headers-if-wanted))
 865       (gnus-summary-remove-process-mark article))))
 866
 867 (defun gnus-summary-supersede-article ()
 868   "Compose an article that will supersede a previous article.
 869 This is done simply by taking the old article and adding a Supersedes
 870 header line with the old Message-ID."
 871   (interactive)
 872   (let ((article (gnus-summary-article-number)))
 873     (gnus-setup-message 'reply-yank
 874       (gnus-summary-select-article t)
 875       (set-buffer gnus-original-article-buffer)
 876       (message-supersede)
 877       (push
 878        `((lambda ()
 879            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 880              (save-excursion
 881                (set-buffer ,gnus-summary-buffer)
 882                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 883                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 884        message-send-actions))))
 885
 886 \f
 887
 888 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 889   ;; make a copy of the article buffer with all text properties removed
 890   ;; this copy is in the buffer gnus-article-copy.
 891   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 892   ;; this buffer should be passed to all mail/news reply/post routines.
 893   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 894   (save-excursion
 895     (set-buffer gnus-article-copy)
 896     (set-buffer-multibyte t))
 897   (let ((article-buffer (or article-buffer gnus-article-buffer))
 898         end beg)
 899     (if (not (and (get-buffer article-buffer)
 900                   (gnus-buffer-exists-p article-buffer)))
 901         (error "Can't find any article buffer")
 902       (save-excursion
 903         (set-buffer article-buffer)
 904         (let ((gnus-newsgroup-charset (or gnus-article-charset
 905                                           gnus-newsgroup-charset))
 906               (gnus-newsgroup-ignored-charsets
 907                (or gnus-article-ignored-charsets
 908                    gnus-newsgroup-ignored-charsets)))
 909           (save-restriction
 910             ;; Copy over the (displayed) article buffer, delete
 911             ;; hidden text and remove text properties.
 912             (widen)
 913             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 914             (set-buffer gnus-article-copy)
 915             ;; There's invisible and intangible text in T-gnus.  Especially,
 916             ;; if there is a boundary line (X-Boundary: ------------------),
 917             ;; in the end of a header, it will cause a serious problem.
 918             (add-text-properties (point-min) (point-max)
 919                                  '(invisible nil intangible nil))
 920             (when yank-string
 921               (message-goto-body)
 922               (delete-region (point) (point-max))
 923               (insert yank-string))
 924             ;; Encode bitmap smileys to ordinary text.
 925             ;; Possibly, the original text might be restored.
 926             (static-unless (featurep 'xemacs)
 927               (when (featurep 'smiley-mule)
 928                 (smiley-encode-buffer)))
 929             (gnus-article-delete-text-of-type 'annotation)
 930             (gnus-remove-text-with-property 'gnus-prev)
 931             (gnus-remove-text-with-property 'gnus-next)
 932             (gnus-remove-text-with-property 'gnus-decoration)
 933             (gnus-remove-text-with-property 'x-face-mule-bitmap-image)
 934             (insert
 935              (prog1
 936                  (static-if (featurep 'xemacs)
 937                      ;; Revome smiley extents for (possibly) XEmacs 21.1.
 938                      (format "%s"
 939                              (buffer-substring-no-properties (point-min)
 940                                                              (point-max)))
 941                    (buffer-substring-no-properties (point-min) (point-max)))
 942                (erase-buffer)))
 943             ;; Find the original headers.
 944             (set-buffer gnus-original-article-buffer)
 945             (goto-char (point-min))
 946             (while (looking-at message-unix-mail-delimiter)
 947               (forward-line 1))
 948             (let ((mail-header-separator ""))
 949               (setq beg (point)
 950                     end (or (message-goto-body)
 951                             ;; There may be just a header.
 952                             (point-max))))
 953             ;; Delete the headers from the displayed articles.
 954             (set-buffer gnus-article-copy)
 955             (let ((mail-header-separator ""))
 956               (delete-region (goto-char (point-min))
 957                              (or (message-goto-body) (point-max))))
 958             ;; Insert the original article headers.
 959             (insert-buffer-substring gnus-original-article-buffer beg end)
 960             ;; Decode charsets.
 961             (let ((gnus-article-decode-hook
 962                    (delq 'article-decode-charset
 963                          (copy-sequence gnus-article-decode-hook))))
 964               ;; Needed for T-gnus.
 965               (add-hook 'gnus-article-decode-hook
 966                         'article-decode-encoded-words)
 967               (run-hooks 'gnus-article-decode-hook)))))
 968       gnus-article-copy)))
 969
 970 (defun gnus-post-news (post &optional group header article-buffer yank subject
 971                             force-news)
 972   (when article-buffer
 973     (gnus-copy-article-buffer))
 974   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 975         (gnus-article-yanked-articles yank)
 976         (add-to-list gnus-add-to-list))
 977     (gnus-setup-message (cond (yank 'reply-yank)
 978                               (article-buffer 'reply)
 979                               (t 'message))
 980       (let* ((group (or group gnus-newsgroup-name))
 981              (charset (gnus-group-name-charset nil group))
 982              (pgroup group)
 983              to-address to-group mailing-list to-list
 984              newsgroup-p)
 985         (when group
 986           (setq to-address (gnus-parameter-to-address group)
 987                 to-group (gnus-group-find-parameter group 'to-group)
 988                 to-list (gnus-parameter-to-list group)
 989                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 990                 mailing-list (when gnus-mailing-list-groups
 991                                (string-match gnus-mailing-list-groups group))
 992                 group (gnus-group-name-decode (gnus-group-real-name group)
 993                                               charset)))
 994         (if (or (and to-group
 995                      (gnus-news-group-p to-group))
 996                 newsgroup-p
 997                 force-news
 998                 (and (gnus-news-group-p
 999                       (or pgroup gnus-newsgroup-name)
1000                       (or header gnus-current-article))
1001                      (not mailing-list)
1002                      (not to-list)
1003                      (not to-address)))
1004             ;; This is news.
1005             (if post
1006                 (message-news
1007                  (or to-group
1008                      (and (not (gnus-virtual-group-p pgroup)) group)))
1009               (set-buffer gnus-article-copy)
1010               (gnus-msg-treat-broken-reply-to)
1011               (message-followup (if (or newsgroup-p force-news)
1012                                     (if (save-restriction
1013                                           (article-narrow-to-head)
1014                                           (message-fetch-field "newsgroups"))
1015                                         nil
1016                                       "")
1017                                   to-group)))
1018           ;; The is mail.
1019           (if post
1020               (progn
1021                 (message-mail (or to-address to-list))
1022                 ;; Arrange for mail groups that have no `to-address' to
1023                 ;; get that when the user sends off the mail.
1024                 (when (and (not to-list)
1025                            (not to-address)
1026                            add-to-list)
1027                   (push (list 'gnus-inews-add-to-address pgroup)
1028                         message-send-actions)))
1029             (set-buffer gnus-article-copy)
1030             (gnus-msg-treat-broken-reply-to)
1031             (message-wide-reply to-address)))
1032         (when yank
1033           (gnus-inews-yank-articles yank))))))
1034
1035 (defun gnus-msg-treat-broken-reply-to (&optional force)
1036   "Remove the Reply-to header if broken-reply-to."
1037   (when (or force
1038             (gnus-group-find-parameter
1039              gnus-newsgroup-name 'broken-reply-to))
1040     (save-restriction
1041       (message-narrow-to-head)
1042       (message-remove-header "reply-to"))))
1043
1044 (defun gnus-post-method (arg group &optional silent)
1045   "Return the posting method based on GROUP and ARG.
1046 If SILENT, don't prompt the user."
1047   (let ((gnus-post-method (or (gnus-parameter-post-method group)
1048                               gnus-post-method))
1049         (group-method (gnus-find-method-for-group group)))
1050     (cond
1051      ;; If the group-method is nil (which shouldn't happen) we use
1052      ;; the default method.
1053      ((null group-method)
1054       (or (and (listp gnus-post-method) ;If not current/native/nil
1055                (not (listp (car gnus-post-method))) ; and not a list of methods
1056                gnus-post-method)        ;then use it.
1057           gnus-select-method
1058           message-post-method))
1059      ;; We want the inverse of the default
1060      ((and arg (not (eq arg 0)))
1061       (if (eq gnus-post-method 'current)
1062           gnus-select-method
1063         group-method))
1064      ;; We query the user for a post method.
1065      ((or arg
1066           (and (listp gnus-post-method)
1067                (listp (car gnus-post-method))))
1068       (let* ((methods
1069               ;; Collect all methods we know about.
1070               (append
1071                (when (listp gnus-post-method)
1072                  (if (listp (car gnus-post-method))
1073                      gnus-post-method
1074                    (list gnus-post-method)))
1075                gnus-secondary-select-methods
1076                (mapcar 'cdr gnus-server-alist)
1077                (mapcar 'car gnus-opened-servers)
1078                (list gnus-select-method)
1079                (list group-method)))
1080              method-alist post-methods method)
1081         ;; Weed out all mail methods.
1082         (while methods
1083           (setq method (gnus-server-get-method "" (pop methods)))
1084           (when (and (or (gnus-method-option-p method 'post)
1085                          (gnus-method-option-p method 'post-mail))
1086                      (not (member method post-methods)))
1087             (push method post-methods)))
1088         ;; Create a name-method alist.
1089         (setq method-alist
1090               (mapcar
1091                (lambda (m)
1092                  (if (equal (cadr m) "")
1093                      (list (symbol-name (car m)) m)
1094                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1095                post-methods))
1096         ;; Query the user.
1097         (cadr
1098          (assoc
1099           (setq gnus-last-posting-server
1100                 (if (and silent
1101                          gnus-last-posting-server)
1102                     ;; Just use the last value.
1103                     gnus-last-posting-server
1104                   (completing-read
1105                    "Posting method: " method-alist nil t
1106                    (cons (or gnus-last-posting-server "") 0))))
1107           method-alist))))
1108      ;; Override normal method.
1109      ((and (eq gnus-post-method 'current)
1110            (not (memq (car group-method) gnus-discouraged-post-methods))
1111            (gnus-get-function group-method 'request-post t))
1112       (assert (not arg))
1113       group-method)
1114      ;; Use gnus-post-method.
1115      ((listp gnus-post-method)          ;A method...
1116       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1117       gnus-post-method)
1118      ;; Use the normal select method (nil or native).
1119      (t gnus-select-method))))
1120
1121 \f
1122 (defun gnus-message-make-user-agent (&optional dummy max-column
1123                                                newline-product)
1124   "Return a user-agent info.  If MAX-COLUMN is specified, the return
1125 value will be folded up as it were filled.  NEWLINE-PRODUCT specifies
1126 whether a newline should be inserted in front of each product-token;
1127 if the value is t or `hard', it works strictly.  Otherwise, if it is
1128 non-nil (e.g. `soft'), it works semi-strictly."
1129   (let ((user-agent (gnus-extended-version)))
1130     (when max-column
1131       (unless (natnump max-column)
1132         (setq max-column 76))
1133       (with-temp-buffer
1134         (set-buffer-multibyte t)
1135         (insert (mapconcat 'identity (split-string user-agent) " "))
1136         (goto-char (point-min))
1137         (let ((bol t)
1138               start agent agents width element swidth)
1139           (while (re-search-forward "\\([^ ]+\\) ?" nil t)
1140             (setq start (match-beginning 0))
1141             (if (eq (char-after start) ?\()
1142                 (progn
1143                   (goto-char start)
1144                   (forward-list)
1145                   (push (buffer-substring start (point)) agent))
1146               (when agent
1147                 (push (nreverse agent) agents))
1148               (setq agent (list (match-string 1)))))
1149           (when agent
1150             (push (nreverse agent) agents))
1151           (setq agents (nreverse agents))
1152           (if (> (+ 12 (string-width (caar agents))) max-column)
1153               (setq user-agent "\n"
1154                     width 0)
1155             (setq user-agent ""
1156                   width 11))
1157           (while agents
1158             (setq agent (car agents)
1159                   agents (cdr agents))
1160             (when (and (not bol)
1161                        (or (memq newline-product '(t hard))
1162                            (and newline-product
1163                                 (> (+ width 1
1164                                       (string-width (mapconcat 'identity
1165                                                                agent " ")))
1166                                    max-column))))
1167               (setq user-agent (concat user-agent "\n")
1168                     width 0
1169                     bol t))
1170             (while agent
1171               (setq element (car agent)
1172                     swidth (string-width element)
1173                     agent (cdr agent))
1174               (if bol
1175                   (setq user-agent (if (member user-agent '("" "\n"))
1176                                        (concat user-agent element)
1177                                      (concat user-agent " " element))
1178                         width (+ width 1 swidth)
1179                         bol nil)
1180                 (if (> (+ width 1 swidth) max-column)
1181                     (setq user-agent (concat user-agent "\n " element)
1182                           width (1+ swidth))
1183                   (setq user-agent (concat user-agent " " element)
1184                         width (+ width 1 swidth)))))))))
1185     user-agent))
1186
1187 \f
1188 ;;;
1189 ;;; Gnus Mail Functions
1190 ;;;
1191
1192 ;;; Mail reply commands of Gnus summary mode
1193
1194 (defun gnus-summary-reply (&optional yank wide very-wide)
1195   "Start composing a mail reply to the current message.
1196 If prefix argument YANK is non-nil, the original article is yanked
1197 automatically.
1198 If WIDE, make a wide reply.
1199 If VERY-WIDE, make a very wide reply."
1200   (interactive
1201    (list (and current-prefix-arg
1202               (gnus-summary-work-articles 1))))
1203   ;; Allow user to require confirmation before replying by mail to the
1204   ;; author of a news article (or mail message).
1205   (when (or
1206             (not (or (gnus-news-group-p gnus-newsgroup-name)
1207                      gnus-confirm-treat-mail-like-news))
1208             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1209                         (string-match gnus-confirm-mail-reply-to-news
1210                                       gnus-newsgroup-name))
1211                        ((functionp gnus-confirm-mail-reply-to-news)
1212                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1213                        (t gnus-confirm-mail-reply-to-news)))
1214             (y-or-n-p "Really reply by mail to article author? "))
1215     (let* ((article
1216             (if (listp (car yank))
1217                 (caar yank)
1218               (car yank)))
1219            (gnus-article-reply (or article (gnus-summary-article-number)))
1220            (gnus-article-yanked-articles yank)
1221            (headers ""))
1222       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1223       (when yank
1224         (gnus-summary-goto-subject article))
1225       (gnus-setup-message (if yank 'reply-yank 'reply)
1226         (if (not very-wide)
1227             (gnus-summary-select-article)
1228           (dolist (article very-wide)
1229             (gnus-summary-select-article nil nil nil article)
1230             (save-excursion
1231               (set-buffer (gnus-copy-article-buffer))
1232               (gnus-msg-treat-broken-reply-to)
1233               (save-restriction
1234                 (message-narrow-to-head)
1235                 (setq headers (concat headers (buffer-string)))))))
1236         (set-buffer (gnus-copy-article-buffer))
1237         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1238         (save-restriction
1239           (message-narrow-to-head)
1240           (when very-wide
1241             (erase-buffer)
1242             (insert headers))
1243           (goto-char (point-max)))
1244         (message-reply nil wide)
1245         (when yank
1246           (gnus-inews-yank-articles yank))
1247         (gnus-summary-handle-replysign)))))
1248
1249 (defun gnus-summary-handle-replysign ()
1250   "Check the various replysign variables and take action accordingly."
1251   (when nil;;(or gnus-message-replysign gnus-message-replyencrypt)
1252     (let (signed encrypted)
1253       (save-excursion
1254         (set-buffer gnus-article-buffer)
1255         (setq signed (memq 'signed gnus-article-wash-types))
1256         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1257       (cond ((and gnus-message-replyencrypt encrypted)
1258              (mml-secure-message mml-default-encrypt-method
1259                                  (if gnus-message-replysignencrypted
1260                                      'signencrypt
1261                                    'encrypt)))
1262             ((and gnus-message-replysign signed)
1263              (mml-secure-message mml-default-sign-method 'sign))))))
1264
1265 (defun gnus-summary-reply-with-original (n &optional wide)
1266   "Start composing a reply mail to the current message.
1267 The original article will be yanked."
1268   (interactive "P")
1269   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1270
1271 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1272   "Like `gnus-summary-reply' except removing reply-to field.
1273 If prefix argument YANK is non-nil, the original article is yanked
1274 automatically.
1275 If WIDE, make a wide reply.
1276 If VERY-WIDE, make a very wide reply."
1277   (interactive
1278    (list (and current-prefix-arg
1279               (gnus-summary-work-articles 1))))
1280   (let ((gnus-msg-force-broken-reply-to t))
1281     (gnus-summary-reply yank wide very-wide)))
1282
1283 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1284   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1285 The original article will be yanked."
1286   (interactive "P")
1287   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1288
1289 (defun gnus-summary-wide-reply (&optional yank)
1290   "Start composing a wide reply mail to the current message.
1291 If prefix argument YANK is non-nil, the original article is yanked
1292 automatically."
1293   (interactive
1294    (list (and current-prefix-arg
1295               (gnus-summary-work-articles 1))))
1296   (gnus-summary-reply yank t))
1297
1298 (defun gnus-summary-wide-reply-with-original (n)
1299   "Start composing a wide reply mail to the current message.
1300 The original article will be yanked.
1301 Uses the process/prefix convention."
1302   (interactive "P")
1303   (gnus-summary-reply-with-original n t))
1304
1305 (defun gnus-summary-very-wide-reply (&optional yank)
1306   "Start composing a very wide reply mail to the current message.
1307 If prefix argument YANK is non-nil, the original article is yanked
1308 automatically."
1309   (interactive
1310    (list (and current-prefix-arg
1311               (gnus-summary-work-articles 1))))
1312   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1313
1314 (defun gnus-summary-very-wide-reply-with-original (n)
1315   "Start composing a very wide reply mail to the current message.
1316 The original article will be yanked."
1317   (interactive "P")
1318   (gnus-summary-reply
1319    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1320
1321 (defun gnus-summary-mail-forward (&optional full-headers post)
1322   "Forward the current message(s) to another user.
1323 If process marks exist, forward all marked messages;
1324 If FULL-HEADERS (the prefix), include full headers when forwarding.
1325
1326 Note that this function definition for T-gnus is totally different
1327 from the original Gnus."
1328   (interactive "P")
1329   (if (cdr (gnus-summary-work-articles nil))
1330       ;; Process marks are given.
1331       (gnus-summary-digest-mail-forward nil post)
1332     ;; No process marks.
1333     (let* ((gnus-article-reply (gnus-summary-article-number))
1334            (gnus-article-yanked-articles (list gnus-article-reply))
1335            charset
1336            (message-included-forward-headers
1337             (if full-headers "" message-included-forward-headers)))
1338       (gnus-setup-message 'forward
1339         (gnus-summary-select-article)
1340         (setq charset default-mime-charset)
1341         (set-buffer gnus-original-article-buffer)
1342         (make-local-variable 'default-mime-charset)
1343         (setq default-mime-charset charset)
1344         (message-forward post)))))
1345
1346 (defun gnus-summary-digest-mail-forward (&optional n post)
1347   "Digests and forwards all articles in this series.
1348 If N is a positive number, forward the N next articles.
1349 If N is a negative number, forward the N previous articles.
1350 If N is nil and any articles have been marked with the process mark,
1351 forward those articles instead.
1352 Optional POST will use news to forward instead of mail."
1353   (interactive "P")
1354   (let* ((articles (gnus-summary-work-articles n))
1355          (gnus-article-yanked-articles (copy-sequence articles))
1356          (topics "Topics:\n")
1357          subject article frame)
1358     (when (car articles)
1359       (gnus-setup-message 'forward
1360         (gnus-summary-select-article)
1361         (if (cdr articles)
1362             (setq articles (sort articles '<)
1363                   subject "Digested Articles")
1364           (with-current-buffer gnus-original-article-buffer
1365             (setq subject (message-make-forward-subject))))
1366         (if post
1367             (message-news nil subject)
1368           (message-mail nil subject))
1369         (when (and message-use-multi-frames (cdr articles))
1370           (setq frame (window-frame (get-buffer-window (current-buffer)))))
1371         (message-goto-body)
1372         (while (setq article (pop articles))
1373           (save-window-excursion
1374             (set-buffer gnus-summary-buffer)
1375             (gnus-summary-select-article nil nil nil article)
1376             (setq topics (concat topics "    "
1377                                  (mail-header-subject gnus-current-headers)
1378                                  "\n"))
1379             (gnus-summary-remove-process-mark article))
1380           (when frame
1381             (select-frame frame))
1382           (insert (mime-make-tag "message" "rfc822") "\n")
1383           (narrow-to-region (point) (point))
1384           (insert-buffer-substring gnus-original-article-buffer)
1385           (save-restriction
1386             (article-narrow-to-head)
1387             (message-remove-header message-included-forward-headers t nil t))
1388           (goto-char (point-max))
1389           (widen))
1390         (push-mark)
1391         (message-goto-body)
1392         (insert topics)
1393         (message-goto-body)
1394         (mime-edit-enclose-digest-region (point)(mark t))))))
1395
1396 (defun gnus-summary-digest-post-forward (&optional n)
1397   "Digest and forwards all articles in this series to a newsgroup.
1398 If N is a positive number, forward the N next articles.
1399 If N is a negative number, forward the N previous articles.
1400 If N is nil and any articles have been marked with the process mark,
1401 forward those articles instead."
1402   (interactive "P")
1403   (gnus-summary-digest-mail-forward n t))
1404
1405 (defun gnus-summary-resend-message (address n)
1406   "Resend the current article to ADDRESS."
1407   (interactive
1408    (list (message-read-from-minibuffer
1409           "Resend message(s) to: "
1410           (when (and gnus-summary-resend-default-address
1411                      (gnus-buffer-live-p gnus-original-article-buffer))
1412             ;; If some other article is currently selected, the
1413             ;; initial-contents is wrong. Whatever, it is just the
1414             ;; initial-contents.
1415             (with-current-buffer gnus-original-article-buffer
1416               (nnmail-fetch-field "to"))))
1417          current-prefix-arg))
1418   (dolist (article (gnus-summary-work-articles n))
1419     (gnus-summary-select-article nil nil nil article)
1420     (save-excursion
1421       (set-buffer gnus-original-article-buffer)
1422       (message-resend address))
1423     (gnus-summary-mark-article-as-forwarded article)))
1424
1425 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1426 (defun gnus-summary-resend-message-edit ()
1427   "Resend an article that has already been sent.
1428 A new buffer will be created to allow the user to modify body and
1429 contents of the message, and then, everything will happen as when
1430 composing a new message."
1431   (interactive)
1432   (let ((article (gnus-summary-article-number)))
1433     (gnus-setup-message 'reply-yank
1434       (gnus-summary-select-article t)
1435       (set-buffer gnus-original-article-buffer)
1436       (let ((cur (current-buffer))
1437             (to (message-fetch-field "to")))
1438         ;; Get a normal message buffer.
1439         (message-pop-to-buffer (message-buffer-name "Resend" to))
1440         (insert-buffer-substring cur)
1441
1442         ;; T-gnus change: Use MIME-Edit to recompose a message.
1443         ;;(mime-to-mml)
1444         (let ((ofn (symbol-function 'mime-edit-decode-single-part-in-buffer)))
1445           (fset 'mime-edit-decode-single-part-in-buffer
1446                 (lambda (&rest args)
1447                   (if (let ((content-type (car args)))
1448                         (and (eq 'message (mime-content-type-primary-type
1449                                            content-type))
1450                              (eq 'rfc822 (mime-content-type-subtype
1451                                           content-type))))
1452                       (setcar (cdr args) 'not-decode-text))
1453                   (apply ofn args)))
1454           (unwind-protect
1455               (mime-edit-again nil t)
1456             (fset 'mime-edit-decode-single-part-in-buffer ofn)))
1457         (message-narrow-to-head-1)
1458         (insert "From: " (message-make-from) "\n")
1459         (while (re-search-forward "^From:" nil t)
1460           (beginning-of-line)
1461           (insert "Original-"))
1462         (message-remove-header "^>From[\t ]" t)
1463
1464         ;; Gnus will generate a new one when sending.
1465         (message-remove-header "Message-ID")
1466         (message-remove-header message-ignored-resent-headers t)
1467         ;; Remove unwanted headers.
1468         (goto-char (point-max))
1469         (insert mail-header-separator)
1470         (goto-char (point-min))
1471         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1472           (forward-char 1))
1473         (widen)))))
1474
1475 (defun gnus-summary-post-forward (&optional full-headers)
1476   "Forward the current article to a newsgroup.
1477 If FULL-HEADERS (the prefix), include full headers when forwarding."
1478   (interactive "P")
1479   (gnus-summary-mail-forward full-headers t))
1480
1481 (defvar gnus-nastygram-message
1482   "The following article was inappropriately posted to %s.\n\n"
1483   "Format string to insert in nastygrams.
1484 The current group name will be inserted at \"%s\".")
1485
1486 (defun gnus-summary-mail-nastygram (n)
1487   "Send a nastygram to the author of the current article."
1488   (interactive "P")
1489   (when (or gnus-expert-user
1490             (gnus-y-or-n-p
1491              "Really send a nastygram to the author of the current article? "))
1492     (let ((group gnus-newsgroup-name))
1493       (gnus-summary-reply-with-original n)
1494       (set-buffer gnus-message-buffer)
1495       (message-goto-body)
1496       (insert (format gnus-nastygram-message group))
1497       (message-send-and-exit))))
1498
1499 (defun gnus-summary-mail-crosspost-complaint (n)
1500   "Send a complaint about crossposting to the current article(s)."
1501   (interactive "P")
1502   (dolist (article (gnus-summary-work-articles n))
1503     (set-buffer gnus-summary-buffer)
1504     (gnus-summary-goto-subject article)
1505     (let ((group (gnus-group-real-name gnus-newsgroup-name))
1506           newsgroups followup-to)
1507       (gnus-summary-select-article)
1508       (set-buffer gnus-original-article-buffer)
1509       (if (and (<= (length (message-tokenize-header
1510                             (setq newsgroups
1511                                   (mail-fetch-field "newsgroups"))
1512                             ", "))
1513                    1)
1514                (or (not (setq followup-to (mail-fetch-field "followup-to")))
1515                    (not (member group (message-tokenize-header
1516                                        followup-to ", ")))))
1517           (if followup-to
1518               (gnus-message 1 "Followup-to restricted")
1519             (gnus-message 1 "Not a crossposted article"))
1520         (set-buffer gnus-summary-buffer)
1521         (gnus-summary-reply-with-original 1)
1522         (set-buffer gnus-message-buffer)
1523         (message-goto-body)
1524         (insert (format gnus-crosspost-complaint newsgroups group))
1525         (message-goto-subject)
1526         (re-search-forward " *$")
1527         (replace-match " (crosspost notification)" t t)
1528         (gnus-deactivate-mark)
1529         (when (gnus-y-or-n-p "Send this complaint? ")
1530           (message-send-and-exit))))))
1531
1532 (defun gnus-mail-parse-comma-list ()
1533   (let (accumulated
1534         beg)
1535     (skip-chars-forward " ")
1536     (while (not (eobp))
1537       (setq beg (point))
1538       (skip-chars-forward "^,")
1539       (while (zerop
1540               (save-excursion
1541                 (save-restriction
1542                   (let ((i 0))
1543                     (narrow-to-region beg (point))
1544                     (goto-char beg)
1545                     (logand (progn
1546                               (while (search-forward "\"" nil t)
1547                                 (incf i))
1548                               (if (zerop i) 2 i))
1549                             2)))))
1550         (skip-chars-forward ",")
1551         (skip-chars-forward "^,"))
1552       (skip-chars-backward " ")
1553       (push (buffer-substring beg (point))
1554             accumulated)
1555       (skip-chars-forward "^,")
1556       (skip-chars-forward ", "))
1557     accumulated))
1558
1559 (defun gnus-inews-add-to-address (group)
1560   (let ((to-address (mail-fetch-field "to")))
1561     (when (and to-address
1562                (gnus-alive-p))
1563       ;; This mail group doesn't have a `to-list', so we add one
1564       ;; here.  Magic!
1565       (when (gnus-y-or-n-p
1566              (format "Do you want to add this as `to-list': %s? " to-address))
1567         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1568
1569 (defun gnus-put-message ()
1570   "Put the current message in some group and return to Gnus."
1571   (interactive)
1572   (let ((reply gnus-article-reply)
1573         (winconf gnus-prev-winconf)
1574         (group gnus-newsgroup-name))
1575     (unless (and group
1576                  (not (gnus-group-read-only-p group)))
1577       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1578
1579     (when (gnus-group-entry group)
1580       (error "No such group: %s" group))
1581     (save-excursion
1582       (save-restriction
1583         (widen)
1584         (message-narrow-to-headers)
1585         (let ((gnus-deletable-headers nil))
1586           (message-generate-headers
1587            (if (message-news-p)
1588                message-required-news-headers
1589              message-required-mail-headers)))
1590         (goto-char (point-max))
1591         (if (string-match " " group)
1592             (insert "Gcc: \"" group "\"\n")
1593           (insert "Gcc: " group "\n"))
1594         (widen)))
1595     (gnus-inews-do-gcc)
1596     (when (and (get-buffer gnus-group-buffer)
1597                (gnus-buffer-exists-p (car-safe reply))
1598                (cdr reply))
1599       (set-buffer (car reply))
1600       (gnus-summary-mark-article-as-replied (cdr reply)))
1601     (when winconf
1602       (set-window-configuration winconf))))
1603
1604 (defun gnus-article-mail (yank)
1605   "Send a reply to the address near point.
1606 If YANK is non-nil, include the original article."
1607   (interactive "P")
1608   (let ((address
1609          (buffer-substring
1610           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1611           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1612     (when address
1613       (gnus-msg-mail address)
1614       (when yank
1615         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1616
1617 (defvar nntp-server-type)
1618 (defun gnus-bug ()
1619   "Send a bug report to the Gnus maintainers."
1620   (interactive)
1621   (unless (gnus-alive-p)
1622     (error "Gnus has been shut down"))
1623   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1624     (unless (message-mail-user-agent)
1625       (message-pop-to-buffer "*Gnus Bug*")
1626       (delete-other-windows)
1627       (when gnus-bug-create-help-buffer
1628         (switch-to-buffer "*Gnus Help Bug*")
1629         (erase-buffer)
1630         (insert gnus-bug-message)
1631         (goto-char (point-min))
1632         (sit-for 0)
1633         (set-buffer "*Gnus Bug*")))
1634     (let ((message-this-is-mail t))
1635       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1636     (when gnus-bug-create-help-buffer
1637       (push `(gnus-bug-kill-buffer) message-send-actions))
1638     (goto-char (point-min))
1639     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1640     (forward-line 1)
1641     (insert gnus-product-name " " gnus-version-number
1642             " (r" gnus-revision-number ") "
1643             "based on " gnus-original-product-name " v"
1644             gnus-original-version-number "\n"
1645             (emacs-version) "\n")
1646     (when (and (boundp 'nntp-server-type)
1647                (stringp nntp-server-type))
1648       (insert nntp-server-type))
1649     (insert "\n\n\n\n\n")
1650     (let (mime-content-types)
1651       (mime-edit-insert-tag
1652        "application" "emacs-lisp"
1653        "\nContent-Disposition: inline\nContent-Description: User settings"))
1654     (insert (with-temp-buffer
1655               (gnus-debug)
1656               (buffer-string)))
1657     (let (mime-content-types)
1658       (mime-edit-insert-tag "text" "plain"))
1659     (goto-char (point-min))
1660     (search-forward "Subject: " nil t)
1661     (message "")))
1662
1663 (defun gnus-bug-kill-buffer ()
1664   (when (get-buffer "*Gnus Help Bug*")
1665     (kill-buffer "*Gnus Help Bug*")))
1666
1667 (defun gnus-summary-yank-message (buffer n)
1668   "Yank the current article into a composed message."
1669   (interactive
1670    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1671          current-prefix-arg))
1672   (when (gnus-buffer-live-p buffer)
1673     (let ((summary-frame (selected-frame))
1674           (message-frame (when (static-if (featurep 'xemacs)
1675                                    (device-on-window-system-p)
1676                                  window-system)
1677                            (let ((window (get-buffer-window buffer t)))
1678                              (when window
1679                                (window-frame window)))))
1680           (separator (concat "^" (regexp-quote mail-header-separator)
1681                              "\n")))
1682       (gnus-summary-iterate n
1683         (gnus-summary-select-article)
1684         (gnus-copy-article-buffer)
1685         (when (frame-live-p message-frame)
1686           (raise-frame message-frame)
1687           (select-frame message-frame))
1688         (with-current-buffer buffer
1689           (when (save-excursion
1690                   (beginning-of-line)
1691                   (let (case-fold-search)
1692                     (and (not (re-search-backward separator nil t))
1693                          (re-search-forward separator nil t))))
1694             (goto-char (match-end 0)))
1695           (message-yank-buffer gnus-article-copy))
1696         (select-frame summary-frame))
1697       (when (frame-live-p message-frame)
1698         (select-frame message-frame)))))
1699
1700 (defun gnus-debug ()
1701   "Attempts to go through the Gnus source file and report what variables have been changed.
1702 The source file has to be in the Emacs load path."
1703   (interactive)
1704   (let ((files gnus-debug-files)
1705         (point (point))
1706         file expr olist sym)
1707     (gnus-message 4 "Please wait while we snoop your variables...")
1708     ;; Go through all the files looking for non-default values for variables.
1709     (save-excursion
1710       (sit-for 0)
1711       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1712       (while files
1713         (erase-buffer)
1714         (when (and (setq file (locate-library (pop files)))
1715                    (file-exists-p file))
1716           (insert-file-contents file)
1717           (goto-char (point-min))
1718           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1719               (gnus-message 4 "Malformed sources in file %s" file)
1720             (narrow-to-region (point-min) (point))
1721             (goto-char (point-min))
1722             (while (setq expr (ignore-errors (read (current-buffer))))
1723               (ignore-errors
1724                 (and (memq (car expr) '(defvar defcustom defvoo))
1725                      (stringp (nth 3 expr))
1726                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1727                      (or (not (boundp (nth 1 expr)))
1728                          (not (equal (eval (nth 2 expr))
1729                                      (symbol-value (nth 1 expr)))))
1730                      (push (nth 1 expr) olist)))))))
1731       (kill-buffer (current-buffer)))
1732     (when (setq olist (nreverse olist))
1733       (insert ";----------------- Environment follows ------------------\n\n"))
1734     (while olist
1735       (if (boundp (car olist))
1736           (ignore-errors
1737            (gnus-pp
1738             `(setq ,(car olist)
1739                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1740                             (and (symbolp sym)
1741                                  (not (or (eq sym nil)
1742                                           (eq sym t)))))
1743                         (list 'quote (symbol-value (car olist)))
1744                       (symbol-value (car olist))))))
1745         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1746       (setq olist (cdr olist)))
1747     ;; Remove any control chars - they seem to cause trouble for some
1748     ;; mailers.  (Byte-compiled output from the stuff above.)
1749     (goto-char point)
1750     (while (re-search-forward (string-as-multibyte
1751                                "[\000-\010\013-\037\200-\237]") nil t)
1752       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1753                      t t))
1754     ;; Break MIME tags purposely.
1755     (goto-char point)
1756     (while (re-search-forward mime-edit-tag-regexp nil t)
1757       (goto-char (1+ (match-beginning 0)))
1758       (insert "X"))))
1759
1760 ;;; Treatment of rejected articles.
1761 ;;; Bounced mail.
1762
1763 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1764   "Re-mail the current message.
1765 This only makes sense if the current message is a bounce message that
1766 contains some mail you have written which has been bounced back to
1767 you.
1768 If FETCH, try to fetch the article that this is a reply to, if indeed
1769 this is a reply."
1770   (interactive "P")
1771   (gnus-summary-select-article t)
1772   (set-buffer gnus-original-article-buffer)
1773   (gnus-setup-message 'compose-bounce
1774     (let* ((references (mail-fetch-field "references"))
1775            (parent (and references (gnus-parent-id references))))
1776       (message-bounce)
1777       ;; If there are references, we fetch the article we answered to.
1778       (and fetch parent
1779            (gnus-summary-refer-article parent)
1780            (gnus-summary-show-all-headers)))))
1781
1782 ;;; Gcc handling.
1783
1784 (defun gnus-inews-group-method (group)
1785   (cond
1786    ;; If the group doesn't exist, we assume
1787    ;; it's an archive group...
1788    ((and (null (gnus-get-info group))
1789          (eq (car (gnus-server-to-method gnus-message-archive-method))
1790              (car (gnus-server-to-method (gnus-group-method group)))))
1791     gnus-message-archive-method)
1792    ;; Use the method.
1793    ((gnus-info-method (gnus-get-info group))
1794     (gnus-info-method (gnus-get-info group)))
1795    ;; Find the method.
1796    (t (gnus-server-to-method (gnus-group-method group)))))
1797
1798 ;; Do Gcc handling, which copied the message over to some group.
1799 (defun gnus-inews-do-gcc (&optional gcc)
1800   (interactive)
1801   (save-excursion
1802     (save-restriction
1803       (message-narrow-to-headers)
1804       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1805             (coding-system-for-write 'raw-text)
1806             groups group method group-art
1807             mml-externalize-attachments)
1808         (when gcc
1809           (message-remove-header "gcc")
1810           (widen)
1811           (setq groups (message-unquote-tokens
1812                         (message-tokenize-header gcc " ,")))
1813           ;; Copy the article over to some group(s).
1814           (while (setq group (pop groups))
1815             (unless (gnus-check-server
1816                      (setq method (gnus-inews-group-method group)))
1817               (error "Can't open server %s" (if (stringp method) method
1818                                               (car method))))
1819             (unless (gnus-request-group group nil method)
1820               (gnus-request-create-group group method))
1821             (setq mml-externalize-attachments
1822                   (if (stringp gnus-gcc-externalize-attachments)
1823                       (string-match gnus-gcc-externalize-attachments group)
1824                     gnus-gcc-externalize-attachments))
1825             (save-excursion
1826               (nnheader-set-temp-buffer " *acc*")
1827               (insert-buffer-substring message-encoding-buffer)
1828               (gnus-run-hooks 'gnus-before-do-gcc-hook)
1829               (goto-char (point-min))
1830               (when (re-search-forward
1831                      (concat "^" (regexp-quote mail-header-separator) "$")
1832                      nil t)
1833                 (replace-match "" t t ))
1834               (when (or (not (gnus-check-backend-function
1835                               'request-accept-article group))
1836                         (not (setq group-art
1837                                    (gnus-request-accept-article
1838                                     group method t t))))
1839                 (gnus-message 1 "Couldn't store article in group %s: %s"
1840                               group (gnus-status-message method)))
1841               (when (and group-art
1842                          ;; FIXME: Should gcc-mark-as-read work when
1843                          ;; Gnus is not running?
1844                          (gnus-alive-p)
1845                          (or gnus-gcc-mark-as-read
1846                              (and
1847                               (boundp 'gnus-inews-mark-gcc-as-read)
1848                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1849                 (gnus-group-mark-article-read group (cdr group-art)))
1850               (kill-buffer (current-buffer)))))))))
1851
1852 (defun gnus-inews-insert-gcc ()
1853   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1854   (save-excursion
1855     (save-restriction
1856       (message-narrow-to-headers)
1857       (let* ((group gnus-outgoing-message-group)
1858              (gcc (cond
1859                    ((functionp group)
1860                     (funcall group))
1861                    ((or (stringp group) (list group))
1862                     group))))
1863         (when gcc
1864           (insert "Gcc: "
1865                   (if (stringp gcc)
1866                       (if (string-match " " gcc)
1867                           (concat "\"" gcc "\"")
1868                         gcc)
1869                     (mapconcat (lambda (group)
1870                                  (if (string-match " " group)
1871                                      (concat "\"" group "\"")
1872                                    group))
1873                                gcc " "))
1874                   "\n"))))))
1875
1876 (defun gnus-inews-insert-archive-gcc (&optional group)
1877   "Insert the Gcc to say where the article is to be archived."
1878   (let* ((var gnus-message-archive-group)
1879          (group (or group gnus-newsgroup-name ""))
1880          (gcc-self-val
1881           (and gnus-newsgroup-name
1882                (not (equal gnus-newsgroup-name ""))
1883                (gnus-group-find-parameter
1884                 gnus-newsgroup-name 'gcc-self)))
1885          result
1886          (groups
1887           (cond
1888            ((null gnus-message-archive-method)
1889             ;; Ignore.
1890             nil)
1891            ((stringp var)
1892             ;; Just a single group.
1893             (list var))
1894            ((null var)
1895             ;; We don't want this.
1896             nil)
1897            ((and (listp var) (stringp (car var)))
1898             ;; A list of groups.
1899             var)
1900            ((functionp var)
1901             ;; A function.
1902             (funcall var group))
1903            (t
1904             ;; An alist of regexps/functions/forms.
1905             (while (and var
1906                         (not
1907                          (setq result
1908                                (cond
1909                                 ((stringp (caar var))
1910                                  ;; Regexp.
1911                                  (when (string-match (caar var) group)
1912                                    (cdar var)))
1913                                 ((functionp (car var))
1914                                  ;; Function.
1915                                  (funcall (car var) group))
1916                                 (t
1917                                  (eval (car var)))))))
1918               (setq var (cdr var)))
1919             result)))
1920          name)
1921     (when (or groups gcc-self-val)
1922       (when (stringp groups)
1923         (setq groups (list groups)))
1924       (save-excursion
1925         (save-restriction
1926           (message-narrow-to-headers)
1927           (goto-char (point-max))
1928           (insert "Gcc: ")
1929           (if gcc-self-val
1930               ;; Use the `gcc-self' param value instead.
1931               (progn
1932                 (insert
1933                  (if (stringp gcc-self-val)
1934                      (if (string-match " " gcc-self-val)
1935                          (concat "\"" gcc-self-val "\"")
1936                        gcc-self-val)
1937                    ;; In nndoc groups, we use the parent group name
1938                    ;; instead of the current group.
1939                    (let ((group (or (gnus-group-find-parameter
1940                                      gnus-newsgroup-name 'parent-group)
1941                                     group)))
1942                      (if (string-match " " group)
1943                          (concat "\"" group "\"")
1944                        group))))
1945                 (if (not (eq gcc-self-val 'none))
1946                     (insert "\n")
1947                   (gnus-delete-line)))
1948             ;; Use the list of groups.
1949             (while (setq name (pop groups))
1950               (let ((str (if (string-match ":" name)
1951                              name
1952                            (gnus-group-prefixed-name
1953                             name gnus-message-archive-method))))
1954                 (insert (if (string-match " " str)
1955                             (concat "\"" str "\"")
1956                           str)))
1957               (when groups
1958                 (insert " ")))
1959             (insert "\n")))))))
1960
1961 (defun gnus-mailing-list-followup-to ()
1962   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1963   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1964         (list-post (gnus-fetch-original-field "list-post")))
1965     (when (and list-post
1966                (string-match "mailto:\\([^>]+\\)" list-post))
1967       (setq list-post (match-string 1 list-post)))
1968     (or list-post
1969         x-been-there)))
1970
1971 ;;; Posting styles.
1972
1973 (defun gnus-configure-posting-styles (&optional group-name)
1974   "Configure posting styles according to `gnus-posting-styles'."
1975   (unless gnus-inhibit-posting-styles
1976     (let ((group (or group-name gnus-newsgroup-name ""))
1977           (styles gnus-posting-styles)
1978           style match attribute results
1979           name address)
1980       ;; If the group has a posting-style parameter, add it at the end with a
1981       ;; regexp matching everything, to be sure it takes precedence over all
1982       ;; the others.
1983       (when gnus-newsgroup-name
1984         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1985           (when tmp-style
1986             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1987       ;; Go through all styles and look for matches.
1988       (dolist (style styles)
1989         (setq match (pop style))
1990         (goto-char (point-min))
1991         (when (cond
1992                ((stringp match)
1993                 ;; Regexp string match on the group name.
1994                 (string-match match group))
1995                ((eq match 'header)
1996                 ;; Obsolete format of header match.
1997                 (and (gnus-buffer-live-p gnus-article-copy)
1998                      (with-current-buffer gnus-article-copy
1999                        (save-restriction
2000                          (nnheader-narrow-to-headers)
2001                          (let ((header (message-fetch-field (pop style))))
2002                            (and header
2003                                 (string-match (pop style) header)))))))
2004                ((or (symbolp match)
2005                     (functionp match))
2006                 (cond
2007                  ((functionp match)
2008                   ;; Function to be called.
2009                   (funcall match))
2010                  ((boundp match)
2011                   ;; Variable to be checked.
2012                   (symbol-value match))))
2013                ((listp match)
2014                 (cond
2015                  ((eq (car match) 'header)
2016                   ;; New format of header match.
2017                   (and (gnus-buffer-live-p gnus-article-copy)
2018                        (with-current-buffer gnus-article-copy
2019                          (save-restriction
2020                            (nnheader-narrow-to-headers)
2021                            (let ((header (message-fetch-field (nth 1 match))))
2022                              (and header
2023                                   (string-match (nth 2 match) header)))))))
2024                  (t
2025                   ;; This is a form to be evaled.
2026                   (eval match)))))
2027           ;; We have a match, so we set the variables.
2028           (setq style (gnus-configure-posting-style style nil))
2029           (dolist (attribute style)
2030             (setq results (delq (assoc (car attribute) results) results))
2031             (push attribute results))))
2032       ;; Now we have all the styles, so we insert them.
2033       (setq name (assq 'name results)
2034             address (assq 'address results))
2035       (setq results (delq name (delq address results)))
2036       (gnus-make-local-hook 'message-setup-hook)
2037       (setq results (sort results (lambda (x y)
2038                                     (string-lessp (car x) (car y)))))
2039       (dolist (result results)
2040         (add-hook 'message-setup-hook
2041                   (cond
2042                    ((eq 'eval (car result))
2043                     'ignore)
2044                    ((eq 'body (car result))
2045                     `(lambda ()
2046                        (save-excursion
2047                          (message-goto-body)
2048                          (insert ,(cdr result)))))
2049                    ((eq 'signature (car result))
2050                     (set (make-local-variable 'message-signature) nil)
2051                     (set (make-local-variable 'message-signature-file) nil)
2052                     (if (not (cdr result))
2053                         'ignore
2054                       `(lambda ()
2055                          (save-excursion
2056                            (let ((message-signature ,(cdr result)))
2057                              (when message-signature
2058                                (message-insert-signature)))))))
2059                    (t
2060                     (let ((header
2061                            (if (symbolp (car result))
2062                                (capitalize (symbol-name (car result)))
2063                              (car result))))
2064                       `(lambda ()
2065                          (save-excursion
2066                            (message-remove-header ,header)
2067                            (let ((value ,(cdr result)))
2068                              (when value
2069                                (message-goto-eoh)
2070                                (insert ,header ": " value)
2071                                (unless (bolp)
2072                                  (insert "\n")))))))))
2073                   nil 'local))
2074       (when (or name address)
2075         (add-hook 'message-setup-hook
2076                   `(lambda ()
2077                      (set (make-local-variable 'user-mail-address)
2078                           ,(or (cdr address) user-mail-address))
2079                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
2080                            (user-mail-address
2081                             ,(or (cdr address) user-mail-address)))
2082                        (save-excursion
2083                          (message-remove-header "From")
2084                          (message-goto-eoh)
2085                          (insert "From: " (message-make-from) "\n"))))
2086                   nil 'local)))))
2087
2088 ;; splitted from gnus-configure-posting-styles to allow recursive traversal.
2089 (defun gnus-configure-posting-style (style stack)
2090   "Parse one posting style STYLE and returns the value as an alist."
2091   (let (results element variable filep value v)
2092     (dolist (attribute style)
2093       (setq element (pop attribute)
2094             variable nil
2095             filep nil)
2096       (setq value
2097             (cond
2098              ((eq (car attribute) ':file)
2099               (setq filep t)
2100               (cadr attribute))
2101              ((eq (car attribute) :value)
2102               (cadr attribute))
2103              (t
2104               (car attribute))))
2105       ;; We get the value.
2106       (setq v
2107             (cond
2108              ((stringp value)
2109               value)
2110              ((or (symbolp value)
2111                   (functionp value))
2112               (cond ((functionp value)
2113                      (funcall value))
2114                     ((boundp value)
2115                      (symbol-value value))))
2116              ((listp value)
2117               (eval value))))
2118       ;; Translate obsolescent value.
2119       (cond
2120        ((eq element 'signature-file)
2121         (setq element 'signature
2122               filep t))
2123        ((eq element 'x-face-file)
2124         (setq element 'x-face
2125               filep t)))
2126       ;; Get the contents of file elems.
2127       (when (and filep v)
2128         (setq v (with-temp-buffer
2129                   (insert-file-contents v)
2130                   (buffer-substring (point-min)
2131                                     (progn
2132                                       (goto-char (point-max))
2133                                       (if (zerop (skip-chars-backward "\n"))
2134                                           (point)
2135                                         (1+ (point))))))))
2136       (if (eq element 'import)
2137           (progn
2138             (if (member v stack)
2139                 (error "Circular import of \"%s\"" v))
2140             (setq results
2141                   (nconc (nreverse (gnus-configure-posting-style
2142                                     (cdr (assoc v gnus-named-posting-styles))
2143                                     (cons v stack)))
2144                          results)))
2145         (push (cons element v) results)))
2146     (nreverse results)))
2147
2148 (defun gnus-summary-execute-command-with-posting-style (style command)
2149   "Temporarily select a posting-style named STYLE and execute COMMAND."
2150   (interactive
2151    (let ((style (completing-read "Posting style: "
2152                                  gnus-named-posting-styles nil t)))
2153      (list style
2154            (key-binding
2155             (read-key-sequence
2156              (format "Command to execute with %s: " style))))))
2157   (let ((gnus-posting-styles (list (list ".*" (list 'import style)))))
2158     (call-interactively command)))
2159
2160
2161 ;;; @ for MIME Edit mode
2162 ;;;
2163
2164 (defun gnus-maybe-setup-default-charset ()
2165   (let ((charset
2166          (and (boundp 'gnus-summary-buffer)
2167               (buffer-live-p gnus-summary-buffer)
2168               (save-excursion
2169                 (set-buffer gnus-summary-buffer)
2170                 default-mime-charset))))
2171     (if charset
2172         (progn
2173           (make-local-variable 'default-mime-charset)
2174           (setq default-mime-charset charset)
2175           ))))
2176
2177
2178 ;;; @ for MIME view mode
2179 ;;;
2180
2181 (defun gnus-following-method (buf)
2182   (gnus-setup-message 'reply-yank
2183     (set-buffer buf)
2184     (if (message-news-p)
2185         (message-followup)
2186       (message-reply nil 'wide))
2187     (let ((message-reply-buffer buf))
2188       (message-yank-original))
2189     (message-goto-body))
2190   (kill-buffer buf))
2191
2192
2193 ;;; Allow redefinition of functions.
2194
2195 (gnus-ems-redefine)
2196
2197 (provide 'gnus-msg)
2198
2199 ;;; gnus-msg.el ends here