git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Semi-gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;         Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Keywords: mail, news, MIME
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method nil
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current', Gnus will use the \"current\" select
  41 method when posting.  If it is nil (which is the default), Gnus will
  42 use the native posting method of the server.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not nil nor `native', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'. It can also be a list of
  49 methods. If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :type `(choice (const nil)
  53                  (const current)
  54                  (const native)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defvar gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names).")
  67
  68 (defvar gnus-mailing-list-groups nil
  69   "*Regexp matching groups that are really mailing lists.
  70 This is useful when you're reading a mailing list that has been
  71 gatewayed to a newsgroup, and you want to followup to an article in
  72 the group.")
  73
  74 (defvar gnus-add-to-list nil
  75   "*If non-nil, add a `to-list' parameter automatically.")
  76
  77 (defvar gnus-crosspost-complaint
  78   "Hi,
  79
  80 You posted the article below with the following Newsgroups header:
  81
  82 Newsgroups: %s
  83
  84 The %s group, at least, was an inappropriate recipient
  85 of this message.  Please trim your Newsgroups header to exclude this
  86 group before posting in the future.
  87
  88 Thank you.
  89
  90 "
  91   "Format string to be inserted when complaining about crossposts.
  92 The first %s will be replaced by the Newsgroups header;
  93 the second with the current group name.")
  94
  95 (defvar gnus-message-setup-hook nil
  96   "Hook run after setting up a message buffer.")
  97
  98 (defvar gnus-bug-create-help-buffer t
  99   "*Should we create the *Gnus Help Bug* buffer?")
 100
 101 (defvar gnus-posting-styles nil
 102   "*Alist of styles to use when posting.")
 103
 104 (defvar gnus-posting-style-alist
 105   '((organization . message-user-organization)
 106     (signature . message-signature)
 107     (signature-file . message-signature-file)
 108     (address . user-mail-address)
 109     (name . user-full-name))
 110   "*Mapping from style parameters to variables.")
 111
 112 ;;; Internal variables.
 113
 114 (defvar gnus-message-buffer "*Mail Gnus*")
 115 (defvar gnus-article-copy nil)
 116 (defvar gnus-last-posting-server nil)
 117 (defvar gnus-message-group-art nil)
 118
 119 (defconst gnus-bug-message
 120   "Sending a bug report to the Gnus Towers.
 121 ========================================
 122
 123 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 124 be sent to the Gnus Bug Exterminators.
 125
 126 At the bottom of the buffer you'll see lots of variable settings.
 127 Please do not delete those.  They will tell the Bug People what your
 128 environment is, so that it will be easier to locate the bugs.
 129
 130 If you have found a bug that makes Emacs go \"beep\", set
 131 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 132 and include the backtrace in your bug report.
 133
 134 Please describe the bug in annoying, painstaking detail.
 135
 136 Thank you for your help in stamping out bugs.
 137 ")
 138
 139 (eval-and-compile
 140   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 141   (autoload 'news-setup "rnewspost")
 142   (autoload 'news-reply-mode "rnewspost")
 143   (autoload 'rmail-dont-reply-to "mail-utils")
 144   (autoload 'rmail-output "rmailout"))
 145
 146 \f
 147 ;;;
 148 ;;; Gnus Posting Functions
 149 ;;;
 150
 151 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 152   "p" gnus-summary-post-news
 153   "f" gnus-summary-followup
 154   "F" gnus-summary-followup-with-original
 155   "c" gnus-summary-cancel-article
 156   "s" gnus-summary-supersede-article
 157   "r" gnus-summary-reply
 158   "R" gnus-summary-reply-with-original
 159   "w" gnus-summary-wide-reply
 160   "W" gnus-summary-wide-reply-with-original
 161   "n" gnus-summary-followup-to-mail
 162   "N" gnus-summary-followup-to-mail-with-original
 163   "m" gnus-summary-mail-other-window
 164   "u" gnus-uu-post-news
 165   "\M-c" gnus-summary-mail-crosspost-complaint
 166   "om" gnus-summary-mail-forward
 167   "op" gnus-summary-post-forward
 168   "Om" gnus-uu-digest-mail-forward
 169   "Op" gnus-uu-digest-post-forward)
 170
 171 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 172   "b" gnus-summary-resend-bounced-mail
 173   ;; "c" gnus-summary-send-draft
 174   "r" gnus-summary-resend-message)
 175
 176 ;;; Internal functions.
 177
 178 (defvar gnus-article-reply nil)
 179 (defmacro gnus-setup-message (config &rest forms)
 180   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 181         (buffer (make-symbol "gnus-setup-message-buffer"))
 182         (article (make-symbol "gnus-setup-message-article"))
 183         (group (make-symbol "gnus-setup-message-group")))
 184     `(let ((,winconf (current-window-configuration))
 185            (,buffer (buffer-name (current-buffer)))
 186            (,article (and gnus-article-reply (gnus-summary-article-number)))
 187            (,group gnus-newsgroup-name)
 188            (message-header-setup-hook
 189             (copy-sequence message-header-setup-hook)))
 190        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 191        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 192        (add-hook 'message-mode-hook 'gnus-configure-posting-styles)
 193        (unwind-protect
 194            (progn
 195              ,@forms)
 196          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 197          (setq gnus-message-buffer (current-buffer))
 198          (set (make-local-variable 'gnus-message-group-art)
 199               (cons ,group ,article))
 200          (make-local-variable 'gnus-newsgroup-name)
 201          (gnus-run-hooks 'gnus-message-setup-hook))
 202        (gnus-add-buffer)
 203        (gnus-configure-windows ,config t)
 204        (set-buffer-modified-p nil))))
 205
 206 (defun gnus-inews-add-send-actions (winconf buffer article)
 207   (make-local-hook 'message-sent-hook)
 208   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 209   (setq message-post-method
 210         `(lambda (arg)
 211            (gnus-post-method arg ,gnus-newsgroup-name)))
 212   (setq message-user-agent (gnus-extended-version))
 213   (message-add-action
 214    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 215   (message-add-action
 216    `(when (gnus-buffer-exists-p ,buffer)
 217       (save-excursion
 218         (set-buffer ,buffer)
 219         ,(when article
 220            `(gnus-summary-mark-article-as-replied ,article))))
 221    'send))
 222
 223 (put 'gnus-setup-message 'lisp-indent-function 1)
 224 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 225
 226 ;;; Post news commands of Gnus group mode and summary mode
 227
 228 (defun gnus-group-mail ()
 229   "Start composing a mail."
 230   (interactive)
 231   (gnus-setup-message 'message
 232     (message-mail)))
 233
 234 (defun gnus-group-post-news (&optional arg)
 235   "Start composing a news message.
 236 If ARG, post to the group under point.
 237 If ARG is 1, prompt for a group name."
 238   (interactive "P")
 239   ;; Bind this variable here to make message mode hooks work ok.
 240   (let ((gnus-newsgroup-name
 241          (if arg
 242              (if (= 1 (prefix-numeric-value arg))
 243                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 244                                   (gnus-read-active-file-p))
 245                (gnus-group-group-name))
 246            "")))
 247     (gnus-post-news 'post gnus-newsgroup-name)))
 248
 249 (defun gnus-summary-post-news ()
 250   "Start composing a news message."
 251   (interactive)
 252   (gnus-post-news 'post gnus-newsgroup-name))
 253
 254 (defun gnus-summary-followup (yank &optional force-news)
 255   "Compose a followup to an article.
 256 If prefix argument YANK is non-nil, original article is yanked automatically."
 257   (interactive
 258    (list (and current-prefix-arg
 259               (gnus-summary-work-articles 1))))
 260   (when yank
 261     (gnus-summary-goto-subject (car yank)))
 262   (save-window-excursion
 263     (gnus-summary-select-article))
 264   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 265         (gnus-newsgroup-name gnus-newsgroup-name))
 266     ;; Send a followup.
 267     (gnus-post-news nil gnus-newsgroup-name
 268                     headers gnus-article-buffer
 269                     yank nil force-news)))
 270
 271 (defun gnus-summary-followup-with-original (n &optional force-news)
 272   "Compose a followup to an article and include the original article."
 273   (interactive "P")
 274   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 275
 276 (defun gnus-summary-followup-to-mail (&optional arg)
 277   "Followup to the current mail message via news."
 278   (interactive
 279    (list (and current-prefix-arg
 280               (gnus-summary-work-articles 1))))
 281   (gnus-summary-followup arg t))
 282
 283 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 284   "Followup to the current mail message via news."
 285   (interactive "P")
 286   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 287
 288 (defun gnus-inews-yank-articles (articles)
 289   (let (beg article)
 290     (message-goto-body)
 291     (while (setq article (pop articles))
 292       (save-window-excursion
 293         (set-buffer gnus-summary-buffer)
 294         (gnus-summary-select-article nil nil nil article)
 295         (gnus-summary-remove-process-mark article))
 296       (gnus-copy-article-buffer)
 297       (let ((message-reply-buffer gnus-article-copy)
 298             (message-reply-headers gnus-current-headers))
 299         (message-yank-original)
 300         (setq beg (or beg (mark t))))
 301       (when articles
 302         (insert "\n")))
 303     (push-mark)
 304     (goto-char beg)))
 305
 306 (defun gnus-summary-cancel-article (&optional n symp)
 307   "Cancel an article you posted.
 308 Uses the process-prefix convention.  If given the symbolic
 309 prefix `a', cancel using the standard posting method; if not
 310 post using the current select method."
 311   (interactive (gnus-interactive "P\ny"))
 312   (let ((articles (gnus-summary-work-articles n))
 313         (message-post-method
 314          `(lambda (arg)
 315             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 316         article)
 317     (while (setq article (pop articles))
 318       (when (gnus-summary-select-article t nil nil article)
 319         (when (gnus-eval-in-buffer-window gnus-article-buffer
 320                 (save-excursion
 321                   (set-buffer gnus-original-article-buffer)
 322                   (message-cancel-news)))
 323           (gnus-summary-mark-as-read article gnus-canceled-mark)
 324           (gnus-cache-remove-article 1))
 325         (gnus-article-hide-headers-if-wanted))
 326       (gnus-summary-remove-process-mark article))))
 327
 328 (defun gnus-summary-supersede-article ()
 329   "Compose an article that will supersede a previous article.
 330 This is done simply by taking the old article and adding a Supersedes
 331 header line with the old Message-ID."
 332   (interactive)
 333   (let ((article (gnus-summary-article-number)))
 334     (gnus-setup-message 'reply-yank
 335       (gnus-summary-select-article t)
 336       (set-buffer gnus-original-article-buffer)
 337       (message-supersede)
 338       (push
 339        `((lambda ()
 340            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 341              (save-excursion
 342                (set-buffer ,gnus-summary-buffer)
 343                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 344                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 345        message-send-actions))))
 346
 347 \f
 348
 349 (defun gnus-copy-article-buffer (&optional article-buffer)
 350   ;; make a copy of the article buffer with all text properties removed
 351   ;; this copy is in the buffer gnus-article-copy.
 352   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 353   ;; this buffer should be passed to all mail/news reply/post routines.
 354   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 355   (buffer-disable-undo gnus-article-copy)
 356   (let ((article-buffer (or article-buffer gnus-article-buffer))
 357         end beg contents)
 358     (if (not (and (get-buffer article-buffer)
 359                   (gnus-buffer-exists-p article-buffer)))
 360         (error "Can't find any article buffer")
 361       (save-excursion
 362         (set-buffer article-buffer)
 363         (save-restriction
 364           ;; Copy over the (displayed) article buffer, delete
 365           ;; hidden text and remove text properties.
 366           (widen)
 367           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 368           (set-buffer gnus-article-copy)
 369           (gnus-article-delete-text-of-type 'annotation)
 370           (gnus-remove-text-with-property 'gnus-prev)
 371           (gnus-remove-text-with-property 'gnus-next)
 372           (insert
 373            (prog1
 374                (format "%s" (buffer-string))
 375              (erase-buffer)))
 376           ;; Find the original headers.
 377           (set-buffer gnus-original-article-buffer)
 378           (goto-char (point-min))
 379           (while (looking-at message-unix-mail-delimiter)
 380             (forward-line 1))
 381           (setq beg (point))
 382           (setq end (or (search-forward "\n\n" nil t) (point)))
 383           ;; Delete the headers from the displayed articles.
 384           (set-buffer gnus-article-copy)
 385           (delete-region (goto-char (point-min))
 386                          (or (search-forward "\n\n" nil t) (point)))
 387           ;; Insert the original article headers.
 388           (insert-buffer-substring gnus-original-article-buffer beg end)
 389           (gnus-article-decode-rfc1522)))
 390       gnus-article-copy)))
 391
 392 (defun gnus-post-news (post &optional group header article-buffer yank subject
 393                             force-news)
 394   (when article-buffer
 395     (gnus-copy-article-buffer))
 396   (let ((gnus-article-reply article-buffer)
 397         (add-to-list gnus-add-to-list))
 398     (gnus-setup-message (cond (yank 'reply-yank)
 399                               (article-buffer 'reply)
 400                               (t 'message))
 401       (let* ((group (or group gnus-newsgroup-name))
 402              (pgroup group)
 403              to-address to-group mailing-list to-list
 404              newsgroup-p)
 405         (when group
 406           (setq to-address (gnus-group-find-parameter group 'to-address)
 407                 to-group (gnus-group-find-parameter group 'to-group)
 408                 to-list (gnus-group-find-parameter group 'to-list)
 409                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 410                 mailing-list (when gnus-mailing-list-groups
 411                                (string-match gnus-mailing-list-groups group))
 412                 group (gnus-group-real-name group)))
 413         (if (or (and to-group
 414                      (gnus-news-group-p to-group))
 415                 newsgroup-p
 416                 force-news
 417                 (and (gnus-news-group-p
 418                       (or pgroup gnus-newsgroup-name)
 419                       (if header (mail-header-number header)
 420                         gnus-current-article))
 421                      (not mailing-list)
 422                      (not to-list)
 423                      (not to-address)))
 424             ;; This is news.
 425             (if post
 426                 (message-news (or to-group group))
 427               (set-buffer gnus-article-copy)
 428               (gnus-msg-treat-broken-reply-to)
 429               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 430           ;; The is mail.
 431           (if post
 432               (progn
 433                 (message-mail (or to-address to-list))
 434                 ;; Arrange for mail groups that have no `to-address' to
 435                 ;; get that when the user sends off the mail.
 436                 (when (and (not to-list)
 437                            (not to-address)
 438                            add-to-list)
 439                   (push (list 'gnus-inews-add-to-address pgroup)
 440                         message-send-actions)))
 441             (set-buffer gnus-article-copy)
 442             (gnus-msg-treat-broken-reply-to)
 443             (message-wide-reply to-address)))
 444         (when yank
 445           (gnus-inews-yank-articles yank))))))
 446
 447 (defun gnus-msg-treat-broken-reply-to ()
 448   "Remove the Reply-to header iff broken-reply-to."
 449   (when (gnus-group-find-parameter
 450          gnus-newsgroup-name 'broken-reply-to)
 451     (save-restriction
 452       (message-narrow-to-head)
 453       (message-remove-header "reply-to"))))
 454
 455 (defun gnus-post-method (arg group &optional silent)
 456   "Return the posting method based on GROUP and ARG.
 457 If SILENT, don't prompt the user."
 458   (let ((group-method (gnus-find-method-for-group group)))
 459     (cond
 460      ;; If the group-method is nil (which shouldn't happen) we use
 461      ;; the default method.
 462      ((null group-method)
 463       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 464                gnus-select-method message-post-method))
 465      ;; We want the inverse of the default
 466      ((and arg (not (eq arg 0)))
 467       (if (eq gnus-post-method 'active)
 468           gnus-select-method
 469         group-method))
 470      ;; We query the user for a post method.
 471      ((or arg
 472           (and gnus-post-method
 473                (not (eq gnus-post-method 'current))
 474                (listp (car gnus-post-method))))
 475       (let* ((methods
 476               ;; Collect all methods we know about.
 477               (append
 478                (when (and gnus-post-method
 479                           (not (eq gnus-post-method 'current)))
 480                  (if (listp (car gnus-post-method))
 481                      gnus-post-method
 482                    (list gnus-post-method)))
 483                gnus-secondary-select-methods
 484                (mapcar 'cdr gnus-server-alist)
 485                (list gnus-select-method)
 486                (list group-method)))
 487              method-alist post-methods method)
 488         ;; Weed out all mail methods.
 489         (while methods
 490           (setq method (gnus-server-get-method "" (pop methods)))
 491           (when (or (gnus-method-option-p method 'post)
 492                     (gnus-method-option-p method 'post-mail))
 493             (push method post-methods)))
 494         ;; Create a name-method alist.
 495         (setq method-alist
 496               (mapcar
 497                (lambda (m)
 498                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 499                post-methods))
 500         ;; Query the user.
 501         (cadr
 502          (assoc
 503           (setq gnus-last-posting-server
 504                 (if (and silent
 505                          gnus-last-posting-server)
 506                     ;; Just use the last value.
 507                     gnus-last-posting-server
 508                   (completing-read
 509                    "Posting method: " method-alist nil t
 510                    (cons (or gnus-last-posting-server "") 0))))
 511           method-alist))))
 512      ;; Override normal method.
 513      ((and (eq gnus-post-method 'current)
 514            (not (eq (car group-method) 'nndraft))
 515            (not arg))
 516       group-method)
 517      (gnus-post-method
 518       gnus-post-method)
 519      ;; Use the normal select method.
 520      (t gnus-select-method))))
 521
 522 \f
 523
 524 ;; Dummy to avoid byte-compile warning.
 525 (defvar nnspool-rejected-article-hook)
 526 (defvar mule-version)
 527 (defvar xemacs-betaname)
 528 (defvar xemacs-codename)
 529
 530 (defun gnus-extended-version ()
 531   "Stringified Gnus version and Emacs version."
 532   (interactive) ; ???
 533   (concat
 534    ;; Semi-gnus/VERSION
 535    gnus-product-name "/" gnus-version-number
 536    ;; EMACS/VERSION
 537    (if (featurep 'xemacs)
 538        ;; XEmacs
 539        (concat
 540         (format " XEmacs/%d.%d%s" emacs-major-version emacs-minor-version
 541                 (if (and (boundp 'xemacs-betaname) xemacs-betaname)
 542                     (if (string-match "\\`(\\(.*\\))\\'" xemacs-betaname)
 543                         (match-string 1 xemacs-betaname)
 544                       "")               ; unknown format
 545                   ""))                  ; not beta
 546         (if (boundp 'xemacs-codename)
 547             (concat " (" xemacs-codename ")")
 548           "")                           ; no codename
 549         )
 550      ;; not XEmacs
 551      (concat
 552       (format " Emacs/%d.%d" emacs-major-version emacs-minor-version)
 553       (if (and (boundp 'enable-multibyte-characters)
 554                enable-multibyte-characters)
 555           ;; Should return " (multibyte)" ?
 556           ""
 557         " (unibyte)")
 558       ))
 559    ;; MULE[/VERSION]
 560    (if (featurep 'mule)
 561        (if (and (boundp 'mule-version) mule-version)
 562            (concat " MULE/" mule-version)
 563          " MULE")                       ; no mule-version
 564      "")                                ; not Mule
 565    ;; Meadow/VERSION
 566    (if (featurep 'meadow)
 567        (let ((version (Meadow-version)))
 568          (if (string-match "\\`Meadow.\\([^ ]*\\)\\( (.*)\\)\\'" version)
 569              (concat " Meadow/"
 570                      (match-string 1 version)
 571                      (match-string 2 version)
 572                      )
 573            "Meadow"))                   ; unknown format
 574      "")                                ; not Meadow
 575    ))
 576
 577 \f
 578 ;;;
 579 ;;; Gnus Mail Functions
 580 ;;;
 581
 582 ;;; Mail reply commands of Gnus summary mode
 583
 584 (defun gnus-summary-reply (&optional yank wide)
 585   "Start composing a reply mail to the current message.
 586 If prefix argument YANK is non-nil, the original article is yanked
 587 automatically."
 588   (interactive
 589    (list (and current-prefix-arg
 590               (gnus-summary-work-articles 1))))
 591   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 592   (when yank
 593     (gnus-summary-goto-subject (car yank)))
 594   (let ((gnus-article-reply t))
 595     (gnus-setup-message (if yank 'reply-yank 'reply)
 596       (gnus-summary-select-article)
 597       (set-buffer (gnus-copy-article-buffer))
 598       (gnus-msg-treat-broken-reply-to)
 599       (message-reply nil wide)
 600       (when yank
 601         (gnus-inews-yank-articles yank)))))
 602
 603 (defun gnus-summary-reply-with-original (n &optional wide)
 604   "Start composing a reply mail to the current message.
 605 The original article will be yanked."
 606   (interactive "P")
 607   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 608
 609 (defun gnus-summary-wide-reply (&optional yank)
 610   "Start composing a wide reply mail to the current message.
 611 If prefix argument YANK is non-nil, the original article is yanked
 612 automatically."
 613   (interactive
 614    (list (and current-prefix-arg
 615               (gnus-summary-work-articles 1))))
 616   (gnus-summary-reply yank t))
 617
 618 (defun gnus-summary-wide-reply-with-original (n)
 619   "Start composing a wide reply mail to the current message.
 620 The original article will be yanked."
 621   (interactive "P")
 622   (gnus-summary-reply-with-original n t))
 623
 624 (defun gnus-summary-mail-forward (&optional full-headers post)
 625   "Forward the current message to another user.
 626 If FULL-HEADERS (the prefix), include full headers when forwarding."
 627   (interactive "P")
 628   (gnus-setup-message 'forward
 629     (gnus-summary-select-article)
 630     (let ((charset default-mime-charset))
 631       (set-buffer gnus-original-article-buffer)
 632       (make-local-variable 'default-mime-charset)
 633       (setq default-mime-charset charset)
 634       )
 635     (let ((message-included-forward-headers
 636            (if full-headers "" message-included-forward-headers)))
 637       (message-forward post))))
 638
 639 (defun gnus-summary-resend-message (address n)
 640   "Resend the current article to ADDRESS."
 641   (interactive "sResend message(s) to: \nP")
 642   (let ((articles (gnus-summary-work-articles n))
 643         article)
 644     (while (setq article (pop articles))
 645       (gnus-summary-select-article nil nil nil article)
 646       (save-excursion
 647         (set-buffer gnus-original-article-buffer)
 648         (message-resend address)))))
 649
 650 (defun gnus-summary-post-forward (&optional full-headers)
 651   "Forward the current article to a newsgroup.
 652 If FULL-HEADERS (the prefix), include full headers when forwarding."
 653   (interactive "P")
 654   (gnus-summary-mail-forward full-headers t))
 655
 656 (defvar gnus-nastygram-message
 657   "The following article was inappropriately posted to %s.\n\n"
 658   "Format string to insert in nastygrams.
 659 The current group name will be inserted at \"%s\".")
 660
 661 (defun gnus-summary-mail-nastygram (n)
 662   "Send a nastygram to the author of the current article."
 663   (interactive "P")
 664   (when (or gnus-expert-user
 665             (gnus-y-or-n-p
 666              "Really send a nastygram to the author of the current article? "))
 667     (let ((group gnus-newsgroup-name))
 668       (gnus-summary-reply-with-original n)
 669       (set-buffer gnus-message-buffer)
 670       (message-goto-body)
 671       (insert (format gnus-nastygram-message group))
 672       (message-send-and-exit))))
 673
 674 (defun gnus-summary-mail-crosspost-complaint (n)
 675   "Send a complaint about crossposting to the current article(s)."
 676   (interactive "P")
 677   (let ((articles (gnus-summary-work-articles n))
 678         article)
 679     (while (setq article (pop articles))
 680       (set-buffer gnus-summary-buffer)
 681       (gnus-summary-goto-subject article)
 682       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 683             newsgroups followup-to)
 684         (gnus-summary-select-article)
 685         (set-buffer gnus-original-article-buffer)
 686         (if (and (<= (length (message-tokenize-header
 687                               (setq newsgroups (mail-fetch-field "newsgroups"))
 688                               ", "))
 689                      1)
 690                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 691                      (not (member group (message-tokenize-header
 692                                          followup-to ", ")))))
 693             (if followup-to
 694                 (gnus-message 1 "Followup-to restricted")
 695               (gnus-message 1 "Not a crossposted article"))
 696           (set-buffer gnus-summary-buffer)
 697           (gnus-summary-reply-with-original 1)
 698           (set-buffer gnus-message-buffer)
 699           (message-goto-body)
 700           (insert (format gnus-crosspost-complaint newsgroups group))
 701           (message-goto-subject)
 702           (re-search-forward " *$")
 703           (replace-match " (crosspost notification)" t t)
 704           (gnus-deactivate-mark)
 705           (when (gnus-y-or-n-p "Send this complaint? ")
 706             (message-send-and-exit)))))))
 707
 708 (defun gnus-summary-mail-other-window ()
 709   "Compose mail in other window."
 710   (interactive)
 711   (gnus-setup-message 'message
 712     (message-mail)))
 713
 714 (defun gnus-mail-parse-comma-list ()
 715   (let (accumulated
 716         beg)
 717     (skip-chars-forward " ")
 718     (while (not (eobp))
 719       (setq beg (point))
 720       (skip-chars-forward "^,")
 721       (while (zerop
 722               (save-excursion
 723                 (save-restriction
 724                   (let ((i 0))
 725                     (narrow-to-region beg (point))
 726                     (goto-char beg)
 727                     (logand (progn
 728                               (while (search-forward "\"" nil t)
 729                                 (incf i))
 730                               (if (zerop i) 2 i))
 731                             2)))))
 732         (skip-chars-forward ",")
 733         (skip-chars-forward "^,"))
 734       (skip-chars-backward " ")
 735       (push (buffer-substring beg (point))
 736             accumulated)
 737       (skip-chars-forward "^,")
 738       (skip-chars-forward ", "))
 739     accumulated))
 740
 741 (defun gnus-inews-add-to-address (group)
 742   (let ((to-address (mail-fetch-field "to")))
 743     (when (and to-address
 744                (gnus-alive-p))
 745       ;; This mail group doesn't have a `to-list', so we add one
 746       ;; here.  Magic!
 747       (when (gnus-y-or-n-p
 748              (format "Do you want to add this as `to-list': %s " to-address))
 749         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 750
 751 (defun gnus-put-message ()
 752   "Put the current message in some group and return to Gnus."
 753   (interactive)
 754   (let ((reply gnus-article-reply)
 755         (winconf gnus-prev-winconf)
 756         (group gnus-newsgroup-name))
 757
 758     (or (and group (not (gnus-group-read-only-p group)))
 759         (setq group (read-string "Put in group: " nil
 760                                  (gnus-writable-groups))))
 761     (when (gnus-gethash group gnus-newsrc-hashtb)
 762       (error "No such group: %s" group))
 763
 764     (save-excursion
 765       (save-restriction
 766         (widen)
 767         (message-narrow-to-headers)
 768         (let (gnus-deletable-headers)
 769           (if (message-news-p)
 770               (message-generate-headers message-required-news-headers)
 771             (message-generate-headers message-required-mail-headers)))
 772         (goto-char (point-max))
 773         (insert "Gcc: " group "\n")
 774         (widen)))
 775
 776     (gnus-inews-do-gcc)
 777
 778     (when (get-buffer gnus-group-buffer)
 779       (when (gnus-buffer-exists-p (car-safe reply))
 780         (set-buffer (car reply))
 781         (and (cdr reply)
 782              (gnus-summary-mark-article-as-replied
 783               (cdr reply))))
 784       (when winconf
 785         (set-window-configuration winconf)))))
 786
 787 (defun gnus-article-mail (yank)
 788   "Send a reply to the address near point.
 789 If YANK is non-nil, include the original article."
 790   (interactive "P")
 791   (let ((address
 792          (buffer-substring
 793           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 794           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 795     (when address
 796       (message-reply address)
 797       (when yank
 798         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 799
 800 (defvar nntp-server-type)
 801 (defun gnus-bug ()
 802   "Send a bug report to the Gnus maintainers."
 803   (interactive)
 804   (unless (gnus-alive-p)
 805     (error "Gnus has been shut down"))
 806   (gnus-setup-message 'bug
 807     (delete-other-windows)
 808     (when gnus-bug-create-help-buffer
 809       (switch-to-buffer "*Gnus Help Bug*")
 810       (erase-buffer)
 811       (insert gnus-bug-message)
 812       (goto-char (point-min)))
 813     (message-pop-to-buffer "*Gnus Bug*")
 814     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 815     (when gnus-bug-create-help-buffer
 816       (push `(gnus-bug-kill-buffer) message-send-actions))
 817     (goto-char (point-min))
 818     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 819     (forward-line 1)
 820     (insert (gnus-version) "\n"
 821             (emacs-version) "\n")
 822     (when (and (boundp 'nntp-server-type)
 823                (stringp nntp-server-type))
 824       (insert nntp-server-type))
 825     (insert "\n\n\n\n\n")
 826     (gnus-debug)
 827     (goto-char (point-min))
 828     (search-forward "Subject: " nil t)
 829     (message "")))
 830
 831 (defun gnus-bug-kill-buffer ()
 832   (when (get-buffer "*Gnus Help Bug*")
 833     (kill-buffer "*Gnus Help Bug*")))
 834
 835 (defun gnus-debug ()
 836   "Attempts to go through the Gnus source file and report what variables have been changed.
 837 The source file has to be in the Emacs load path."
 838   (interactive)
 839   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 840                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 841                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 842                  "nnmail.el" "message.el"))
 843         (point (point))
 844         file expr olist sym)
 845     (gnus-message 4 "Please wait while we snoop your variables...")
 846     (sit-for 0)
 847     ;; Go through all the files looking for non-default values for variables.
 848     (save-excursion
 849       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
 850       (buffer-disable-undo (current-buffer))
 851       (while files
 852         (erase-buffer)
 853         (when (and (setq file (locate-library (pop files)))
 854                    (file-exists-p file))
 855           (insert-file-contents file)
 856           (goto-char (point-min))
 857           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 858               (gnus-message 4 "Malformed sources in file %s" file)
 859             (narrow-to-region (point-min) (point))
 860             (goto-char (point-min))
 861             (while (setq expr (ignore-errors (read (current-buffer))))
 862               (ignore-errors
 863                 (and (or (eq (car expr) 'defvar)
 864                          (eq (car expr) 'defcustom))
 865                      (stringp (nth 3 expr))
 866                      (or (not (boundp (nth 1 expr)))
 867                          (not (equal (eval (nth 2 expr))
 868                                      (symbol-value (nth 1 expr)))))
 869                      (push (nth 1 expr) olist)))))))
 870       (kill-buffer (current-buffer)))
 871     (when (setq olist (nreverse olist))
 872       (insert "------------------ Environment follows ------------------\n\n"))
 873     (while olist
 874       (if (boundp (car olist))
 875           (condition-case ()
 876               (pp `(setq ,(car olist)
 877                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 878                                   (and (symbolp sym)
 879                                        (not (or (eq sym nil)
 880                                                 (eq sym t)))))
 881                               (list 'quote (symbol-value (car olist)))
 882                             (symbol-value (car olist))))
 883                   (current-buffer))
 884             (error
 885              (format "(setq %s 'whatever)\n" (car olist))))
 886         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 887       (setq olist (cdr olist)))
 888     (insert "\n\n")
 889     ;; Remove any control chars - they seem to cause trouble for some
 890     ;; mailers.  (Byte-compiled output from the stuff above.)
 891     (goto-char point)
 892     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 893       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 894                      t t))))
 895
 896 ;;; Treatment of rejected articles.
 897 ;;; Bounced mail.
 898
 899 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 900   "Re-mail the current message.
 901 This only makes sense if the current message is a bounce message than
 902 contains some mail you have written which has been bounced back to
 903 you.
 904 If FETCH, try to fetch the article that this is a reply to, if indeed
 905 this is a reply."
 906   (interactive "P")
 907   (gnus-summary-select-article t)
 908   (set-buffer gnus-original-article-buffer)
 909   (gnus-setup-message 'compose-bounce
 910     (let* ((references (mail-fetch-field "references"))
 911            (parent (and references (gnus-parent-id references))))
 912       (message-bounce)
 913       ;; If there are references, we fetch the article we answered to.
 914       (and fetch parent
 915            (gnus-summary-refer-article parent)
 916            (gnus-summary-show-all-headers)))))
 917
 918 ;;; Gcc handling.
 919
 920 ;; Do Gcc handling, which copied the message over to some group.
 921 (defun gnus-inews-do-gcc (&optional gcc)
 922   (interactive)
 923   (when (gnus-alive-p)
 924     (save-excursion
 925       (save-restriction
 926         (message-narrow-to-headers)
 927         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 928               (coding-system-for-write 'raw-text)
 929               groups group method)
 930           (when gcc
 931             (message-remove-header "gcc")
 932             (widen)
 933             (setq groups (message-tokenize-header gcc " ,"))
 934             ;; Copy the article over to some group(s).
 935             (while (setq group (pop groups))
 936               (gnus-check-server
 937                (setq method
 938                      (cond ((and (null (gnus-get-info group))
 939                                  (eq (car gnus-message-archive-method)
 940                                      (car
 941                                       (gnus-server-to-method
 942                                        (gnus-group-method group)))))
 943                             ;; If the group doesn't exist, we assume
 944                             ;; it's an archive group...
 945                             gnus-message-archive-method)
 946                            ;; Use the method.
 947                            ((gnus-info-method (gnus-get-info group))
 948                             (gnus-info-method (gnus-get-info group)))
 949                            ;; Find the method.
 950                            (t (gnus-group-method group)))))
 951               (gnus-check-server method)
 952               (unless (gnus-request-group group t method)
 953                 (gnus-request-create-group group method))
 954               (save-excursion
 955                 (nnheader-set-temp-buffer " *acc*")
 956                 (insert-buffer-substring message-encoding-buffer)
 957                 (gnus-run-hooks 'gnus-before-do-gcc-hook)
 958                 (goto-char (point-min))
 959                 (when (re-search-forward
 960                        (concat "^" (regexp-quote mail-header-separator) "$")
 961                        nil t)
 962                   (replace-match "" t t ))
 963                 (unless (gnus-request-accept-article group method t)
 964                   (gnus-message 1 "Couldn't store article in group %s: %s"
 965                                 group (gnus-status-message method))
 966                   (sit-for 2))
 967                 (kill-buffer (current-buffer))))))))))
 968
 969 (defun gnus-inews-insert-gcc ()
 970   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 971   (save-excursion
 972     (save-restriction
 973       (message-narrow-to-headers)
 974       (let* ((group gnus-outgoing-message-group)
 975              (gcc (cond
 976                    ((gnus-functionp group)
 977                     (funcall group))
 978                    ((or (stringp group) (list group))
 979                     group))))
 980         (when gcc
 981           (insert "Gcc: "
 982                   (if (stringp gcc) gcc
 983                     (mapconcat 'identity gcc " "))
 984                   "\n"))))))
 985
 986 (defun gnus-inews-insert-archive-gcc (&optional group)
 987   "Insert the Gcc to say where the article is to be archived."
 988   (let* ((var gnus-message-archive-group)
 989          (group (or group gnus-newsgroup-name ""))
 990          (gcc-self-val
 991           (and gnus-newsgroup-name
 992                (gnus-group-find-parameter
 993                 gnus-newsgroup-name 'gcc-self)))
 994          result
 995          (groups
 996           (cond
 997            ((null gnus-message-archive-method)
 998             ;; Ignore.
 999             nil)
1000            ((stringp var)
1001             ;; Just a single group.
1002             (list var))
1003            ((null var)
1004             ;; We don't want this.
1005             nil)
1006            ((and (listp var) (stringp (car var)))
1007             ;; A list of groups.
1008             var)
1009            ((gnus-functionp var)
1010             ;; A function.
1011             (funcall var group))
1012            (t
1013             ;; An alist of regexps/functions/forms.
1014             (while (and var
1015                         (not
1016                          (setq result
1017                                (cond
1018                                 ((stringp (caar var))
1019                                  ;; Regexp.
1020                                  (when (string-match (caar var) group)
1021                                    (cdar var)))
1022                                 ((gnus-functionp (car var))
1023                                  ;; Function.
1024                                  (funcall (car var) group))
1025                                 (t
1026                                  (eval (car var)))))))
1027               (setq var (cdr var)))
1028             result)))
1029          name)
1030     (when (or groups gcc-self-val)
1031       (when (stringp groups)
1032         (setq groups (list groups)))
1033       (save-excursion
1034         (save-restriction
1035           (message-narrow-to-headers)
1036           (goto-char (point-max))
1037           (insert "Gcc: ")
1038           (if gcc-self-val
1039               ;; Use the `gcc-self' param value instead.
1040               (progn
1041                 (insert
1042                  (if (stringp gcc-self-val)
1043                      gcc-self-val
1044                    group))
1045                 (if (not (eq gcc-self-val 'none))
1046                     (insert "\n")
1047                   (progn
1048                     (beginning-of-line)
1049                     (kill-line))))
1050             ;; Use the list of groups.
1051             (while (setq name (pop groups))
1052               (insert (if (string-match ":" name)
1053                           name
1054                         (gnus-group-prefixed-name
1055                          name gnus-message-archive-method)))
1056               (when groups
1057                 (insert " ")))
1058             (insert "\n")))))))
1059
1060 ;;; Posting styles.
1061
1062 (defun gnus-configure-posting-styles ()
1063   "Configure posting styles according to `gnus-posting-styles'."
1064   (let ((styles gnus-posting-styles)
1065         (gnus-newsgroup-name (or gnus-newsgroup-name ""))
1066         style match variable attribute value value-value)
1067     ;; Go through all styles and look for matches.
1068     (while styles
1069       (setq style (pop styles)
1070             match (pop style))
1071       (when (cond ((stringp match)
1072                    ;; Regexp string match on the group name.
1073                    (string-match match gnus-newsgroup-name))
1074                   ((or (symbolp match)
1075                        (gnus-functionp match))
1076                    (cond ((gnus-functionp match)
1077                           ;; Function to be called.
1078                           (funcall match))
1079                          ((boundp match)
1080                           ;; Variable to be checked.
1081                           (symbol-value match))))
1082                   ((listp match)
1083                    ;; This is a form to be evaled.
1084                    (eval match)))
1085         ;; We have a match, so we set the variables.
1086         (while style
1087           (setq attribute (pop style)
1088                 value (cadr attribute)
1089                 variable nil)
1090           ;; We find the variable that is to be modified.
1091           (if (and (not (stringp (car attribute)))
1092                    (not (eq 'body (car attribute)))
1093                    (not (setq variable (cdr (assq (car attribute)
1094                                                   gnus-posting-style-alist)))))
1095               (message "Couldn't find attribute %s" (car attribute))
1096             ;; We get the value.
1097             (setq value-value
1098                   (cond ((stringp value)
1099                          value)
1100                         ((or (symbolp value)
1101                              (gnus-functionp value))
1102                          (cond ((gnus-functionp value)
1103                                 (funcall value))
1104                                ((boundp value)
1105                                 (symbol-value value))))
1106                         ((listp value)
1107                          (eval value))))
1108             (if variable
1109                 ;; This is an ordinary variable.
1110                 (set (make-local-variable variable) value-value)
1111               ;; This is either a body or a header to be inserted in the
1112               ;; message
1113               (when value-value
1114                 (let ((attr (car attribute)))
1115                   (if (eq 'body attr)
1116                       (save-excursion
1117                         (goto-char (point-max))
1118                         (insert value-value))
1119                     (save-excursion
1120                       (message-goto-eoh)
1121                       (insert (if (stringp attr) attr (symbol-name attr))
1122                               ": " value-value "\n"))))))))))))
1123
1124 ;;; Allow redefinition of functions.
1125
1126 (gnus-ems-redefine)
1127
1128 (provide 'gnus-msg)
1129
1130 ;;; gnus-msg.el ends here