git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news xpm annotation glyph faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; There are three picon types relevant to Gnus:
  29 ;;
  30 ;; Persons: person@subdomain.dom
  31 ;;          users/dom/subdomain/person/face.gif
  32 ;;          usenix/dom/subdomain/person/face.gif
  33 ;;          misc/MISC/person/face.gif
  34 ;; Domains: subdomain.dom
  35 ;;          domain/dom/subdomain/unknown/face.gif
  36 ;; Groups:  comp.lang.lisp
  37 ;;          news/comp/lang/lisp/unknown/face.gif
  38 ;;
  39 ;; Original implementation by Wes Hardaker <hardaker@ece.ucdavis.edu>.
  40 ;;
  41 ;;; Code:
  42
  43 (eval-when-compile (require 'cl))
  44
  45 (require 'gnus)
  46 (require 'custom)
  47 (require 'gnus-art)
  48
  49 ;;; User variables:
  50
  51 (defcustom gnus-picon-news-directories '("news")
  52   "*List of directories to search for newsgroups faces."
  53   :type '(repeat string)
  54   :group 'gnus-picon)
  55
  56 (defcustom gnus-picon-user-directories '("users" "usenix" "local" "misc")
  57   "*List of directories to search for user faces."
  58   :type '(repeat string)
  59   :group 'gnus-picon)
  60
  61 (defcustom gnus-picon-domain-directories '("domains")
  62   "*List of directories to search for domain faces.
  63 Some people may want to add \"unknown\" to this list."
  64   :type '(repeat string)
  65   :group 'gnus-picon)
  66
  67 (defcustom gnus-picon-file-types
  68   (let ((types (list "xbm")))
  69     (if (gnus-image-type-available-p 'gif)
  70         (setq types (cons "gif" types)))
  71     (if (gnus-image-type-available-p 'xpm)
  72         (setq types (cons "xpm" types)))
  73     types)
  74   "*List of suffixes on picon file names to try."
  75   :type '(repeat string)
  76   :group 'gnus-picon)
  77
  78 (defface gnus-picon-xbm-face '((t (:foreground "black" :background "white")))
  79   "Face to show xbm picon in."
  80   :group 'gnus-picon)
  81
  82 (defface gnus-picon-face '((t (:foreground "black" :background "white")))
  83   "Face to show picon in."
  84   :group 'gnus-picon)
  85
  86 ;;; Internal variables:
  87
  88 (defvar gnus-picon-setup-p nil)
  89 (defvar gnus-picon-glyph-alist nil
  90   "Picon glyphs cache.
  91 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
  92 (defvar gnus-picon-cache nil)
  93
  94 ;;; Functions:
  95
  96 (defsubst gnus-picon-split-address (address)
  97   (setq address (split-string address "@"))
  98   (if (stringp (cadr address))
  99       (cons (car address) (split-string (cadr address) "\\."))
 100     (if (stringp (car address))
 101         (split-string (car address) "\\."))))
 102
 103 (defun gnus-picon-find-face (address directories &optional exact)
 104   (let* ((address (gnus-picon-split-address address))
 105          (user (pop address))
 106          (faddress address)
 107          database directory result instance base)
 108     (catch 'found
 109       (dolist (database gnus-picon-databases)
 110         (dolist (directory directories)
 111           (setq address faddress
 112                 base (expand-file-name directory database))
 113           (while address
 114             (when (setq result (gnus-picon-find-image
 115                                 (concat base "/" (mapconcat 'downcase
 116                                                             (reverse address)
 117                                                             "/")
 118                                         "/" (downcase user) "/")))
 119               (throw 'found result))
 120             (if exact
 121                 (setq address nil)
 122               (pop address)))
 123           ;; Kludge to search MISC as well.  But not in "news".
 124           (unless (string= directory "news")
 125             (when (setq result (gnus-picon-find-image
 126                                 (concat base "/MISC/" user "/")))
 127               (throw 'found result))))))))
 128
 129 (defun gnus-picon-find-image (directory)
 130   (let ((types gnus-picon-file-types)
 131         found type file)
 132     (while (and (not found)
 133                 (setq type (pop types)))
 134       (setq found (file-exists-p (setq file (concat directory "face." type)))))
 135     (if found
 136         file
 137       nil)))
 138
 139 (defun gnus-picon-insert-glyph (glyph category)
 140   "Insert GLYPH into the buffer.
 141 GLYPH can be either a glyph or a string."
 142   (if (stringp glyph)
 143       (insert glyph)
 144     (gnus-add-wash-type category)
 145     (gnus-add-image category (car glyph))
 146     (gnus-put-image (car glyph) (cdr glyph) category)))
 147
 148 (defun gnus-picon-create-glyph (file)
 149   (or (cdr (assoc file gnus-picon-glyph-alist))
 150       (cdar (push (cons file (gnus-create-image file))
 151                   gnus-picon-glyph-alist))))
 152
 153 ;;; Functions that does picon transformations:
 154
 155 (defun gnus-picon-transform-address (header category)
 156   (gnus-with-article-headers
 157     (let ((addresses
 158            (mail-header-parse-addresses
 159             ;; mail-header-parse-addresses does not work (reliably) on
 160             ;; decoded headers.
 161             (or
 162              (ignore-errors
 163                (mail-encode-encoded-word-string
 164                 (or (mail-fetch-field header) "")))
 165              (mail-fetch-field header))))
 166           spec file point cache)
 167       (dolist (address addresses)
 168         (setq address (car address))
 169         (when (and (stringp address)
 170                    (setq spec (gnus-picon-split-address address)))
 171           (if (setq cache (cdr (assoc address gnus-picon-cache)))
 172               (setq spec cache)
 173             (when (setq file (or (gnus-picon-find-face
 174                                   address gnus-picon-user-directories)
 175                                  (gnus-picon-find-face
 176                                   (concat "unknown@"
 177                                           (mapconcat
 178                                            'identity (cdr spec) "."))
 179                                   gnus-picon-user-directories)))
 180               (setcar spec (cons (gnus-picon-create-glyph file)
 181                                  (car spec))))
 182
 183             (dotimes (i (1- (length spec)))
 184               (when (setq file (gnus-picon-find-face
 185                                 (concat "unknown@"
 186                                         (mapconcat
 187                                          'identity (nthcdr (1+ i) spec) "."))
 188                                 gnus-picon-domain-directories t))
 189                 (setcar (nthcdr (1+ i) spec)
 190                         (cons (gnus-picon-create-glyph file)
 191                               (nth (1+ i) spec)))))
 192             (setq spec (nreverse spec))
 193             (push (cons address spec) gnus-picon-cache))
 194
 195           (gnus-article-goto-header header)
 196           (mail-header-narrow-to-field)
 197           (when (search-forward address nil t)
 198             (delete-region (match-beginning 0) (match-end 0))
 199             (setq point (point))
 200             (while spec
 201               (goto-char point)
 202               (if (> (length spec) 2)
 203                   (insert ".")
 204                 (if (= (length spec) 2)
 205                   (insert "@")))
 206               (gnus-picon-insert-glyph (pop spec) category))))))))
 207
 208 (defun gnus-picon-transform-newsgroups (header)
 209   (interactive)
 210   (gnus-with-article-headers
 211     (gnus-article-goto-header header)
 212     (mail-header-narrow-to-field)
 213     (let ((groups (message-tokenize-header (mail-fetch-field header)))
 214           spec file point)
 215       (dolist (group groups)
 216         (unless (setq spec (cdr (assoc group gnus-picon-cache)))
 217           (setq spec (nreverse (split-string group "[.]")))
 218           (dotimes (i (length spec))
 219             (when (setq file (gnus-picon-find-face
 220                               (concat "unknown@"
 221                                       (mapconcat
 222                                        'identity (nthcdr i spec) "."))
 223                               gnus-picon-news-directories t))
 224               (setcar (nthcdr i spec)
 225                       (cons (gnus-picon-create-glyph file)
 226                             (nth i spec)))))
 227             (push (cons group spec) gnus-picon-cache))
 228         (when (search-forward group nil t)
 229           (delete-region (match-beginning 0) (match-end 0))
 230           (save-restriction
 231             (narrow-to-region (point) (point))
 232             (while spec
 233               (goto-char (point-min))
 234               (if (> (length spec) 1)
 235                   (insert "."))
 236               (gnus-picon-insert-glyph (pop spec) 'newsgroups-picon))
 237             (goto-char (point-max))))))))
 238
 239 ;;; Commands:
 240
 241 ;; #### NOTE: the test for buffer-read-only is the same as in
 242 ;; article-display-[x-]face. See the comment up there.
 243
 244 ;;;###autoload
 245 (defun gnus-treat-from-picon ()
 246   "Display picons in the From header.
 247 If picons are already displayed, remove them."
 248   (interactive)
 249   (let ((wash-picon-p buffer-read-only))
 250     (gnus-with-article-buffer
 251       (if (and wash-picon-p (memq 'from-picon gnus-article-wash-types))
 252           (gnus-delete-images 'from-picon)
 253         (gnus-picon-transform-address "from" 'from-picon)))
 254     ))
 255
 256 ;;;###autoload
 257 (defun gnus-treat-mail-picon ()
 258   "Display picons in the Cc and To headers.
 259 If picons are already displayed, remove them."
 260   (interactive)
 261   (let ((wash-picon-p buffer-read-only))
 262     (gnus-with-article-buffer
 263       (if (and wash-picon-p (memq 'mail-picon gnus-article-wash-types))
 264           (gnus-delete-images 'mail-picon)
 265         (gnus-picon-transform-address "cc" 'mail-picon)
 266         (gnus-picon-transform-address "to" 'mail-picon)))
 267     ))
 268
 269 ;;;###autoload
 270 (defun gnus-treat-newsgroups-picon ()
 271   "Display picons in the Newsgroups and Followup-To headers.
 272 If picons are already displayed, remove them."
 273   (interactive)
 274   (let ((wash-picon-p buffer-read-only))
 275     (gnus-with-article-buffer
 276       (if (and wash-picon-p (memq 'newsgroups-picon gnus-article-wash-types))
 277           (gnus-delete-images 'newsgroups-picon)
 278         (gnus-picon-transform-newsgroups "newsgroups")
 279         (gnus-picon-transform-newsgroups "followup-to")))
 280     ))
 281
 282 (provide 'gnus-picon)
 283
 284 ;;; gnus-picon.el ends here