git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31
  32 ;;; Internal variables.
  33
  34 (defvar gnus-summary-mark-positions nil)
  35 (defvar gnus-group-mark-positions nil)
  36 (defvar gnus-group-indentation "")
  37
  38 ;; Format specs.  The chunks below are the machine-generated forms
  39 ;; that are to be evaled as the result of the default format strings.
  40 ;; We write them in here to get them byte-compiled.  That way the
  41 ;; default actions will be quite fast, while still retaining the full
  42 ;; flexibility of the user-defined format specs.
  43
  44 ;; First we have lots of dummy defvars to let the compiler know these
  45 ;; are really dynamic variables.
  46
  47 (defvar gnus-tmp-unread)
  48 (defvar gnus-tmp-replied)
  49 (defvar gnus-tmp-score-char)
  50 (defvar gnus-tmp-indentation)
  51 (defvar gnus-tmp-opening-bracket)
  52 (defvar gnus-tmp-lines)
  53 (defvar gnus-tmp-name)
  54 (defvar gnus-tmp-closing-bracket)
  55 (defvar gnus-tmp-subject-or-nil)
  56 (defvar gnus-tmp-subject)
  57 (defvar gnus-tmp-marked)
  58 (defvar gnus-tmp-marked-mark)
  59 (defvar gnus-tmp-subscribed)
  60 (defvar gnus-tmp-process-marked)
  61 (defvar gnus-tmp-number-of-unread)
  62 (defvar gnus-tmp-group-name)
  63 (defvar gnus-tmp-group)
  64 (defvar gnus-tmp-article-number)
  65 (defvar gnus-tmp-unread-and-unselected)
  66 (defvar gnus-tmp-news-method)
  67 (defvar gnus-tmp-news-server)
  68 (defvar gnus-tmp-article-number)
  69 (defvar gnus-mouse-face)
  70 (defvar gnus-mouse-face-prop)
  71
  72 (defun gnus-summary-line-format-spec ()
  73   (insert gnus-tmp-unread gnus-tmp-replied
  74           gnus-tmp-score-char gnus-tmp-indentation)
  75   (gnus-put-text-property
  76    (point)
  77    (progn
  78      (insert
  79       gnus-tmp-opening-bracket
  80       (format "%4d: %-20s"
  81               gnus-tmp-lines
  82               (if (> (length gnus-tmp-name) 20)
  83                   (substring gnus-tmp-name 0 20)
  84                 gnus-tmp-name))
  85       gnus-tmp-closing-bracket)
  86      (point))
  87    gnus-mouse-face-prop gnus-mouse-face)
  88   (insert " " gnus-tmp-subject-or-nil "\n"))
  89
  90 (defvar gnus-summary-line-format-spec
  91   (gnus-byte-code 'gnus-summary-line-format-spec))
  92
  93 (defun gnus-summary-dummy-line-format-spec ()
  94   (insert "*  ")
  95   (gnus-put-text-property
  96    (point)
  97    (progn
  98      (insert ":                          :")
  99      (point))
 100    gnus-mouse-face-prop gnus-mouse-face)
 101   (insert " " gnus-tmp-subject "\n"))
 102
 103 (defvar gnus-summary-dummy-line-format-spec
 104   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 105
 106 (defun gnus-group-line-format-spec ()
 107   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 108           gnus-tmp-process-marked
 109           gnus-group-indentation
 110           (format "%5s: " gnus-tmp-number-of-unread))
 111   (gnus-put-text-property
 112    (point)
 113    (progn
 114      (insert gnus-tmp-group "\n")
 115      (1- (point)))
 116    gnus-mouse-face-prop gnus-mouse-face))
 117 (defvar gnus-group-line-format-spec
 118   (gnus-byte-code 'gnus-group-line-format-spec))
 119
 120 (defvar gnus-format-specs
 121   `((version . ,emacs-version)
 122     (group "%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec)
 123     (summary-dummy "*  %(:                          :%) %S\n"
 124                    ,gnus-summary-dummy-line-format-spec)
 125     (summary "%U\%R\%z\%I\%(%[%4L: %-20,20n%]%) %s\n"
 126              ,gnus-summary-line-format-spec))
 127   "Alist of format specs.")
 128
 129 (defvar gnus-article-mode-line-format-spec nil)
 130 (defvar gnus-summary-mode-line-format-spec nil)
 131 (defvar gnus-group-mode-line-format-spec nil)
 132
 133 ;;; Phew.  All that gruft is over, fortunately.
 134
 135 ;;;###autoload
 136 (defun gnus-update-format (var)
 137   "Update the format specification near point."
 138   (interactive
 139    (list
 140     (save-excursion
 141       (eval-defun nil)
 142       ;; Find the end of the current word.
 143       (re-search-forward "[ \t\n]" nil t)
 144       ;; Search backward.
 145       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 146         (match-string 1)))))
 147   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 148                               (match-string 1 var))))
 149          (entry (assq type gnus-format-specs))
 150          value spec)
 151     (when entry
 152       (setq gnus-format-specs (delq entry gnus-format-specs)))
 153     (set
 154      (intern (format "%s-spec" var))
 155      (gnus-parse-format (setq value (symbol-value (intern var)))
 156                         (symbol-value (intern (format "%s-alist" var)))
 157                         (not (string-match "mode" var))))
 158     (setq spec (symbol-value (intern (format "%s-spec" var))))
 159     (push (list type value spec) gnus-format-specs)
 160
 161     (pop-to-buffer "*Gnus Format*")
 162     (erase-buffer)
 163     (lisp-interaction-mode)
 164     (insert (pp-to-string spec))))
 165
 166 (defun gnus-update-format-specifications (&optional force &rest types)
 167   "Update all (necessary) format specifications."
 168   ;; Make the indentation array.
 169   ;; See whether all the stored info needs to be flushed.
 170   (when (or force
 171             (not (equal emacs-version
 172                         (cdr (assq 'version gnus-format-specs)))))
 173     (setq gnus-format-specs nil))
 174
 175   ;; Go through all the formats and see whether they need updating.
 176   (let (new-format entry type val)
 177     (while (setq type (pop types))
 178       ;; Jump to the proper buffer to find out the value of
 179       ;; the variable, if possible.  (It may be buffer-local.)
 180       (save-excursion
 181         (let ((buffer (intern (format "gnus-%s-buffer" type)))
 182               val)
 183           (when (and (boundp buffer)
 184                      (setq val (symbol-value buffer))
 185                      (gnus-buffer-exists-p val))
 186             (set-buffer val))
 187           (setq new-format (symbol-value
 188                             (intern (format "gnus-%s-line-format" type)))))
 189         (setq entry (cdr (assq type gnus-format-specs)))
 190         (if (and (car entry)
 191                  (equal (car entry) new-format))
 192             ;; Use the old format.
 193             (set (intern (format "gnus-%s-line-format-spec" type))
 194                  (cadr entry))
 195           ;; This is a new format.
 196           (setq val
 197                 (if (not (stringp new-format))
 198                     ;; This is a function call or something.
 199                     new-format
 200                   ;; This is a "real" format.
 201                   (gnus-parse-format
 202                    new-format
 203                    (symbol-value
 204                     (intern (format "gnus-%s-line-format-alist"
 205                                     (if (eq type 'article-mode)
 206                                         'summary-mode type))))
 207                    (not (string-match "mode$" (symbol-name type))))))
 208           ;; Enter the new format spec into the list.
 209           (if entry
 210               (progn
 211                 (setcar (cdr entry) val)
 212                 (setcar entry new-format))
 213             (push (list type new-format val) gnus-format-specs))
 214           (set (intern (format "gnus-%s-line-format-spec" type)) val)))))
 215
 216   (unless (assq 'version gnus-format-specs)
 217     (push (cons 'version emacs-version) gnus-format-specs)))
 218
 219 (defvar gnus-mouse-face-0 'highlight)
 220 (defvar gnus-mouse-face-1 'highlight)
 221 (defvar gnus-mouse-face-2 'highlight)
 222 (defvar gnus-mouse-face-3 'highlight)
 223 (defvar gnus-mouse-face-4 'highlight)
 224
 225 (defun gnus-mouse-face-function (form type)
 226   `(gnus-put-text-property
 227     (point) (progn ,@form (point))
 228     gnus-mouse-face-prop
 229     ,(if (equal type 0)
 230          'gnus-mouse-face
 231        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 232
 233 (defvar gnus-face-0 'bold)
 234 (defvar gnus-face-1 'italic)
 235 (defvar gnus-face-2 'bold-italic)
 236 (defvar gnus-face-3 'bold)
 237 (defvar gnus-face-4 'bold)
 238
 239 (defun gnus-face-face-function (form type)
 240   `(gnus-add-text-properties
 241     (point) (progn ,@form (point))
 242     (list 'gnus-face t
 243           'face ',(symbol-value (intern (format "gnus-face-%d" type))))))
 244
 245 (defun gnus-tilde-max-form (el max-width)
 246   "Return a form that limits EL to MAX-WIDTH."
 247   (let ((max (abs max-width)))
 248     (if (symbolp el)
 249         `(if (> (length ,el) ,max)
 250              ,(if (< max-width 0)
 251                   `(substring ,el (- (length el) ,max))
 252                 `(substring ,el 0 ,max))
 253            ,el)
 254       `(let ((val (eval ,el)))
 255          (if (> (length val) ,max)
 256              ,(if (< max-width 0)
 257                   `(substring val (- (length val) ,max))
 258                 `(substring val 0 ,max))
 259            val)))))
 260
 261 (defun gnus-tilde-cut-form (el cut-width)
 262   "Return a form that cuts CUT-WIDTH off of EL."
 263   (let ((cut (abs cut-width)))
 264     (if (symbolp el)
 265         `(if (> (length ,el) ,cut)
 266              ,(if (< cut-width 0)
 267                   `(substring ,el 0 (- (length el) ,cut))
 268                 `(substring ,el ,cut))
 269            ,el)
 270       `(let ((val (eval ,el)))
 271          (if (> (length val) ,cut)
 272              ,(if (< cut-width 0)
 273                   `(substring val 0 (- (length val) ,cut))
 274                 `(substring val ,cut))
 275            val)))))
 276
 277 (defun gnus-tilde-ignore-form (el ignore-value)
 278   "Return a form that is blank when EL is IGNORE-VALUE."
 279   (if (symbolp el)
 280       `(if (equal ,el ,ignore-value)
 281            "" ,el)
 282     `(let ((val (eval ,el)))
 283        (if (equal val ,ignore-value)
 284            "" val))))
 285
 286 (defun gnus-parse-format (format spec-alist &optional insert)
 287   ;; This function parses the FORMAT string with the help of the
 288   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 289   ;; string.  If the FORMAT string contains the specifiers %( and %)
 290   ;; the text between them will have the mouse-face text property.
 291   (if (string-match
 292        "\\`\\(.*\\)%[0-9]?[{(]\\(.*\\)%[0-9]?[})]\\(.*\n?\\)\\'"
 293        format)
 294       (gnus-parse-complex-format format spec-alist)
 295     ;; This is a simple format.
 296     (gnus-parse-simple-format format spec-alist insert)))
 297
 298 (defun gnus-parse-complex-format (format spec-alist)
 299   (save-excursion
 300     (gnus-set-work-buffer)
 301     (insert format)
 302     (goto-char (point-min))
 303     (while (re-search-forward "\"" nil t)
 304       (replace-match "\\\"" nil t))
 305     (goto-char (point-min))
 306     (insert "(\"")
 307     (while (re-search-forward "%\\([0-9]+\\)?\\([{}()]\\)" nil t)
 308       (let ((number (if (match-beginning 1)
 309                         (match-string 1) "0"))
 310             (delim (aref (match-string 2) 0)))
 311         (if (or (= delim ?\()
 312                 (= delim ?\{))
 313             (replace-match (concat "\"(" (if (= delim ?\() "mouse" "face")
 314                                    " " number " \""))
 315           (replace-match "\")\""))))
 316     (goto-char (point-max))
 317     (insert "\")")
 318     (goto-char (point-min))
 319     (let ((form (read (current-buffer))))
 320       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 321
 322 (defun gnus-complex-form-to-spec (form spec-alist)
 323   (delq nil
 324         (mapcar
 325          (lambda (sform)
 326            (if (stringp sform)
 327                (gnus-parse-simple-format sform spec-alist t)
 328              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 329                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 330                       (nth 1 sform))))
 331          form)))
 332
 333 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 334   ;; This function parses the FORMAT string with the help of the
 335   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 336   ;; string.
 337   (let ((max-width 0)
 338         spec flist fstring elem result dontinsert user-defined
 339         type value pad-width spec-beg cut-width ignore-value
 340         tilde-form tilde elem-type)
 341     (save-excursion
 342       (gnus-set-work-buffer)
 343       (insert format)
 344       (goto-char (point-min))
 345       (while (re-search-forward "%" nil t)
 346         (setq user-defined nil
 347               spec-beg nil
 348               pad-width nil
 349               max-width nil
 350               cut-width nil
 351               ignore-value nil
 352               tilde-form nil)
 353         (setq spec-beg (1- (point)))
 354
 355         ;; Parse this spec fully.
 356         (while
 357             (cond
 358              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 359               (setq pad-width (string-to-number (match-string 1)))
 360               (when (match-beginning 2)
 361                 (setq max-width (string-to-number (buffer-substring
 362                                                    (1+ (match-beginning 2))
 363                                                    (match-end 2)))))
 364               (goto-char (match-end 0)))
 365              ((looking-at "~")
 366               (forward-char 1)
 367               (setq tilde (read (current-buffer))
 368                     type (car tilde)
 369                     value (cadr tilde))
 370               (cond
 371                ((memq type '(pad pad-left))
 372                 (setq pad-width value))
 373                ((eq type 'pad-right)
 374                 (setq pad-width (- value)))
 375                ((memq type '(max-right max))
 376                 (setq max-width value))
 377                ((eq type 'max-left)
 378                 (setq max-width (- value)))
 379                ((memq type '(cut cut-left))
 380                 (setq cut-width value))
 381                ((eq type 'cut-right)
 382                 (setq cut-width (- value)))
 383                ((eq type 'ignore)
 384                 (setq ignore-value
 385                       (if (stringp value) value (format "%s" value))))
 386                ((eq type 'form)
 387                 (setq tilde-form value))
 388                (t
 389                 (error "Unknown tilde type: %s" tilde)))
 390               t)
 391              (t
 392               nil)))
 393         ;; User-defined spec -- find the spec name.
 394         (when (= (setq spec (following-char)) ?u)
 395           (forward-char 1)
 396           (setq user-defined (following-char)))
 397         (forward-char 1)
 398         (delete-region spec-beg (point))
 399
 400         ;; Now we have all the relevant data on this spec, so
 401         ;; we start doing stuff.
 402         (insert "%")
 403         (if (eq spec ?%)
 404             ;; "%%" just results in a "%".
 405             (insert "%")
 406           (cond
 407            ;; Do tilde forms.
 408            ((eq spec ?@)
 409             (setq elem (list tilde-form ?s)))
 410            ;; Treat user defined format specifiers specially.
 411            (user-defined
 412             (setq elem
 413                   (list
 414                    (list (intern (format "gnus-user-format-function-%c"
 415                                          user-defined))
 416                          'gnus-tmp-header)
 417                    ?s)))
 418            ;; Find the specification from `spec-alist'.
 419            ((setq elem (cdr (assq spec spec-alist))))
 420            (t
 421             (setq elem '("*" ?s))))
 422           (setq elem-type (cadr elem))
 423           ;; Insert the new format elements.
 424           (when pad-width
 425             (insert (number-to-string pad-width)))
 426           ;; Create the form to be evaled.
 427           (if (or max-width cut-width ignore-value)
 428               (progn
 429                 (insert ?s)
 430                 (let ((el (car elem)))
 431                   (cond ((= (cadr elem) ?c)
 432                          (setq el (list 'char-to-string el)))
 433                         ((= (cadr elem) ?d)
 434                          (setq el (list 'int-to-string el))))
 435                   (when ignore-value
 436                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 437                   (when cut-width
 438                     (setq el (gnus-tilde-cut-form el cut-width)))
 439                   (when max-width
 440                     (setq el (gnus-tilde-max-form el max-width)))
 441                   (push el flist)))
 442             (insert elem-type)
 443             (push (car elem) flist))))
 444       (setq fstring (buffer-string)))
 445
 446     ;; Do some postprocessing to increase efficiency.
 447     (setq
 448      result
 449      (cond
 450       ;; Emptyness.
 451       ((string= fstring "")
 452        nil)
 453       ;; Not a format string.
 454       ((not (string-match "%" fstring))
 455        (list fstring))
 456       ;; A format string with just a single string spec.
 457       ((string= fstring "%s")
 458        (list (car flist)))
 459       ;; A single character.
 460       ((string= fstring "%c")
 461        (list (car flist)))
 462       ;; A single number.
 463       ((string= fstring "%d")
 464        (setq dontinsert)
 465        (if insert
 466            (list `(princ ,(car flist)))
 467          (list `(int-to-string ,(car flist)))))
 468       ;; Just lots of chars and strings.
 469       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 470        (nreverse flist))
 471       ;; A single string spec at the beginning of the spec.
 472       ((string-match "\\`%[sc][^%]+\\'" fstring)
 473        (list (car flist) (substring fstring 2)))
 474       ;; A single string spec in the middle of the spec.
 475       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 476        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 477       ;; A single string spec in the end of the spec.
 478       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 479        (list (match-string 1 fstring) (car flist)))
 480       ;; A more complex spec.
 481       (t
 482        (list (cons 'format (cons fstring (nreverse flist)))))))
 483
 484     (if insert
 485         (when result
 486           (if dontinsert
 487               result
 488             (cons 'insert result)))
 489       (cond ((stringp result)
 490              result)
 491             ((consp result)
 492              (cons 'concat result))
 493             (t "")))))
 494
 495 (defun gnus-eval-format (format &optional alist props)
 496   "Eval the format variable FORMAT, using ALIST.
 497 If PROPS, insert the result."
 498   (let ((form (gnus-parse-format format alist props)))
 499     (if props
 500         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 501       (eval form))))
 502
 503 (defun gnus-compile ()
 504   "Byte-compile the user-defined format specs."
 505   (interactive)
 506   (require 'bytecomp)
 507   (let ((entries gnus-format-specs)
 508         (byte-compile-warnings '(unresolved callargs redefine))
 509         entry gnus-tmp-func)
 510     (save-excursion
 511       (gnus-message 7 "Compiling format specs...")
 512
 513       (while entries
 514         (setq entry (pop entries))
 515         (if (eq (car entry) 'version)
 516             (setq gnus-format-specs (delq entry gnus-format-specs))
 517           (let ((form (caddr entry)))
 518             (when (and (listp form)
 519                        ;; Under GNU Emacs, it's (byte-code ...)
 520                        (not (eq 'byte-code (car form)))
 521                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 522                        (not (and (eq 'funcall (car form))
 523                                  (compiled-function-p (cadr form)))))
 524               (fset 'gnus-tmp-func `(lambda () ,form))
 525               (byte-compile 'gnus-tmp-func)
 526               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 527
 528       (push (cons 'version emacs-version) gnus-format-specs)
 529       ;; Mark the .newsrc.eld file as "dirty".
 530       (gnus-dribble-enter " ")
 531       (gnus-message 7 "Compiling user specs...done"))))
 532
 533 (defun gnus-set-format (type &optional insertable)
 534   (set (intern (format "gnus-%s-line-format-spec" type))
 535        (gnus-parse-format
 536         (symbol-value (intern (format "gnus-%s-line-format" type)))
 537         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 538         insertable)))
 539
 540
 541 (provide 'gnus-spec)
 542
 543 ;;; gnus-spec.el ends here