git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus  -*- coding: iso-latin-1 -*-
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'alist)
  33 (require 'gnus)
  34
  35 (defcustom gnus-use-correct-string-widths t
  36   "*If non-nil, use correct functions for dealing with wide characters."
  37   :group 'gnus-format
  38   :type 'boolean)
  39
  40 ;;; Internal variables.
  41
  42 (defvar gnus-summary-mark-positions nil)
  43 (defvar gnus-group-mark-positions nil)
  44 (defvar gnus-group-indentation "")
  45
  46 ;; Format specs.  The chunks below are the machine-generated forms
  47 ;; that are to be evaled as the result of the default format strings.
  48 ;; We write them in here to get them byte-compiled.  That way the
  49 ;; default actions will be quite fast, while still retaining the full
  50 ;; flexibility of the user-defined format specs.
  51
  52 ;; First we have lots of dummy defvars to let the compiler know these
  53 ;; are really dynamic variables.
  54
  55 (defvar gnus-tmp-unread)
  56 (defvar gnus-tmp-replied)
  57 (defvar gnus-tmp-score-char)
  58 (defvar gnus-tmp-indentation)
  59 (defvar gnus-tmp-opening-bracket)
  60 (defvar gnus-tmp-lines)
  61 (defvar gnus-tmp-name)
  62 (defvar gnus-tmp-closing-bracket)
  63 (defvar gnus-tmp-subject-or-nil)
  64 (defvar gnus-tmp-subject)
  65 (defvar gnus-tmp-marked)
  66 (defvar gnus-tmp-marked-mark)
  67 (defvar gnus-tmp-subscribed)
  68 (defvar gnus-tmp-process-marked)
  69 (defvar gnus-tmp-number-of-unread)
  70 (defvar gnus-tmp-group-name)
  71 (defvar gnus-tmp-group)
  72 (defvar gnus-tmp-article-number)
  73 (defvar gnus-tmp-unread-and-unselected)
  74 (defvar gnus-tmp-news-method)
  75 (defvar gnus-tmp-news-server)
  76 (defvar gnus-tmp-article-number)
  77 (defvar gnus-mouse-face)
  78 (defvar gnus-mouse-face-prop)
  79
  80 (defun gnus-summary-line-format-spec ()
  81   (insert gnus-tmp-unread gnus-tmp-replied
  82           gnus-tmp-score-char gnus-tmp-indentation)
  83   (gnus-put-text-property
  84    (point)
  85    (progn
  86      (insert
  87       gnus-tmp-opening-bracket
  88       (format "%4d: %-20s"
  89               gnus-tmp-lines
  90               (if (> (length gnus-tmp-name) 20)
  91                   (substring gnus-tmp-name 0 20)
  92                 gnus-tmp-name))
  93       gnus-tmp-closing-bracket)
  94      (point))
  95    gnus-mouse-face-prop gnus-mouse-face)
  96   (insert " " gnus-tmp-subject-or-nil "\n"))
  97
  98 (defvar gnus-summary-line-format-spec
  99   (gnus-byte-code 'gnus-summary-line-format-spec))
 100
 101 (defun gnus-summary-dummy-line-format-spec ()
 102   (insert "*  ")
 103   (gnus-put-text-property
 104    (point)
 105    (progn
 106      (insert ":                          :")
 107      (point))
 108    gnus-mouse-face-prop gnus-mouse-face)
 109   (insert " " gnus-tmp-subject "\n"))
 110
 111 (defvar gnus-summary-dummy-line-format-spec
 112   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 113
 114 (defun gnus-group-line-format-spec ()
 115   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 116           gnus-tmp-process-marked
 117           gnus-group-indentation
 118           (format "%5s: " gnus-tmp-number-of-unread))
 119   (gnus-put-text-property
 120    (point)
 121    (progn
 122      (insert gnus-tmp-group "\n")
 123      (1- (point)))
 124    gnus-mouse-face-prop gnus-mouse-face))
 125 (defvar gnus-group-line-format-spec
 126   (gnus-byte-code 'gnus-group-line-format-spec))
 127
 128 (defvar gnus-format-specs
 129   `((group ("%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec))
 130     (summary-dummy ("*  %(:                          :%) %S\n"
 131                     ,gnus-summary-dummy-line-format-spec))
 132     (summary ("%U\%R\%z\%I\%(%[%4L: %-23,23n%]%) %s\n"
 133               ,gnus-summary-line-format-spec)))
 134   "Alist of format specs.")
 135
 136 (defvar gnus-format-specs-compiled nil
 137   "Alist of compiled format specs.  Each element should be the form:
 138 \(TYPE (FORMAT-STRING-1 . COMPILED-FUNCTION-1)
 139                  :
 140        (FORMAT-STRING-n . COMPILED-FUNCTION-n)).")
 141
 142 (defvar gnus-article-mode-line-format-spec nil)
 143 (defvar gnus-summary-mode-line-format-spec nil)
 144 (defvar gnus-group-mode-line-format-spec nil)
 145
 146 ;;; Phew.  All that gruft is over with, fortunately.
 147
 148 ;;;###autoload
 149 (defun gnus-update-format (var)
 150   "Update the format specification near point."
 151   (interactive
 152    (list
 153     (save-excursion
 154       (eval-defun nil)
 155       ;; Find the end of the current word.
 156       (re-search-forward "[ \t\n]" nil t)
 157       ;; Search backward.
 158       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 159         (match-string 1)))))
 160   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 161                               (match-string 1 var))))
 162          (value (symbol-value (intern var)))
 163          (spec (set
 164                 (intern (format "%s-spec" var))
 165                 (gnus-parse-format
 166                  value (symbol-value (intern (format "%s-alist" var)))
 167                  (not (string-match "mode" var)))))
 168          (entry (assq type gnus-format-specs)))
 169     (if entry
 170         (let ((elem (assoc value entry)))
 171           (if elem
 172               (setcdr elem spec)
 173             (setcdr entry (cons (cons value elem) (cdr entry)))))
 174       (push (list type (cons value spec)) gnus-format-specs))
 175     (gnus-product-variable-touch 'gnus-format-specs)
 176
 177     (pop-to-buffer "*Gnus Format*")
 178     (erase-buffer)
 179     (lisp-interaction-mode)
 180     (insert (pp-to-string spec))))
 181
 182 (put 'gnus-search-or-regist-spec 'lisp-indent-function 1)
 183 (defmacro gnus-search-or-regist-spec (mspec &rest body)
 184   (let ((specs (nth 0 mspec)) (type (nth 1 mspec)) (format (nth 2 mspec))
 185         (spec (nth 3 mspec)) (entry (nth 4 mspec)) (elem (nth 5 mspec)))
 186     `(let* ((,entry (assq ,type ,specs))
 187             (,elem (assoc ,format (cdr ,entry))))
 188        (or (cdr ,elem)
 189            (when (progn ,@body)
 190              (if ,entry
 191                  (if ,elem
 192                      (setcdr ,elem ,spec)
 193                    (setcdr ,entry (cons (cons ,format ,spec) (cdr ,entry))))
 194                (push (list ,type (cons ,format ,spec)) ,specs))
 195              (gnus-product-variable-touch (quote ,specs)))
 196            ,spec))))
 197
 198 (defun gnus-update-format-specification-1 (type format val)
 199   (set (intern (format "gnus-%s-line-format-spec" type))
 200        (gnus-search-or-regist-spec (gnus-format-specs-compiled
 201                                     type format val entry elem)
 202          (when (and gnus-compile-user-specs val)
 203            (setq val (prog1
 204                          (progn
 205                            (fset 'gnus-tmp-func `(lambda () ,val))
 206                            (require 'bytecomp)
 207                            (let (byte-compile-warnings)
 208                              (byte-compile 'gnus-tmp-func))
 209                            (gnus-byte-code 'gnus-tmp-func))
 210                        (when (get-buffer "*Compile-Log*")
 211                          (bury-buffer "*Compile-Log*"))
 212                        (when (get-buffer "*Compile-Log-Show*")
 213                          (bury-buffer "*Compile-Log-Show*"))))))))
 214
 215 (defun gnus-update-format-specifications (&optional force &rest types)
 216   "Update all (necessary) format specifications."
 217   ;; Make the indentation array.
 218   ;; See whether all the stored info needs to be flushed.
 219   (when force
 220     (message "%s" "Force update format specs.")
 221     (setq gnus-format-specs nil
 222           gnus-format-specs-compiled nil)
 223     (gnus-product-variable-touch 'gnus-format-specs
 224                                  'gnus-format-specs-compiled))
 225
 226   ;; Go through all the formats and see whether they need updating.
 227   (let (type val)
 228     (save-excursion
 229       (while (setq type (pop types))
 230         ;; Jump to the proper buffer to find out the value of the
 231         ;; variable, if possible.  (It may be buffer-local.)
 232         (let* ((new-format
 233                 (let ((buffer (intern (format "gnus-%s-buffer" type))))
 234                   (when (and (boundp buffer)
 235                              (setq val (symbol-value buffer))
 236                              (gnus-buffer-exists-p val))
 237                     (set-buffer val))
 238                   (symbol-value
 239                    (intern (format "gnus-%s-line-format" type))))))
 240           (or (gnus-update-format-specification-1 type new-format nil)
 241               ;; This is a new format.
 242               (gnus-update-format-specification-1
 243                type new-format
 244                (gnus-search-or-regist-spec (gnus-format-specs
 245                                             type new-format val entry elem)
 246                  (setq val (if (stringp new-format)
 247                                ;; This is a "real" format.
 248                                (gnus-parse-format
 249                                 new-format
 250                                 (symbol-value
 251                                  (intern (format "gnus-%s-line-format-alist"
 252                                                  type)))
 253                                 (not (string-match "mode$"
 254                                                    (symbol-name type))))
 255                              ;; This is a function call or something.
 256                              new-format))))))))))
 257
 258 (defvar gnus-mouse-face-0 'highlight)
 259 (defvar gnus-mouse-face-1 'highlight)
 260 (defvar gnus-mouse-face-2 'highlight)
 261 (defvar gnus-mouse-face-3 'highlight)
 262 (defvar gnus-mouse-face-4 'highlight)
 263
 264 (defun gnus-mouse-face-function (form type)
 265   `(gnus-put-text-property
 266     (point) (progn ,@form (point))
 267     gnus-mouse-face-prop
 268     ,(if (equal type 0)
 269          'gnus-mouse-face
 270        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 271
 272 (defvar gnus-face-0 'bold)
 273 (defvar gnus-face-1 'italic)
 274 (defvar gnus-face-2 'bold-italic)
 275 (defvar gnus-face-3 'bold)
 276 (defvar gnus-face-4 'bold)
 277
 278 (defun gnus-face-face-function (form type)
 279   `(gnus-add-text-properties
 280     (point) (progn ,@form (point))
 281     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 282
 283 ;;; Avoid byte-compile warning.
 284 (defun gnus-tilde-pad-form (el pad-width)
 285   "Dummy function except for XEmacs-mule. It will be redefined
 286 by `gnus-xmas-redefine'."
 287   (let ((val (if (symbolp el) (eval el) el)))
 288     (` (, val))))
 289
 290 (defun gnus-balloon-face-function (form type)
 291   `(gnus-put-text-property
 292     (point) (progn ,@form (point))
 293     'balloon-help
 294     ,(intern (format "gnus-balloon-face-%d" type))))
 295
 296 (defun gnus-spec-tab (column)
 297   (if (> column 0)
 298       `(insert (make-string (max (- ,column (current-column)) 0) ? ))
 299     `(progn
 300        (if (> (current-column) ,(abs column))
 301            (delete-region (point)
 302                           (- (point) (- (current-column) ,(abs column))))
 303          (insert (make-string (max (- ,(abs column) (current-column)) 0)
 304                               ? ))))))
 305
 306 (defun gnus-correct-length (string)
 307   "Return the correct width of STRING."
 308   (let ((length 0))
 309     (mapcar (lambda (char) (incf length (gnus-char-width char))) string)
 310     length))
 311
 312 (defun gnus-correct-substring (string start end)
 313   (let ((wstart 0)
 314         (wend 0)
 315         (seek 0)
 316         (length (length string)))
 317     ;; Find the start position.
 318     (while (and (< seek length)
 319                 (< wstart start))
 320       (incf wstart (gnus-char-width (aref string seek)))
 321       (incf seek))
 322     (setq wend wstart
 323           wstart seek)
 324     ;; Find the end position.
 325     (while (and (< seek length)
 326                 (<= wend end))
 327       (incf wend (gnus-char-width (aref string seek)))
 328       (incf seek))
 329     (setq wend seek)
 330     (substring string wstart (1- wend))))
 331
 332 (defun gnus-tilde-max-form (el max-width)
 333   "Return a form that limits EL to MAX-WIDTH."
 334   (let ((max (abs max-width)))
 335     (if (symbolp el)
 336         `(if (> (,(if gnus-use-correct-string-widths
 337                       'gnus-correct-length
 338                     'length) ,el)
 339                 ,max)
 340              ,(if (< max-width 0)
 341                   `(,(if gnus-use-correct-string-widths
 342                          'gnus-correct-substring
 343                        'substring)
 344                     ,el (- (,(if gnus-use-correct-string-widths
 345                                  'gnus-correct-length
 346                                'length)
 347                             el) ,max))
 348                 `(,(if gnus-use-correct-string-widths
 349                        'gnus-correct-substring
 350                      'substring)
 351                   ,el 0 ,max))
 352            ,el)
 353       `(let ((val (eval ,el)))
 354          (if (> (,(if gnus-use-correct-string-widths
 355                       'gnus-correct-length
 356                     'length) val) ,max)
 357              ,(if (< max-width 0)
 358                   `(,(if gnus-use-correct-string-widths
 359                          'gnus-correct-substring
 360                        'substring)
 361                     val (- (,(if gnus-use-correct-string-widths
 362                                  'gnus-correct-length
 363                                'length) val) ,max))
 364                 `(,(if gnus-use-correct-string-widths
 365                        'gnus-correct-substring
 366                      'substring)
 367                   val 0 ,max))
 368            val)))))
 369
 370 (defun gnus-tilde-cut-form (el cut-width)
 371   "Return a form that cuts CUT-WIDTH off of EL."
 372   (let ((cut (abs cut-width)))
 373     (if (symbolp el)
 374         `(if (> (,(if gnus-use-correct-string-widths
 375                       'gnus-correct-length
 376                     'length) ,el) ,cut)
 377              ,(if (< cut-width 0)
 378                   `(,(if gnus-use-correct-string-widths
 379                          'gnus-correct-substring
 380                        'substring) ,el 0
 381                        (- (,(if gnus-use-correct-string-widths
 382                                 'gnus-correct-length
 383                               'length) el) ,cut))
 384                 `(,(if gnus-use-correct-string-widths
 385                        'gnus-correct-substring
 386                      'substring) ,el ,cut))
 387            ,el)
 388       `(let ((val (eval ,el)))
 389          (if (> (,(if gnus-use-correct-string-widths
 390                       'gnus-correct-length
 391                     'length) val) ,cut)
 392              ,(if (< cut-width 0)
 393                   `(,(if gnus-use-correct-string-widths
 394                          'gnus-correct-substring
 395                        'substring) val 0
 396                        (- (,(if gnus-use-correct-string-widths
 397                                 'gnus-correct-length
 398                               'length) val) ,cut))
 399                 `(,(if gnus-use-correct-string-widths
 400                        'gnus-correct-substring
 401                      'substring) val ,cut))
 402            val)))))
 403
 404 (defun gnus-tilde-ignore-form (el ignore-value)
 405   "Return a form that is blank when EL is IGNORE-VALUE."
 406   (if (symbolp el)
 407       `(if (equal ,el ,ignore-value)
 408            "" ,el)
 409     `(let ((val (eval ,el)))
 410        (if (equal val ,ignore-value)
 411            "" val))))
 412
 413 (defun gnus-parse-format (format spec-alist &optional insert)
 414   ;; This function parses the FORMAT string with the help of the
 415   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 416   ;; string.  If the FORMAT string contains the specifiers %( and %)
 417   ;; the text between them will have the mouse-face text property.
 418   ;; If the FORMAT string contains the specifiers %[ and %], the text between
 419   ;; them will have the balloon-help text property.
 420   (if (string-match
 421        "\\`\\(.*\\)%[0-9]?[{(«]\\(.*\\)%[0-9]?[»})]\\(.*\n?\\)\\'"
 422        format)
 423       (gnus-parse-complex-format format spec-alist)
 424     ;; This is a simple format.
 425     (gnus-parse-simple-format format spec-alist insert)))
 426
 427 (defun gnus-parse-complex-format (format spec-alist)
 428   (save-excursion
 429     (gnus-set-work-buffer)
 430     (insert format)
 431     (goto-char (point-min))
 432     (while (re-search-forward "\"" nil t)
 433       (replace-match "\\\"" nil t))
 434     (goto-char (point-min))
 435     (insert "(\"")
 436     ;; Convert all font specs into font spec lists.
 437     (while (re-search-forward "%\\([0-9]+\\)?\\([«»{}()]\\)" nil t)
 438       (let ((number (if (match-beginning 1)
 439                         (match-string 1) "0"))
 440             (delim (aref (match-string 2) 0)))
 441         (if (or (= delim ?\()
 442                 (= delim ?\{)
 443                 (= delim ?\«))
 444             (replace-match (concat "\"("
 445                                    (cond ((= delim ?\() "mouse")
 446                                          ((= delim ?\{) "face")
 447                                          (t "balloon"))
 448                                    " " number " \"")
 449                            t t)
 450           (replace-match "\")\""))))
 451     (goto-char (point-max))
 452     (insert "\")")
 453     ;; Convert point position commands.
 454     (goto-char (point-min))
 455     (while (re-search-forward "%\\([-0-9]+\\)?C" nil t)
 456       (replace-match "\"(point)\"" t t))
 457     ;; Convert TAB commands.
 458     (goto-char (point-min))
 459     (while (re-search-forward "%\\([-0-9]+\\)=" nil t)
 460       (replace-match (format "\"(tab %s)\"" (match-string 1)) t t))
 461     ;; Convert the buffer into the spec.
 462     (goto-char (point-min))
 463     (let ((form (read (current-buffer))))
 464       ;; If the first element is '(point), we just remove it.
 465       (when (equal (car form) '(point))
 466         (pop form))
 467       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 468
 469 (defun gnus-complex-form-to-spec (form spec-alist)
 470   (delq nil
 471         (mapcar
 472          (lambda (sform)
 473            (cond
 474             ((stringp sform)
 475              (gnus-parse-simple-format sform spec-alist t))
 476             ((eq (car sform) 'point)
 477              `(gnus-put-text-property (1- (point)) (point) 'gnus-position t))
 478             ((eq (car sform) 'tab)
 479              (gnus-spec-tab (cadr sform)))
 480             (t
 481              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 482                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 483                       (nth 1 sform)))))
 484          form)))
 485
 486 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 487   ;; This function parses the FORMAT string with the help of the
 488   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 489   ;; string.
 490   (let ((xemacs-mule-p (and (featurep 'xemacs) (featurep 'mule)))
 491         max-width
 492         spec flist fstring elem result dontinsert user-defined
 493         type value pad-width spec-beg cut-width ignore-value
 494         tilde-form tilde elem-type)
 495     (save-excursion
 496       (gnus-set-work-buffer)
 497       (insert format)
 498       (goto-char (point-min))
 499       (while (search-forward "%" nil t)
 500         (setq user-defined nil
 501               spec-beg nil
 502               pad-width nil
 503               max-width nil
 504               cut-width nil
 505               ignore-value nil
 506               tilde-form nil)
 507         (setq spec-beg (1- (point)))
 508
 509         ;; Parse this spec fully.
 510         (while
 511             (cond
 512              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 513               (setq pad-width (string-to-number (match-string 1)))
 514               (when (match-beginning 2)
 515                 (setq max-width (string-to-number (buffer-substring
 516                                                    (1+ (match-beginning 2))
 517                                                    (match-end 2)))))
 518               (goto-char (match-end 0)))
 519              ((looking-at "~")
 520               (forward-char 1)
 521               (setq tilde (read (current-buffer))
 522                     type (car tilde)
 523                     value (cadr tilde))
 524               (cond
 525                ((memq type '(pad pad-left))
 526                 (setq pad-width value))
 527                ((eq type 'pad-right)
 528                 (setq pad-width (- value)))
 529                ((memq type '(max-right max))
 530                 (setq max-width value))
 531                ((eq type 'max-left)
 532                 (setq max-width (- value)))
 533                ((memq type '(cut cut-left))
 534                 (setq cut-width value))
 535                ((eq type 'cut-right)
 536                 (setq cut-width (- value)))
 537                ((eq type 'ignore)
 538                 (setq ignore-value
 539                       (if (stringp value) value (format "%s" value))))
 540                ((eq type 'form)
 541                 (setq tilde-form value))
 542                (t
 543                 (error "Unknown tilde type: %s" tilde)))
 544               t)
 545              (t
 546               nil)))
 547         ;; User-defined spec -- find the spec name.
 548         (when (eq (setq spec (char-after)) ?u)
 549           (forward-char 1)
 550           (setq user-defined (char-after)))
 551         (forward-char 1)
 552         (delete-region spec-beg (point))
 553
 554         ;; Now we have all the relevant data on this spec, so
 555         ;; we start doing stuff.
 556         (insert "%")
 557         (if (eq spec ?%)
 558             ;; "%%" just results in a "%".
 559             (insert "%")
 560           (cond
 561            ;; Do tilde forms.
 562            ((eq spec ?@)
 563             (setq elem (list tilde-form ?s)))
 564            ;; Treat user defined format specifiers specially.
 565            (user-defined
 566             (setq elem
 567                   (list
 568                    (list (intern (format "gnus-user-format-function-%c"
 569                                          user-defined))
 570                          'gnus-tmp-header)
 571                    ?s)))
 572            ;; Find the specification from `spec-alist'.
 573            ((setq elem (cdr (assq spec spec-alist))))
 574            (t
 575             (setq elem '("*" ?s))))
 576           (setq elem-type (cadr elem))
 577           ;; Insert the new format elements.
 578           (and pad-width (not xemacs-mule-p)
 579                (insert (number-to-string pad-width)))
 580           ;; Create the form to be evaled.
 581           (if (or max-width cut-width ignore-value
 582                   (and pad-width xemacs-mule-p))
 583               (progn
 584                 (insert ?s)
 585                 (let ((el (car elem)))
 586                   (cond ((= (cadr elem) ?c)
 587                          (setq el (list 'char-to-string el)))
 588                         ((= (cadr elem) ?d)
 589                          (setq el (list 'int-to-string el))))
 590                   (when ignore-value
 591                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 592                   (when cut-width
 593                     (setq el (gnus-tilde-cut-form el cut-width)))
 594                   (when max-width
 595                     (setq el (gnus-tilde-max-form el max-width)))
 596                   (and pad-width xemacs-mule-p
 597                        (setq el (gnus-tilde-pad-form el pad-width)))
 598                   (push el flist)))
 599             (insert elem-type)
 600             (push (car elem) flist))))
 601       (setq fstring (buffer-string)))
 602
 603     ;; Do some postprocessing to increase efficiency.
 604     (setq
 605      result
 606      (cond
 607       ;; Emptyness.
 608       ((string= fstring "")
 609        nil)
 610       ;; Not a format string.
 611       ((not (string-match "%" fstring))
 612        (list fstring))
 613       ;; A format string with just a single string spec.
 614       ((string= fstring "%s")
 615        (list (car flist)))
 616       ;; A single character.
 617       ((string= fstring "%c")
 618        (list (car flist)))
 619       ;; A single number.
 620       ((string= fstring "%d")
 621        (setq dontinsert)
 622        (if insert
 623            (list `(princ ,(car flist)))
 624          (list `(int-to-string ,(car flist)))))
 625       ;; Just lots of chars and strings.
 626       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 627        (nreverse flist))
 628       ;; A single string spec at the beginning of the spec.
 629       ((string-match "\\`%[sc][^%]+\\'" fstring)
 630        (list (car flist) (substring fstring 2)))
 631       ;; A single string spec in the middle of the spec.
 632       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 633        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 634       ;; A single string spec in the end of the spec.
 635       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 636        (list (match-string 1 fstring) (car flist)))
 637       ;; A more complex spec.
 638       (t
 639        (list (cons 'format (cons fstring (nreverse flist)))))))
 640
 641     (if insert
 642         (when result
 643           (if dontinsert
 644               result
 645             (cons 'insert result)))
 646       (cond ((stringp result)
 647              result)
 648             ((consp result)
 649              (cons 'concat result))
 650             (t "")))))
 651
 652 (defun gnus-eval-format (format &optional alist props)
 653   "Eval the format variable FORMAT, using ALIST.
 654 If PROPS, insert the result."
 655   (let ((form (gnus-parse-format format alist props)))
 656     (if props
 657         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 658       (eval form))))
 659
 660 (defun gnus-compile ()
 661   "Byte-compile the user-defined format specs."
 662   (interactive)
 663   (require 'bytecomp)
 664   (let ((entries gnus-format-specs)
 665         (byte-compile-warnings '(unresolved callargs redefine))
 666         entry type compiled-function)
 667     (save-excursion
 668       (gnus-message 7 "Compiling format specs...")
 669
 670       (while entries
 671         (setq entry (pop entries)
 672               type (car entry))
 673         (if (memq type '(version gnus-version))
 674             (setq gnus-format-specs (delq entry gnus-format-specs))
 675           (let ((form (caddr entry)))
 676             (when (and (listp form)
 677                        ;; Under GNU Emacs, it's (byte-code ...)
 678                        (not (eq 'byte-code (car form)))
 679                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 680                        (not (and (eq 'funcall (car form))
 681                                  (byte-code-function-p (cadr form)))))
 682               (defalias 'gnus-tmp-func `(lambda () ,form))
 683               (byte-compile 'gnus-tmp-func)
 684               (setq compiled-function (gnus-byte-code 'gnus-tmp-func))
 685               (set (intern (format "gnus-%s-line-format-spec" type))
 686                    compiled-function)
 687               (let ((elem (cdr (assq type gnus-format-specs-compiled))))
 688                 (if elem
 689                     (set-alist 'elem (cadr entry) compiled-function)
 690                   (setq elem (list (cadr entry) compiled-function)))
 691                 (set-alist 'gnus-format-specs-compiled type elem))))))
 692
 693       (push (cons 'version emacs-version) gnus-format-specs)
 694       (gnus-message 7 "Compiling user specs...done"))))
 695
 696 (defun gnus-set-format (type &optional insertable)
 697   (set (intern (format "gnus-%s-line-format-spec" type))
 698        (gnus-parse-format
 699         (symbol-value (intern (format "gnus-%s-line-format" type)))
 700         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 701         insertable)))
 702
 703 (gnus-ems-redefine)
 704
 705 (provide 'gnus-spec)
 706
 707 ;; Local Variables:
 708 ;; coding: iso-8859-1
 709 ;; End:
 710
 711 ;;; gnus-spec.el ends here