git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31
  32 ;;; Internal variables.
  33
  34 (defvar gnus-summary-mark-positions nil)
  35 (defvar gnus-group-mark-positions nil)
  36 (defvar gnus-group-indentation "")
  37
  38 ;; Format specs.  The chunks below are the machine-generated forms
  39 ;; that are to be evaled as the result of the default format strings.
  40 ;; We write them in here to get them byte-compiled.  That way the
  41 ;; default actions will be quite fast, while still retaining the full
  42 ;; flexibility of the user-defined format specs.
  43
  44 ;; First we have lots of dummy defvars to let the compiler know these
  45 ;; are really dynamic variables.
  46
  47 (defvar gnus-tmp-unread)
  48 (defvar gnus-tmp-replied)
  49 (defvar gnus-tmp-score-char)
  50 (defvar gnus-tmp-indentation)
  51 (defvar gnus-tmp-opening-bracket)
  52 (defvar gnus-tmp-lines)
  53 (defvar gnus-tmp-name)
  54 (defvar gnus-tmp-closing-bracket)
  55 (defvar gnus-tmp-subject-or-nil)
  56 (defvar gnus-tmp-subject)
  57 (defvar gnus-tmp-marked)
  58 (defvar gnus-tmp-marked-mark)
  59 (defvar gnus-tmp-subscribed)
  60 (defvar gnus-tmp-process-marked)
  61 (defvar gnus-tmp-number-of-unread)
  62 (defvar gnus-tmp-group-name)
  63 (defvar gnus-tmp-group)
  64 (defvar gnus-tmp-article-number)
  65 (defvar gnus-tmp-unread-and-unselected)
  66 (defvar gnus-tmp-news-method)
  67 (defvar gnus-tmp-news-server)
  68 (defvar gnus-tmp-article-number)
  69 (defvar gnus-mouse-face)
  70 (defvar gnus-mouse-face-prop)
  71
  72 (defun gnus-summary-line-format-spec ()
  73   (insert gnus-tmp-unread gnus-tmp-replied
  74           gnus-tmp-score-char gnus-tmp-indentation)
  75   (gnus-put-text-property
  76    (point)
  77    (progn
  78      (insert
  79       gnus-tmp-opening-bracket
  80       (format "%4d: %-20s"
  81               gnus-tmp-lines
  82               (if (> (length gnus-tmp-name) 20)
  83                   (substring gnus-tmp-name 0 20)
  84                 gnus-tmp-name))
  85       gnus-tmp-closing-bracket)
  86      (point))
  87    gnus-mouse-face-prop gnus-mouse-face)
  88   (insert " " gnus-tmp-subject-or-nil "\n"))
  89
  90 (defvar gnus-summary-line-format-spec
  91   (gnus-byte-code 'gnus-summary-line-format-spec))
  92
  93 (defun gnus-summary-dummy-line-format-spec ()
  94   (insert "*  ")
  95   (gnus-put-text-property
  96    (point)
  97    (progn
  98      (insert ":                          :")
  99      (point))
 100    gnus-mouse-face-prop gnus-mouse-face)
 101   (insert " " gnus-tmp-subject "\n"))
 102
 103 (defvar gnus-summary-dummy-line-format-spec
 104   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 105
 106 (defun gnus-group-line-format-spec ()
 107   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 108           gnus-tmp-process-marked
 109           gnus-group-indentation
 110           (format "%5s: " gnus-tmp-number-of-unread))
 111   (gnus-put-text-property
 112    (point)
 113    (progn
 114      (insert gnus-tmp-group "\n")
 115      (1- (point)))
 116    gnus-mouse-face-prop gnus-mouse-face))
 117 (defvar gnus-group-line-format-spec
 118   (gnus-byte-code 'gnus-group-line-format-spec))
 119
 120 (defvar gnus-format-specs
 121   `((version . ,emacs-version)
 122     (group "%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec)
 123     (summary-dummy "*  %(:                          :%) %S\n"
 124                    ,gnus-summary-dummy-line-format-spec)
 125     (summary "%U\%R\%z\%I\%(%[%4L: %-20,20n%]%) %s\n"
 126              ,gnus-summary-line-format-spec))
 127   "Alist of format specs.")
 128
 129 (defvar gnus-article-mode-line-format-spec nil)
 130 (defvar gnus-summary-mode-line-format-spec nil)
 131 (defvar gnus-group-mode-line-format-spec nil)
 132
 133 ;;; Phew.  All that gruft is over, fortunately.
 134
 135 ;;;###autoload
 136 (defun gnus-update-format (var)
 137   "Update the format specification near point."
 138   (interactive
 139    (list
 140     (save-excursion
 141       (eval-defun nil)
 142       ;; Find the end of the current word.
 143       (re-search-forward "[ \t\n]" nil t)
 144       ;; Search backward.
 145       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 146         (match-string 1)))))
 147   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 148                               (match-string 1 var))))
 149          (entry (assq type gnus-format-specs))
 150          value spec)
 151     (when entry
 152       (setq gnus-format-specs (delq entry gnus-format-specs)))
 153     (set
 154      (intern (format "%s-spec" var))
 155      (gnus-parse-format (setq value (symbol-value (intern var)))
 156                         (symbol-value (intern (format "%s-alist" var)))
 157                         (not (string-match "mode" var))))
 158     (setq spec (symbol-value (intern (format "%s-spec" var))))
 159     (push (list type value spec) gnus-format-specs)
 160
 161     (pop-to-buffer "*Gnus Format*")
 162     (erase-buffer)
 163     (lisp-interaction-mode)
 164     (insert (pp-to-string spec))))
 165
 166 (defun gnus-update-format-specifications (&optional force &rest types)
 167   "Update all (necessary) format specifications."
 168   ;; Make the indentation array.
 169   ;; See whether all the stored info needs to be flushed.
 170   (when (or force
 171             (not (equal emacs-version
 172                         (cdr (assq 'version gnus-format-specs)))))
 173     (setq gnus-format-specs nil))
 174
 175   ;; Go through all the formats and see whether they need updating.
 176   (let (new-format entry type val)
 177     (while (setq type (pop types))
 178       ;; Jump to the proper buffer to find out the value of
 179       ;; the variable, if possible.  (It may be buffer-local.)
 180       (save-excursion
 181         (let ((buffer (intern (format "gnus-%s-buffer" type)))
 182               val)
 183           (when (and (boundp buffer)
 184                      (setq val (symbol-value buffer))
 185                      (gnus-buffer-exists-p val))
 186             (set-buffer val))
 187           (setq new-format (symbol-value
 188                             (intern (format "gnus-%s-line-format" type)))))
 189         (setq entry (cdr (assq type gnus-format-specs)))
 190         (if (and (car entry)
 191                  (equal (car entry) new-format))
 192             ;; Use the old format.
 193             (set (intern (format "gnus-%s-line-format-spec" type))
 194                  (cadr entry))
 195           ;; This is a new format.
 196           (setq val
 197                 (if (not (stringp new-format))
 198                     ;; This is a function call or something.
 199                     new-format
 200                   ;; This is a "real" format.
 201                   (gnus-parse-format
 202                    new-format
 203                    (symbol-value
 204                     (intern (format "gnus-%s-line-format-alist"
 205                                     (if (eq type 'article-mode)
 206                                         'summary-mode type))))
 207                    (not (string-match "mode$" (symbol-name type))))))
 208           ;; Enter the new format spec into the list.
 209           (if entry
 210               (progn
 211                 (setcar (cdr entry) val)
 212                 (setcar entry new-format))
 213             (push (list type new-format val) gnus-format-specs))
 214           (set (intern (format "gnus-%s-line-format-spec" type)) val)))))
 215
 216   (unless (assq 'version gnus-format-specs)
 217     (push (cons 'version emacs-version) gnus-format-specs)))
 218
 219 (defvar gnus-mouse-face-0 'highlight)
 220 (defvar gnus-mouse-face-1 'highlight)
 221 (defvar gnus-mouse-face-2 'highlight)
 222 (defvar gnus-mouse-face-3 'highlight)
 223 (defvar gnus-mouse-face-4 'highlight)
 224
 225 (defun gnus-mouse-face-function (form type)
 226   `(gnus-put-text-property
 227     (point) (progn ,@form (point))
 228     gnus-mouse-face-prop
 229     ,(if (equal type 0)
 230          'gnus-mouse-face
 231        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 232
 233 (defvar gnus-face-0 'bold)
 234 (defvar gnus-face-1 'italic)
 235 (defvar gnus-face-2 'bold-italic)
 236 (defvar gnus-face-3 'bold)
 237 (defvar gnus-face-4 'bold)
 238
 239 (defun gnus-face-face-function (form type)
 240   `(gnus-add-text-properties
 241     (point) (progn ,@form (point))
 242     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 243
 244 ;;; Avoid byte-compile warning.
 245 (defun gnus-tilde-pad-form (el pad-width)
 246   "Dummy function except for XEmacs-mule. It will be redefined
 247 by `gnus-xmas-redefine'."
 248   (if (symbolp el)
 249       `(eval ,el)
 250     `,el))
 251
 252 (defun gnus-tilde-max-form (el max-width)
 253   "Return a form that limits EL to MAX-WIDTH."
 254   (let ((max (abs max-width)))
 255     (if (symbolp el)
 256         `(if (> (length ,el) ,max)
 257              ,(if (< max-width 0)
 258                   `(substring ,el (- (length el) ,max))
 259                 `(substring ,el 0 ,max))
 260            ,el)
 261       `(let ((val (eval ,el)))
 262          (if (> (length val) ,max)
 263              ,(if (< max-width 0)
 264                   `(substring val (- (length val) ,max))
 265                 `(substring val 0 ,max))
 266            val)))))
 267
 268 (defun gnus-tilde-cut-form (el cut-width)
 269   "Return a form that cuts CUT-WIDTH off of EL."
 270   (let ((cut (abs cut-width)))
 271     (if (symbolp el)
 272         `(if (> (length ,el) ,cut)
 273              ,(if (< cut-width 0)
 274                   `(substring ,el 0 (- (length el) ,cut))
 275                 `(substring ,el ,cut))
 276            ,el)
 277       `(let ((val (eval ,el)))
 278          (if (> (length val) ,cut)
 279              ,(if (< cut-width 0)
 280                   `(substring val 0 (- (length val) ,cut))
 281                 `(substring val ,cut))
 282            val)))))
 283
 284 (defun gnus-tilde-ignore-form (el ignore-value)
 285   "Return a form that is blank when EL is IGNORE-VALUE."
 286   (if (symbolp el)
 287       `(if (equal ,el ,ignore-value)
 288            "" ,el)
 289     `(let ((val (eval ,el)))
 290        (if (equal val ,ignore-value)
 291            "" val))))
 292
 293 (defun gnus-parse-format (format spec-alist &optional insert)
 294   ;; This function parses the FORMAT string with the help of the
 295   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 296   ;; string.  If the FORMAT string contains the specifiers %( and %)
 297   ;; the text between them will have the mouse-face text property.
 298   (if (string-match
 299        "\\`\\(.*\\)%[0-9]?[{(]\\(.*\\)%[0-9]?[})]\\(.*\n?\\)\\'"
 300        format)
 301       (gnus-parse-complex-format format spec-alist)
 302     ;; This is a simple format.
 303     (gnus-parse-simple-format format spec-alist insert)))
 304
 305 (defun gnus-parse-complex-format (format spec-alist)
 306   (save-excursion
 307     (gnus-set-work-buffer)
 308     (insert format)
 309     (goto-char (point-min))
 310     (while (re-search-forward "\"" nil t)
 311       (replace-match "\\\"" nil t))
 312     (goto-char (point-min))
 313     (insert "(\"")
 314     (while (re-search-forward "%\\([0-9]+\\)?\\([{}()]\\)" nil t)
 315       (let ((number (if (match-beginning 1)
 316                         (match-string 1) "0"))
 317             (delim (aref (match-string 2) 0)))
 318         (if (or (= delim ?\()
 319                 (= delim ?\{))
 320             (replace-match (concat "\"(" (if (= delim ?\() "mouse" "face")
 321                                    " " number " \""))
 322           (replace-match "\")\""))))
 323     (goto-char (point-max))
 324     (insert "\")")
 325     (goto-char (point-min))
 326     (let ((form (read (current-buffer))))
 327       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 328
 329 (defun gnus-complex-form-to-spec (form spec-alist)
 330   (delq nil
 331         (mapcar
 332          (lambda (sform)
 333            (if (stringp sform)
 334                (gnus-parse-simple-format sform spec-alist t)
 335              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 336                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 337                       (nth 1 sform))))
 338          form)))
 339
 340 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 341   ;; This function parses the FORMAT string with the help of the
 342   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 343   ;; string.
 344   (let ((xemacs-mule-p (and gnus-xemacs (featurep 'mule)))
 345         max-width
 346         spec flist fstring elem result dontinsert user-defined
 347         type value pad-width spec-beg cut-width ignore-value
 348         tilde-form tilde elem-type)
 349     (save-excursion
 350       (gnus-set-work-buffer)
 351       (insert format)
 352       (goto-char (point-min))
 353       (while (search-forward "%" nil t)
 354         (setq user-defined nil
 355               spec-beg nil
 356               pad-width nil
 357               max-width nil
 358               cut-width nil
 359               ignore-value nil
 360               tilde-form nil)
 361         (setq spec-beg (1- (point)))
 362
 363         ;; Parse this spec fully.
 364         (while
 365             (cond
 366              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 367               (setq pad-width (string-to-number (match-string 1)))
 368               (when (match-beginning 2)
 369                 (setq max-width (string-to-number (buffer-substring
 370                                                    (1+ (match-beginning 2))
 371                                                    (match-end 2)))))
 372               (goto-char (match-end 0)))
 373              ((looking-at "~")
 374               (forward-char 1)
 375               (setq tilde (read (current-buffer))
 376                     type (car tilde)
 377                     value (cadr tilde))
 378               (cond
 379                ((memq type '(pad pad-left))
 380                 (setq pad-width value))
 381                ((eq type 'pad-right)
 382                 (setq pad-width (- value)))
 383                ((memq type '(max-right max))
 384                 (setq max-width value))
 385                ((eq type 'max-left)
 386                 (setq max-width (- value)))
 387                ((memq type '(cut cut-left))
 388                 (setq cut-width value))
 389                ((eq type 'cut-right)
 390                 (setq cut-width (- value)))
 391                ((eq type 'ignore)
 392                 (setq ignore-value
 393                       (if (stringp value) value (format "%s" value))))
 394                ((eq type 'form)
 395                 (setq tilde-form value))
 396                (t
 397                 (error "Unknown tilde type: %s" tilde)))
 398               t)
 399              (t
 400               nil)))
 401         ;; User-defined spec -- find the spec name.
 402         (when (= (setq spec (following-char)) ?u)
 403           (forward-char 1)
 404           (setq user-defined (following-char)))
 405         (forward-char 1)
 406         (delete-region spec-beg (point))
 407
 408         ;; Now we have all the relevant data on this spec, so
 409         ;; we start doing stuff.
 410         (insert "%")
 411         (if (eq spec ?%)
 412             ;; "%%" just results in a "%".
 413             (insert "%")
 414           (cond
 415            ;; Do tilde forms.
 416            ((eq spec ?@)
 417             (setq elem (list tilde-form ?s)))
 418            ;; Treat user defined format specifiers specially.
 419            (user-defined
 420             (setq elem
 421                   (list
 422                    (list (intern (format "gnus-user-format-function-%c"
 423                                          user-defined))
 424                          'gnus-tmp-header)
 425                    ?s)))
 426            ;; Find the specification from `spec-alist'.
 427            ((setq elem (cdr (assq spec spec-alist))))
 428            (t
 429             (setq elem '("*" ?s))))
 430           (setq elem-type (cadr elem))
 431           ;; Insert the new format elements.
 432           (and pad-width (not xemacs-mule-p)
 433                (insert (number-to-string pad-width)))
 434           ;; Create the form to be evaled.
 435           (if (or max-width cut-width ignore-value
 436                   (and pad-width xemacs-mule-p))
 437               (progn
 438                 (insert ?s)
 439                 (let ((el (car elem)))
 440                   (cond ((= (cadr elem) ?c)
 441                          (setq el (list 'char-to-string el)))
 442                         ((= (cadr elem) ?d)
 443                          (setq el (list 'int-to-string el))))
 444                   (when ignore-value
 445                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 446                   (when cut-width
 447                     (setq el (gnus-tilde-cut-form el cut-width)))
 448                   (when max-width
 449                     (setq el (gnus-tilde-max-form el max-width)))
 450                   (and pad-width xemacs-mule-p
 451                        (setq el (gnus-tilde-pad-form el pad-width)))
 452                   (push el flist)))
 453             (insert elem-type)
 454             (push (car elem) flist))))
 455       (setq fstring (buffer-string)))
 456
 457     ;; Do some postprocessing to increase efficiency.
 458     (setq
 459      result
 460      (cond
 461       ;; Emptyness.
 462       ((string= fstring "")
 463        nil)
 464       ;; Not a format string.
 465       ((not (string-match "%" fstring))
 466        (list fstring))
 467       ;; A format string with just a single string spec.
 468       ((string= fstring "%s")
 469        (list (car flist)))
 470       ;; A single character.
 471       ((string= fstring "%c")
 472        (list (car flist)))
 473       ;; A single number.
 474       ((string= fstring "%d")
 475        (setq dontinsert)
 476        (if insert
 477            (list `(princ ,(car flist)))
 478          (list `(int-to-string ,(car flist)))))
 479       ;; Just lots of chars and strings.
 480       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 481        (nreverse flist))
 482       ;; A single string spec at the beginning of the spec.
 483       ((string-match "\\`%[sc][^%]+\\'" fstring)
 484        (list (car flist) (substring fstring 2)))
 485       ;; A single string spec in the middle of the spec.
 486       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 487        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 488       ;; A single string spec in the end of the spec.
 489       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 490        (list (match-string 1 fstring) (car flist)))
 491       ;; A more complex spec.
 492       (t
 493        (list (cons 'format (cons fstring (nreverse flist)))))))
 494
 495     (if insert
 496         (when result
 497           (if dontinsert
 498               result
 499             (cons 'insert result)))
 500       (cond ((stringp result)
 501              result)
 502             ((consp result)
 503              (cons 'concat result))
 504             (t "")))))
 505
 506 (defun gnus-eval-format (format &optional alist props)
 507   "Eval the format variable FORMAT, using ALIST.
 508 If PROPS, insert the result."
 509   (let ((form (gnus-parse-format format alist props)))
 510     (if props
 511         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 512       (eval form))))
 513
 514 (defun gnus-compile ()
 515   "Byte-compile the user-defined format specs."
 516   (interactive)
 517   (require 'bytecomp)
 518   (let ((entries gnus-format-specs)
 519         (byte-compile-warnings '(unresolved callargs redefine))
 520         entry gnus-tmp-func)
 521     (save-excursion
 522       (gnus-message 7 "Compiling format specs...")
 523
 524       (while entries
 525         (setq entry (pop entries))
 526         (if (eq (car entry) 'version)
 527             (setq gnus-format-specs (delq entry gnus-format-specs))
 528           (let ((form (caddr entry)))
 529             (when (and (listp form)
 530                        ;; Under GNU Emacs, it's (byte-code ...)
 531                        (not (eq 'byte-code (car form)))
 532                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 533                        (not (and (eq 'funcall (car form))
 534                                  (compiled-function-p (cadr form)))))
 535               (fset 'gnus-tmp-func `(lambda () ,form))
 536               (byte-compile 'gnus-tmp-func)
 537               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 538
 539       (push (cons 'version emacs-version) gnus-format-specs)
 540       ;; Mark the .newsrc.eld file as "dirty".
 541       (gnus-dribble-touch)
 542       (gnus-message 7 "Compiling user specs...done"))))
 543
 544 (defun gnus-set-format (type &optional insertable)
 545   (set (intern (format "gnus-%s-line-format-spec" type))
 546        (gnus-parse-format
 547         (symbol-value (intern (format "gnus-%s-line-format" type)))
 548         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 549         insertable)))
 550
 551
 552 (provide 'gnus-spec)
 553
 554 ;;; gnus-spec.el ends here