git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus  -*- coding: iso-latin-1 -*-
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'alist)
  33 (require 'gnus)
  34
  35 (defcustom gnus-use-correct-string-widths t
  36   "*If non-nil, use correct functions for dealing with wide characters."
  37   :group 'gnus-format
  38   :type 'boolean)
  39
  40 ;;; Internal variables.
  41
  42 (defvar gnus-summary-mark-positions nil)
  43 (defvar gnus-group-mark-positions nil)
  44 (defvar gnus-group-indentation "")
  45
  46 ;; Format specs.  The chunks below are the machine-generated forms
  47 ;; that are to be evaled as the result of the default format strings.
  48 ;; We write them in here to get them byte-compiled.  That way the
  49 ;; default actions will be quite fast, while still retaining the full
  50 ;; flexibility of the user-defined format specs.
  51
  52 ;; First we have lots of dummy defvars to let the compiler know these
  53 ;; are really dynamic variables.
  54
  55 (defvar gnus-tmp-unread)
  56 (defvar gnus-tmp-replied)
  57 (defvar gnus-tmp-score-char)
  58 (defvar gnus-tmp-indentation)
  59 (defvar gnus-tmp-opening-bracket)
  60 (defvar gnus-tmp-lines)
  61 (defvar gnus-tmp-name)
  62 (defvar gnus-tmp-closing-bracket)
  63 (defvar gnus-tmp-subject-or-nil)
  64 (defvar gnus-tmp-subject)
  65 (defvar gnus-tmp-marked)
  66 (defvar gnus-tmp-marked-mark)
  67 (defvar gnus-tmp-subscribed)
  68 (defvar gnus-tmp-process-marked)
  69 (defvar gnus-tmp-number-of-unread)
  70 (defvar gnus-tmp-group-name)
  71 (defvar gnus-tmp-group)
  72 (defvar gnus-tmp-article-number)
  73 (defvar gnus-tmp-unread-and-unselected)
  74 (defvar gnus-tmp-news-method)
  75 (defvar gnus-tmp-news-server)
  76 (defvar gnus-tmp-article-number)
  77 (defvar gnus-mouse-face)
  78 (defvar gnus-mouse-face-prop)
  79
  80 (defun gnus-summary-line-format-spec ()
  81   (insert gnus-tmp-unread gnus-tmp-replied
  82           gnus-tmp-score-char gnus-tmp-indentation)
  83   (gnus-put-text-property
  84    (point)
  85    (progn
  86      (insert
  87       gnus-tmp-opening-bracket
  88       (format "%4d: %-20s"
  89               gnus-tmp-lines
  90               (if (> (length gnus-tmp-name) 20)
  91                   (substring gnus-tmp-name 0 20)
  92                 gnus-tmp-name))
  93       gnus-tmp-closing-bracket)
  94      (point))
  95    gnus-mouse-face-prop gnus-mouse-face)
  96   (insert " " gnus-tmp-subject-or-nil "\n"))
  97
  98 (defvar gnus-summary-line-format-spec
  99   (gnus-byte-code 'gnus-summary-line-format-spec))
 100
 101 (defun gnus-summary-dummy-line-format-spec ()
 102   (insert "*  ")
 103   (gnus-put-text-property
 104    (point)
 105    (progn
 106      (insert ":                          :")
 107      (point))
 108    gnus-mouse-face-prop gnus-mouse-face)
 109   (insert " " gnus-tmp-subject "\n"))
 110
 111 (defvar gnus-summary-dummy-line-format-spec
 112   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 113
 114 (defun gnus-group-line-format-spec ()
 115   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 116           gnus-tmp-process-marked
 117           gnus-group-indentation
 118           (format "%5s: " gnus-tmp-number-of-unread))
 119   (gnus-put-text-property
 120    (point)
 121    (progn
 122      (insert gnus-tmp-group "\n")
 123      (1- (point)))
 124    gnus-mouse-face-prop gnus-mouse-face))
 125 (defvar gnus-group-line-format-spec
 126   (gnus-byte-code 'gnus-group-line-format-spec))
 127
 128 (defvar gnus-format-specs
 129   `((group ("%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec))
 130     (summary-dummy ("*  %(:                          :%) %S\n"
 131                     ,gnus-summary-dummy-line-format-spec))
 132     (summary ("%U\%R\%z\%I\%(%[%4L: %-23,23n%]%) %s\n"
 133               ,gnus-summary-line-format-spec)))
 134   "Alist of format specs.")
 135
 136 (defvar gnus-format-specs-compiled nil
 137   "Alist of compiled format specs.  Each element should be the form:
 138 \(TYPE (FORMAT-STRING-1 . COMPILED-FUNCTION-1)
 139                  :
 140        (FORMAT-STRING-n . COMPILED-FUNCTION-n)).")
 141
 142 (defvar gnus-article-mode-line-format-spec nil)
 143 (defvar gnus-summary-mode-line-format-spec nil)
 144 (defvar gnus-group-mode-line-format-spec nil)
 145
 146 ;;; Phew.  All that gruft is over with, fortunately.
 147
 148 ;;;###autoload
 149 (defun gnus-update-format (var)
 150   "Update the format specification near point."
 151   (interactive
 152    (list
 153     (save-excursion
 154       (eval-defun nil)
 155       ;; Find the end of the current word.
 156       (re-search-forward "[ \t\n]" nil t)
 157       ;; Search backward.
 158       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 159         (match-string 1)))))
 160   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 161                               (match-string 1 var))))
 162          (value (symbol-value (intern var)))
 163          (spec (set
 164                 (intern (format "%s-spec" var))
 165                 (gnus-parse-format
 166                  value (symbol-value (intern (format "%s-alist" var)))
 167                  (not (string-match "mode" var)))))
 168          (entry (assq type gnus-format-specs)))
 169     (if entry
 170         (let ((elem (assoc value entry)))
 171           (if elem
 172               (setcdr elem spec)
 173             (setcdr entry (cons (cons value elem) (cdr entry)))))
 174       (push (list type (cons value spec)) gnus-format-specs))
 175     (gnus-product-variable-touch 'gnus-format-specs)
 176
 177     (pop-to-buffer "*Gnus Format*")
 178     (erase-buffer)
 179     (lisp-interaction-mode)
 180     (insert (pp-to-string spec))))
 181
 182 (put 'gnus-search-or-regist-spec 'lisp-indent-function 1)
 183 (defmacro gnus-search-or-regist-spec (mspec &rest body)
 184   (let ((specs (nth 0 mspec)) (type (nth 1 mspec)) (format (nth 2 mspec))
 185         (spec (nth 3 mspec)) (entry (nth 4 mspec)) (elem (nth 5 mspec)))
 186     `(let* ((,entry (assq ,type ,specs))
 187             (,elem (assoc ,format (cdr ,entry))))
 188        (or (cdr ,elem)
 189            (when (progn ,@body)
 190              (if ,entry
 191                  (if ,elem
 192                      (setcdr ,elem ,spec)
 193                    (setcdr ,entry (cons (cons ,format ,spec) (cdr ,entry))))
 194                (push (list ,type (cons ,format ,spec)) ,specs))
 195              (gnus-product-variable-touch (quote ,specs)))
 196            ,spec))))
 197
 198 (defun gnus-update-format-specification-1 (type format val)
 199   (set (intern (format "gnus-%s-line-format-spec" type))
 200        (gnus-search-or-regist-spec (gnus-format-specs-compiled
 201                                     type format val entry elem)
 202          (when (and gnus-compile-user-specs val)
 203            (setq val (prog1
 204                          (progn
 205                            (fset 'gnus-tmp-func `(lambda () ,val))
 206                            (require 'bytecomp)
 207                            (let (byte-compile-warnings)
 208                              (byte-compile 'gnus-tmp-func))
 209                            (gnus-byte-code 'gnus-tmp-func))
 210                        (when (get-buffer "*Compile-Log*")
 211                          (bury-buffer "*Compile-Log*"))
 212                        (when (get-buffer "*Compile-Log-Show*")
 213                          (bury-buffer "*Compile-Log-Show*"))))))))
 214
 215 (defun gnus-update-format-specifications (&optional force &rest types)
 216   "Update all (necessary) format specifications."
 217   ;; Make the indentation array.
 218   ;; See whether all the stored info needs to be flushed.
 219   (when force
 220     (message "%s" "Force update format specs.")
 221     (setq gnus-format-specs nil
 222           gnus-format-specs-compiled nil)
 223     (gnus-product-variable-touch 'gnus-format-specs
 224                                  'gnus-format-specs-compiled))
 225
 226   ;; Go through all the formats and see whether they need updating.
 227   (let (type val)
 228     (save-excursion
 229       (while (setq type (pop types))
 230         ;; Jump to the proper buffer to find out the value of the
 231         ;; variable, if possible.  (It may be buffer-local.)
 232         (let* ((new-format
 233                 (let ((buffer (intern (format "gnus-%s-buffer" type))))
 234                   (when (and (boundp buffer)
 235                              (setq val (symbol-value buffer))
 236                              (gnus-buffer-exists-p val))
 237                     (set-buffer val))
 238                   (symbol-value
 239                    (intern (format "gnus-%s-line-format" type))))))
 240           (or (gnus-update-format-specification-1 type new-format nil)
 241               ;; This is a new format.
 242               (gnus-update-format-specification-1
 243                type new-format
 244                (gnus-search-or-regist-spec (gnus-format-specs
 245                                             type new-format val entry elem)
 246                  (setq val (if (stringp new-format)
 247                                ;; This is a "real" format.
 248                                (gnus-parse-format
 249                                 new-format
 250                                 (symbol-value
 251                                  (intern (format "gnus-%s-line-format-alist"
 252                                                  type)))
 253                                 (not (string-match "mode$"
 254                                                    (symbol-name type))))
 255                              ;; This is a function call or something.
 256                              new-format))))))))))
 257
 258 (defvar gnus-mouse-face-0 'highlight)
 259 (defvar gnus-mouse-face-1 'highlight)
 260 (defvar gnus-mouse-face-2 'highlight)
 261 (defvar gnus-mouse-face-3 'highlight)
 262 (defvar gnus-mouse-face-4 'highlight)
 263
 264 (defun gnus-mouse-face-function (form type)
 265   `(gnus-put-text-property
 266     (point) (progn ,@form (point))
 267     gnus-mouse-face-prop
 268     ,(if (equal type 0)
 269          'gnus-mouse-face
 270        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 271
 272 (defvar gnus-face-0 'bold)
 273 (defvar gnus-face-1 'italic)
 274 (defvar gnus-face-2 'bold-italic)
 275 (defvar gnus-face-3 'bold)
 276 (defvar gnus-face-4 'bold)
 277
 278 (defun gnus-face-face-function (form type)
 279   `(gnus-add-text-properties
 280     (point) (progn ,@form (point))
 281     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 282
 283 (defun gnus-balloon-face-function (form type)
 284   `(gnus-put-text-property
 285     (point) (progn ,@form (point))
 286     'balloon-help
 287     ,(intern (format "gnus-balloon-face-%d" type))))
 288
 289 (defun gnus-spec-tab (column)
 290   (if (> column 0)
 291       `(insert (make-string (max (- ,column (current-column)) 0) ? ))
 292     `(progn
 293        (if (> (current-column) ,(abs column))
 294            (delete-region (point)
 295                           (- (point) (- (current-column) ,(abs column))))
 296          (insert (make-string (max (- ,(abs column) (current-column)) 0)
 297                               ? ))))))
 298
 299 (defun gnus-correct-length (string)
 300   "Return the correct width of STRING."
 301   (let ((length 0))
 302     (mapcar (lambda (char) (incf length (gnus-char-width char))) string)
 303     length))
 304
 305 (defun gnus-correct-substring (string start &optional end)
 306   (let ((wstart 0)
 307         (wend 0)
 308         (wseek 0)
 309         (seek 0)
 310         (length (length string))
 311         (string (concat string "\0")))
 312     ;; Find the start position.
 313     (while (and (< seek length)
 314                 (< wseek start))
 315       (incf wseek (gnus-char-width (aref string seek)))
 316       (incf seek))
 317     (setq wstart seek)
 318     ;; Find the end position.
 319     (while (and (<= seek length)
 320                 (or (not end)
 321                     (<= wseek end)))
 322       (incf wseek (gnus-char-width (aref string seek)))
 323       (incf seek))
 324     (setq wend seek)
 325     (substring string wstart (1- wend))))
 326
 327 (defun gnus-tilde-max-form (el max-width)
 328   "Return a form that limits EL to MAX-WIDTH."
 329   (let ((max (abs max-width))
 330         (length-fun (if gnus-use-correct-string-widths
 331                       'gnus-correct-length
 332                     'length))
 333         (substring-fun (if gnus-use-correct-string-widths
 334                        'gnus-correct-substring
 335                      'substring)))
 336     (if (symbolp el)
 337         `(if (> (,length-fun ,el) ,max)
 338              ,(if (< max-width 0)
 339                   `(,substring-fun ,el (- (,length-fun ,el) ,max))
 340                 `(,substring-fun ,el 0 ,max))
 341            ,el)
 342       `(let ((val (eval ,el)))
 343          (if (> (,length-fun val) ,max)
 344              ,(if (< max-width 0)
 345                   `(,substring-fun val (- (,length-fun val) ,max))
 346                 `(,substring-fun val 0 ,max))
 347            val)))))
 348
 349 (defun gnus-tilde-cut-form (el cut-width)
 350   "Return a form that cuts CUT-WIDTH off of EL."
 351   (let ((cut (abs cut-width))
 352         (length-fun (if gnus-use-correct-string-widths
 353                       'gnus-correct-length
 354                     'length))
 355         (substring-fun (if gnus-use-correct-string-widths
 356                        'gnus-correct-substring
 357                      'substring)))
 358     (if (symbolp el)
 359         `(if (> (,length-fun ,el) ,cut)
 360              ,(if (< cut-width 0)
 361                   `(,substring-fun ,el 0 (- (,length-fun ,el) ,cut))
 362                 `(,substring-fun ,el ,cut))
 363            ,el)
 364       `(let ((val (eval ,el)))
 365          (if (> (,length-fun val) ,cut)
 366              ,(if (< cut-width 0)
 367                   `(,substring-fun val 0 (- (,length-fun val) ,cut))
 368                 `(,substring-fun val ,cut))
 369            val)))))
 370
 371 (defun gnus-tilde-ignore-form (el ignore-value)
 372   "Return a form that is blank when EL is IGNORE-VALUE."
 373   (if (symbolp el)
 374       `(if (equal ,el ,ignore-value)
 375            "" ,el)
 376     `(let ((val (eval ,el)))
 377        (if (equal val ,ignore-value)
 378            "" val))))
 379
 380 (defun gnus-correct-pad-form (el pad-width)
 381   "Return a form that pads EL to PAD-WIDTH accounting for multi-column
 382 characters correctly. This is because `format' may pad to columns or to
 383 characters when given a pad value."
 384   (let ((pad (abs pad-width))
 385         (side (< 0 pad-width)))
 386     (if (symbolp el)
 387         `(let ((need (- ,pad (gnus-correct-length ,el))))
 388            (if (> need 0)
 389                (concat ,(when side '(make-string need ?\ ))
 390                        ,el
 391                        ,(when (not side) '(make-string need ?\ )))
 392              ,el))
 393       `(let* ((val (eval ,el))
 394               (need (- ,pad (gnus-correct-length ,el))))
 395          (if (> need 0)
 396              (concat ,(when side '(make-string need ?\ ))
 397                      ,el
 398                      ,(when (not side) '(make-string need ?\ )))
 399            ,el)))))
 400
 401 (defun gnus-parse-format (format spec-alist &optional insert)
 402   ;; This function parses the FORMAT string with the help of the
 403   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 404   ;; string.  If the FORMAT string contains the specifiers %( and %)
 405   ;; the text between them will have the mouse-face text property.
 406   ;; If the FORMAT string contains the specifiers %[ and %], the text between
 407   ;; them will have the balloon-help text property.
 408   (let ((case-fold-search nil))
 409     (if (string-match
 410        "\\`\\(.*\\)%[0-9]?[{(«]\\(.*\\)%[0-9]?[»})]\\(.*\n?\\)\\'"
 411        format)
 412       (gnus-parse-complex-format format spec-alist)
 413       ;; This is a simple format.
 414       (gnus-parse-simple-format format spec-alist insert))))
 415
 416 (defun gnus-parse-complex-format (format spec-alist)
 417   (save-excursion
 418     (gnus-set-work-buffer)
 419     (insert format)
 420     (goto-char (point-min))
 421     (while (re-search-forward "\"" nil t)
 422       (replace-match "\\\"" nil t))
 423     (goto-char (point-min))
 424     (insert "(\"")
 425     ;; Convert all font specs into font spec lists.
 426     (while (re-search-forward "%\\([0-9]+\\)?\\([«»{}()]\\)" nil t)
 427       (let ((number (if (match-beginning 1)
 428                         (match-string 1) "0"))
 429             (delim (aref (match-string 2) 0)))
 430         (if (or (= delim ?\()
 431                 (= delim ?\{)
 432                 (= delim ?\«))
 433             (replace-match (concat "\"("
 434                                    (cond ((= delim ?\() "mouse")
 435                                          ((= delim ?\{) "face")
 436                                          (t "balloon"))
 437                                    " " number " \"")
 438                            t t)
 439           (replace-match "\")\""))))
 440     (goto-char (point-max))
 441     (insert "\")")
 442     ;; Convert point position commands.
 443     (goto-char (point-min))
 444     (let ((case-fold-search nil))
 445       (while (re-search-forward "%\\([-0-9]+\\)?C" nil t)
 446         (replace-match "\"(point)\"" t t)))
 447     ;; Convert TAB commands.
 448     (goto-char (point-min))
 449     (while (re-search-forward "%\\([-0-9]+\\)=" nil t)
 450       (replace-match (format "\"(tab %s)\"" (match-string 1)) t t))
 451     ;; Convert the buffer into the spec.
 452     (goto-char (point-min))
 453     (let ((form (read (current-buffer))))
 454       ;; If the first element is '(point), we just remove it.
 455       (when (equal (car form) '(point))
 456         (pop form))
 457       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 458
 459 (defun gnus-complex-form-to-spec (form spec-alist)
 460   (delq nil
 461         (mapcar
 462          (lambda (sform)
 463            (cond
 464             ((stringp sform)
 465              (gnus-parse-simple-format sform spec-alist t))
 466             ((eq (car sform) 'point)
 467              `(gnus-put-text-property (1- (point)) (point) 'gnus-position t))
 468             ((eq (car sform) 'tab)
 469              (gnus-spec-tab (cadr sform)))
 470             (t
 471              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 472                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 473                       (nth 1 sform)))))
 474          form)))
 475
 476 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 477   ;; This function parses the FORMAT string with the help of the
 478   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 479   ;; string.
 480   (let (max-width
 481         spec flist fstring elem result dontinsert user-defined
 482         type value pad-width spec-beg cut-width ignore-value
 483         tilde-form tilde elem-type)
 484     (save-excursion
 485       (gnus-set-work-buffer)
 486       (insert format)
 487       (goto-char (point-min))
 488       (while (search-forward "%" nil t)
 489         (setq user-defined nil
 490               spec-beg nil
 491               pad-width nil
 492               max-width nil
 493               cut-width nil
 494               ignore-value nil
 495               tilde-form nil)
 496         (setq spec-beg (1- (point)))
 497
 498         ;; Parse this spec fully.
 499         (while
 500             (cond
 501              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 502               (setq pad-width (string-to-number (match-string 1)))
 503               (when (match-beginning 2)
 504                 (setq max-width (string-to-number (buffer-substring
 505                                                    (1+ (match-beginning 2))
 506                                                    (match-end 2)))))
 507               (goto-char (match-end 0)))
 508              ((looking-at "~")
 509               (forward-char 1)
 510               (setq tilde (read (current-buffer))
 511                     type (car tilde)
 512                     value (cadr tilde))
 513               (cond
 514                ((memq type '(pad pad-left))
 515                 (setq pad-width value))
 516                ((eq type 'pad-right)
 517                 (setq pad-width (- value)))
 518                ((memq type '(max-right max))
 519                 (setq max-width value))
 520                ((eq type 'max-left)
 521                 (setq max-width (- value)))
 522                ((memq type '(cut cut-left))
 523                 (setq cut-width value))
 524                ((eq type 'cut-right)
 525                 (setq cut-width (- value)))
 526                ((eq type 'ignore)
 527                 (setq ignore-value
 528                       (if (stringp value) value (format "%s" value))))
 529                ((eq type 'form)
 530                 (setq tilde-form value))
 531                (t
 532                 (error "Unknown tilde type: %s" tilde)))
 533               t)
 534              (t
 535               nil)))
 536         ;; User-defined spec -- find the spec name.
 537         (when (eq (setq spec (char-after)) ?u)
 538           (forward-char 1)
 539           (setq user-defined (char-after)))
 540         (forward-char 1)
 541         (delete-region spec-beg (point))
 542
 543         ;; Now we have all the relevant data on this spec, so
 544         ;; we start doing stuff.
 545         (insert "%")
 546         (if (eq spec ?%)
 547             ;; "%%" just results in a "%".
 548             (insert "%")
 549           (cond
 550            ;; Do tilde forms.
 551            ((eq spec ?@)
 552             (setq elem (list tilde-form ?s)))
 553            ;; Treat user defined format specifiers specially.
 554            (user-defined
 555             (setq elem
 556                   (list
 557                    (list (intern (format "gnus-user-format-function-%c"
 558                                          user-defined))
 559                          'gnus-tmp-header)
 560                    ?s)))
 561            ;; Find the specification from `spec-alist'.
 562            ((setq elem (cdr (assq spec spec-alist))))
 563            (t
 564             (setq elem '("*" ?s))))
 565           (setq elem-type (cadr elem))
 566           ;; Insert the new format elements.
 567           (when (and pad-width
 568                      (not (and (featurep 'xemacs)
 569                                gnus-use-correct-string-widths)))
 570             (insert (number-to-string pad-width)))
 571           ;; Create the form to be evaled.
 572           (if (or max-width cut-width ignore-value
 573                   (and (featurep 'xemacs)
 574                        gnus-use-correct-string-widths))
 575               (progn
 576                 (insert ?s)
 577                 (let ((el (car elem)))
 578                   (cond ((= (cadr elem) ?c)
 579                          (setq el (list 'char-to-string el)))
 580                         ((= (cadr elem) ?d)
 581                          (setq el (list 'int-to-string el))))
 582                   (when ignore-value
 583                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 584                   (when cut-width
 585                     (setq el (gnus-tilde-cut-form el cut-width)))
 586                   (when max-width
 587                     (setq el (gnus-tilde-max-form el max-width)))
 588                   (when pad-width
 589                     (setq el (gnus-correct-pad-form el pad-width)))
 590                   (push el flist)))
 591             (insert elem-type)
 592             (push (car elem) flist))))
 593       (setq fstring (buffer-string)))
 594
 595     ;; Do some postprocessing to increase efficiency.
 596     (setq
 597      result
 598      (cond
 599       ;; Emptyness.
 600       ((string= fstring "")
 601        nil)
 602       ;; Not a format string.
 603       ((not (string-match "%" fstring))
 604        (list fstring))
 605       ;; A format string with just a single string spec.
 606       ((string= fstring "%s")
 607        (list (car flist)))
 608       ;; A single character.
 609       ((string= fstring "%c")
 610        (list (car flist)))
 611       ;; A single number.
 612       ((string= fstring "%d")
 613        (setq dontinsert)
 614        (if insert
 615            (list `(princ ,(car flist)))
 616          (list `(int-to-string ,(car flist)))))
 617       ;; Just lots of chars and strings.
 618       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 619        (nreverse flist))
 620       ;; A single string spec at the beginning of the spec.
 621       ((string-match "\\`%[sc][^%]+\\'" fstring)
 622        (list (car flist) (substring fstring 2)))
 623       ;; A single string spec in the middle of the spec.
 624       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 625        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 626       ;; A single string spec in the end of the spec.
 627       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 628        (list (match-string 1 fstring) (car flist)))
 629       ;; A more complex spec.
 630       (t
 631        (list (cons 'format (cons fstring (nreverse flist)))))))
 632
 633     (if insert
 634         (when result
 635           (if dontinsert
 636               result
 637             (cons 'insert result)))
 638       (cond ((stringp result)
 639              result)
 640             ((consp result)
 641              (cons 'concat result))
 642             (t "")))))
 643
 644 (defun gnus-eval-format (format &optional alist props)
 645   "Eval the format variable FORMAT, using ALIST.
 646 If PROPS, insert the result."
 647   (let ((form (gnus-parse-format format alist props)))
 648     (if props
 649         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 650       (eval form))))
 651
 652 (defun gnus-compile ()
 653   "Byte-compile the user-defined format specs."
 654   (interactive)
 655   (require 'bytecomp)
 656   (let ((entries gnus-format-specs)
 657         (byte-compile-warnings '(unresolved callargs redefine))
 658         entry type compiled-function)
 659     (save-excursion
 660       (gnus-message 7 "Compiling format specs...")
 661
 662       (while entries
 663         (setq entry (pop entries)
 664               type (car entry))
 665         (if (memq type '(gnus-version version))
 666             (setq gnus-format-specs (delq entry gnus-format-specs))
 667           (let ((form (caddr entry)))
 668             (when (and (listp form)
 669                        ;; Under GNU Emacs, it's (byte-code ...)
 670                        (not (eq 'byte-code (car form)))
 671                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 672                        (not (and (eq 'funcall (car form))
 673                                  (byte-code-function-p (cadr form)))))
 674               (defalias 'gnus-tmp-func `(lambda () ,form))
 675               (byte-compile 'gnus-tmp-func)
 676               (setq compiled-function (gnus-byte-code 'gnus-tmp-func))
 677               (set (intern (format "gnus-%s-line-format-spec" type))
 678                    compiled-function)
 679               (let ((elem (cdr (assq type gnus-format-specs-compiled))))
 680                 (if elem
 681                     (set-alist 'elem (cadr entry) compiled-function)
 682                   (setq elem (list (cadr entry) compiled-function)))
 683                 (set-alist 'gnus-format-specs-compiled type elem))))))
 684
 685       (push (cons 'version emacs-version) gnus-format-specs)
 686       (gnus-message 7 "Compiling user specs...done"))))
 687
 688 (defun gnus-set-format (type &optional insertable)
 689   (set (intern (format "gnus-%s-line-format-spec" type))
 690        (gnus-parse-format
 691         (symbol-value (intern (format "gnus-%s-line-format" type)))
 692         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 693         insertable)))
 694
 695 (gnus-ems-redefine)
 696
 697 (provide 'gnus-spec)
 698
 699 ;; Local Variables:
 700 ;; coding: iso-8859-1
 701 ;; End:
 702
 703 ;;; gnus-spec.el ends here