git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Semi-gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;         Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Keywords: mail, news, MIME
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method nil
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current', Gnus will use the \"current\" select
  41 method when posting.  If it is nil (which is the default), Gnus will
  42 use the native posting method of the server.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not nil nor `native', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'. It can also be a list of
  49 methods. If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :type `(choice (const nil)
  53                  (const current)
  54                  (const native)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defvar gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names).")
  67
  68 (defvar gnus-mailing-list-groups nil
  69   "*Regexp matching groups that are really mailing lists.
  70 This is useful when you're reading a mailing list that has been
  71 gatewayed to a newsgroup, and you want to followup to an article in
  72 the group.")
  73
  74 (defvar gnus-add-to-list nil
  75   "*If non-nil, add a `to-list' parameter automatically.")
  76
  77 (defvar gnus-crosspost-complaint
  78   "Hi,
  79
  80 You posted the article below with the following Newsgroups header:
  81
  82 Newsgroups: %s
  83
  84 The %s group, at least, was an inappropriate recipient
  85 of this message.  Please trim your Newsgroups header to exclude this
  86 group before posting in the future.
  87
  88 Thank you.
  89
  90 "
  91   "Format string to be inserted when complaining about crossposts.
  92 The first %s will be replaced by the Newsgroups header;
  93 the second with the current group name.")
  94
  95 (defvar gnus-message-setup-hook nil
  96   "Hook run after setting up a message buffer.")
  97
  98 (defvar gnus-bug-create-help-buffer t
  99   "*Should we create the *Gnus Help Bug* buffer?")
 100
 101 ;;; Internal variables.
 102
 103 (defvar gnus-message-buffer "*Mail Gnus*")
 104 (defvar gnus-article-copy nil)
 105 (defvar gnus-last-posting-server nil)
 106 (defvar gnus-message-group-art nil)
 107
 108 (defconst gnus-bug-message
 109   "Sending a bug report to the Gnus Towers.
 110 ========================================
 111
 112 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 113 be sent to the Gnus Bug Exterminators.
 114
 115 At the bottom of the buffer you'll see lots of variable settings.
 116 Please do not delete those.  They will tell the Bug People what your
 117 environment is, so that it will be easier to locate the bugs.
 118
 119 If you have found a bug that makes Emacs go \"beep\", set
 120 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 121 and include the backtrace in your bug report.
 122
 123 Please describe the bug in annoying, painstaking detail.
 124
 125 Thank you for your help in stamping out bugs.
 126 ")
 127
 128 (eval-and-compile
 129   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 130   (autoload 'news-setup "rnewspost")
 131   (autoload 'news-reply-mode "rnewspost")
 132   (autoload 'rmail-dont-reply-to "mail-utils")
 133   (autoload 'rmail-output "rmailout"))
 134
 135 \f
 136 ;;;
 137 ;;; Gnus Posting Functions
 138 ;;;
 139
 140 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 141   "p" gnus-summary-post-news
 142   "f" gnus-summary-followup
 143   "F" gnus-summary-followup-with-original
 144   "c" gnus-summary-cancel-article
 145   "s" gnus-summary-supersede-article
 146   "r" gnus-summary-reply
 147   "R" gnus-summary-reply-with-original
 148   "w" gnus-summary-wide-reply
 149   "W" gnus-summary-wide-reply-with-original
 150   "n" gnus-summary-followup-to-mail
 151   "N" gnus-summary-followup-to-mail-with-original
 152   "m" gnus-summary-mail-other-window
 153   "u" gnus-uu-post-news
 154   "\M-c" gnus-summary-mail-crosspost-complaint
 155   "om" gnus-summary-mail-forward
 156   "op" gnus-summary-post-forward
 157   "Om" gnus-uu-digest-mail-forward
 158   "Op" gnus-uu-digest-post-forward)
 159
 160 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 161   "b" gnus-summary-resend-bounced-mail
 162   ;; "c" gnus-summary-send-draft
 163   "r" gnus-summary-resend-message)
 164
 165 ;;; Internal functions.
 166
 167 (defvar gnus-article-reply nil)
 168 (defmacro gnus-setup-message (config &rest forms)
 169   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 170         (buffer (make-symbol "gnus-setup-message-buffer"))
 171         (article (make-symbol "gnus-setup-message-article"))
 172         (group (make-symbol "gnus-setup-message-group")))
 173     `(let ((,winconf (current-window-configuration))
 174            (,buffer (buffer-name (current-buffer)))
 175            (,article (and gnus-article-reply (gnus-summary-article-number)))
 176            (,group gnus-newsgroup-name)
 177            (message-header-setup-hook
 178             (copy-sequence message-header-setup-hook)))
 179        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 180        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 181        (unwind-protect
 182            (progn
 183              ,@forms)
 184          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 185          (setq gnus-message-buffer (current-buffer))
 186          (set (make-local-variable 'gnus-message-group-art)
 187               (cons ,group ,article))
 188          (make-local-variable 'gnus-newsgroup-name)
 189          (gnus-run-hooks 'gnus-message-setup-hook))
 190        (gnus-configure-windows ,config t)
 191        (set-buffer-modified-p nil))))
 192
 193 (defun gnus-inews-add-send-actions (winconf buffer article)
 194   (make-local-hook 'message-sent-hook)
 195   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 196   (setq message-post-method
 197         `(lambda (arg)
 198            (gnus-post-method arg ,gnus-newsgroup-name)))
 199   (setq message-user-agent (gnus-extended-version))
 200   (message-add-action
 201    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 202   (message-add-action
 203    `(when (gnus-buffer-exists-p ,buffer)
 204       (save-excursion
 205         (set-buffer ,buffer)
 206         ,(when article
 207            `(gnus-summary-mark-article-as-replied ,article))))
 208    'send))
 209
 210 (put 'gnus-setup-message 'lisp-indent-function 1)
 211 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 212
 213 ;;; Post news commands of Gnus group mode and summary mode
 214
 215 (defun gnus-group-mail ()
 216   "Start composing a mail."
 217   (interactive)
 218   (gnus-setup-message 'message
 219     (message-mail)))
 220
 221 (defun gnus-group-post-news (&optional arg)
 222   "Start composing a news message.
 223 If ARG, post to the group under point.
 224 If ARG is 1, prompt for a group name."
 225   (interactive "P")
 226   ;; Bind this variable here to make message mode hooks work ok.
 227   (let ((gnus-newsgroup-name
 228          (if arg
 229              (if (= 1 (prefix-numeric-value arg))
 230                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 231                                   (gnus-read-active-file-p))
 232                (gnus-group-group-name))
 233            "")))
 234     (gnus-post-news 'post gnus-newsgroup-name)))
 235
 236 (defun gnus-summary-post-news ()
 237   "Start composing a news message."
 238   (interactive)
 239   (gnus-post-news 'post gnus-newsgroup-name))
 240
 241 (defun gnus-summary-followup (yank &optional force-news)
 242   "Compose a followup to an article.
 243 If prefix argument YANK is non-nil, original article is yanked automatically."
 244   (interactive
 245    (list (and current-prefix-arg
 246               (gnus-summary-work-articles 1))))
 247   (when yank
 248     (gnus-summary-goto-subject (car yank)))
 249   (save-window-excursion
 250     (gnus-summary-select-article))
 251   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 252         (gnus-newsgroup-name gnus-newsgroup-name))
 253     ;; Send a followup.
 254     (gnus-post-news nil gnus-newsgroup-name
 255                     headers gnus-article-buffer
 256                     yank nil force-news)))
 257
 258 (defun gnus-summary-followup-with-original (n &optional force-news)
 259   "Compose a followup to an article and include the original article."
 260   (interactive "P")
 261   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 262
 263 (defun gnus-summary-followup-to-mail (&optional arg)
 264   "Followup to the current mail message via news."
 265   (interactive
 266    (list (and current-prefix-arg
 267               (gnus-summary-work-articles 1))))
 268   (gnus-summary-followup arg t))
 269
 270 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 271   "Followup to the current mail message via news."
 272   (interactive "P")
 273   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 274
 275 (defun gnus-inews-yank-articles (articles)
 276   (let (beg article)
 277     (message-goto-body)
 278     (while (setq article (pop articles))
 279       (save-window-excursion
 280         (set-buffer gnus-summary-buffer)
 281         (gnus-summary-select-article nil nil nil article)
 282         (gnus-summary-remove-process-mark article))
 283       (gnus-copy-article-buffer)
 284       (let ((message-reply-buffer gnus-article-copy)
 285             (message-reply-headers gnus-current-headers))
 286         (message-yank-original)
 287         (setq beg (or beg (mark t))))
 288       (when articles
 289         (insert "\n")))
 290     (push-mark)
 291     (goto-char beg)))
 292
 293 (defun gnus-summary-cancel-article (&optional n symp)
 294   "Cancel an article you posted.
 295 Uses the process-prefix convention.  If given the symbolic
 296 prefix `a', cancel using the standard posting method; if not
 297 post using the current select method."
 298   (interactive (gnus-interactive "P\ny"))
 299   (let ((articles (gnus-summary-work-articles n))
 300         (message-post-method
 301          `(lambda (arg)
 302             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 303         article)
 304     (while (setq article (pop articles))
 305       (when (gnus-summary-select-article t nil nil article)
 306         (when (gnus-eval-in-buffer-window gnus-article-buffer
 307                 (save-excursion
 308                   (set-buffer gnus-original-article-buffer)
 309                   (message-cancel-news)))
 310           (gnus-summary-mark-as-read article gnus-canceled-mark)
 311           (gnus-cache-remove-article 1))
 312         (gnus-article-hide-headers-if-wanted))
 313       (gnus-summary-remove-process-mark article))))
 314
 315 (defun gnus-summary-supersede-article ()
 316   "Compose an article that will supersede a previous article.
 317 This is done simply by taking the old article and adding a Supersedes
 318 header line with the old Message-ID."
 319   (interactive)
 320   (let ((article (gnus-summary-article-number)))
 321     (gnus-setup-message 'reply-yank
 322       (gnus-summary-select-article t)
 323       (set-buffer gnus-original-article-buffer)
 324       (message-supersede)
 325       (push
 326        `((lambda ()
 327            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 328              (save-excursion
 329                (set-buffer ,gnus-summary-buffer)
 330                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 331                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 332        message-send-actions))))
 333
 334 \f
 335
 336 (defun gnus-copy-article-buffer (&optional article-buffer)
 337   ;; make a copy of the article buffer with all text properties removed
 338   ;; this copy is in the buffer gnus-article-copy.
 339   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 340   ;; this buffer should be passed to all mail/news reply/post routines.
 341   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 342   (buffer-disable-undo gnus-article-copy)
 343   (or (memq gnus-article-copy gnus-buffer-list)
 344       (push gnus-article-copy gnus-buffer-list))
 345   (let ((article-buffer (or article-buffer gnus-article-buffer))
 346         end beg contents)
 347     (if (not (and (get-buffer article-buffer)
 348                   (gnus-buffer-exists-p article-buffer)))
 349         (error "Can't find any article buffer")
 350       (save-excursion
 351         (set-buffer article-buffer)
 352         (save-restriction
 353           ;; Copy over the (displayed) article buffer, delete
 354           ;; hidden text and remove text properties.
 355           (widen)
 356           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 357           (set-buffer gnus-article-copy)
 358           (gnus-article-delete-text-of-type 'annotation)
 359           (gnus-remove-text-with-property 'gnus-prev)
 360           (gnus-remove-text-with-property 'gnus-next)
 361           (insert
 362            (prog1
 363                (format "%s" (buffer-string))
 364              (erase-buffer)))
 365           ;; Find the original headers.
 366           (set-buffer gnus-original-article-buffer)
 367           (goto-char (point-min))
 368           (while (looking-at message-unix-mail-delimiter)
 369             (forward-line 1))
 370           (setq beg (point))
 371           (setq end (or (search-forward "\n\n" nil t) (point)))
 372           ;; Delete the headers from the displayed articles.
 373           (set-buffer gnus-article-copy)
 374           (delete-region (goto-char (point-min))
 375                          (or (search-forward "\n\n" nil t) (point)))
 376           ;; Insert the original article headers.
 377           (insert-buffer-substring gnus-original-article-buffer beg end)
 378           (gnus-article-decode-rfc1522)))
 379       gnus-article-copy)))
 380
 381 (defun gnus-post-news (post &optional group header article-buffer yank subject
 382                             force-news)
 383   (when article-buffer
 384     (gnus-copy-article-buffer))
 385   (let ((gnus-article-reply article-buffer)
 386         (add-to-list gnus-add-to-list))
 387     (gnus-setup-message (cond (yank 'reply-yank)
 388                               (article-buffer 'reply)
 389                               (t 'message))
 390       (let* ((group (or group gnus-newsgroup-name))
 391              (pgroup group)
 392              to-address to-group mailing-list to-list
 393              newsgroup-p)
 394         (when group
 395           (setq to-address (gnus-group-find-parameter group 'to-address)
 396                 to-group (gnus-group-find-parameter group 'to-group)
 397                 to-list (gnus-group-find-parameter group 'to-list)
 398                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 399                 mailing-list (when gnus-mailing-list-groups
 400                                (string-match gnus-mailing-list-groups group))
 401                 group (gnus-group-real-name group)))
 402         (if (or (and to-group
 403                      (gnus-news-group-p to-group))
 404                 newsgroup-p
 405                 force-news
 406                 (and (gnus-news-group-p
 407                       (or pgroup gnus-newsgroup-name)
 408                       (if header (mail-header-number header)
 409                         gnus-current-article))
 410                      (not mailing-list)
 411                      (not to-list)
 412                      (not to-address)))
 413             ;; This is news.
 414             (if post
 415                 (message-news (or to-group group))
 416               (set-buffer gnus-article-copy)
 417               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 418           ;; The is mail.
 419           (if post
 420               (progn
 421                 (message-mail (or to-address to-list))
 422                 ;; Arrange for mail groups that have no `to-address' to
 423                 ;; get that when the user sends off the mail.
 424                 (when (and (not to-list)
 425                            (not to-address)
 426                            add-to-list)
 427                   (push (list 'gnus-inews-add-to-address pgroup)
 428                         message-send-actions)))
 429             (set-buffer gnus-article-copy)
 430             (message-wide-reply to-address
 431                                 (gnus-group-find-parameter
 432                                  gnus-newsgroup-name 'broken-reply-to))))
 433         (when yank
 434           (gnus-inews-yank-articles yank))))))
 435
 436 (defun gnus-post-method (arg group &optional silent)
 437   "Return the posting method based on GROUP and ARG.
 438 If SILENT, don't prompt the user."
 439   (let ((group-method (gnus-find-method-for-group group)))
 440     (cond
 441      ;; If the group-method is nil (which shouldn't happen) we use
 442      ;; the default method.
 443      ((null group-method)
 444       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 445                gnus-select-method message-post-method))
 446      ;; We want the inverse of the default
 447      ((and arg (not (eq arg 0)))
 448       (if (eq gnus-post-method 'active)
 449           gnus-select-method
 450         group-method))
 451      ;; We query the user for a post method.
 452      ((or arg
 453           (and gnus-post-method
 454                (not (eq gnus-post-method 'current))
 455                (listp (car gnus-post-method))))
 456       (let* ((methods
 457               ;; Collect all methods we know about.
 458               (append
 459                (when (and gnus-post-method
 460                           (not (eq gnus-post-method 'current)))
 461                  (if (listp (car gnus-post-method))
 462                      gnus-post-method
 463                    (list gnus-post-method)))
 464                gnus-secondary-select-methods
 465                (list gnus-select-method)
 466                (list group-method)))
 467              method-alist post-methods method)
 468         ;; Weed out all mail methods.
 469         (while methods
 470           (setq method (gnus-server-get-method "" (pop methods)))
 471           (when (or (gnus-method-option-p method 'post)
 472                     (gnus-method-option-p method 'post-mail))
 473             (push method post-methods)))
 474         ;; Create a name-method alist.
 475         (setq method-alist
 476               (mapcar
 477                (lambda (m)
 478                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 479                post-methods))
 480         ;; Query the user.
 481         (cadr
 482          (assoc
 483           (setq gnus-last-posting-server
 484                 (if (and silent
 485                          gnus-last-posting-server)
 486                     ;; Just use the last value.
 487                     gnus-last-posting-server
 488                   (completing-read
 489                    "Posting method: " method-alist nil t
 490                    (cons (or gnus-last-posting-server "") 0))))
 491           method-alist))))
 492      ;; Override normal method.
 493      ((and (eq gnus-post-method 'current)
 494            (not arg))
 495       group-method)
 496      (gnus-post-method
 497       gnus-post-method)
 498      ;; Use the normal select method.
 499      (t gnus-select-method))))
 500
 501 \f
 502
 503 ;; Dummy to avoid byte-compile warning.
 504 (defvar nnspool-rejected-article-hook)
 505 (defvar xemacs-codename)
 506
 507 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 508 ;;; as well include the Emacs version as well.
 509 ;;; The following function works with later GNU Emacs, and XEmacs.
 510 (defun gnus-extended-version ()
 511   "Stringified Gnus version and Emacs version."
 512   (interactive)
 513   (concat
 514    "Semi-gnus/" gnus-version-number " "
 515    (cond
 516     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 517      (concat "Emacs/" (substring emacs-version
 518                                  (match-beginning 1)
 519                                  (match-end 1))
 520              (if (boundp 'mule-version)
 521                  (concat " Mule/" mule-version)
 522                "")
 523              (if (featurep 'meadow)
 524                  ;; XXX: (Meadow-version) -> Meadow-1.0x (CODENAME)
 525                  (concat " " (Meadow-version))
 526                "")))
 527     ;; XXX: rewrite to use "(featurep 'xemacs)"?
 528     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 529                    emacs-version)
 530      (concat (substring emacs-version
 531                         (match-beginning 1)
 532                         (match-end 1))
 533              (format "/%d.%d" emacs-major-version emacs-minor-version)
 534              (if (match-beginning 3)
 535                  (substring emacs-version
 536                             (match-beginning 3)
 537                             (match-end 3))
 538                "")
 539              ;; XXX: Insert `with-mule' or `without-mule'?
 540              (if (boundp 'xemacs-codename)
 541                  (concat " (" xemacs-codename ")")
 542                "")))
 543     (t emacs-version))))
 544
 545 \f
 546 ;;;
 547 ;;; Gnus Mail Functions
 548 ;;;
 549
 550 ;;; Mail reply commands of Gnus summary mode
 551
 552 (defun gnus-summary-reply (&optional yank wide)
 553   "Start composing a reply mail to the current message.
 554 If prefix argument YANK is non-nil, the original article is yanked
 555 automatically."
 556   (interactive
 557    (list (and current-prefix-arg
 558               (gnus-summary-work-articles 1))))
 559   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 560   (when yank
 561     (gnus-summary-goto-subject (car yank)))
 562   (let ((gnus-article-reply t))
 563     (gnus-setup-message (if yank 'reply-yank 'reply)
 564       (gnus-summary-select-article)
 565       (set-buffer (gnus-copy-article-buffer))
 566       (message-reply nil wide (gnus-group-find-parameter
 567                                gnus-newsgroup-name 'broken-reply-to))
 568       (when yank
 569         (gnus-inews-yank-articles yank)))))
 570
 571 (defun gnus-summary-reply-with-original (n &optional wide)
 572   "Start composing a reply mail to the current message.
 573 The original article will be yanked."
 574   (interactive "P")
 575   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 576
 577 (defun gnus-summary-wide-reply (&optional yank)
 578   "Start composing a wide reply mail to the current message.
 579 If prefix argument YANK is non-nil, the original article is yanked
 580 automatically."
 581   (interactive
 582    (list (and current-prefix-arg
 583               (gnus-summary-work-articles 1))))
 584   (gnus-summary-reply yank t))
 585
 586 (defun gnus-summary-wide-reply-with-original (n)
 587   "Start composing a wide reply mail to the current message.
 588 The original article will be yanked."
 589   (interactive "P")
 590   (gnus-summary-reply-with-original n t))
 591
 592 (defun gnus-summary-mail-forward (&optional full-headers post)
 593   "Forward the current message to another user.
 594 If FULL-HEADERS (the prefix), include full headers when forwarding."
 595   (interactive "P")
 596   (gnus-setup-message 'forward
 597     (gnus-summary-select-article)
 598     (let ((charset default-mime-charset))
 599       (set-buffer gnus-original-article-buffer)
 600       (make-local-variable 'default-mime-charset)
 601       (setq default-mime-charset charset)
 602       )
 603     (let ((message-included-forward-headers
 604            (if full-headers "" message-included-forward-headers)))
 605       (message-forward post))))
 606
 607 (defun gnus-summary-resend-message (address n)
 608   "Resend the current article to ADDRESS."
 609   (interactive "sResend message(s) to: \nP")
 610   (let ((articles (gnus-summary-work-articles n))
 611         article)
 612     (while (setq article (pop articles))
 613       (gnus-summary-select-article nil nil nil article)
 614       (save-excursion
 615         (set-buffer gnus-original-article-buffer)
 616         (message-resend address)))))
 617
 618 (defun gnus-summary-post-forward (&optional full-headers)
 619   "Forward the current article to a newsgroup.
 620 If FULL-HEADERS (the prefix), include full headers when forwarding."
 621   (interactive "P")
 622   (gnus-summary-mail-forward full-headers t))
 623
 624 (defvar gnus-nastygram-message
 625   "The following article was inappropriately posted to %s.\n\n"
 626   "Format string to insert in nastygrams.
 627 The current group name will be inserted at \"%s\".")
 628
 629 (defun gnus-summary-mail-nastygram (n)
 630   "Send a nastygram to the author of the current article."
 631   (interactive "P")
 632   (when (or gnus-expert-user
 633             (gnus-y-or-n-p
 634              "Really send a nastygram to the author of the current article? "))
 635     (let ((group gnus-newsgroup-name))
 636       (gnus-summary-reply-with-original n)
 637       (set-buffer gnus-message-buffer)
 638       (message-goto-body)
 639       (insert (format gnus-nastygram-message group))
 640       (message-send-and-exit))))
 641
 642 (defun gnus-summary-mail-crosspost-complaint (n)
 643   "Send a complaint about crossposting to the current article(s)."
 644   (interactive "P")
 645   (let ((articles (gnus-summary-work-articles n))
 646         article)
 647     (while (setq article (pop articles))
 648       (set-buffer gnus-summary-buffer)
 649       (gnus-summary-goto-subject article)
 650       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 651             newsgroups followup-to)
 652         (gnus-summary-select-article)
 653         (set-buffer gnus-original-article-buffer)
 654         (if (and (<= (length (message-tokenize-header
 655                               (setq newsgroups (mail-fetch-field "newsgroups"))
 656                               ", "))
 657                      1)
 658                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 659                      (not (member group (message-tokenize-header
 660                                          followup-to ", ")))))
 661             (if followup-to
 662                 (gnus-message 1 "Followup-to restricted")
 663               (gnus-message 1 "Not a crossposted article"))
 664           (set-buffer gnus-summary-buffer)
 665           (gnus-summary-reply-with-original 1)
 666           (set-buffer gnus-message-buffer)
 667           (message-goto-body)
 668           (insert (format gnus-crosspost-complaint newsgroups group))
 669           (message-goto-subject)
 670           (re-search-forward " *$")
 671           (replace-match " (crosspost notification)" t t)
 672           (gnus-deactivate-mark)
 673           (when (gnus-y-or-n-p "Send this complaint? ")
 674             (message-send-and-exit)))))))
 675
 676 (defun gnus-summary-mail-other-window ()
 677   "Compose mail in other window."
 678   (interactive)
 679   (gnus-setup-message 'message
 680     (message-mail)))
 681
 682 (defun gnus-mail-parse-comma-list ()
 683   (let (accumulated
 684         beg)
 685     (skip-chars-forward " ")
 686     (while (not (eobp))
 687       (setq beg (point))
 688       (skip-chars-forward "^,")
 689       (while (zerop
 690               (save-excursion
 691                 (save-restriction
 692                   (let ((i 0))
 693                     (narrow-to-region beg (point))
 694                     (goto-char beg)
 695                     (logand (progn
 696                               (while (search-forward "\"" nil t)
 697                                 (incf i))
 698                               (if (zerop i) 2 i))
 699                             2)))))
 700         (skip-chars-forward ",")
 701         (skip-chars-forward "^,"))
 702       (skip-chars-backward " ")
 703       (push (buffer-substring beg (point))
 704             accumulated)
 705       (skip-chars-forward "^,")
 706       (skip-chars-forward ", "))
 707     accumulated))
 708
 709 (defun gnus-inews-add-to-address (group)
 710   (let ((to-address (mail-fetch-field "to")))
 711     (when (and to-address
 712                (gnus-alive-p))
 713       ;; This mail group doesn't have a `to-list', so we add one
 714       ;; here.  Magic!
 715       (when (gnus-y-or-n-p
 716              (format "Do you want to add this as `to-list': %s " to-address))
 717         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 718
 719 (defun gnus-put-message ()
 720   "Put the current message in some group and return to Gnus."
 721   (interactive)
 722   (let ((reply gnus-article-reply)
 723         (winconf gnus-prev-winconf)
 724         (group gnus-newsgroup-name))
 725
 726     (or (and group (not (gnus-group-read-only-p group)))
 727         (setq group (read-string "Put in group: " nil
 728                                  (gnus-writable-groups))))
 729     (when (gnus-gethash group gnus-newsrc-hashtb)
 730       (error "No such group: %s" group))
 731
 732     (save-excursion
 733       (save-restriction
 734         (widen)
 735         (message-narrow-to-headers)
 736         (let (gnus-deletable-headers)
 737           (if (message-news-p)
 738               (message-generate-headers message-required-news-headers)
 739             (message-generate-headers message-required-mail-headers)))
 740         (goto-char (point-max))
 741         (insert "Gcc: " group "\n")
 742         (widen)))
 743
 744     (gnus-inews-do-gcc)
 745
 746     (when (get-buffer gnus-group-buffer)
 747       (when (gnus-buffer-exists-p (car-safe reply))
 748         (set-buffer (car reply))
 749         (and (cdr reply)
 750              (gnus-summary-mark-article-as-replied
 751               (cdr reply))))
 752       (when winconf
 753         (set-window-configuration winconf)))))
 754
 755 (defun gnus-article-mail (yank)
 756   "Send a reply to the address near point.
 757 If YANK is non-nil, include the original article."
 758   (interactive "P")
 759   (let ((address
 760          (buffer-substring
 761           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 762           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 763     (when address
 764       (message-reply address)
 765       (when yank
 766         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 767
 768 (defvar nntp-server-type)
 769 (defun gnus-bug ()
 770   "Send a bug report to the Gnus maintainers."
 771   (interactive)
 772   (unless (gnus-alive-p)
 773     (error "Gnus has been shut down"))
 774   (gnus-setup-message 'bug
 775     (delete-other-windows)
 776     (when gnus-bug-create-help-buffer
 777       (switch-to-buffer "*Gnus Help Bug*")
 778       (erase-buffer)
 779       (insert gnus-bug-message)
 780       (goto-char (point-min)))
 781     (message-pop-to-buffer "*Gnus Bug*")
 782     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 783     (when gnus-bug-create-help-buffer
 784       (push `(gnus-bug-kill-buffer) message-send-actions))
 785     (goto-char (point-min))
 786     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 787     (forward-line 1)
 788     (insert (gnus-version) "\n"
 789             (emacs-version) "\n")
 790     (when (and (boundp 'nntp-server-type)
 791                (stringp nntp-server-type))
 792       (insert nntp-server-type))
 793     (insert "\n\n\n\n\n")
 794     (gnus-debug)
 795     (goto-char (point-min))
 796     (search-forward "Subject: " nil t)
 797     (message "")))
 798
 799 (defun gnus-bug-kill-buffer ()
 800   (when (get-buffer "*Gnus Help Bug*")
 801     (kill-buffer "*Gnus Help Bug*")))
 802
 803 (defun gnus-debug ()
 804   "Attempts to go through the Gnus source file and report what variables have been changed.
 805 The source file has to be in the Emacs load path."
 806   (interactive)
 807   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 808                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 809                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 810                  "nnmail.el" "message.el"))
 811         (point (point))
 812         file expr olist sym)
 813     (gnus-message 4 "Please wait while we snoop your variables...")
 814     (sit-for 0)
 815     ;; Go through all the files looking for non-default values for variables.
 816     (save-excursion
 817       (set-buffer (get-buffer-create " *gnus bug info*"))
 818       (buffer-disable-undo (current-buffer))
 819       (while files
 820         (erase-buffer)
 821         (when (and (setq file (locate-library (pop files)))
 822                    (file-exists-p file))
 823           (insert-file-contents file)
 824           (goto-char (point-min))
 825           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 826               (gnus-message 4 "Malformed sources in file %s" file)
 827             (narrow-to-region (point-min) (point))
 828             (goto-char (point-min))
 829             (while (setq expr (ignore-errors (read (current-buffer))))
 830               (ignore-errors
 831                 (and (or (eq (car expr) 'defvar)
 832                          (eq (car expr) 'defcustom))
 833                      (stringp (nth 3 expr))
 834                      (or (not (boundp (nth 1 expr)))
 835                          (not (equal (eval (nth 2 expr))
 836                                      (symbol-value (nth 1 expr)))))
 837                      (push (nth 1 expr) olist)))))))
 838       (kill-buffer (current-buffer)))
 839     (when (setq olist (nreverse olist))
 840       (insert "------------------ Environment follows ------------------\n\n"))
 841     (while olist
 842       (if (boundp (car olist))
 843           (condition-case ()
 844               (pp `(setq ,(car olist)
 845                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 846                                   (and (symbolp sym)
 847                                        (not (or (eq sym nil)
 848                                                 (eq sym t)))))
 849                               (list 'quote (symbol-value (car olist)))
 850                             (symbol-value (car olist))))
 851                   (current-buffer))
 852             (error
 853              (format "(setq %s 'whatever)\n" (car olist))))
 854         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 855       (setq olist (cdr olist)))
 856     (insert "\n\n")
 857     ;; Remove any control chars - they seem to cause trouble for some
 858     ;; mailers.  (Byte-compiled output from the stuff above.)
 859     (goto-char point)
 860     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 861       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 862                      t t))))
 863
 864 ;;; Treatment of rejected articles.
 865 ;;; Bounced mail.
 866
 867 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 868   "Re-mail the current message.
 869 This only makes sense if the current message is a bounce message than
 870 contains some mail you have written which has been bounced back to
 871 you.
 872 If FETCH, try to fetch the article that this is a reply to, if indeed
 873 this is a reply."
 874   (interactive "P")
 875   (gnus-summary-select-article t)
 876   (set-buffer gnus-original-article-buffer)
 877   (gnus-setup-message 'compose-bounce
 878     (let* ((references (mail-fetch-field "references"))
 879            (parent (and references (gnus-parent-id references))))
 880       (message-bounce)
 881       ;; If there are references, we fetch the article we answered to.
 882       (and fetch parent
 883            (gnus-summary-refer-article parent)
 884            (gnus-summary-show-all-headers)))))
 885
 886 ;;; Gcc handling.
 887
 888 ;; Do Gcc handling, which copied the message over to some group.
 889 (defun gnus-inews-do-gcc (&optional gcc)
 890   (interactive)
 891   (when (gnus-alive-p)
 892     (save-excursion
 893       (save-restriction
 894         (message-narrow-to-headers)
 895         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 896               (coding-system-for-write 'raw-text)
 897               groups group method)
 898           (when gcc
 899             (message-remove-header "gcc")
 900             (widen)
 901             (setq groups (message-tokenize-header gcc " ,"))
 902             ;; Copy the article over to some group(s).
 903             (while (setq group (pop groups))
 904               (gnus-check-server
 905                (setq method
 906                      (cond ((and (null (gnus-get-info group))
 907                                  (eq (car gnus-message-archive-method)
 908                                      (car
 909                                       (gnus-server-to-method
 910                                        (gnus-group-method group)))))
 911                             ;; If the group doesn't exist, we assume
 912                             ;; it's an archive group...
 913                             gnus-message-archive-method)
 914                            ;; Use the method.
 915                            ((gnus-info-method (gnus-get-info group))
 916                             (gnus-info-method (gnus-get-info group)))
 917                            ;; Find the method.
 918                            (t (gnus-group-method group)))))
 919               (gnus-check-server method)
 920               (unless (gnus-request-group group t method)
 921                 (gnus-request-create-group group method))
 922               (save-excursion
 923                 (nnheader-set-temp-buffer " *acc*")
 924                 (insert-buffer-substring message-encoding-buffer)
 925                 (gnus-run-hooks 'gnus-before-do-gcc-hook)
 926                 (goto-char (point-min))
 927                 (when (re-search-forward
 928                        (concat "^" (regexp-quote mail-header-separator) "$")
 929                        nil t)
 930                   (replace-match "" t t ))
 931                 (unless (gnus-request-accept-article group method t)
 932                   (gnus-message 1 "Couldn't store article in group %s: %s"
 933                                 group (gnus-status-message method))
 934                   (sit-for 2))
 935                 (kill-buffer (current-buffer))))))))))
 936
 937 (defun gnus-inews-insert-gcc ()
 938   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 939   (save-excursion
 940     (save-restriction
 941       (message-narrow-to-headers)
 942       (let* ((group gnus-outgoing-message-group)
 943              (gcc (cond
 944                    ((gnus-functionp group)
 945                     (funcall group))
 946                    ((or (stringp group) (list group))
 947                     group))))
 948         (when gcc
 949           (insert "Gcc: "
 950                   (if (stringp gcc) gcc
 951                     (mapconcat 'identity gcc " "))
 952                   "\n"))))))
 953
 954 (defun gnus-inews-insert-archive-gcc (&optional group)
 955   "Insert the Gcc to say where the article is to be archived."
 956   (let* ((var gnus-message-archive-group)
 957          (group (or group gnus-newsgroup-name ""))
 958          (gcc-self-val
 959           (and gnus-newsgroup-name
 960                (gnus-group-find-parameter
 961                 gnus-newsgroup-name 'gcc-self)))
 962          result
 963          (groups
 964           (cond
 965            ((null gnus-message-archive-method)
 966             ;; Ignore.
 967             nil)
 968            ((stringp var)
 969             ;; Just a single group.
 970             (list var))
 971            ((null var)
 972             ;; We don't want this.
 973             nil)
 974            ((and (listp var) (stringp (car var)))
 975             ;; A list of groups.
 976             var)
 977            ((gnus-functionp var)
 978             ;; A function.
 979             (funcall var group))
 980            (t
 981             ;; An alist of regexps/functions/forms.
 982             (while (and var
 983                         (not
 984                          (setq result
 985                                (cond
 986                                 ((stringp (caar var))
 987                                  ;; Regexp.
 988                                  (when (string-match (caar var) group)
 989                                    (cdar var)))
 990                                 ((gnus-functionp (car var))
 991                                  ;; Function.
 992                                  (funcall (car var) group))
 993                                 (t
 994                                  (eval (car var)))))))
 995               (setq var (cdr var)))
 996             result)))
 997          name)
 998     (when (or groups gcc-self-val)
 999       (when (stringp groups)
1000         (setq groups (list groups)))
1001       (save-excursion
1002         (save-restriction
1003           (message-narrow-to-headers)
1004           (goto-char (point-max))
1005           (insert "Gcc: ")
1006           (if gcc-self-val
1007               ;; Use the `gcc-self' param value instead.
1008               (progn
1009                 (insert
1010                  (if (stringp gcc-self-val)
1011                      gcc-self-val
1012                    group))
1013                 (if (not (eq gcc-self-val 'none))
1014                     (insert "\n")
1015                   (progn
1016                     (beginning-of-line)
1017                     (kill-line))))
1018             ;; Use the list of groups.
1019             (while (setq name (pop groups))
1020               (insert (if (string-match ":" name)
1021                           name
1022                         (gnus-group-prefixed-name
1023                          name gnus-message-archive-method)))
1024               (when groups
1025                 (insert " ")))
1026             (insert "\n")))))))
1027
1028 ;;; Allow redefinition of functions.
1029
1030 (gnus-ems-redefine)
1031
1032 (provide 'gnus-msg)
1033
1034 ;;; gnus-msg.el ends here