git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h back end
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :version "21.4"
  75   :group 'gnus-server-visual
  76   :type 'boolean)
  77
  78 ;;; Internal variables.
  79
  80 (defvar gnus-inserted-opened-servers nil)
  81
  82 (defvar gnus-server-line-format-alist
  83   `((?h gnus-tmp-how ?s)
  84     (?n gnus-tmp-name ?s)
  85     (?w gnus-tmp-where ?s)
  86     (?s gnus-tmp-status ?s)
  87     (?a gnus-tmp-agent ?s)))
  88
  89 (defvar gnus-server-mode-line-format-alist
  90   `((?S gnus-tmp-news-server ?s)
  91     (?M gnus-tmp-news-method ?s)
  92     (?u gnus-tmp-user-defined ?s)))
  93
  94 (defvar gnus-server-line-format-spec nil)
  95 (defvar gnus-server-mode-line-format-spec nil)
  96 (defvar gnus-server-killed-servers nil)
  97
  98 (defvar gnus-server-mode-map)
  99
 100 (defvar gnus-server-menu-hook nil
 101   "*Hook run after the creation of the server mode menu.")
 102
 103 (defun gnus-server-make-menu-bar ()
 104   (gnus-turn-off-edit-menu 'server)
 105   (unless (boundp 'gnus-server-server-menu)
 106     (easy-menu-define
 107      gnus-server-server-menu gnus-server-mode-map ""
 108      '("Server"
 109        ["Add..." gnus-server-add-server t]
 110        ["Browse" gnus-server-read-server t]
 111        ["Scan" gnus-server-scan-server t]
 112        ["List" gnus-server-list-servers t]
 113        ["Kill" gnus-server-kill-server t]
 114        ["Yank" gnus-server-yank-server t]
 115        ["Copy" gnus-server-copy-server t]
 116        ["Edit" gnus-server-edit-server t]
 117        ["Regenerate" gnus-server-regenerate-server t]
 118        ["Exit" gnus-server-exit t]))
 119
 120     (easy-menu-define
 121      gnus-server-connections-menu gnus-server-mode-map ""
 122      '("Connections"
 123        ["Open" gnus-server-open-server t]
 124        ["Close" gnus-server-close-server t]
 125        ["Offline" gnus-server-offline-server t]
 126        ["Deny" gnus-server-deny-server t]
 127        "---"
 128        ["Open All" gnus-server-open-all-servers t]
 129        ["Close All" gnus-server-close-all-servers t]
 130        ["Reset All" gnus-server-remove-denials t]))
 131
 132     (gnus-run-hooks 'gnus-server-menu-hook)))
 133
 134 (defvar gnus-server-mode-map nil)
 135 (put 'gnus-server-mode 'mode-class 'special)
 136
 137 (unless gnus-server-mode-map
 138   (setq gnus-server-mode-map (make-sparse-keymap))
 139   (suppress-keymap gnus-server-mode-map)
 140
 141   (gnus-define-keys gnus-server-mode-map
 142     " " gnus-server-read-server-in-server-buffer
 143     "\r" gnus-server-read-server
 144     gnus-mouse-2 gnus-server-pick-server
 145     "q" gnus-server-exit
 146     "l" gnus-server-list-servers
 147     "k" gnus-server-kill-server
 148     "y" gnus-server-yank-server
 149     "c" gnus-server-copy-server
 150     "a" gnus-server-add-server
 151     "e" gnus-server-edit-server
 152     "s" gnus-server-scan-server
 153
 154     "O" gnus-server-open-server
 155     "\M-o" gnus-server-open-all-servers
 156     "C" gnus-server-close-server
 157     "\M-c" gnus-server-close-all-servers
 158     "D" gnus-server-deny-server
 159     "L" gnus-server-offline-server
 160     "R" gnus-server-remove-denials
 161
 162     "n" next-line
 163     "p" previous-line
 164
 165     "g" gnus-server-regenerate-server
 166
 167     "\C-c\C-i" gnus-info-find-node
 168     "\C-c\C-b" gnus-bug))
 169
 170 (defface gnus-server-agent-face
 171   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 172     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 173     (t (:bold t)))
 174   "Face used for displaying AGENTIZED servers"
 175   :group 'gnus-server-visual)
 176
 177 (defface gnus-server-opened-face
 178   '((((class color) (background light)) (:foreground "Green3" :bold t))
 179     (((class color) (background dark)) (:foreground "Green1" :bold t))
 180     (t (:bold t)))
 181   "Face used for displaying OPENED servers"
 182   :group 'gnus-server-visual)
 183
 184 (defface gnus-server-closed-face
 185   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 186     (((class color) (background dark))
 187      (:foreground "Light Steel Blue" :italic t))
 188     (t (:italic t)))
 189   "Face used for displaying CLOSED servers"
 190   :group 'gnus-server-visual)
 191
 192 (defface gnus-server-denied-face
 193   '((((class color) (background light)) (:foreground "Red" :bold t))
 194     (((class color) (background dark)) (:foreground "Pink" :bold t))
 195     (t (:inverse-video t :bold t)))
 196   "Face used for displaying DENIED servers"
 197   :group 'gnus-server-visual)
 198
 199 (defface gnus-server-offline-face
 200   '((((class color) (background light)) (:foreground "Orange" :bold t))
 201     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 202     (t (:inverse-video t :bold t)))
 203   "Face used for displaying OFFLINE servers"
 204   :group 'gnus-server-visual)
 205
 206 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 207   "Face name to use on AGENTIZED servers."
 208   :group 'gnus-server-visual
 209   :type 'face)
 210
 211 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 212   "Face name to use on OPENED servers."
 213   :group 'gnus-server-visual
 214   :type 'face)
 215
 216 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 217   "Face name to use on CLOSED servers."
 218   :group 'gnus-server-visual
 219   :type 'face)
 220
 221 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 222   "Face name to use on DENIED servers."
 223   :group 'gnus-server-visual
 224   :type 'face)
 225
 226 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 227   "Face name to use on OFFLINE servers."
 228   :version "21.4"
 229   :group 'gnus-server-visual
 230   :type 'face)
 231
 232 (defvar gnus-server-font-lock-keywords
 233   (list
 234    '("(\\(agent\\))" 1 gnus-server-agent-face)
 235    '("(\\(opened\\))" 1 gnus-server-opened-face)
 236    '("(\\(closed\\))" 1 gnus-server-closed-face)
 237    '("(\\(offline\\))" 1 gnus-server-offline-face)
 238    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 239
 240 (defun gnus-server-mode ()
 241   "Major mode for listing and editing servers.
 242
 243 All normal editing commands are switched off.
 244 \\<gnus-server-mode-map>
 245 For more in-depth information on this mode, read the manual
 246 \(`\\[gnus-info-find-node]').
 247
 248 The following commands are available:
 249
 250 \\{gnus-server-mode-map}"
 251   (interactive)
 252   (when (gnus-visual-p 'server-menu 'menu)
 253     (gnus-server-make-menu-bar))
 254   (kill-all-local-variables)
 255   (gnus-simplify-mode-line)
 256   (setq major-mode 'gnus-server-mode)
 257   (setq mode-name "Server")
 258   (gnus-set-default-directory)
 259   (setq mode-line-process nil)
 260   (use-local-map gnus-server-mode-map)
 261   (buffer-disable-undo)
 262   (setq truncate-lines t)
 263   (setq buffer-read-only t)
 264   (if (featurep 'xemacs)
 265       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 266     (set (make-local-variable 'font-lock-defaults)
 267          '(gnus-server-font-lock-keywords t)))
 268   (gnus-run-hooks 'gnus-server-mode-hook))
 269
 270 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 271   (let* ((gnus-tmp-how (car method))
 272          (gnus-tmp-where (nth 1 method))
 273          (elem (assoc method gnus-opened-servers))
 274          (gnus-tmp-status
 275           (cond
 276            ((eq (nth 1 elem) 'denied) "(denied)")
 277            ((eq (nth 1 elem) 'offline) "(offline)")
 278            (t
 279             (condition-case nil
 280                 (if (or (gnus-server-opened method)
 281                         (eq (nth 1 elem) 'ok))
 282                     "(opened)"
 283                   "(closed)")
 284               ((error) "(error)")))))
 285          (gnus-tmp-agent (if (and gnus-agent
 286                                   (gnus-agent-method-p method))
 287                              " (agent)"
 288                            "")))
 289     (beginning-of-line)
 290     (gnus-add-text-properties
 291      (point)
 292      (prog1 (1+ (point))
 293        ;; Insert the text.
 294        (eval gnus-server-line-format-spec))
 295      (list 'gnus-server (intern gnus-tmp-name)
 296            'gnus-named-server (intern (gnus-method-to-server method))))))
 297
 298 (defun gnus-enter-server-buffer ()
 299   "Set up the server buffer."
 300   (gnus-server-setup-buffer)
 301   (gnus-configure-windows 'server)
 302   (gnus-server-prepare))
 303
 304 (defun gnus-server-setup-buffer ()
 305   "Initialize the server buffer."
 306   (unless (get-buffer gnus-server-buffer)
 307     (save-excursion
 308       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 309       (gnus-server-mode)
 310       (when gnus-carpal
 311         (gnus-carpal-setup-buffer 'server)))))
 312
 313 (defun gnus-server-prepare ()
 314   (gnus-set-format 'server-mode)
 315   (gnus-set-format 'server t)
 316   (let ((alist gnus-server-alist)
 317         (buffer-read-only nil)
 318         (opened gnus-opened-servers)
 319         done server op-ser)
 320     (erase-buffer)
 321     (setq gnus-inserted-opened-servers nil)
 322     ;; First we do the real list of servers.
 323     (while alist
 324       (unless (member (cdar alist) done)
 325         (push (cdar alist) done)
 326         (setq server (pop alist))
 327         (when (and server (car server) (cdr server))
 328           (gnus-server-insert-server-line (car server) (cdr server))))
 329       (when (member (cdar alist) done)
 330         (pop alist)))
 331     ;; Then we insert the list of servers that have been opened in
 332     ;; this session.
 333     (while opened
 334       (when (and (not (member (caar opened) done))
 335                  ;; Just ignore ephemeral servers.
 336                  (not (member (caar opened) gnus-ephemeral-servers)))
 337         (push (caar opened) done)
 338         (gnus-server-insert-server-line
 339          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 340          (caar opened))
 341         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 342       (setq opened (cdr opened))))
 343   (goto-char (point-min))
 344   (gnus-server-position-point))
 345
 346 (defun gnus-server-server-name ()
 347   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 348     (and server (symbol-name server))))
 349
 350 (defun gnus-server-named-server ()
 351   "Return a server name that matches one of the names returned by
 352 `gnus-method-to-server'."
 353   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 354     (and server (symbol-name server))))
 355
 356 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 357
 358 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 359
 360 (defun gnus-server-update-server (server)
 361   (save-excursion
 362     (set-buffer gnus-server-buffer)
 363     (let* ((buffer-read-only nil)
 364            (entry (assoc server gnus-server-alist))
 365            (oentry (assoc (gnus-server-to-method server)
 366                           gnus-opened-servers)))
 367       (when entry
 368         (gnus-dribble-enter
 369          (concat "(gnus-server-set-info \"" server "\" '"
 370                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 371       (when (or entry oentry)
 372         ;; Buffer may be narrowed.
 373         (save-restriction
 374           (widen)
 375           (when (gnus-server-goto-server server)
 376             (gnus-delete-line))
 377           (if entry
 378               (gnus-server-insert-server-line (car entry) (cdr entry))
 379             (gnus-server-insert-server-line
 380              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 381              (car oentry)))
 382           (gnus-server-position-point))))))
 383
 384 (defun gnus-server-set-info (server info)
 385   ;; Enter a select method into the virtual server alist.
 386   (when (and server info)
 387     (gnus-dribble-enter
 388      (concat "(gnus-server-set-info \"" server "\" '"
 389              (gnus-prin1-to-string info) ")"))
 390     (let* ((server (nth 1 info))
 391            (entry (assoc server gnus-server-alist))
 392            (cached (assoc server gnus-server-method-cache)))
 393       (if cached
 394           (setq gnus-server-method-cache
 395                 (delq cached gnus-server-method-cache)))
 396       (if entry
 397           (progn
 398             ;; Remove the server from `gnus-opened-servers' since
 399             ;; it has never been opened with the new `info' yet.
 400             (gnus-opened-servers-remove (cdr entry))
 401             ;; Don't make a new Lisp object.
 402             (setcar (cdr entry) (car info))
 403             (setcdr (cdr entry) (cdr info)))
 404         (setq gnus-server-alist
 405               (nconc gnus-server-alist (list (cons server info))))))))
 406
 407 ;;; Interactive server functions.
 408
 409 (defun gnus-server-kill-server (server)
 410   "Kill the server on the current line."
 411   (interactive (list (gnus-server-server-name)))
 412   (unless (gnus-server-goto-server server)
 413     (if server (error "No such server: %s" server)
 414       (error "No server on the current line")))
 415   (unless (assoc server gnus-server-alist)
 416     (error "Read-only server %s" server))
 417   (gnus-dribble-touch)
 418   (let ((buffer-read-only nil))
 419     (gnus-delete-line))
 420   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 421   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 422                                 gnus-server-alist))
 423   (let ((groups (gnus-groups-from-server server)))
 424     (when (and groups
 425                (gnus-yes-or-no-p
 426                 (format "Kill all %s groups from this server? "
 427                         (length groups))))
 428       (dolist (group groups)
 429         (setq gnus-newsrc-alist
 430               (delq (assoc group gnus-newsrc-alist)
 431                     gnus-newsrc-alist))
 432         (when gnus-group-change-level-function
 433           (funcall gnus-group-change-level-function
 434                    group gnus-level-killed 3)))))
 435   (gnus-server-position-point))
 436
 437 (defun gnus-server-yank-server ()
 438   "Yank the previously killed server."
 439   (interactive)
 440   (unless gnus-server-killed-servers
 441     (error "No killed servers to be yanked"))
 442   (let ((alist gnus-server-alist)
 443         (server (gnus-server-server-name))
 444         (killed (car gnus-server-killed-servers)))
 445     (if (not server)
 446         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 447       (if (string= server (caar gnus-server-alist))
 448           (push killed gnus-server-alist)
 449         (while (and (cdr alist)
 450                     (not (string= server (caadr alist))))
 451           (setq alist (cdr alist)))
 452         (if alist
 453             (setcdr alist (cons killed (cdr alist)))
 454           (setq gnus-server-alist (list killed)))))
 455     (gnus-server-update-server (car killed))
 456     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 457     (gnus-server-position-point)))
 458
 459 (defun gnus-server-exit ()
 460   "Return to the group buffer."
 461   (interactive)
 462   (gnus-run-hooks 'gnus-server-exit-hook)
 463   (gnus-kill-buffer (current-buffer))
 464   (gnus-configure-windows 'group t))
 465
 466 (defun gnus-server-list-servers ()
 467   "List all available servers."
 468   (interactive)
 469   (let ((cur (gnus-server-server-name)))
 470     (gnus-server-prepare)
 471     (if cur (gnus-server-goto-server cur)
 472       (goto-char (point-max))
 473       (forward-line -1))
 474     (gnus-server-position-point)))
 475
 476 (defun gnus-server-set-status (method status)
 477   "Make METHOD have STATUS."
 478   (let ((entry (assoc method gnus-opened-servers)))
 479     (if entry
 480         (setcar (cdr entry) status)
 481       (push (list method status) gnus-opened-servers))))
 482
 483 (defun gnus-opened-servers-remove (method)
 484   "Remove METHOD from the list of opened servers."
 485   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 486                                   gnus-opened-servers)))
 487
 488 (defun gnus-server-open-server (server)
 489   "Force an open of SERVER."
 490   (interactive (list (gnus-server-server-name)))
 491   (let ((method (gnus-server-to-method server)))
 492     (unless method
 493       (error "No such server: %s" server))
 494     (gnus-server-set-status method 'ok)
 495     (prog1
 496         (or (gnus-open-server method)
 497             (progn (message "Couldn't open %s" server) nil))
 498       (gnus-server-update-server server)
 499       (gnus-server-position-point))))
 500
 501 (defun gnus-server-open-all-servers ()
 502   "Open all servers."
 503   (interactive)
 504   (let ((servers gnus-inserted-opened-servers))
 505     (while servers
 506       (gnus-server-open-server (car (pop servers))))))
 507
 508 (defun gnus-server-close-server (server)
 509   "Close SERVER."
 510   (interactive (list (gnus-server-server-name)))
 511   (let ((method (gnus-server-to-method server)))
 512     (unless method
 513       (error "No such server: %s" server))
 514     (gnus-server-set-status method 'closed)
 515     (prog1
 516         (gnus-close-server method)
 517       (gnus-server-update-server server)
 518       (gnus-server-position-point))))
 519
 520 (defun gnus-server-offline-server (server)
 521   "Set SERVER to offline."
 522   (interactive (list (gnus-server-server-name)))
 523   (let ((method (gnus-server-to-method server)))
 524     (unless method
 525       (error "No such server: %s" server))
 526     (prog1
 527         (gnus-close-server method)
 528       (gnus-server-set-status method 'offline)
 529       (gnus-server-update-server server)
 530       (gnus-server-position-point))))
 531
 532 (defun gnus-server-close-all-servers ()
 533   "Close all servers."
 534   (interactive)
 535   (dolist (server gnus-inserted-opened-servers)
 536     (gnus-server-close-server (car server))))
 537
 538 (defun gnus-server-deny-server (server)
 539   "Make sure SERVER will never be attempted opened."
 540   (interactive (list (gnus-server-server-name)))
 541   (let ((method (gnus-server-to-method server)))
 542     (unless method
 543       (error "No such server: %s" server))
 544     (gnus-server-set-status method 'denied))
 545   (gnus-server-update-server server)
 546   (gnus-server-position-point)
 547   t)
 548
 549 (defun gnus-server-remove-denials ()
 550   "Make all denied servers into closed servers."
 551   (interactive)
 552   (dolist (server gnus-opened-servers)
 553     (when (eq (nth 1 server) 'denied)
 554       (setcar (nthcdr 1 server) 'closed)))
 555   (gnus-server-list-servers))
 556
 557 (defun gnus-server-copy-server (from to)
 558   (interactive
 559    (list
 560     (or (gnus-server-server-name)
 561         (error "No server on the current line"))
 562     (read-string "Copy to: ")))
 563   (unless from
 564     (error "No server on current line"))
 565   (unless (and to (not (string= to "")))
 566     (error "No name to copy to"))
 567   (when (assoc to gnus-server-alist)
 568     (error "%s already exists" to))
 569   (unless (gnus-server-to-method from)
 570     (error "%s: no such server" from))
 571   (let ((to-entry (cons from (gnus-copy-sequence
 572                               (gnus-server-to-method from)))))
 573     (setcar to-entry to)
 574     (setcar (nthcdr 2 to-entry) to)
 575     (push to-entry gnus-server-killed-servers)
 576     (gnus-server-yank-server)))
 577
 578 (defun gnus-server-add-server (how where)
 579   (interactive
 580    (list (intern (completing-read "Server method: "
 581                                   gnus-valid-select-methods nil t))
 582          (read-string "Server name: ")))
 583   (when (assq where gnus-server-alist)
 584     (error "Server with that name already defined"))
 585   (push (list where how where) gnus-server-killed-servers)
 586   (gnus-server-yank-server))
 587
 588 (defun gnus-server-goto-server (server)
 589   "Jump to a server line."
 590   (interactive
 591    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 592   (let ((to (text-property-any (point-min) (point-max)
 593                                'gnus-server (intern server))))
 594     (when to
 595       (goto-char to)
 596       (gnus-server-position-point))))
 597
 598 (defun gnus-server-edit-server (server)
 599   "Edit the server on the current line."
 600   (interactive (list (gnus-server-server-name)))
 601   (unless server
 602     (error "No server on current line"))
 603   (unless (assoc server gnus-server-alist)
 604     (error "This server can't be edited"))
 605   (let ((info (cdr (assoc server gnus-server-alist))))
 606     (gnus-close-server info)
 607     (gnus-edit-form
 608      info "Editing the server."
 609      `(lambda (form)
 610         (gnus-server-set-info ,server form)
 611         (gnus-server-list-servers)
 612         (gnus-server-position-point)))))
 613
 614 (defun gnus-server-scan-server (server)
 615   "Request a scan from the current server."
 616   (interactive (list (gnus-server-server-name)))
 617   (let ((method (gnus-server-to-method server)))
 618     (if (not (gnus-get-function method 'request-scan))
 619         (error "Server %s can't scan" (car method))
 620       (gnus-message 3 "Scanning %s..." server)
 621       (gnus-request-scan nil method)
 622       (gnus-message 3 "Scanning %s...done" server))))
 623
 624 (defun gnus-server-read-server-in-server-buffer (server)
 625   "Browse a server in server buffer."
 626   (interactive (list (gnus-server-server-name)))
 627   (let (gnus-server-browse-in-group-buffer)
 628     (gnus-server-read-server server)))
 629
 630 (defun gnus-server-read-server (server)
 631   "Browse a server."
 632   (interactive (list (gnus-server-server-name)))
 633   (let ((buf (current-buffer)))
 634     (prog1
 635         (gnus-browse-foreign-server server buf)
 636       (save-excursion
 637         (set-buffer buf)
 638         (gnus-server-update-server (gnus-server-server-name))
 639         (gnus-server-position-point)))))
 640
 641 (defun gnus-server-pick-server (e)
 642   (interactive "e")
 643   (mouse-set-point e)
 644   (gnus-server-read-server (gnus-server-server-name)))
 645
 646 \f
 647 ;;;
 648 ;;; Browse Server Mode
 649 ;;;
 650
 651 (defvar gnus-browse-menu-hook nil
 652   "*Hook run after the creation of the browse mode menu.")
 653
 654 (defvar gnus-browse-mode-hook nil)
 655 (defvar gnus-browse-mode-map nil)
 656 (put 'gnus-browse-mode 'mode-class 'special)
 657
 658 (unless gnus-browse-mode-map
 659   (setq gnus-browse-mode-map (make-keymap))
 660   (suppress-keymap gnus-browse-mode-map)
 661
 662   (gnus-define-keys
 663       gnus-browse-mode-map
 664     " " gnus-browse-read-group
 665     "=" gnus-browse-select-group
 666     "n" gnus-browse-next-group
 667     "p" gnus-browse-prev-group
 668     "\177" gnus-browse-prev-group
 669     [delete] gnus-browse-prev-group
 670     "N" gnus-browse-next-group
 671     "P" gnus-browse-prev-group
 672     "\M-n" gnus-browse-next-group
 673     "\M-p" gnus-browse-prev-group
 674     "\r" gnus-browse-select-group
 675     "u" gnus-browse-unsubscribe-current-group
 676     "l" gnus-browse-exit
 677     "L" gnus-browse-exit
 678     "q" gnus-browse-exit
 679     "Q" gnus-browse-exit
 680     "d" gnus-browse-describe-group
 681     "\C-c\C-c" gnus-browse-exit
 682     "?" gnus-browse-describe-briefly
 683
 684     "\C-c\C-i" gnus-info-find-node
 685     "\C-c\C-b" gnus-bug))
 686
 687 (defun gnus-browse-make-menu-bar ()
 688   (gnus-turn-off-edit-menu 'browse)
 689   (unless (boundp 'gnus-browse-menu)
 690     (easy-menu-define
 691      gnus-browse-menu gnus-browse-mode-map ""
 692      '("Browse"
 693        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 694        ["Read" gnus-browse-read-group t]
 695        ["Select" gnus-browse-select-group t]
 696        ["Describe" gnus-browse-describe-group t]
 697        ["Next" gnus-browse-next-group t]
 698        ["Prev" gnus-browse-prev-group t]
 699        ["Exit" gnus-browse-exit t]))
 700     (gnus-run-hooks 'gnus-browse-menu-hook)))
 701
 702 (defvar gnus-browse-current-method nil)
 703 (defvar gnus-browse-return-buffer nil)
 704
 705 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 706
 707 (defun gnus-browse-foreign-server (server &optional return-buffer)
 708   "Browse the server SERVER."
 709   (setq gnus-browse-current-method (gnus-server-to-method server))
 710   (setq gnus-browse-return-buffer return-buffer)
 711   (let* ((method gnus-browse-current-method)
 712          (orig-select-method gnus-select-method)
 713          (gnus-select-method method)
 714          groups group)
 715     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 716     (cond
 717      ((not (gnus-check-server method))
 718       (gnus-message
 719        1 "Unable to contact server %s: %s" (nth 1 method)
 720        (gnus-status-message method))
 721       nil)
 722      ((not
 723        (prog2
 724            (gnus-message 6 "Reading active file...")
 725            (gnus-request-list method)
 726          (gnus-message 6 "Reading active file...done")))
 727       (gnus-message
 728        1 "Couldn't request list: %s" (gnus-status-message method))
 729       nil)
 730      (t
 731       (with-current-buffer nntp-server-buffer
 732         (let ((cur (current-buffer)))
 733           (goto-char (point-min))
 734           (unless (string= gnus-ignored-newsgroups "")
 735             (delete-matching-lines gnus-ignored-newsgroups))
 736           ;; We treat NNTP as a special case to avoid problems with
 737           ;; garbage group names like `"foo' that appear in some badly
 738           ;; managed active files. -jh.
 739           (if (eq (car method) 'nntp)
 740               (while (not (eobp))
 741                 (ignore-errors
 742                   (push (cons
 743                          (buffer-substring
 744                           (point)
 745                           (progn
 746                             (skip-chars-forward "^ \t")
 747                             (point)))
 748                          (let ((last (read cur)))
 749                            (cons (read cur) last)))
 750                         groups))
 751                 (forward-line))
 752             (while (not (eobp))
 753               (ignore-errors
 754                 (push (cons
 755                        (if (eq (char-after) ?\")
 756                            (read cur)
 757                          (let ((p (point)) (name ""))
 758                            (skip-chars-forward "^ \t\\\\")
 759                            (setq name (buffer-substring p (point)))
 760                            (while (eq (char-after) ?\\)
 761                              (setq p (1+ (point)))
 762                              (forward-char 2)
 763                              (skip-chars-forward "^ \t\\\\")
 764                              (setq name (concat name (buffer-substring
 765                                                       p (point)))))
 766                            name))
 767                        (let ((last (read cur)))
 768                          (cons (read cur) last)))
 769                       groups))
 770               (forward-line)))))
 771       (setq groups (sort groups
 772                          (lambda (l1 l2)
 773                            (string< (car l1) (car l2)))))
 774       (if gnus-server-browse-in-group-buffer
 775           (let* ((gnus-select-method orig-select-method)
 776                  (gnus-group-listed-groups
 777                   (mapcar (lambda (group)
 778                             (let ((name
 779                                    (gnus-group-prefixed-name
 780                                     (car group) method)))
 781                               (gnus-set-active name (cdr group))
 782                               name))
 783                           groups)))
 784             (gnus-configure-windows 'group)
 785             (funcall gnus-group-prepare-function
 786                      gnus-level-killed 'ignore 1 'ignore))
 787         (gnus-get-buffer-create gnus-browse-buffer)
 788         (when gnus-carpal
 789           (gnus-carpal-setup-buffer 'browse))
 790         (gnus-configure-windows 'browse)
 791         (buffer-disable-undo)
 792         (let ((buffer-read-only nil))
 793           (erase-buffer))
 794         (gnus-browse-mode)
 795         (setq mode-line-buffer-identification
 796               (list
 797                (format
 798                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 799         (let ((buffer-read-only nil)
 800               name
 801               (prefix (let ((gnus-select-method orig-select-method))
 802                         (gnus-group-prefixed-name "" method))))
 803           (while (setq group (pop groups))
 804             (gnus-add-text-properties
 805              (point)
 806              (prog1 (1+ (point))
 807                (insert
 808                 (format "%c%7d: %s\n"
 809                         (let ((level
 810                                (if (string= prefix "")
 811                                    (gnus-group-level (setq name (car group)))
 812                                  (gnus-group-level
 813                                   (concat prefix (setq name (car group)))))))
 814                           (cond
 815                            ((<= level gnus-level-subscribed) ? )
 816                            ((<= level gnus-level-unsubscribed) ?U)
 817                            ((= level gnus-level-zombie) ?Z)
 818                            (t ?K)))
 819                         (max 0 (- (1+ (cddr group)) (cadr group)))
 820                         ;; Don't decode if name is ASCII
 821                         (if (and (fboundp 'detect-coding-string)
 822                                  (eq (detect-coding-string name t) 'undecided))
 823                             name
 824                           (decode-coding-string
 825                            name
 826                            (inline (gnus-group-name-charset method name)))))))
 827              (list 'gnus-group name)
 828              )))
 829         (switch-to-buffer (current-buffer)))
 830       (goto-char (point-min))
 831       (gnus-group-position-point)
 832       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 833       t))))
 834
 835 (defun gnus-browse-mode ()
 836   "Major mode for browsing a foreign server.
 837
 838 All normal editing commands are switched off.
 839
 840 \\<gnus-browse-mode-map>
 841 The only things you can do in this buffer is
 842
 843 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 844 The group will be inserted into the group buffer upon exit from this
 845 buffer.
 846
 847 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 848
 849 3) `\\[gnus-browse-exit]' to return to the group buffer."
 850   (interactive)
 851   (kill-all-local-variables)
 852   (when (gnus-visual-p 'browse-menu 'menu)
 853     (gnus-browse-make-menu-bar))
 854   (gnus-simplify-mode-line)
 855   (setq major-mode 'gnus-browse-mode)
 856   (setq mode-name "Browse Server")
 857   (setq mode-line-process nil)
 858   (use-local-map gnus-browse-mode-map)
 859   (buffer-disable-undo)
 860   (setq truncate-lines t)
 861   (gnus-set-default-directory)
 862   (setq buffer-read-only t)
 863   (gnus-run-hooks 'gnus-browse-mode-hook))
 864
 865 (defun gnus-browse-read-group (&optional no-article)
 866   "Enter the group at the current line."
 867   (interactive)
 868   (let ((group (gnus-browse-group-name)))
 869     (if (or (not (gnus-get-info group))
 870             (gnus-ephemeral-group-p group))
 871         (unless (gnus-group-read-ephemeral-group
 872                  group gnus-browse-current-method nil
 873                  (cons (current-buffer) 'browse))
 874           (error "Couldn't enter %s" group))
 875       (unless (gnus-group-read-group nil no-article group)
 876         (error "Couldn't enter %s" group)))))
 877
 878 (defun gnus-browse-select-group ()
 879   "Select the current group."
 880   (interactive)
 881   (gnus-browse-read-group 'no))
 882
 883 (defun gnus-browse-next-group (n)
 884   "Go to the next group."
 885   (interactive "p")
 886   (prog1
 887       (forward-line n)
 888     (gnus-group-position-point)))
 889
 890 (defun gnus-browse-prev-group (n)
 891   "Go to the next group."
 892   (interactive "p")
 893   (gnus-browse-next-group (- n)))
 894
 895 (defun gnus-browse-unsubscribe-current-group (arg)
 896   "(Un)subscribe to the next ARG groups."
 897   (interactive "p")
 898   (when (eobp)
 899     (error "No group at current line"))
 900   (let ((ward (if (< arg 0) -1 1))
 901         (arg (abs arg)))
 902     (while (and (> arg 0)
 903                 (not (eobp))
 904                 (gnus-browse-unsubscribe-group)
 905                 (zerop (gnus-browse-next-group ward)))
 906       (decf arg))
 907     (gnus-group-position-point)
 908     (when (/= 0 arg)
 909       (gnus-message 7 "No more newsgroups"))
 910     arg))
 911
 912 (defun gnus-browse-group-name ()
 913   (save-excursion
 914     (beginning-of-line)
 915     (let ((name (get-text-property (point) 'gnus-group)))
 916       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 917         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 918                 (or name
 919                     (match-string-no-properties 1)))))))
 920
 921 (defun gnus-browse-describe-group (group)
 922   "Describe the current group."
 923   (interactive (list (gnus-browse-group-name)))
 924   (gnus-group-describe-group nil group))
 925
 926 (defun gnus-browse-unsubscribe-group ()
 927   "Toggle subscription of the current group in the browse buffer."
 928   (let ((sub nil)
 929         (buffer-read-only nil)
 930         group)
 931     (save-excursion
 932       (beginning-of-line)
 933       ;; If this group it killed, then we want to subscribe it.
 934       (unless (eq (char-after) ? )
 935         (setq sub t))
 936       (setq group (gnus-browse-group-name))
 937       (when (gnus-server-equal gnus-browse-current-method "native")
 938         (setq group (gnus-group-real-name group)))
 939       (if sub
 940           (progn
 941             ;; Make sure the group has been properly removed before we
 942             ;; subscribe to it.
 943             (gnus-kill-ephemeral-group group)
 944             (gnus-group-change-level
 945              (list t group gnus-level-default-subscribed
 946                    nil nil (if (gnus-server-equal
 947                                 gnus-browse-current-method "native")
 948                                nil
 949                              (gnus-method-simplify
 950                               gnus-browse-current-method)))
 951              gnus-level-default-subscribed (gnus-group-level group)
 952              (and (car (nth 1 gnus-newsrc-alist))
 953                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 954              t)
 955             (delete-char 1)
 956             (insert ? ))
 957         (gnus-group-change-level
 958          group gnus-level-unsubscribed gnus-level-default-subscribed)
 959         (delete-char 1)
 960         (insert ?U)))
 961     t))
 962
 963 (defun gnus-browse-exit ()
 964   "Quit browsing and return to the group buffer."
 965   (interactive)
 966   (when (eq major-mode 'gnus-browse-mode)
 967     (gnus-kill-buffer (current-buffer)))
 968   ;; Insert the newly subscribed groups in the group buffer.
 969   (save-excursion
 970     (set-buffer gnus-group-buffer)
 971     (gnus-group-list-groups nil))
 972   (if gnus-browse-return-buffer
 973       (gnus-configure-windows 'server 'force)
 974     (gnus-configure-windows 'group 'force)))
 975
 976 (defun gnus-browse-describe-briefly ()
 977   "Give a one line description of the group mode commands."
 978   (interactive)
 979   (gnus-message 6
 980                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 981
 982 (defun gnus-server-regenerate-server ()
 983   "Issue a command to the server to regenerate all its data structures."
 984   (interactive)
 985   (let ((server (gnus-server-server-name)))
 986     (unless server
 987       (error "No server on the current line"))
 988     (condition-case ()
 989         (gnus-get-function (gnus-server-to-method server)
 990                            'request-regenerate)
 991       (error
 992        (error "This back end doesn't support regeneration")))
 993     (gnus-message 5 "Requesting regeneration of %s..." server)
 994     (unless (gnus-open-server server)
 995       (error "Couldn't open server"))
 996     (if (gnus-request-regenerate server)
 997         (gnus-message 5 "Requesting regeneration of %s...done" server)
 998       (gnus-message 5 "Couldn't regenerate %s" server))))
 999
1000 (provide 'gnus-srvr)
1001
1002 ;;; gnus-srvr.el ends here