git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-nocem.el

   1 ;;; gnus-nocem.el --- NoCeM pseudo-cancellation treatment
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'nnmail)
  34 (require 'gnus-art)
  35 (require 'gnus-sum)
  36 (require 'gnus-range)
  37
  38 (defgroup gnus-nocem nil
  39   "NoCeM pseudo-cancellation treatment."
  40   :group 'gnus-score)
  41
  42 (defcustom gnus-nocem-groups
  43   '("news.lists.filters" "news.admin.net-abuse.bulletins"
  44     "alt.nocem.misc" "news.admin.net-abuse.announce")
  45   "*List of groups that will be searched for NoCeM messages."
  46   :group 'gnus-nocem
  47   :type '(repeat (string :tag "Group")))
  48
  49 (defcustom gnus-nocem-issuers
  50   '("AutoMoose-1"                       ; CancelMoose[tm]
  51     "clewis@ferret.ocunix"              ; Chris Lewis
  52     "cosmo.roadkill"
  53     "SpamHippo"
  54     "hweede@snafu.de")
  55   "*List of NoCeM issuers to pay attention to.
  56
  57 This can also be a list of `(ISSUER CONDITION ...)' elements.
  58
  59 See <URL:http://www.xs4all.nl/~rosalind/nocemreg/nocemreg.html> for an
  60 issuer registry."
  61   :group 'gnus-nocem
  62   :link '(url-link "http://www.xs4all.nl/~rosalind/nocemreg/nocemreg.html")
  63   :type '(repeat (choice string sexp)))
  64
  65 (defcustom gnus-nocem-directory
  66   (nnheader-concat gnus-article-save-directory "NoCeM/")
  67   "*Directory where NoCeM files will be stored."
  68   :group 'gnus-nocem
  69   :type 'directory)
  70
  71 (defcustom gnus-nocem-expiry-wait 15
  72   "*Number of days to keep NoCeM headers in the cache."
  73   :group 'gnus-nocem
  74   :type 'integer)
  75
  76 (defcustom gnus-nocem-verifyer (lambda ()
  77                                  (pgg-verify-region (point-min) (point-max)))
  78   "*Function called to verify that the NoCeM message is valid.
  79 One likely value is the function using `pgg-verify-region'.
  80 If the function in this variable isn't bound, the message will be used
  81 unconditionally."
  82   :group 'gnus-nocem
  83   :type '(radio (function (lambda ()
  84                             (pgg-verify-region (point-min) (point-max))))
  85                 (function-item mc-verify)
  86                 (function :tag "other")))
  87
  88 (defcustom gnus-nocem-liberal-fetch nil
  89   "*If t try to fetch all messages which have @@NCM in the subject.
  90 Otherwise don't fetch messages which have references or whose message-id
  91 matches a previously scanned and verified nocem message."
  92   :group 'gnus-nocem
  93   :type 'boolean)
  94
  95 (defcustom gnus-nocem-check-article-limit 500
  96   "*If non-nil, the maximum number of articles to check in any NoCeM group."
  97   :group 'gnus-nocem
  98   :version "21.1"
  99   :type '(choice (const :tag "unlimited" nil)
 100                  (integer 1000)))
 101
 102 (defcustom gnus-nocem-check-from t
 103   "Non-nil means check for valid issuers in message bodies.
 104 Otherwise don't bother fetching articles unless their author matches a
 105 valid issuer, which is much faster if you are selective about the issuers."
 106   :group 'gnus-nocem
 107   :version "21.1"
 108   :type 'boolean)
 109
 110 ;;; Internal variables
 111
 112 (defvar gnus-nocem-active nil)
 113 (defvar gnus-nocem-alist nil)
 114 (defvar gnus-nocem-touched-alist nil)
 115 (defvar gnus-nocem-hashtb nil)
 116 (defvar gnus-nocem-seen-message-ids nil)
 117
 118 ;;; Functions
 119
 120 (defun gnus-nocem-active-file ()
 121   (concat (file-name-as-directory gnus-nocem-directory) "active"))
 122
 123 (defun gnus-nocem-cache-file ()
 124   (concat (file-name-as-directory gnus-nocem-directory) "cache"))
 125
 126 ;;
 127 ;; faster lookups for group names:
 128 ;;
 129
 130 (defvar gnus-nocem-real-group-hashtb nil
 131   "Real-name mappings of subscribed groups.")
 132
 133 (defun gnus-fill-real-hashtb ()
 134   "Fill up a hash table with the real-name mappings from the user's active file."
 135   (if (hash-table-p gnus-nocem-real-group-hashtb)
 136       (clrhash gnus-nocem-real-group-hashtb)
 137     (setq gnus-nocem-real-group-hashtb (make-hash-table :test 'equal)))
 138   (mapcar (lambda (group)
 139             (setq group (gnus-group-real-name (car group)))
 140             (puthash group t gnus-nocem-real-group-hashtb))
 141           gnus-newsrc-alist))
 142
 143 ;;;###autoload
 144 (defun gnus-nocem-scan-groups ()
 145   "Scan all NoCeM groups for new NoCeM messages."
 146   (interactive)
 147   (let ((groups gnus-nocem-groups)
 148         (gnus-inhibit-demon t)
 149         group active gactive articles check-headers)
 150     (gnus-make-directory gnus-nocem-directory)
 151     ;; Load any previous NoCeM headers.
 152     (gnus-nocem-load-cache)
 153     ;; Get the group name mappings:
 154     (gnus-fill-real-hashtb)
 155     ;; Read the active file if it hasn't been read yet.
 156     (and (file-exists-p (gnus-nocem-active-file))
 157          (not gnus-nocem-active)
 158          (ignore-errors
 159            (load (gnus-nocem-active-file) t t t)))
 160     ;; Go through all groups and see whether new articles have
 161     ;; arrived.
 162     (while (setq group (pop groups))
 163       (if (not (setq gactive (gnus-activate-group group)))
 164           ()                            ; This group doesn't exist.
 165         (setq active (nth 1 (assoc group gnus-nocem-active)))
 166         (when (and (not (< (cdr gactive) (car gactive))) ; Empty group.
 167                    (or (not active)
 168                        (< (cdr active) (cdr gactive))))
 169           ;; Ok, there are new articles in this group, se we fetch the
 170           ;; headers.
 171           (save-excursion
 172             (let ((dependencies (make-vector 10 nil))
 173                   headers header)
 174               (with-temp-buffer
 175                 (setq headers
 176                       (if (eq 'nov
 177                               (gnus-retrieve-headers
 178                                (setq articles
 179                                      (gnus-uncompress-range
 180                                       (cons
 181                                        (if active (1+ (cdr active))
 182                                          (car gactive))
 183                                        (cdr gactive))))
 184                                group))
 185                           (gnus-get-newsgroup-headers-xover
 186                            articles nil dependencies)
 187                         (gnus-get-newsgroup-headers dependencies)))
 188                 (while (setq header (pop headers))
 189                   ;; We take a closer look on all articles that have
 190                   ;; "@@NCM" in the subject.  Unless we already read
 191                   ;; this cross posted message.  Nocem messages
 192                   ;; are not allowed to have references, so we can
 193                   ;; ignore scanning followups.
 194                   (and (string-match "@@NCM" (mail-header-subject header))
 195                        (and gnus-nocem-check-from
 196                             (let ((case-fold-search t))
 197                               (catch 'ok
 198                                 (mapc
 199                                  (lambda (author)
 200                                    (if (consp author)
 201                                        (setq author (car author)))
 202                                    (if (string-match
 203                                         author (mail-header-from header))
 204                                        (throw 'ok t)))
 205                                  gnus-nocem-issuers)
 206                                 nil)))
 207                        (or gnus-nocem-liberal-fetch
 208                            (and (or (string= "" (mail-header-references
 209                                                  header))
 210                                     (null (mail-header-references header)))
 211                                 (not (member (mail-header-message-id header)
 212                                              gnus-nocem-seen-message-ids))))
 213                        (push header check-headers)))
 214                 (setq check-headers (last (nreverse check-headers)
 215                                           gnus-nocem-check-article-limit))
 216                 (let ((i 0)
 217                       (len (length check-headers)))
 218                   (dolist (h check-headers)
 219                     (gnus-message
 220                      7 "Checking article %d in %s for NoCeM (%d of %d)..."
 221                      (mail-header-number h) group (incf i) len)
 222                     (gnus-nocem-check-article group h)))))))
 223         (setq gnus-nocem-active
 224               (cons (list group gactive)
 225                     (delq (assoc group gnus-nocem-active)
 226                           gnus-nocem-active)))))
 227     ;; Save the results, if any.
 228     (gnus-nocem-save-cache)
 229     (gnus-nocem-save-active)))
 230
 231 (defun gnus-nocem-check-article (group header)
 232   "Check whether the current article is an NCM article and that we want it."
 233   ;; Get the article.
 234   (let ((date (mail-header-date header))
 235         (gnus-newsgroup-name group)
 236         issuer b e type)
 237     (when (or (not date)
 238               (time-less-p
 239                (time-since (date-to-time date))
 240                (days-to-time gnus-nocem-expiry-wait)))
 241       (gnus-request-article-this-buffer (mail-header-number header) group)
 242       (goto-char (point-min))
 243       (when (re-search-forward
 244              "-----BEGIN PGP\\(?: SIGNED\\)? MESSAGE-----"
 245              nil t)
 246         (delete-region (point-min) (match-beginning 0)))
 247       (when (re-search-forward
 248              "-----END PGP \\(?:MESSAGE\\|SIGNATURE\\)-----\n?"
 249              nil t)
 250         (delete-region (match-end 0) (point-max)))
 251       (goto-char (point-min))
 252       ;; The article has to have proper NoCeM headers.
 253       (when (and (setq b (search-forward "\n@@BEGIN NCM HEADERS\n" nil t))
 254                  (setq e (search-forward "\n@@BEGIN NCM BODY\n" nil t)))
 255         ;; We get the name of the issuer.
 256         (narrow-to-region b e)
 257         (setq issuer (mail-fetch-field "issuer")
 258               type (mail-fetch-field "type"))
 259         (widen)
 260         (if (not (gnus-nocem-message-wanted-p issuer type))
 261             (message "invalid NoCeM issuer: %s" issuer)
 262           (and (gnus-nocem-verify-issuer issuer) ; She is who she says she is.
 263                (gnus-nocem-enter-article) ; We gobble the message.
 264                (push (mail-header-message-id header) ; But don't come back for
 265                      gnus-nocem-seen-message-ids))))))) ; second helpings.
 266
 267 (defun gnus-nocem-message-wanted-p (issuer type)
 268   (let ((issuers gnus-nocem-issuers)
 269         wanted conditions condition)
 270     (cond
 271      ;; Do the quick check first.
 272      ((member issuer issuers)
 273       t)
 274      ((setq conditions (cdr (assoc issuer issuers)))
 275       ;; Check whether we want this type.
 276       (while (setq condition (pop conditions))
 277         (cond
 278          ((stringp condition)
 279           (when (string-match condition type)
 280             (setq wanted t)))
 281          ((and (consp condition)
 282                (eq (car condition) 'not)
 283                (stringp (cadr condition)))
 284           (when (string-match (cadr condition) type)
 285             (setq wanted nil)))
 286          (t
 287           (error "Invalid NoCeM condition: %S" condition))))
 288       wanted))))
 289
 290 (defun gnus-nocem-verify-issuer (person)
 291   "Verify using PGP that the canceler is who she says she is."
 292   (if (functionp gnus-nocem-verifyer)
 293       (ignore-errors
 294         (funcall gnus-nocem-verifyer))
 295     ;; If we don't have Mailcrypt, then we use the message anyway.
 296     t))
 297
 298 (defun gnus-nocem-enter-article ()
 299   "Enter the current article into the NoCeM cache."
 300   (goto-char (point-min))
 301   (let ((b (search-forward "\n@@BEGIN NCM BODY\n" nil t))
 302         (e (search-forward "\n@@END NCM BODY\n" nil t))
 303         (buf (current-buffer))
 304         ncm id group)
 305     (when (and b e)
 306       (narrow-to-region b (1+ (match-beginning 0)))
 307       (goto-char (point-min))
 308       (while (search-forward "\t" nil t)
 309         (cond
 310          ((not (ignore-errors
 311                  (setq group (gnus-group-real-name (symbol-name (read buf))))
 312                  (gethash group gnus-nocem-real-group-hashtb)))
 313           ;; An error.
 314           )
 315          (t
 316           ;; Valid group.
 317           (beginning-of-line)
 318           (while (eq (char-after) ?\t)
 319             (forward-line -1))
 320           (setq id (buffer-substring (point) (1- (search-forward "\t"))))
 321           (unless (if (hash-table-p gnus-nocem-hashtb)
 322                       (gethash id gnus-nocem-hashtb)
 323                     (setq gnus-nocem-hashtb (make-hash-table :test 'equal))
 324                     nil)
 325             ;; only store if not already present
 326             (puthash id t gnus-nocem-hashtb)
 327             (push id ncm))
 328           (forward-line 1)
 329           (while (eq (char-after) ?\t)
 330             (forward-line 1)))))
 331       (when ncm
 332         (setq gnus-nocem-touched-alist t)
 333         (push (cons (let ((time (current-time))) (setcdr (cdr time) nil) time)
 334                     ncm)
 335               gnus-nocem-alist))
 336       t)))
 337
 338 ;;;###autoload
 339 (defun gnus-nocem-load-cache ()
 340   "Load the NoCeM cache."
 341   (interactive)
 342   (unless gnus-nocem-alist
 343     ;; The buffer doesn't exist, so we create it and load the NoCeM
 344     ;; cache.
 345     (when (file-exists-p (gnus-nocem-cache-file))
 346       (load (gnus-nocem-cache-file) t t t)
 347       (gnus-nocem-alist-to-hashtb))))
 348
 349 (defun gnus-nocem-save-cache ()
 350   "Save the NoCeM cache."
 351   (when (and gnus-nocem-alist
 352              gnus-nocem-touched-alist)
 353     (with-temp-file (gnus-nocem-cache-file)
 354       (gnus-prin1 `(setq gnus-nocem-alist ',gnus-nocem-alist)))
 355     (setq gnus-nocem-touched-alist nil)))
 356
 357 (defun gnus-nocem-save-active ()
 358   "Save the NoCeM active file."
 359   (with-temp-file (gnus-nocem-active-file)
 360     (gnus-prin1 `(setq gnus-nocem-active ',gnus-nocem-active))))
 361
 362 (defun gnus-nocem-alist-to-hashtb ()
 363   "Create a hashtable from the Message-IDs we have."
 364   (let* ((alist gnus-nocem-alist)
 365          (pprev (cons nil alist))
 366          (prev pprev)
 367          (expiry (days-to-time gnus-nocem-expiry-wait))
 368          entry)
 369     (if (hash-table-p gnus-nocem-hashtb)
 370         (clrhash gnus-nocem-hashtb)
 371       (setq gnus-nocem-hashtb (make-hash-table :test 'equal)))
 372     (while (setq entry (car alist))
 373       (if (not (time-less-p (time-since (car entry)) expiry))
 374           ;; This entry has expired, so we remove it.
 375           (setcdr prev (cdr alist))
 376         (setq prev alist)
 377         ;; This is ok, so we enter it into the hashtable.
 378         (setq entry (cdr entry))
 379         (while entry
 380           (puthash (car entry) t gnus-nocem-hashtb)
 381           (setq entry (cdr entry))))
 382       (setq alist (cdr alist)))))
 383
 384 (gnus-add-shutdown 'gnus-nocem-close 'gnus)
 385
 386 (defun gnus-nocem-close ()
 387   "Clear internal NoCeM variables."
 388   (setq gnus-nocem-alist nil
 389         gnus-nocem-hashtb nil
 390         gnus-nocem-active nil
 391         gnus-nocem-touched-alist nil
 392         gnus-nocem-seen-message-ids nil
 393         gnus-nocem-real-group-hashtb nil))
 394
 395 (defun gnus-nocem-unwanted-article-p (id)
 396   "Say whether article ID in the current group is wanted."
 397   (and gnus-nocem-hashtb
 398        (gethash id gnus-nocem-hashtb)))
 399
 400 (provide 'gnus-nocem)
 401
 402 ;;; gnus-nocem.el ends here