git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Semi-gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;         Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Keywords: mail, news, MIME
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method nil
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current', Gnus will use the \"current\" select
  41 method when posting.  If it is nil (which is the default), Gnus will
  42 use the native posting method of the server.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not nil nor `native', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'. It can also be a list of
  49 methods. If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :type `(choice (const nil)
  53                  (const current)
  54                  (const native)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defvar gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names).")
  67
  68 (defvar gnus-mailing-list-groups nil
  69   "*Regexp matching groups that are really mailing lists.
  70 This is useful when you're reading a mailing list that has been
  71 gatewayed to a newsgroup, and you want to followup to an article in
  72 the group.")
  73
  74 (defvar gnus-add-to-list nil
  75   "*If non-nil, add a `to-list' parameter automatically.")
  76
  77 (defvar gnus-crosspost-complaint
  78   "Hi,
  79
  80 You posted the article below with the following Newsgroups header:
  81
  82 Newsgroups: %s
  83
  84 The %s group, at least, was an inappropriate recipient
  85 of this message.  Please trim your Newsgroups header to exclude this
  86 group before posting in the future.
  87
  88 Thank you.
  89
  90 "
  91   "Format string to be inserted when complaining about crossposts.
  92 The first %s will be replaced by the Newsgroups header;
  93 the second with the current group name.")
  94
  95 (defvar gnus-message-setup-hook nil
  96   "Hook run after setting up a message buffer.")
  97
  98 (defvar gnus-bug-create-help-buffer t
  99   "*Should we create the *Gnus Help Bug* buffer?")
 100
 101 ;;; Internal variables.
 102
 103 (defvar gnus-message-buffer "*Mail Gnus*")
 104 (defvar gnus-article-copy nil)
 105 (defvar gnus-last-posting-server nil)
 106 (defvar gnus-message-group-art nil)
 107
 108 (defconst gnus-bug-message
 109   "Sending a bug report to the Gnus Towers.
 110 ========================================
 111
 112 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 113 be sent to the Gnus Bug Exterminators.
 114
 115 At the bottom of the buffer you'll see lots of variable settings.
 116 Please do not delete those.  They will tell the Bug People what your
 117 environment is, so that it will be easier to locate the bugs.
 118
 119 If you have found a bug that makes Emacs go \"beep\", set
 120 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 121 and include the backtrace in your bug report.
 122
 123 Please describe the bug in annoying, painstaking detail.
 124
 125 Thank you for your help in stamping out bugs.
 126 ")
 127
 128 (eval-and-compile
 129   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 130   (autoload 'news-setup "rnewspost")
 131   (autoload 'news-reply-mode "rnewspost")
 132   (autoload 'rmail-dont-reply-to "mail-utils")
 133   (autoload 'rmail-output "rmailout"))
 134
 135 \f
 136 ;;;
 137 ;;; Gnus Posting Functions
 138 ;;;
 139
 140 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 141   "p" gnus-summary-post-news
 142   "f" gnus-summary-followup
 143   "F" gnus-summary-followup-with-original
 144   "c" gnus-summary-cancel-article
 145   "s" gnus-summary-supersede-article
 146   "r" gnus-summary-reply
 147   "R" gnus-summary-reply-with-original
 148   "w" gnus-summary-wide-reply
 149   "W" gnus-summary-wide-reply-with-original
 150   "n" gnus-summary-followup-to-mail
 151   "N" gnus-summary-followup-to-mail-with-original
 152   "m" gnus-summary-mail-other-window
 153   "u" gnus-uu-post-news
 154   "\M-c" gnus-summary-mail-crosspost-complaint
 155   "om" gnus-summary-mail-forward
 156   "op" gnus-summary-post-forward
 157   "Om" gnus-uu-digest-mail-forward
 158   "Op" gnus-uu-digest-post-forward)
 159
 160 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 161   "b" gnus-summary-resend-bounced-mail
 162   ;; "c" gnus-summary-send-draft
 163   "r" gnus-summary-resend-message)
 164
 165 ;;; Internal functions.
 166
 167 (defvar gnus-article-reply nil)
 168 (defmacro gnus-setup-message (config &rest forms)
 169   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 170         (buffer (make-symbol "gnus-setup-message-buffer"))
 171         (article (make-symbol "gnus-setup-message-article"))
 172         (group (make-symbol "gnus-setup-message-group")))
 173     `(let ((,winconf (current-window-configuration))
 174            (,buffer (buffer-name (current-buffer)))
 175            (,article (and gnus-article-reply (gnus-summary-article-number)))
 176            (,group gnus-newsgroup-name)
 177            (message-header-setup-hook
 178             (copy-sequence message-header-setup-hook)))
 179        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 180        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 181        (unwind-protect
 182            (progn
 183              ,@forms)
 184          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 185          (setq gnus-message-buffer (current-buffer))
 186          (set (make-local-variable 'gnus-message-group-art)
 187               (cons ,group ,article))
 188          (make-local-variable 'gnus-newsgroup-name)
 189          (gnus-run-hooks 'gnus-message-setup-hook))
 190        (gnus-configure-windows ,config t)
 191        (set-buffer-modified-p nil))))
 192
 193 (defun gnus-inews-add-send-actions (winconf buffer article)
 194   (make-local-hook 'message-sent-hook)
 195   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 196   (setq message-post-method
 197         `(lambda (arg)
 198            (gnus-post-method arg ,gnus-newsgroup-name)))
 199   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 200   (message-add-action
 201    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 202   (message-add-action
 203    `(when (gnus-buffer-exists-p ,buffer)
 204       (save-excursion
 205         (set-buffer ,buffer)
 206         ,(when article
 207            `(gnus-summary-mark-article-as-replied ,article))))
 208    'send))
 209
 210 (put 'gnus-setup-message 'lisp-indent-function 1)
 211 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 212
 213 ;;; Post news commands of Gnus group mode and summary mode
 214
 215 (defun gnus-group-mail ()
 216   "Start composing a mail."
 217   (interactive)
 218   (gnus-setup-message 'message
 219     (message-mail)))
 220
 221 (defun gnus-group-post-news (&optional arg)
 222   "Start composing a news message.
 223 If ARG, post to the group under point.
 224 If ARG is 1, prompt for a group name."
 225   (interactive "P")
 226   ;; Bind this variable here to make message mode hooks work ok.
 227   (let ((gnus-newsgroup-name
 228          (if arg
 229              (if (= 1 (prefix-numeric-value arg))
 230                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 231                                   (gnus-read-active-file-p))
 232                (gnus-group-group-name))
 233            "")))
 234     (gnus-post-news 'post gnus-newsgroup-name)))
 235
 236 (defun gnus-summary-post-news ()
 237   "Start composing a news message."
 238   (interactive)
 239   (gnus-post-news 'post gnus-newsgroup-name))
 240
 241 (defun gnus-summary-followup (yank &optional force-news)
 242   "Compose a followup to an article.
 243 If prefix argument YANK is non-nil, original article is yanked automatically."
 244   (interactive
 245    (list (and current-prefix-arg
 246               (gnus-summary-work-articles 1))))
 247   (when yank
 248     (gnus-summary-goto-subject (car yank)))
 249   (save-window-excursion
 250     (gnus-summary-select-article))
 251   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 252         (gnus-newsgroup-name gnus-newsgroup-name))
 253     ;; Send a followup.
 254     (gnus-post-news nil gnus-newsgroup-name
 255                     headers gnus-article-buffer
 256                     yank nil force-news)))
 257
 258 (defun gnus-summary-followup-with-original (n &optional force-news)
 259   "Compose a followup to an article and include the original article."
 260   (interactive "P")
 261   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 262
 263 (defun gnus-summary-followup-to-mail (&optional arg)
 264   "Followup to the current mail message via news."
 265   (interactive
 266    (list (and current-prefix-arg
 267               (gnus-summary-work-articles 1))))
 268   (gnus-summary-followup arg t))
 269
 270 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 271   "Followup to the current mail message via news."
 272   (interactive "P")
 273   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 274
 275 (defun gnus-inews-yank-articles (articles)
 276   (let (beg article)
 277     (message-goto-body)
 278     (while (setq article (pop articles))
 279       (save-window-excursion
 280         (set-buffer gnus-summary-buffer)
 281         (gnus-summary-select-article nil nil nil article)
 282         (gnus-summary-remove-process-mark article))
 283       (gnus-copy-article-buffer)
 284       (let ((message-reply-buffer gnus-article-copy)
 285             (message-reply-headers gnus-current-headers))
 286         (message-yank-original)
 287         (setq beg (or beg (mark t))))
 288       (when articles
 289         (insert "\n")))
 290     (push-mark)
 291     (goto-char beg)))
 292
 293 (defun gnus-summary-cancel-article (&optional n symp)
 294   "Cancel an article you posted.
 295 Uses the process-prefix convention.  If given the symbolic
 296 prefix `a', cancel using the standard posting method; if not
 297 post using the current select method."
 298   (interactive (gnus-interactive "P\ny"))
 299   (let ((articles (gnus-summary-work-articles n))
 300         (message-post-method
 301          `(lambda (arg)
 302             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 303         article)
 304     (while (setq article (pop articles))
 305       (when (gnus-summary-select-article t nil nil article)
 306         (when (gnus-eval-in-buffer-window gnus-article-buffer
 307                 (save-excursion
 308                   (set-buffer gnus-original-article-buffer)
 309                   (message-cancel-news)))
 310           (gnus-summary-mark-as-read article gnus-canceled-mark)
 311           (gnus-cache-remove-article 1))
 312         (gnus-article-hide-headers-if-wanted))
 313       (gnus-summary-remove-process-mark article))))
 314
 315 (defun gnus-summary-supersede-article ()
 316   "Compose an article that will supersede a previous article.
 317 This is done simply by taking the old article and adding a Supersedes
 318 header line with the old Message-ID."
 319   (interactive)
 320   (let ((article (gnus-summary-article-number)))
 321     (gnus-setup-message 'reply-yank
 322       (gnus-summary-select-article t)
 323       (set-buffer gnus-original-article-buffer)
 324       (message-supersede)
 325       (push
 326        `((lambda ()
 327            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 328              (save-excursion
 329                (set-buffer ,gnus-summary-buffer)
 330                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 331                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 332        message-send-actions))))
 333
 334 \f
 335
 336 (defun gnus-copy-article-buffer (&optional article-buffer)
 337   ;; make a copy of the article buffer with all text properties removed
 338   ;; this copy is in the buffer gnus-article-copy.
 339   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 340   ;; this buffer should be passed to all mail/news reply/post routines.
 341   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 342   (buffer-disable-undo gnus-article-copy)
 343   (or (memq gnus-article-copy gnus-buffer-list)
 344       (push gnus-article-copy gnus-buffer-list))
 345   (let ((article-buffer (or article-buffer gnus-article-buffer))
 346         end beg contents)
 347     (if (not (and (get-buffer article-buffer)
 348                   (gnus-buffer-exists-p article-buffer)))
 349         (error "Can't find any article buffer")
 350       (save-excursion
 351         (set-buffer article-buffer)
 352         (save-restriction
 353           ;; Copy over the (displayed) article buffer, delete
 354           ;; hidden text and remove text properties.
 355           (widen)
 356           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 357           (set-buffer gnus-article-copy)
 358           (gnus-article-delete-text-of-type 'annotation)
 359           (gnus-remove-text-with-property 'gnus-prev)
 360           (gnus-remove-text-with-property 'gnus-next)
 361           (insert
 362            (prog1
 363                (format "%s" (buffer-string))
 364              (erase-buffer)))
 365           ;; Find the original headers.
 366           (set-buffer gnus-original-article-buffer)
 367           (goto-char (point-min))
 368           (while (looking-at message-unix-mail-delimiter)
 369             (forward-line 1))
 370           (setq beg (point))
 371           (setq end (or (search-forward "\n\n" nil t) (point)))
 372           ;; Delete the headers from the displayed articles.
 373           (set-buffer gnus-article-copy)
 374           (delete-region (goto-char (point-min))
 375                          (or (search-forward "\n\n" nil t) (point)))
 376           ;; Insert the original article headers.
 377           (insert-buffer-substring gnus-original-article-buffer beg end)
 378           (gnus-article-decode-rfc1522)))
 379       gnus-article-copy)))
 380
 381 (defun gnus-post-news (post &optional group header article-buffer yank subject
 382                             force-news)
 383   (when article-buffer
 384     (gnus-copy-article-buffer))
 385   (let ((gnus-article-reply article-buffer)
 386         (add-to-list gnus-add-to-list))
 387     (gnus-setup-message (cond (yank 'reply-yank)
 388                               (article-buffer 'reply)
 389                               (t 'message))
 390       (let* ((group (or group gnus-newsgroup-name))
 391              (pgroup group)
 392              to-address to-group mailing-list to-list
 393              newsgroup-p)
 394         (when group
 395           (setq to-address (gnus-group-find-parameter group 'to-address)
 396                 to-group (gnus-group-find-parameter group 'to-group)
 397                 to-list (gnus-group-find-parameter group 'to-list)
 398                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 399                 mailing-list (when gnus-mailing-list-groups
 400                                (string-match gnus-mailing-list-groups group))
 401                 group (gnus-group-real-name group)))
 402         (if (or (and to-group
 403                      (gnus-news-group-p to-group))
 404                 newsgroup-p
 405                 force-news
 406                 (and (gnus-news-group-p
 407                       (or pgroup gnus-newsgroup-name)
 408                       (if header (mail-header-number header)
 409                         gnus-current-article))
 410                      (not mailing-list)
 411                      (not to-list)
 412                      (not to-address)))
 413             ;; This is news.
 414             (if post
 415                 (message-news (or to-group group))
 416               (set-buffer gnus-article-copy)
 417               (gnus-msg-treat-broken-reply-to)
 418               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 419           ;; The is mail.
 420           (if post
 421               (progn
 422                 (message-mail (or to-address to-list))
 423                 ;; Arrange for mail groups that have no `to-address' to
 424                 ;; get that when the user sends off the mail.
 425                 (when (and (not to-list)
 426                            (not to-address)
 427                            add-to-list)
 428                   (push (list 'gnus-inews-add-to-address pgroup)
 429                         message-send-actions)))
 430             (set-buffer gnus-article-copy)
 431             (gnus-msg-treat-broken-reply-to)
 432             (message-wide-reply to-address)))
 433         (when yank
 434           (gnus-inews-yank-articles yank))))))
 435
 436 (defun gnus-msg-treat-broken-reply-to ()
 437   "Remove the Reply-to header iff broken-reply-to."
 438   (when (gnus-group-find-parameter
 439          gnus-newsgroup-name 'broken-reply-to)
 440     (save-restriction
 441       (message-narrow-to-head)
 442       (message-remove-header "reply-to"))))
 443
 444 (defun gnus-post-method (arg group &optional silent)
 445   "Return the posting method based on GROUP and ARG.
 446 If SILENT, don't prompt the user."
 447   (let ((group-method (gnus-find-method-for-group group)))
 448     (cond
 449      ;; If the group-method is nil (which shouldn't happen) we use
 450      ;; the default method.
 451      ((null group-method)
 452       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 453                gnus-select-method message-post-method))
 454      ;; We want the inverse of the default
 455      ((and arg (not (eq arg 0)))
 456       (if (eq gnus-post-method 'active)
 457           gnus-select-method
 458         group-method))
 459      ;; We query the user for a post method.
 460      ((or arg
 461           (and gnus-post-method
 462                (not (eq gnus-post-method 'current))
 463                (listp (car gnus-post-method))))
 464       (let* ((methods
 465               ;; Collect all methods we know about.
 466               (append
 467                (when (and gnus-post-method
 468                           (not (eq gnus-post-method 'current)))
 469                  (if (listp (car gnus-post-method))
 470                      gnus-post-method
 471                    (list gnus-post-method)))
 472                gnus-secondary-select-methods
 473                (mapcar 'cdr gnus-server-alist)
 474                (list gnus-select-method)
 475                (list group-method)))
 476              method-alist post-methods method)
 477         ;; Weed out all mail methods.
 478         (while methods
 479           (setq method (gnus-server-get-method "" (pop methods)))
 480           (when (or (gnus-method-option-p method 'post)
 481                     (gnus-method-option-p method 'post-mail))
 482             (push method post-methods)))
 483         ;; Create a name-method alist.
 484         (setq method-alist
 485               (mapcar
 486                (lambda (m)
 487                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 488                post-methods))
 489         ;; Query the user.
 490         (cadr
 491          (assoc
 492           (setq gnus-last-posting-server
 493                 (if (and silent
 494                          gnus-last-posting-server)
 495                     ;; Just use the last value.
 496                     gnus-last-posting-server
 497                   (completing-read
 498                    "Posting method: " method-alist nil t
 499                    (cons (or gnus-last-posting-server "") 0))))
 500           method-alist))))
 501      ;; Override normal method.
 502      ((and (eq gnus-post-method 'current)
 503            (not arg))
 504       group-method)
 505      (gnus-post-method
 506       gnus-post-method)
 507      ;; Use the normal select method.
 508      (t gnus-select-method))))
 509
 510 \f
 511
 512 ;; Dummy to avoid byte-compile warning.
 513 (defvar nnspool-rejected-article-hook)
 514 (defvar xemacs-codename)
 515
 516 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 517 ;;; as well include the Emacs version as well.
 518 ;;; The following function works with later GNU Emacs, and XEmacs.
 519 (defun gnus-extended-version ()
 520   "Stringified gnus version."
 521   (interactive)
 522   gnus-version)
 523
 524 \f
 525 ;;;
 526 ;;; Gnus Mail Functions
 527 ;;;
 528
 529 ;;; Mail reply commands of Gnus summary mode
 530
 531 (defun gnus-summary-reply (&optional yank wide)
 532   "Start composing a reply mail to the current message.
 533 If prefix argument YANK is non-nil, the original article is yanked
 534 automatically."
 535   (interactive
 536    (list (and current-prefix-arg
 537               (gnus-summary-work-articles 1))))
 538   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 539   (when yank
 540     (gnus-summary-goto-subject (car yank)))
 541   (let ((gnus-article-reply t))
 542     (gnus-setup-message (if yank 'reply-yank 'reply)
 543       (gnus-summary-select-article)
 544       (set-buffer (gnus-copy-article-buffer))
 545       (gnus-msg-treat-broken-reply-to)
 546       (message-reply nil wide)
 547       (when yank
 548         (gnus-inews-yank-articles yank)))))
 549
 550 (defun gnus-summary-reply-with-original (n &optional wide)
 551   "Start composing a reply mail to the current message.
 552 The original article will be yanked."
 553   (interactive "P")
 554   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 555
 556 (defun gnus-summary-wide-reply (&optional yank)
 557   "Start composing a wide reply mail to the current message.
 558 If prefix argument YANK is non-nil, the original article is yanked
 559 automatically."
 560   (interactive
 561    (list (and current-prefix-arg
 562               (gnus-summary-work-articles 1))))
 563   (gnus-summary-reply yank t))
 564
 565 (defun gnus-summary-wide-reply-with-original (n)
 566   "Start composing a wide reply mail to the current message.
 567 The original article will be yanked."
 568   (interactive "P")
 569   (gnus-summary-reply-with-original n t))
 570
 571 (defun gnus-summary-mail-forward (&optional full-headers post)
 572   "Forward the current message to another user.
 573 If FULL-HEADERS (the prefix), include full headers when forwarding."
 574   (interactive "P")
 575   (gnus-setup-message 'forward
 576     (gnus-summary-select-article)
 577     (let ((charset default-mime-charset))
 578       (set-buffer gnus-original-article-buffer)
 579       (make-local-variable 'default-mime-charset)
 580       (setq default-mime-charset charset)
 581       )
 582     (let ((message-included-forward-headers
 583            (if full-headers "" message-included-forward-headers)))
 584       (message-forward post))))
 585
 586 (defun gnus-summary-resend-message (address n)
 587   "Resend the current article to ADDRESS."
 588   (interactive "sResend message(s) to: \nP")
 589   (let ((articles (gnus-summary-work-articles n))
 590         article)
 591     (while (setq article (pop articles))
 592       (gnus-summary-select-article nil nil nil article)
 593       (save-excursion
 594         (set-buffer gnus-original-article-buffer)
 595         (message-resend address)))))
 596
 597 (defun gnus-summary-post-forward (&optional full-headers)
 598   "Forward the current article to a newsgroup.
 599 If FULL-HEADERS (the prefix), include full headers when forwarding."
 600   (interactive "P")
 601   (gnus-summary-mail-forward full-headers t))
 602
 603 (defvar gnus-nastygram-message
 604   "The following article was inappropriately posted to %s.\n\n"
 605   "Format string to insert in nastygrams.
 606 The current group name will be inserted at \"%s\".")
 607
 608 (defun gnus-summary-mail-nastygram (n)
 609   "Send a nastygram to the author of the current article."
 610   (interactive "P")
 611   (when (or gnus-expert-user
 612             (gnus-y-or-n-p
 613              "Really send a nastygram to the author of the current article? "))
 614     (let ((group gnus-newsgroup-name))
 615       (gnus-summary-reply-with-original n)
 616       (set-buffer gnus-message-buffer)
 617       (message-goto-body)
 618       (insert (format gnus-nastygram-message group))
 619       (message-send-and-exit))))
 620
 621 (defun gnus-summary-mail-crosspost-complaint (n)
 622   "Send a complaint about crossposting to the current article(s)."
 623   (interactive "P")
 624   (let ((articles (gnus-summary-work-articles n))
 625         article)
 626     (while (setq article (pop articles))
 627       (set-buffer gnus-summary-buffer)
 628       (gnus-summary-goto-subject article)
 629       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 630             newsgroups followup-to)
 631         (gnus-summary-select-article)
 632         (set-buffer gnus-original-article-buffer)
 633         (if (and (<= (length (message-tokenize-header
 634                               (setq newsgroups (mail-fetch-field "newsgroups"))
 635                               ", "))
 636                      1)
 637                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 638                      (not (member group (message-tokenize-header
 639                                          followup-to ", ")))))
 640             (if followup-to
 641                 (gnus-message 1 "Followup-to restricted")
 642               (gnus-message 1 "Not a crossposted article"))
 643           (set-buffer gnus-summary-buffer)
 644           (gnus-summary-reply-with-original 1)
 645           (set-buffer gnus-message-buffer)
 646           (message-goto-body)
 647           (insert (format gnus-crosspost-complaint newsgroups group))
 648           (message-goto-subject)
 649           (re-search-forward " *$")
 650           (replace-match " (crosspost notification)" t t)
 651           (gnus-deactivate-mark)
 652           (when (gnus-y-or-n-p "Send this complaint? ")
 653             (message-send-and-exit)))))))
 654
 655 (defun gnus-summary-mail-other-window ()
 656   "Compose mail in other window."
 657   (interactive)
 658   (gnus-setup-message 'message
 659     (message-mail)))
 660
 661 (defun gnus-mail-parse-comma-list ()
 662   (let (accumulated
 663         beg)
 664     (skip-chars-forward " ")
 665     (while (not (eobp))
 666       (setq beg (point))
 667       (skip-chars-forward "^,")
 668       (while (zerop
 669               (save-excursion
 670                 (save-restriction
 671                   (let ((i 0))
 672                     (narrow-to-region beg (point))
 673                     (goto-char beg)
 674                     (logand (progn
 675                               (while (search-forward "\"" nil t)
 676                                 (incf i))
 677                               (if (zerop i) 2 i))
 678                             2)))))
 679         (skip-chars-forward ",")
 680         (skip-chars-forward "^,"))
 681       (skip-chars-backward " ")
 682       (push (buffer-substring beg (point))
 683             accumulated)
 684       (skip-chars-forward "^,")
 685       (skip-chars-forward ", "))
 686     accumulated))
 687
 688 (defun gnus-inews-add-to-address (group)
 689   (let ((to-address (mail-fetch-field "to")))
 690     (when (and to-address
 691                (gnus-alive-p))
 692       ;; This mail group doesn't have a `to-list', so we add one
 693       ;; here.  Magic!
 694       (when (gnus-y-or-n-p
 695              (format "Do you want to add this as `to-list': %s " to-address))
 696         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 697
 698 (defun gnus-put-message ()
 699   "Put the current message in some group and return to Gnus."
 700   (interactive)
 701   (let ((reply gnus-article-reply)
 702         (winconf gnus-prev-winconf)
 703         (group gnus-newsgroup-name))
 704
 705     (or (and group (not (gnus-group-read-only-p group)))
 706         (setq group (read-string "Put in group: " nil
 707                                  (gnus-writable-groups))))
 708     (when (gnus-gethash group gnus-newsrc-hashtb)
 709       (error "No such group: %s" group))
 710
 711     (save-excursion
 712       (save-restriction
 713         (widen)
 714         (message-narrow-to-headers)
 715         (let (gnus-deletable-headers)
 716           (if (message-news-p)
 717               (message-generate-headers message-required-news-headers)
 718             (message-generate-headers message-required-mail-headers)))
 719         (goto-char (point-max))
 720         (insert "Gcc: " group "\n")
 721         (widen)))
 722
 723     (gnus-inews-do-gcc)
 724
 725     (when (get-buffer gnus-group-buffer)
 726       (when (gnus-buffer-exists-p (car-safe reply))
 727         (set-buffer (car reply))
 728         (and (cdr reply)
 729              (gnus-summary-mark-article-as-replied
 730               (cdr reply))))
 731       (when winconf
 732         (set-window-configuration winconf)))))
 733
 734 (defun gnus-article-mail (yank)
 735   "Send a reply to the address near point.
 736 If YANK is non-nil, include the original article."
 737   (interactive "P")
 738   (let ((address
 739          (buffer-substring
 740           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 741           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 742     (when address
 743       (message-reply address)
 744       (when yank
 745         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 746
 747 (defvar nntp-server-type)
 748 (defun gnus-bug ()
 749   "Send a bug report to the Gnus maintainers."
 750   (interactive)
 751   (unless (gnus-alive-p)
 752     (error "Gnus has been shut down"))
 753   (gnus-setup-message 'bug
 754     (delete-other-windows)
 755     (when gnus-bug-create-help-buffer
 756       (switch-to-buffer "*Gnus Help Bug*")
 757       (erase-buffer)
 758       (insert gnus-bug-message)
 759       (goto-char (point-min)))
 760     (message-pop-to-buffer "*Gnus Bug*")
 761     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 762     (when gnus-bug-create-help-buffer
 763       (push `(gnus-bug-kill-buffer) message-send-actions))
 764     (goto-char (point-min))
 765     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 766     (forward-line 1)
 767     (insert (gnus-version) "\n"
 768             (emacs-version) "\n")
 769     (when (and (boundp 'nntp-server-type)
 770                (stringp nntp-server-type))
 771       (insert nntp-server-type))
 772     (insert "\n\n\n\n\n")
 773     (gnus-debug)
 774     (goto-char (point-min))
 775     (search-forward "Subject: " nil t)
 776     (message "")))
 777
 778 (defun gnus-bug-kill-buffer ()
 779   (when (get-buffer "*Gnus Help Bug*")
 780     (kill-buffer "*Gnus Help Bug*")))
 781
 782 (defun gnus-debug ()
 783   "Attempts to go through the Gnus source file and report what variables have been changed.
 784 The source file has to be in the Emacs load path."
 785   (interactive)
 786   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 787                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 788                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 789                  "nnmail.el" "message.el"))
 790         (point (point))
 791         file expr olist sym)
 792     (gnus-message 4 "Please wait while we snoop your variables...")
 793     (sit-for 0)
 794     ;; Go through all the files looking for non-default values for variables.
 795     (save-excursion
 796       (set-buffer (get-buffer-create " *gnus bug info*"))
 797       (buffer-disable-undo (current-buffer))
 798       (while files
 799         (erase-buffer)
 800         (when (and (setq file (locate-library (pop files)))
 801                    (file-exists-p file))
 802           (insert-file-contents file)
 803           (goto-char (point-min))
 804           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 805               (gnus-message 4 "Malformed sources in file %s" file)
 806             (narrow-to-region (point-min) (point))
 807             (goto-char (point-min))
 808             (while (setq expr (ignore-errors (read (current-buffer))))
 809               (ignore-errors
 810                 (and (or (eq (car expr) 'defvar)
 811                          (eq (car expr) 'defcustom))
 812                      (stringp (nth 3 expr))
 813                      (or (not (boundp (nth 1 expr)))
 814                          (not (equal (eval (nth 2 expr))
 815                                      (symbol-value (nth 1 expr)))))
 816                      (push (nth 1 expr) olist)))))))
 817       (kill-buffer (current-buffer)))
 818     (when (setq olist (nreverse olist))
 819       (insert "------------------ Environment follows ------------------\n\n"))
 820     (while olist
 821       (if (boundp (car olist))
 822           (condition-case ()
 823               (pp `(setq ,(car olist)
 824                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 825                                   (and (symbolp sym)
 826                                        (not (or (eq sym nil)
 827                                                 (eq sym t)))))
 828                               (list 'quote (symbol-value (car olist)))
 829                             (symbol-value (car olist))))
 830                   (current-buffer))
 831             (error
 832              (format "(setq %s 'whatever)\n" (car olist))))
 833         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 834       (setq olist (cdr olist)))
 835     (insert "\n\n")
 836     ;; Remove any control chars - they seem to cause trouble for some
 837     ;; mailers.  (Byte-compiled output from the stuff above.)
 838     (goto-char point)
 839     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 840       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 841                      t t))))
 842
 843 ;;; Treatment of rejected articles.
 844 ;;; Bounced mail.
 845
 846 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 847   "Re-mail the current message.
 848 This only makes sense if the current message is a bounce message than
 849 contains some mail you have written which has been bounced back to
 850 you.
 851 If FETCH, try to fetch the article that this is a reply to, if indeed
 852 this is a reply."
 853   (interactive "P")
 854   (gnus-summary-select-article t)
 855   (set-buffer gnus-original-article-buffer)
 856   (gnus-setup-message 'compose-bounce
 857     (let* ((references (mail-fetch-field "references"))
 858            (parent (and references (gnus-parent-id references))))
 859       (message-bounce)
 860       ;; If there are references, we fetch the article we answered to.
 861       (and fetch parent
 862            (gnus-summary-refer-article parent)
 863            (gnus-summary-show-all-headers)))))
 864
 865 ;;; Gcc handling.
 866
 867 ;; Do Gcc handling, which copied the message over to some group.
 868 (defun gnus-inews-do-gcc (&optional gcc)
 869   (interactive)
 870   (when (gnus-alive-p)
 871     (save-excursion
 872       (save-restriction
 873         (message-narrow-to-headers)
 874         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 875               (coding-system-for-write 'raw-text)
 876               groups group method)
 877           (when gcc
 878             (message-remove-header "gcc")
 879             (widen)
 880             (setq groups (message-tokenize-header gcc " ,"))
 881             ;; Copy the article over to some group(s).
 882             (while (setq group (pop groups))
 883               (gnus-check-server
 884                (setq method
 885                      (cond ((and (null (gnus-get-info group))
 886                                  (eq (car gnus-message-archive-method)
 887                                      (car
 888                                       (gnus-server-to-method
 889                                        (gnus-group-method group)))))
 890                             ;; If the group doesn't exist, we assume
 891                             ;; it's an archive group...
 892                             gnus-message-archive-method)
 893                            ;; Use the method.
 894                            ((gnus-info-method (gnus-get-info group))
 895                             (gnus-info-method (gnus-get-info group)))
 896                            ;; Find the method.
 897                            (t (gnus-group-method group)))))
 898               (gnus-check-server method)
 899               (unless (gnus-request-group group t method)
 900                 (gnus-request-create-group group method))
 901               (save-excursion
 902                 (nnheader-set-temp-buffer " *acc*")
 903                 (insert-buffer-substring message-encoding-buffer)
 904                 (gnus-run-hooks 'gnus-before-do-gcc-hook)
 905                 (goto-char (point-min))
 906                 (when (re-search-forward
 907                        (concat "^" (regexp-quote mail-header-separator) "$")
 908                        nil t)
 909                   (replace-match "" t t ))
 910                 (unless (gnus-request-accept-article group method t)
 911                   (gnus-message 1 "Couldn't store article in group %s: %s"
 912                                 group (gnus-status-message method))
 913                   (sit-for 2))
 914                 (kill-buffer (current-buffer))))))))))
 915
 916 (defun gnus-inews-insert-gcc ()
 917   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 918   (save-excursion
 919     (save-restriction
 920       (message-narrow-to-headers)
 921       (let* ((group gnus-outgoing-message-group)
 922              (gcc (cond
 923                    ((gnus-functionp group)
 924                     (funcall group))
 925                    ((or (stringp group) (list group))
 926                     group))))
 927         (when gcc
 928           (insert "Gcc: "
 929                   (if (stringp gcc) gcc
 930                     (mapconcat 'identity gcc " "))
 931                   "\n"))))))
 932
 933 (defun gnus-inews-insert-archive-gcc (&optional group)
 934   "Insert the Gcc to say where the article is to be archived."
 935   (let* ((var gnus-message-archive-group)
 936          (group (or group gnus-newsgroup-name ""))
 937          (gcc-self-val
 938           (and gnus-newsgroup-name
 939                (gnus-group-find-parameter
 940                 gnus-newsgroup-name 'gcc-self)))
 941          result
 942          (groups
 943           (cond
 944            ((null gnus-message-archive-method)
 945             ;; Ignore.
 946             nil)
 947            ((stringp var)
 948             ;; Just a single group.
 949             (list var))
 950            ((null var)
 951             ;; We don't want this.
 952             nil)
 953            ((and (listp var) (stringp (car var)))
 954             ;; A list of groups.
 955             var)
 956            ((gnus-functionp var)
 957             ;; A function.
 958             (funcall var group))
 959            (t
 960             ;; An alist of regexps/functions/forms.
 961             (while (and var
 962                         (not
 963                          (setq result
 964                                (cond
 965                                 ((stringp (caar var))
 966                                  ;; Regexp.
 967                                  (when (string-match (caar var) group)
 968                                    (cdar var)))
 969                                 ((gnus-functionp (car var))
 970                                  ;; Function.
 971                                  (funcall (car var) group))
 972                                 (t
 973                                  (eval (car var)))))))
 974               (setq var (cdr var)))
 975             result)))
 976          name)
 977     (when (or groups gcc-self-val)
 978       (when (stringp groups)
 979         (setq groups (list groups)))
 980       (save-excursion
 981         (save-restriction
 982           (message-narrow-to-headers)
 983           (goto-char (point-max))
 984           (insert "Gcc: ")
 985           (if gcc-self-val
 986               ;; Use the `gcc-self' param value instead.
 987               (progn
 988                 (insert
 989                  (if (stringp gcc-self-val)
 990                      gcc-self-val
 991                    group))
 992                 (if (not (eq gcc-self-val 'none))
 993                     (insert "\n")
 994                   (progn
 995                     (beginning-of-line)
 996                     (kill-line))))
 997             ;; Use the list of groups.
 998             (while (setq name (pop groups))
 999               (insert (if (string-match ":" name)
1000                           name
1001                         (gnus-group-prefixed-name
1002                          name gnus-message-archive-method)))
1003               (when groups
1004                 (insert " ")))
1005             (insert "\n")))))))
1006
1007 ;;; Allow redefinition of functions.
1008
1009 (gnus-ems-redefine)
1010
1011 (provide 'gnus-msg)
1012
1013 ;;; gnus-msg.el ends here