git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   5 ;; Keywords: news xpm annotation glyph faces
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'xpm)
  30 (require 'annotations)
  31 (require 'custom)
  32 (require 'gnus-art)
  33 (require 'gnus-win)
  34
  35 ;;; User variables:
  36
  37 (defgroup picons nil
  38   "Show pictures of people, domains, and newsgroups (XEmacs).
  39 For this to work, you must add gnus-group-display-picons to the
  40 gnus-summary-display-hook or to the gnus-article-display-hook
  41 depending on what gnus-picons-display-where is set to.  You must
  42 also add gnus-article-display-picons to gnus-article-display-hook."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Legal values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-x-face-file-name
  93   (format "/tmp/picon-xface.%s.xbm" (user-login-name))
  94   "*The name of the file in which to store the converted X-face header."
  95   :type 'string
  96   :group 'picons)
  97
  98 (defcustom gnus-picons-convert-x-face (format "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pbmtoxbm > %s" gnus-picons-x-face-file-name)
  99   "*Command to convert the x-face header into a xbm file."
 100   :type 'string
 101   :group 'picons)
 102
 103 (defcustom gnus-picons-display-as-address t
 104   "*If t display textual email addresses along with pictures."
 105   :type 'boolean
 106   :group 'picons)
 107
 108 (defcustom gnus-picons-file-suffixes
 109   (when (featurep 'x)
 110     (let ((types (list "xbm")))
 111       (when (featurep 'gif)
 112         (push "gif" types))
 113       (when (featurep 'xpm)
 114         (push "xpm" types))
 115       types))
 116   "*List of suffixes on picon file names to try."
 117   :type '(repeat string)
 118   :group 'picons)
 119
 120 (defcustom gnus-picons-display-article-move-p nil
 121   "*Whether to move point to first empty line when displaying picons.
 122 This has only an effect if `gnus-picons-display-where' has value `article'."
 123   :type 'boolean
 124   :group 'picons)
 125
 126 (defcustom gnus-picons-clear-cache-on-shutdown t
 127   "*Whether to clear the picons cache when exiting gnus.
 128 Gnus caches every picons it finds while it is running.  This saves
 129 some time in the search process but eats some memory.  If this
 130 variable is set to nil, Gnus will never clear the cache itself; you
 131 will have to manually call `gnus-picons-clear-cache' to clear it.
 132 Otherwise the cache will be cleared every time you exit Gnus."
 133   :type 'boolean
 134   :group 'picons)
 135
 136 (defcustom gnus-picons-piconsearch-url nil
 137   "*The url to query for picons.  Setting this to nil will disable it.
 138 The only publicly available address currently known is
 139 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 140 please tell me so that we can list it."
 141   :type '(choice (const :tag "Disable" :value nil)
 142                  (const :tag "www.cs.indiana.edu"
 143                         :value "http://www.cs.indiana.edu:800/piconsearch")
 144                  (string))
 145   :group 'picons)
 146
 147 (defface gnus-picons-xbm-face '((t (:foreground "black" :background "white")))
 148   "Face to show xbm picons in."
 149   :group 'picons)
 150
 151 ;;; Internal variables:
 152
 153 (defvar gnus-picons-processes-alist nil
 154   "Picons processes currently running and their environment.")
 155 (defvar gnus-picons-glyph-alist nil
 156   "Picons glyphs cache.
 157 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 158 (defvar gnus-picons-url-alist nil
 159   "Picons file names cache.
 160 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 161
 162 (defvar gnus-picons-jobs-alist nil
 163   "List of jobs that still need be done.
 164 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 165 TAG is one of `picon' or `search' indicating that the job should query a
 166 picon or do a search for picons file names, and ARGS is some additionnal
 167 arguments necessary for the job.")
 168
 169 (defvar gnus-picons-job-already-running nil
 170   "Lock to ensure only one stream of http requests is running.")
 171
 172 ;;; Functions:
 173
 174 (defun gnus-picons-remove-all ()
 175   "Removes all picons from the Gnus display(s)."
 176   (interactive)
 177   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 178                nil nil nil nil nil 'gnus-picon)
 179   (setq gnus-picons-jobs-alist '())
 180   ;; notify running job that it may have been preempted
 181   (if (and (listp gnus-picons-job-already-running)
 182            gnus-picons-job-already-running)
 183       (setq gnus-picons-job-already-running t)))
 184
 185 (defun gnus-get-buffer-name (variable)
 186   "Returns the buffer name associated with the contents of a variable."
 187   (let ((buf (gnus-get-buffer-create (gnus-window-to-buffer-helper
 188                                  (cdr
 189                                   (assq variable gnus-window-to-buffer))))))
 190     (and buf
 191          (buffer-name buf))))
 192
 193 (defun gnus-picons-buffer-name ()
 194   (cond ((or (stringp gnus-picons-display-where)
 195              (bufferp gnus-picons-display-where))
 196          gnus-picons-display-where)
 197         ((eq gnus-picons-display-where 'picons)
 198          (if gnus-single-article-buffer
 199              "*Picons*"
 200            (concat "*Picons " gnus-newsgroup-name "*")))
 201         (t
 202          (gnus-get-buffer-name gnus-picons-display-where))))
 203
 204 (defun gnus-picons-kill-buffer ()
 205   (let ((buf (get-buffer (gnus-picons-buffer-name))))
 206     (if (buffer-live-p buf)
 207         (kill-buffer buf))))
 208
 209 (defun gnus-picons-setup-buffer ()
 210   (let ((name (gnus-picons-buffer-name)))
 211     (save-excursion
 212       (if (get-buffer name)
 213           (set-buffer name)
 214         (set-buffer (gnus-get-buffer-create name))
 215         (buffer-disable-undo)
 216         (setq buffer-read-only t)
 217         (add-hook 'gnus-summary-prepare-exit-hook 'gnus-picons-kill-buffer))
 218       (current-buffer))))
 219
 220 (defun gnus-picons-set-buffer ()
 221   (set-buffer (gnus-picons-setup-buffer))
 222   (goto-char (point-min))
 223   (if (and (eq gnus-picons-display-where 'article)
 224            gnus-picons-display-article-move-p)
 225       (if (search-forward "\n\n" nil t)
 226           (forward-line -1)
 227         (goto-char (point-max)))
 228     (setq buffer-read-only t)
 229     (unless gnus-picons-has-modeline-p
 230       (set-specifier has-modeline-p
 231                      (list (list (current-buffer)
 232                                  (cons nil gnus-picons-has-modeline-p)))))))
 233
 234 (defun gnus-picons-prepare-for-annotations ()
 235   "Prepare picons buffer for putting annotations."
 236   ;; let drawing catch up
 237   (when gnus-picons-refresh-before-display
 238     (sit-for 0))
 239   (gnus-picons-set-buffer)
 240   (gnus-picons-remove-all))
 241
 242 (defun gnus-picons-make-annotation (&rest args)
 243   (let ((annot (apply 'make-annotation args)))
 244     (set-extent-property annot 'gnus-picon t)
 245     (set-extent-property annot 'duplicable t)
 246     annot))
 247
 248 (defun gnus-picons-article-display-x-face ()
 249   "Display the x-face header bitmap in the 'gnus-picons-display-where buffer."
 250   (let ((gnus-article-x-face-command 'gnus-picons-display-x-face))
 251     (gnus-article-display-x-face)))
 252
 253 (defun gnus-picons-x-face-sentinel (process event)
 254   (when (memq process gnus-picons-processes-alist)
 255     (setq gnus-picons-processes-alist
 256           (delq process gnus-picons-processes-alist))
 257     (gnus-picons-set-buffer)
 258     (gnus-picons-make-annotation (make-glyph gnus-picons-x-face-file-name)
 259                                  nil 'text)
 260     (when (file-exists-p gnus-picons-x-face-file-name)
 261       (delete-file gnus-picons-x-face-file-name))))
 262
 263 (defun gnus-picons-display-x-face (beg end)
 264   "Function to display the x-face header in the picons window.
 265 To use:  (setq gnus-article-x-face-command 'gnus-picons-display-x-face)"
 266   (interactive)
 267   (if (featurep 'xface)
 268       ;; Use builtin support
 269       (save-excursion
 270         ;; Don't remove this binding, it is really needed: when
 271         ;; `gnus-picons-set-buffer' changes buffer (like when it is
 272         ;; set to display picons outside of the article buffer), BEG
 273         ;; and END still refer the buffer current now !
 274         (let ((buf (current-buffer)))
 275           (gnus-picons-set-buffer)
 276           (gnus-picons-make-annotation
 277            (vector 'xface
 278                    :data (concat "X-Face: " (buffer-substring beg end buf)))
 279            nil 'text nil nil nil t)))
 280     ;; convert the x-face header to a .xbm file
 281     (let* ((process-connection-type nil)
 282            (process (start-process-shell-command "gnus-x-face" nil
 283                                                  gnus-picons-convert-x-face)))
 284       (push process gnus-picons-processes-alist)
 285       (process-kill-without-query process)
 286       (set-process-sentinel process 'gnus-picons-x-face-sentinel)
 287       (process-send-region process beg end)
 288       (process-send-eof process))))
 289
 290 (defun gnus-article-display-picons ()
 291   "Display faces for an author and her domain in gnus-picons-display-where."
 292   (interactive)
 293   (let (from at-idx)
 294     (when (and (featurep 'xpm)
 295                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 296                (setq from (mail-fetch-field "from"))
 297                (setq from (downcase (or (cadr
 298                                          (funcall gnus-extract-address-components
 299                                                   from))
 300                                         "")))
 301                (or (setq at-idx (string-match "@" from))
 302                    (setq at-idx (length from))))
 303       (save-excursion
 304         (let ((username (downcase (substring from 0 at-idx)))
 305               (addrs (if (eq at-idx (length from))
 306                          (if gnus-local-domain
 307                              (message-tokenize-header gnus-local-domain "."))
 308                        (message-tokenize-header (substring from (1+ at-idx))
 309                                                 "."))))
 310           (gnus-picons-prepare-for-annotations)
 311           (gnus-group-display-picons)
 312           (unless gnus-picons-display-article-move-p
 313             (save-restriction
 314               (let ((buffer-read-only nil))
 315                 (when (re-search-forward "^From: " nil t)
 316                   (narrow-to-region (point) (gnus-point-at-eol))
 317                   (when (search-forward from nil t)
 318                     (gnus-put-text-property
 319                      (match-beginning 0) (match-end 0)
 320                      'invisible t))))))
 321           (if (null gnus-picons-piconsearch-url)
 322               (progn
 323                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 324                                             addrs
 325                                             gnus-picons-domain-directories)
 326                                            gnus-picons-display-as-address
 327                                            "." t)
 328                 (if (and gnus-picons-display-as-address addrs)
 329                     (gnus-picons-make-annotation
 330                      [string :data "@"] nil 'text nil nil nil t))
 331                 (gnus-picons-display-picon-or-name
 332                  (gnus-picons-lookup-user username addrs)
 333                  username t))
 334             (push (list 'gnus-article-annotations 'search username addrs
 335                         gnus-picons-domain-directories t)
 336                   gnus-picons-jobs-alist)
 337             (gnus-picons-next-job)))))))
 338
 339 (defun gnus-group-display-picons ()
 340   "Display icons for the group in the `gnus-picons-display-where' buffer."
 341   (interactive)
 342   (when (and (featurep 'xpm)
 343              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 344              (or (null gnus-picons-group-excluded-groups)
 345                  (not (string-match gnus-picons-group-excluded-groups
 346                                     gnus-newsgroup-name))))
 347     (let ((groups
 348            (if gnus-picons-display-article-move-p
 349                (list (gnus-group-real-name gnus-newsgroup-name))
 350              (split-string (mail-fetch-field "newsgroups") ",")))
 351           group)
 352       (save-excursion
 353         (gnus-picons-prepare-for-annotations)
 354         (while (setq group (pop groups))
 355           (unless gnus-picons-display-article-move-p
 356             (save-restriction
 357               (let ((buffer-read-only nil))
 358                 (goto-char (point-min))
 359                 (when (re-search-forward "^Newsgroups:" nil t)
 360                   (narrow-to-region (point) (gnus-point-at-eol))
 361                   (when (search-forward group nil t)
 362                     (gnus-put-text-property
 363                      (match-beginning 0) (match-end 0)
 364                      'invisible t))))))
 365           (if (null gnus-picons-piconsearch-url)
 366               (gnus-picons-display-pairs
 367                (gnus-picons-lookup-pairs
 368                 (reverse (split-string group "\\."))
 369                 gnus-picons-news-directories)
 370                t ".")
 371             (push (list 'gnus-group-annotations 'search nil
 372                         (split-string group "\\.")
 373                         (if (listp gnus-picons-news-directories)
 374                             gnus-picons-news-directories
 375                           (list gnus-picons-news-directories))
 376                         nil)
 377                   gnus-picons-jobs-alist)
 378             (gnus-picons-next-job))
 379
 380           (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))))
 381
 382 (defun gnus-picons-lookup-internal (addrs dir)
 383   (setq dir (expand-file-name dir gnus-picons-database))
 384   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 385                           (setq dir (expand-file-name part dir)))))
 386
 387 (defun gnus-picons-lookup (addrs dirs)
 388   "Lookup the picon for ADDRS in databases DIRS.
 389 Returns the picon filename or NIL if none found."
 390   (let (result)
 391     (while (and dirs (null result))
 392       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 393     result))
 394
 395 (defun gnus-picons-lookup-user-internal (user domains)
 396   (let ((dirs gnus-picons-user-directories)
 397         domains-tmp dir picon)
 398     (while (and dirs (null picon))
 399       (setq domains-tmp domains
 400             dir (pop dirs))
 401       (while (and domains-tmp
 402                   (null (setq picon (gnus-picons-lookup-internal
 403                                      (cons user domains-tmp) dir))))
 404         (pop domains-tmp))
 405       ;; Also make a try in MISC subdir
 406       (unless picon
 407         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 408     picon))
 409
 410 (defun gnus-picons-lookup-user (user domains)
 411   "Lookup the picon for USER at DOMAINS.
 412 USER is a string containing a name.
 413 DOMAINS is a list of strings from the fully qualified domain name."
 414   (or (gnus-picons-lookup-user-internal user domains)
 415       (gnus-picons-lookup-user-internal "unknown" domains)))
 416
 417 (defun gnus-picons-lookup-pairs (domains directories)
 418   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 419 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 420 none, and whose CDR is the corresponding element of DOMAINS."
 421   (let (picons)
 422     (setq directories (if (listp directories)
 423                           directories
 424                         (list directories)))
 425     (while domains
 426       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 427                   (pop domains))
 428             picons))
 429     picons))
 430
 431 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 432   (cond (picon (gnus-picons-display-glyph picon name right-p))
 433         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 434                                                (vector 'string :data name)
 435                                                nil 'text
 436                                                nil nil nil right-p)))))
 437
 438 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 439   "Display picons in list PAIRS."
 440   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 441         pair picons)
 442     (when (and bar-p domain-p right-p
 443                gnus-picons-display-article-move-p)
 444       (setq picons (gnus-picons-display-glyph
 445                     (let ((gnus-picons-file-suffixes '("xbm")))
 446                       (gnus-picons-try-face
 447                        gnus-xmas-glyph-directory "bar."))
 448                     nil right-p)))
 449     (while (setq pair (pop pairs))
 450       (setq picons (nconc picons
 451                           (gnus-picons-display-picon-or-name
 452                            (car pair) (cadr pair) right-p)
 453                           (if (and domain-p pairs)
 454                               (list (gnus-picons-make-annotation
 455                                      (vector 'string :data dot-p)
 456                                      nil 'text nil nil nil right-p))))))
 457     picons))
 458
 459 (defun gnus-picons-try-face (dir &optional filebase)
 460   (let* ((dir (file-name-as-directory dir))
 461          (filebase (or filebase "face."))
 462          (key (concat dir filebase))
 463          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 464          (suffixes gnus-picons-file-suffixes)
 465          f suf)
 466     (while (setq suf (pop suffixes))
 467       (when (file-exists-p (setq f (expand-file-name
 468                                     (concat filebase suf)
 469                                     dir)))
 470         (setq suffixes nil
 471               glyph (make-glyph f))
 472         (when (equal suf "xbm")
 473           (set-glyph-face glyph 'gnus-picons-xbm-face))
 474         (push (cons key glyph) gnus-picons-glyph-alist)))
 475     glyph))
 476
 477 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 478   (set-glyph-baseline glyph 70)
 479   (let ((new (gnus-picons-make-annotation
 480               glyph (point) 'text nil nil nil rightp)))
 481     (when (and part gnus-picons-display-as-address)
 482       (set-annotation-data
 483        new (cons new (make-glyph (vector 'string :data part))))
 484       (set-annotation-action new 'gnus-picons-action-toggle))
 485     (nconc
 486      (list new)
 487      (if (and (eq major-mode 'gnus-article-mode)
 488               (not gnus-picons-display-as-address)
 489               (not part))
 490          (list (gnus-picons-make-annotation [string :data " "] (point)
 491                                             'text nil nil nil rightp))))))
 492
 493 (defun gnus-picons-action-toggle (data)
 494   "Toggle annotation."
 495   (interactive "e")
 496   (let* ((annot (car data))
 497          (glyph (annotation-glyph annot)))
 498     (set-annotation-glyph annot (cdr data))
 499     (set-annotation-data annot (cons annot glyph))))
 500
 501 (defun gnus-picons-clear-cache ()
 502   "Clear the picons cache."
 503   (interactive)
 504   (setq gnus-picons-glyph-alist nil
 505         gnus-picons-url-alist nil))
 506
 507 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 508
 509 (defun gnus-picons-close ()
 510   "Shut down the picons."
 511   (if gnus-picons-clear-cache-on-shutdown
 512       (gnus-picons-clear-cache)))
 513
 514 ;;; Query a remote DB.  This requires some stuff from w3 !
 515
 516 (require 'url)
 517 (require 'w3-forms)
 518
 519 (defun gnus-picons-url-retrieve (url fn arg)
 520   (let ((old-asynch (default-value 'url-be-asynchronous))
 521         (url-working-buffer (generate-new-buffer " *picons*"))
 522         (url-package-name "Gnus")
 523         (url-package-version gnus-version-number)
 524         url-request-method)
 525     (setq-default url-be-asynchronous t)
 526     (save-excursion
 527       (set-buffer url-working-buffer)
 528       (setq url-be-asynchronous t
 529             url-current-callback-data arg
 530             url-current-callback-func fn)
 531       (url-retrieve url t))
 532     (setq-default url-be-asynchronous old-asynch)))
 533
 534 (defun gnus-picons-make-glyph (type)
 535   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 536   (cond ((null type) nil)
 537         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 538                           (write-region (point-min) (point-max) fname
 539                                         nil 'quiet)
 540                           (prog1 (make-glyph (vector 'xbm :file fname))
 541                             (delete-file fname))))
 542         (t (make-glyph (vector type :data (buffer-string))))))
 543
 544 ;;; Parsing of piconsearch result page.
 545
 546 ;; Assumes:
 547 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 548 ;; 2 - a "<p>" separates the keywords from the results
 549 ;; 3 - every results begins by the path within the database at the beginning
 550 ;;     of the line in raw text.
 551 ;; 3b - and the href following it is the preferred image type.
 552
 553 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 554 ;; will go undetected
 555
 556 (defun gnus-picons-parse-value (name)
 557   (goto-char (point-min))
 558   (re-search-forward (concat "<strong>"
 559                              (regexp-quote name)
 560                              "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>"))
 561   (buffer-substring (match-beginning 1) (match-end 1)))
 562
 563 (defun gnus-picons-parse-filenames ()
 564   ;; returns an alist of ((USER ADDRS DB) . URL)
 565   (let* ((case-fold-search t)
 566          (user (gnus-picons-parse-value "user"))
 567          (host (gnus-picons-parse-value "host"))
 568          (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 569          (start-re
 570           (concat
 571            ;; dbs
 572            "^\\(" (mapconcat 'identity dbs "\\|") "\\)/"
 573            ;; host
 574            "\\(\\(" (replace-in-string host "\\." "/\\|" t) "/\\|MISC/\\)*\\)"
 575            ;; user
 576            "\\(" (regexp-quote user) "\\|unknown\\)/"
 577            "face\\."))
 578          cur-db cur-host cur-user types res)
 579     ;; now point will be somewhere in the header.  Find beginning of
 580     ;; entries
 581     (re-search-forward "<p>[ \t\n]*")
 582     (while (re-search-forward start-re nil t)
 583       (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 584             cur-host (buffer-substring (match-beginning 2) (match-end 2))
 585             cur-user (buffer-substring (match-beginning 4) (match-end 4))
 586             cur-host (nreverse (message-tokenize-header cur-host "/")))
 587       ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 588       (unless (and (string-equal cur-db "news")
 589                    (string-equal cur-user "unknown")
 590                    (equal cur-host '("MISC")))
 591         ;; ok now we have found an entry (USER HOST DB), find the
 592         ;; corresponding picon URL
 593         (save-restriction
 594           ;; restrict region to this entry
 595           (narrow-to-region (point) (search-forward "<br>"))
 596           (goto-char (point-min))
 597           (setq types gnus-picons-file-suffixes)
 598           (while (and types
 599                       (not (re-search-forward
 600                             (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 601                                     (regexp-quote (car types)) "\\)\"")
 602                             nil t)))
 603             (pop types))
 604           (push (cons (list cur-user cur-host cur-db)
 605                       (buffer-substring (match-beginning 1) (match-end 1)))
 606                 res))))
 607     (nreverse res)))
 608
 609 ;;; picon network display functions :
 610
 611 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p)
 612   (gnus-picons-set-buffer)
 613   (gnus-picons-display-picon-or-name glyph part right-p)
 614   (gnus-picons-next-job-internal))
 615
 616 (defun gnus-picons-network-display-callback (url part sym-ann right-p)
 617   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 618                                                    w3-image-mappings)))))
 619     (kill-buffer (current-buffer))
 620     (push (cons url glyph) gnus-picons-glyph-alist)
 621     ;; only do the job if it has not been preempted.
 622     (if (equal gnus-picons-job-already-running
 623                (list sym-ann 'picon url part right-p))
 624         (gnus-picons-network-display-internal sym-ann glyph part right-p)
 625       (gnus-picons-next-job-internal))))
 626
 627 (defun gnus-picons-network-display (url part sym-ann right-p)
 628   (let ((cache (assoc url gnus-picons-glyph-alist)))
 629     (if (or cache (null url))
 630         (gnus-picons-network-display-internal sym-ann (cdr cache) part right-p)
 631       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 632                                 (list url part sym-ann right-p)))))
 633
 634 ;;; search job functions
 635
 636 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 637                                                  &optional fnames)
 638   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 639     ;; First do the domain search
 640     (dolist (part (if right-p
 641                       (reverse addrs)
 642                     addrs))
 643       (setq pfx (nconc (list part) pfx)
 644             dom (cond ((and dom right-p) (concat part "." dom))
 645                       (dom (concat dom "." part))
 646                       (t part))
 647             curkey (list "unknown" dom dbs))
 648       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 649         ;; This one is not yet in the cache, create a new entry
 650         ;; Search for an entry
 651         (setq dbs-tmp dbs
 652               url nil)
 653         (while (and dbs-tmp (null url))
 654           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 655                         (and (eq dom part)
 656                              ;; This is the first component.  Try the
 657                              ;; catch-all MISC component
 658                              (cdr (assoc (list "unknown"
 659                                                '("MISC")
 660                                                (car dbs-tmp))
 661                                          fnames)))))
 662           (pop dbs-tmp))
 663         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 664       ;; Put this glyph in the job list
 665       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 666           (push (list sym-ann "." right-p) new-jobs))
 667       (push (list sym-ann 'picon (cdr cache) part right-p) new-jobs))
 668     ;; next, the user search
 669     (when user
 670       (setq curkey (list user dom gnus-picons-user-directories))
 671       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 672           (let ((users (list user "unknown"))
 673                 dirs usr domains-tmp dir picon)
 674             (while (and users (null picon))
 675               (setq dirs gnus-picons-user-directories
 676                     usr (pop users))
 677               (while (and dirs (null picon))
 678                 (setq domains-tmp addrs
 679                       dir (pop dirs))
 680                 (while (and domains-tmp
 681                             (null (setq picon (assoc (list usr domains-tmp dir)
 682                                                      fnames))))
 683                   (pop domains-tmp))
 684                 (unless picon
 685                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 686             (push (setq cache (cons curkey (cdr picon)))
 687                   gnus-picons-url-alist)))
 688       (if (and gnus-picons-display-as-address new-jobs)
 689           (push (list sym-ann "@" right-p) new-jobs))
 690       (push (list sym-ann 'picon (cdr cache) user right-p) new-jobs))
 691     (if (and gnus-picons-display-as-address (not right-p))
 692         (push (list sym-ann 'bar right-p) new-jobs))
 693     ;; only put the jobs in the queue if this job has not been preempted.
 694     (if (equal gnus-picons-job-already-running
 695                (list sym-ann 'search user addrs dbs right-p))
 696         (setq gnus-picons-jobs-alist
 697               (nconc (if (and gnus-picons-display-as-address right-p)
 698                          (list (list sym-ann 'bar right-p)))
 699                      (nreverse new-jobs)
 700                      gnus-picons-jobs-alist)))
 701     (gnus-picons-next-job-internal)))
 702
 703 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p)
 704   (gnus-picons-network-search-internal user addrs dbs sym-ann right-p
 705                                        (prog1 (gnus-picons-parse-filenames)
 706                                          (kill-buffer (current-buffer)))))
 707
 708 ;; Initiate a query on the picon database
 709 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p)
 710   (let* ((host (mapconcat 'identity addrs "."))
 711          (key (list (or user "unknown") host (if user
 712                                                   gnus-picons-user-directories
 713                                                 dbs)))
 714          (cache (assoc key gnus-picons-url-alist)))
 715     (if (null cache)
 716         (gnus-picons-url-retrieve
 717          (concat gnus-picons-piconsearch-url
 718                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 719                  "&host=" (w3-form-encode-xwfu host)
 720                  "&db=" (mapconcat 'w3-form-encode-xwfu
 721                                    (if user
 722                                        (append dbs
 723                                                gnus-picons-user-directories)
 724                                      dbs)
 725                                    "+"))
 726          'gnus-picons-network-search-callback
 727          (list user addrs dbs sym-ann right-p))
 728       (gnus-picons-network-search-internal user addrs dbs sym-ann right-p))))
 729
 730 ;;; Main jobs dispatcher function
 731
 732 (defun gnus-picons-next-job-internal ()
 733   (if (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 734       (let* ((job gnus-picons-job-already-running)
 735              (sym-ann (pop job))
 736              (tag (pop job)))
 737         (if tag
 738             (cond ((stringp tag);; (SYM-ANN "..." RIGHT-P)
 739                    (gnus-picons-network-display-internal sym-ann nil tag
 740                                                          (pop job)))
 741                   ((and (eq 'bar tag)
 742                         gnus-picons-display-article-move-p)
 743                    (gnus-picons-network-display-internal
 744                     sym-ann
 745                     (let ((gnus-picons-file-suffixes '("xbm")))
 746                       (gnus-picons-try-face
 747                        gnus-xmas-glyph-directory "bar."))
 748                     nil (pop job)))
 749                   ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P)
 750                    (gnus-picons-network-search
 751                     (pop job) (pop job) (pop job) sym-ann (pop job)))
 752                   ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P)
 753                    (gnus-picons-network-display
 754                     (pop job) (pop job) sym-ann (pop job)))
 755                   (t (setq gnus-picons-job-already-running nil)
 756                      (error "Unknown picon job tag %s" tag)))))))
 757
 758 (defun gnus-picons-next-job ()
 759   "Start processing the job queue if it is not in progress."
 760   (unless gnus-picons-job-already-running
 761     (gnus-picons-next-job-internal)))
 762
 763 (provide 'gnus-picon)
 764
 765 ;;; gnus-picon.el ends here