git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (defvar gnus-server-mode-hook nil
  37   "Hook run in `gnus-server-mode' buffers.")
  38
  39 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  40   "Format of server lines.
  41 It works along the same lines as a normal formatting string,
  42 with some simple extensions.
  43
  44 The following specs are understood:
  45
  46 %h backend
  47 %n name
  48 %w address
  49 %s status")
  50
  51 (defvar gnus-server-mode-line-format "Gnus: %%b"
  52   "The format specification for the server mode line.")
  53
  54 (defvar gnus-server-exit-hook nil
  55   "*Hook run when exiting the server buffer.")
  56
  57 ;;; Internal variables.
  58
  59 (defvar gnus-inserted-opened-servers nil)
  60
  61 (defvar gnus-server-line-format-alist
  62   `((?h gnus-tmp-how ?s)
  63     (?n gnus-tmp-name ?s)
  64     (?w gnus-tmp-where ?s)
  65     (?s gnus-tmp-status ?s)))
  66
  67 (defvar gnus-server-mode-line-format-alist
  68   `((?S gnus-tmp-news-server ?s)
  69     (?M gnus-tmp-news-method ?s)
  70     (?u gnus-tmp-user-defined ?s)))
  71
  72 (defvar gnus-server-line-format-spec nil)
  73 (defvar gnus-server-mode-line-format-spec nil)
  74 (defvar gnus-server-killed-servers nil)
  75
  76 (defvar gnus-server-mode-map)
  77
  78 (defvar gnus-server-menu-hook nil
  79   "*Hook run after the creation of the server mode menu.")
  80
  81 (defun gnus-server-make-menu-bar ()
  82   (gnus-turn-off-edit-menu 'server)
  83   (unless (boundp 'gnus-server-server-menu)
  84     (easy-menu-define
  85      gnus-server-server-menu gnus-server-mode-map ""
  86      '("Server"
  87        ["Add" gnus-server-add-server t]
  88        ["Browse" gnus-server-read-server t]
  89        ["Scan" gnus-server-scan-server t]
  90        ["List" gnus-server-list-servers t]
  91        ["Kill" gnus-server-kill-server t]
  92        ["Yank" gnus-server-yank-server t]
  93        ["Copy" gnus-server-copy-server t]
  94        ["Edit" gnus-server-edit-server t]
  95        ["Regenerate" gnus-server-regenerate-server t]
  96        ["Exit" gnus-server-exit t]))
  97
  98     (easy-menu-define
  99      gnus-server-connections-menu gnus-server-mode-map ""
 100      '("Connections"
 101        ["Open" gnus-server-open-server t]
 102        ["Close" gnus-server-close-server t]
 103        ["Deny" gnus-server-deny-server t]
 104        "---"
 105        ["Open All" gnus-server-open-all-servers t]
 106        ["Close All" gnus-server-close-all-servers t]
 107        ["Reset All" gnus-server-remove-denials t]))
 108
 109     (gnus-run-hooks 'gnus-server-menu-hook)))
 110
 111 (defvar gnus-server-mode-map nil)
 112 (put 'gnus-server-mode 'mode-class 'special)
 113
 114 (unless gnus-server-mode-map
 115   (setq gnus-server-mode-map (make-sparse-keymap))
 116   (suppress-keymap gnus-server-mode-map)
 117
 118   (gnus-define-keys gnus-server-mode-map
 119     " " gnus-server-read-server
 120     "\r" gnus-server-read-server
 121     gnus-mouse-2 gnus-server-pick-server
 122     "q" gnus-server-exit
 123     "l" gnus-server-list-servers
 124     "k" gnus-server-kill-server
 125     "y" gnus-server-yank-server
 126     "c" gnus-server-copy-server
 127     "a" gnus-server-add-server
 128     "e" gnus-server-edit-server
 129     "s" gnus-server-scan-server
 130
 131     "O" gnus-server-open-server
 132     "\M-o" gnus-server-open-all-servers
 133     "C" gnus-server-close-server
 134     "\M-c" gnus-server-close-all-servers
 135     "D" gnus-server-deny-server
 136     "R" gnus-server-remove-denials
 137
 138     "n" next-line
 139     "p" previous-line
 140
 141     "g" gnus-server-regenerate-server
 142
 143     "\C-c\C-i" gnus-info-find-node
 144     "\C-c\C-b" gnus-bug))
 145
 146 (defun gnus-server-mode ()
 147   "Major mode for listing and editing servers.
 148
 149 All normal editing commands are switched off.
 150 \\<gnus-server-mode-map>
 151 For more in-depth information on this mode, read the manual
 152 (`\\[gnus-info-find-node]').
 153
 154 The following commands are available:
 155
 156 \\{gnus-server-mode-map}"
 157   (interactive)
 158   (when (gnus-visual-p 'server-menu 'menu)
 159     (gnus-server-make-menu-bar))
 160   (kill-all-local-variables)
 161   (gnus-simplify-mode-line)
 162   (setq major-mode 'gnus-server-mode)
 163   (setq mode-name "Server")
 164   (gnus-set-default-directory)
 165   (setq mode-line-process nil)
 166   (use-local-map gnus-server-mode-map)
 167   (buffer-disable-undo)
 168   (setq truncate-lines t)
 169   (setq buffer-read-only t)
 170   (gnus-run-hooks 'gnus-server-mode-hook))
 171
 172 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 173   (let* ((gnus-tmp-how (car method))
 174          (gnus-tmp-where (nth 1 method))
 175          (elem (assoc method gnus-opened-servers))
 176          (gnus-tmp-status (cond ((eq (nth 1 elem) 'denied)
 177                         "(denied)")
 178                        ((or (gnus-server-opened method)
 179                             (eq (nth 1 elem) 'ok))
 180                         "(opened)")
 181                        (t
 182                         "(closed)"))))
 183     (beginning-of-line)
 184     (gnus-add-text-properties
 185      (point)
 186      (prog1 (1+ (point))
 187        ;; Insert the text.
 188        (eval gnus-server-line-format-spec))
 189      (list 'gnus-server (intern gnus-tmp-name)))))
 190
 191 (defun gnus-enter-server-buffer ()
 192   "Set up the server buffer."
 193   (gnus-server-setup-buffer)
 194   (gnus-configure-windows 'server)
 195   (gnus-server-prepare))
 196
 197 (defun gnus-server-setup-buffer ()
 198   "Initialize the server buffer."
 199   (unless (get-buffer gnus-server-buffer)
 200     (save-excursion
 201       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 202       (gnus-server-mode)
 203       (when gnus-carpal
 204         (gnus-carpal-setup-buffer 'server)))))
 205
 206 (defun gnus-server-prepare ()
 207   (gnus-set-format 'server-mode)
 208   (gnus-set-format 'server t)
 209   (let ((alist gnus-server-alist)
 210         (buffer-read-only nil)
 211         (opened gnus-opened-servers)
 212         done server op-ser)
 213     (erase-buffer)
 214     (setq gnus-inserted-opened-servers nil)
 215     ;; First we do the real list of servers.
 216     (while alist
 217       (unless (member (cdar alist) done)
 218         (push (cdar alist) done)
 219         (cdr (setq server (pop alist)))
 220         (when (and server (car server) (cdr server))
 221           (gnus-server-insert-server-line (car server) (cdr server))))
 222       (when (member (cdar alist) done)
 223         (pop alist)))
 224     ;; Then we insert the list of servers that have been opened in
 225     ;; this session.
 226     (while opened
 227       (when (and (not (member (caar opened) done))
 228                  ;; Just ignore ephemeral servers.
 229                  (not (member (caar opened) gnus-ephemeral-servers)))
 230         (push (caar opened) done)
 231         (gnus-server-insert-server-line
 232          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 233          (caar opened))
 234         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 235       (setq opened (cdr opened))))
 236   (goto-char (point-min))
 237   (gnus-server-position-point))
 238
 239 (defun gnus-server-server-name ()
 240   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 241     (and server (symbol-name server))))
 242
 243 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 244
 245 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 246
 247 (defun gnus-server-update-server (server)
 248   (save-excursion
 249     (set-buffer gnus-server-buffer)
 250     (let* ((buffer-read-only nil)
 251            (entry (assoc server gnus-server-alist))
 252            (oentry (assoc (gnus-server-to-method server)
 253                           gnus-opened-servers)))
 254       (when entry
 255         (gnus-dribble-enter
 256          (concat "(gnus-server-set-info \"" server "\" '"
 257                  (prin1-to-string (cdr entry)) ")\n")))
 258       (when (or entry oentry)
 259         ;; Buffer may be narrowed.
 260         (save-restriction
 261           (widen)
 262           (when (gnus-server-goto-server server)
 263             (gnus-delete-line))
 264           (if entry
 265               (gnus-server-insert-server-line (car entry) (cdr entry))
 266             (gnus-server-insert-server-line
 267              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 268              (car oentry)))
 269           (gnus-server-position-point))))))
 270
 271 (defun gnus-server-set-info (server info)
 272   ;; Enter a select method into the virtual server alist.
 273   (when (and server info)
 274     (gnus-dribble-enter
 275      (concat "(gnus-server-set-info \"" server "\" '"
 276              (prin1-to-string info) ")"))
 277     (let* ((server (nth 1 info))
 278            (entry (assoc server gnus-server-alist)))
 279       (if entry (setcdr entry info)
 280         (setq gnus-server-alist
 281               (nconc gnus-server-alist (list (cons server info))))))))
 282
 283 ;;; Interactive server functions.
 284
 285 (defun gnus-server-kill-server (server)
 286   "Kill the server on the current line."
 287   (interactive (list (gnus-server-server-name)))
 288   (unless (gnus-server-goto-server server)
 289     (if server (error "No such server: %s" server)
 290       (error "No server on the current line")))
 291   (unless (assoc server gnus-server-alist)
 292     (error "Read-only server %s" server))
 293   (gnus-dribble-touch)
 294   (let ((buffer-read-only nil))
 295     (gnus-delete-line))
 296   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 297   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 298                                 gnus-server-alist))
 299   (gnus-server-position-point))
 300
 301 (defun gnus-server-yank-server ()
 302   "Yank the previously killed server."
 303   (interactive)
 304   (unless gnus-server-killed-servers
 305     (error "No killed servers to be yanked"))
 306   (let ((alist gnus-server-alist)
 307         (server (gnus-server-server-name))
 308         (killed (car gnus-server-killed-servers)))
 309     (if (not server)
 310         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 311       (if (string= server (caar gnus-server-alist))
 312           (push killed gnus-server-alist)
 313         (while (and (cdr alist)
 314                     (not (string= server (caadr alist))))
 315           (setq alist (cdr alist)))
 316         (if alist
 317             (setcdr alist (cons killed (cdr alist)))
 318           (setq gnus-server-alist (list killed)))))
 319     (gnus-server-update-server (car killed))
 320     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 321     (gnus-server-position-point)))
 322
 323 (defun gnus-server-exit ()
 324   "Return to the group buffer."
 325   (interactive)
 326   (gnus-run-hooks 'gnus-server-exit-hook)
 327   (kill-buffer (current-buffer))
 328   (gnus-configure-windows 'group t))
 329
 330 (defun gnus-server-list-servers ()
 331   "List all available servers."
 332   (interactive)
 333   (let ((cur (gnus-server-server-name)))
 334     (gnus-server-prepare)
 335     (if cur (gnus-server-goto-server cur)
 336       (goto-char (point-max))
 337       (forward-line -1))
 338     (gnus-server-position-point)))
 339
 340 (defun gnus-server-set-status (method status)
 341   "Make METHOD have STATUS."
 342   (let ((entry (assoc method gnus-opened-servers)))
 343     (if entry
 344         (setcar (cdr entry) status)
 345       (push (list method status) gnus-opened-servers))))
 346
 347 (defun gnus-opened-servers-remove (method)
 348   "Remove METHOD from the list of opened servers."
 349   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 350                                   gnus-opened-servers)))
 351
 352 (defun gnus-server-open-server (server)
 353   "Force an open of SERVER."
 354   (interactive (list (gnus-server-server-name)))
 355   (let ((method (gnus-server-to-method server)))
 356     (unless method
 357       (error "No such server: %s" server))
 358     (gnus-server-set-status method 'ok)
 359     (prog1
 360         (or (gnus-open-server method)
 361             (progn (message "Couldn't open %s" server) nil))
 362       (gnus-server-update-server server)
 363       (gnus-server-position-point))))
 364
 365 (defun gnus-server-open-all-servers ()
 366   "Open all servers."
 367   (interactive)
 368   (let ((servers gnus-inserted-opened-servers))
 369     (while servers
 370       (gnus-server-open-server (car (pop servers))))))
 371
 372 (defun gnus-server-close-server (server)
 373   "Close SERVER."
 374   (interactive (list (gnus-server-server-name)))
 375   (let ((method (gnus-server-to-method server)))
 376     (unless method
 377       (error "No such server: %s" server))
 378     (gnus-server-set-status method 'closed)
 379     (prog1
 380         (gnus-close-server method)
 381       (gnus-server-update-server server)
 382       (gnus-server-position-point))))
 383
 384 (defun gnus-server-close-all-servers ()
 385   "Close all servers."
 386   (interactive)
 387   (let ((servers gnus-inserted-opened-servers))
 388     (while servers
 389       (gnus-server-close-server (car (pop servers))))))
 390
 391 (defun gnus-server-deny-server (server)
 392   "Make sure SERVER will never be attempted opened."
 393   (interactive (list (gnus-server-server-name)))
 394   (let ((method (gnus-server-to-method server)))
 395     (unless method
 396       (error "No such server: %s" server))
 397     (gnus-server-set-status method 'denied))
 398   (gnus-server-update-server server)
 399   (gnus-server-position-point)
 400   t)
 401
 402 (defun gnus-server-remove-denials ()
 403   "Make all denied servers into closed servers."
 404   (interactive)
 405   (let ((servers gnus-opened-servers))
 406     (while servers
 407       (when (eq (nth 1 (car servers)) 'denied)
 408         (setcar (nthcdr 1 (car servers)) 'closed))
 409       (setq servers (cdr servers))))
 410   (gnus-server-list-servers))
 411
 412 (defun gnus-server-copy-server (from to)
 413   (interactive
 414    (list
 415     (or (gnus-server-server-name)
 416         (error "No server on the current line"))
 417     (read-string "Copy to: ")))
 418   (unless from
 419     (error "No server on current line"))
 420   (unless (and to (not (string= to "")))
 421     (error "No name to copy to"))
 422   (when (assoc to gnus-server-alist)
 423     (error "%s already exists" to))
 424   (unless (gnus-server-to-method from)
 425     (error "%s: no such server" from))
 426   (let ((to-entry (cons from (gnus-copy-sequence
 427                               (gnus-server-to-method from)))))
 428     (setcar to-entry to)
 429     (setcar (nthcdr 2 to-entry) to)
 430     (push to-entry gnus-server-killed-servers)
 431     (gnus-server-yank-server)))
 432
 433 (defun gnus-server-add-server (how where)
 434   (interactive
 435    (list (intern (completing-read "Server method: "
 436                                   gnus-valid-select-methods nil t))
 437          (read-string "Server name: ")))
 438   (when (assq where gnus-server-alist)
 439     (error "Server with that name already defined"))
 440   (push (list where how where) gnus-server-killed-servers)
 441   (gnus-server-yank-server))
 442
 443 (defun gnus-server-goto-server (server)
 444   "Jump to a server line."
 445   (interactive
 446    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 447   (let ((to (text-property-any (point-min) (point-max)
 448                                'gnus-server (intern server))))
 449     (when to
 450       (goto-char to)
 451       (gnus-server-position-point))))
 452
 453 (defun gnus-server-edit-server (server)
 454   "Edit the server on the current line."
 455   (interactive (list (gnus-server-server-name)))
 456   (unless server
 457     (error "No server on current line"))
 458   (unless (assoc server gnus-server-alist)
 459     (error "This server can't be edited"))
 460   (let ((info (cdr (assoc server gnus-server-alist))))
 461     (gnus-close-server info)
 462     (gnus-edit-form
 463      info "Editing the server."
 464      `(lambda (form)
 465         (gnus-server-set-info ,server form)
 466         (gnus-server-list-servers)
 467         (gnus-server-position-point)))))
 468
 469 (defun gnus-server-scan-server (server)
 470   "Request a scan from the current server."
 471   (interactive (list (gnus-server-server-name)))
 472   (let ((method (gnus-server-to-method server)))
 473     (if (not (gnus-get-function method 'request-scan))
 474         (error "Server %s can't scan" (car method))
 475       (gnus-message 3 "Scanning %s..." server)
 476       (gnus-request-scan nil method)
 477       (gnus-message 3 "Scanning %s...done" server))))
 478
 479 (defun gnus-server-read-server (server)
 480   "Browse a server."
 481   (interactive (list (gnus-server-server-name)))
 482   (let ((buf (current-buffer)))
 483     (prog1
 484         (gnus-browse-foreign-server server buf)
 485       (save-excursion
 486         (set-buffer buf)
 487         (gnus-server-update-server (gnus-server-server-name))
 488         (gnus-server-position-point)))))
 489
 490 (defun gnus-server-pick-server (e)
 491   (interactive "e")
 492   (mouse-set-point e)
 493   (gnus-server-read-server (gnus-server-server-name)))
 494
 495 \f
 496 ;;;
 497 ;;; Browse Server Mode
 498 ;;;
 499
 500 (defvar gnus-browse-menu-hook nil
 501   "*Hook run after the creation of the browse mode menu.")
 502
 503 (defvar gnus-browse-mode-hook nil)
 504 (defvar gnus-browse-mode-map nil)
 505 (put 'gnus-browse-mode 'mode-class 'special)
 506
 507 (unless gnus-browse-mode-map
 508   (setq gnus-browse-mode-map (make-keymap))
 509   (suppress-keymap gnus-browse-mode-map)
 510
 511   (gnus-define-keys
 512    gnus-browse-mode-map
 513    " " gnus-browse-read-group
 514    "=" gnus-browse-select-group
 515    "n" gnus-browse-next-group
 516    "p" gnus-browse-prev-group
 517    "\177" gnus-browse-prev-group
 518    [delete] gnus-browse-prev-group
 519    "N" gnus-browse-next-group
 520    "P" gnus-browse-prev-group
 521    "\M-n" gnus-browse-next-group
 522    "\M-p" gnus-browse-prev-group
 523    "\r" gnus-browse-select-group
 524    "u" gnus-browse-unsubscribe-current-group
 525    "l" gnus-browse-exit
 526    "L" gnus-browse-exit
 527    "q" gnus-browse-exit
 528    "Q" gnus-browse-exit
 529    "\C-c\C-c" gnus-browse-exit
 530    "?" gnus-browse-describe-briefly
 531
 532    "\C-c\C-i" gnus-info-find-node
 533    "\C-c\C-b" gnus-bug))
 534
 535 (defun gnus-browse-make-menu-bar ()
 536   (gnus-turn-off-edit-menu 'browse)
 537   (unless (boundp 'gnus-browse-menu)
 538     (easy-menu-define
 539      gnus-browse-menu gnus-browse-mode-map ""
 540      '("Browse"
 541        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 542        ["Read" gnus-browse-read-group t]
 543        ["Select" gnus-browse-select-group t]
 544        ["Next" gnus-browse-next-group t]
 545        ["Prev" gnus-browse-next-group t]
 546        ["Exit" gnus-browse-exit t]))
 547     (gnus-run-hooks 'gnus-browse-menu-hook)))
 548
 549 (defvar gnus-browse-current-method nil)
 550 (defvar gnus-browse-return-buffer nil)
 551
 552 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 553
 554 (defun gnus-browse-foreign-server (server &optional return-buffer)
 555   "Browse the server SERVER."
 556   (setq gnus-browse-current-method (gnus-server-to-method server))
 557   (setq gnus-browse-return-buffer return-buffer)
 558   (let* ((method gnus-browse-current-method)
 559          (gnus-select-method method)
 560          groups group)
 561     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 562     (cond
 563      ((not (gnus-check-server method))
 564       (gnus-message
 565        1 "Unable to contact server %s: %s" (nth 1 method)
 566        (gnus-status-message method))
 567       nil)
 568      ((not
 569        (prog2
 570            (gnus-message 6 "Reading active file...")
 571            (gnus-request-list method)
 572          (gnus-message 6 "Reading active file...done")))
 573       (gnus-message
 574        1 "Couldn't request list: %s" (gnus-status-message method))
 575       nil)
 576      (t
 577       (gnus-get-buffer-create gnus-browse-buffer)
 578       (when gnus-carpal
 579         (gnus-carpal-setup-buffer 'browse))
 580       (gnus-configure-windows 'browse)
 581       (buffer-disable-undo)
 582       (let ((buffer-read-only nil))
 583         (erase-buffer))
 584       (gnus-browse-mode)
 585       (setq mode-line-buffer-identification
 586             (list
 587              (format
 588               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 589       (save-excursion
 590         (set-buffer nntp-server-buffer)
 591         (let ((cur (current-buffer)))
 592           (goto-char (point-min))
 593           (unless (string= gnus-ignored-newsgroups "")
 594             (delete-matching-lines gnus-ignored-newsgroups))
 595           (while (not (eobp))
 596             (ignore-errors
 597              (push (cons (let ((p (point)))
 598                            (skip-chars-forward "^ \t")
 599                            (buffer-substring p (point)))
 600                           (max 0 (- (1+ (read cur)) (read cur))))
 601                     groups))
 602             (forward-line))))
 603       (setq groups (sort groups
 604                          (lambda (l1 l2)
 605                            (string< (car l1) (car l2)))))
 606       (let ((buffer-read-only nil)
 607             (gnus-select-method nil)
 608             name)
 609         (while groups
 610           (setq group (car groups)
 611                 name (format "%s" (car group)))
 612           (insert (if (cadr (gnus-gethash
 613                              (gnus-group-prefixed-name name method)
 614                              gnus-newsrc-hashtb))
 615                       " " "K")
 616                   (format "%7d: " (cdr group)) name "\n")
 617           (setq groups (cdr groups))))
 618       (switch-to-buffer (current-buffer))
 619       (goto-char (point-min))
 620       (gnus-group-position-point)
 621       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 622       t))))
 623
 624 (defun gnus-browse-mode ()
 625   "Major mode for browsing a foreign server.
 626
 627 All normal editing commands are switched off.
 628
 629 \\<gnus-browse-mode-map>
 630 The only things you can do in this buffer is
 631
 632 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 633 The group will be inserted into the group buffer upon exit from this
 634 buffer.
 635
 636 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 637
 638 3) `\\[gnus-browse-exit]' to return to the group buffer."
 639   (interactive)
 640   (kill-all-local-variables)
 641   (when (gnus-visual-p 'browse-menu 'menu)
 642     (gnus-browse-make-menu-bar))
 643   (gnus-simplify-mode-line)
 644   (setq major-mode 'gnus-browse-mode)
 645   (setq mode-name "Browse Server")
 646   (setq mode-line-process nil)
 647   (use-local-map gnus-browse-mode-map)
 648   (buffer-disable-undo)
 649   (setq truncate-lines t)
 650   (gnus-set-default-directory)
 651   (setq buffer-read-only t)
 652   (gnus-run-hooks 'gnus-browse-mode-hook))
 653
 654 (defun gnus-browse-read-group (&optional no-article)
 655   "Enter the group at the current line."
 656   (interactive)
 657   (let ((group (gnus-browse-group-name)))
 658     (if (or (not (gnus-get-info group))
 659             (gnus-ephemeral-group-p group))
 660         (unless (gnus-group-read-ephemeral-group
 661                  group gnus-browse-current-method nil
 662                  (cons (current-buffer) 'browse))
 663           (error "Couldn't enter %s" group))
 664       (unless (gnus-group-read-group nil no-article group)
 665         (error "Couldn't enter %s" group)))))
 666
 667 (defun gnus-browse-select-group ()
 668   "Select the current group."
 669   (interactive)
 670   (gnus-browse-read-group 'no))
 671
 672 (defun gnus-browse-next-group (n)
 673   "Go to the next group."
 674   (interactive "p")
 675   (prog1
 676       (forward-line n)
 677     (gnus-group-position-point)))
 678
 679 (defun gnus-browse-prev-group (n)
 680   "Go to the next group."
 681   (interactive "p")
 682   (gnus-browse-next-group (- n)))
 683
 684 (defun gnus-browse-unsubscribe-current-group (arg)
 685   "(Un)subscribe to the next ARG groups."
 686   (interactive "p")
 687   (when (eobp)
 688     (error "No group at current line"))
 689   (let ((ward (if (< arg 0) -1 1))
 690         (arg (abs arg)))
 691     (while (and (> arg 0)
 692                 (not (eobp))
 693                 (gnus-browse-unsubscribe-group)
 694                 (zerop (gnus-browse-next-group ward)))
 695       (decf arg))
 696     (gnus-group-position-point)
 697     (when (/= 0 arg)
 698       (gnus-message 7 "No more newsgroups"))
 699     arg))
 700
 701 (defun gnus-browse-group-name ()
 702   (save-excursion
 703     (beginning-of-line)
 704     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 705       (gnus-group-prefixed-name
 706        ;; Remove text props.
 707        (format "%s" (match-string 1))
 708        gnus-browse-current-method))))
 709
 710 (defun gnus-browse-unsubscribe-group ()
 711   "Toggle subscription of the current group in the browse buffer."
 712   (let ((sub nil)
 713         (buffer-read-only nil)
 714         group)
 715     (save-excursion
 716       (beginning-of-line)
 717       ;; If this group it killed, then we want to subscribe it.
 718       (when (eq (char-after) ?K)
 719         (setq sub t))
 720       (setq group (gnus-browse-group-name))
 721       (when (and sub
 722                  (cadr (gnus-gethash group gnus-newsrc-hashtb)))
 723         (error "Group already subscribed"))
 724       (delete-char 1)
 725       (if sub
 726           (progn
 727             ;; Make sure the group has been properly removed before we
 728             ;; subscribe to it.
 729             (gnus-kill-ephemeral-group group)
 730             (gnus-group-change-level
 731              (list t group gnus-level-default-subscribed
 732                    nil nil (if (gnus-server-equal
 733                                 gnus-browse-current-method "native")
 734                                nil
 735                              gnus-browse-current-method))
 736              gnus-level-default-subscribed gnus-level-killed
 737              (and (car (nth 1 gnus-newsrc-alist))
 738                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 739                                 gnus-newsrc-hashtb))
 740              t)
 741             (insert ? ))
 742         (gnus-group-change-level
 743          group gnus-level-killed gnus-level-default-subscribed)
 744         (insert ?K)))
 745     t))
 746
 747 (defun gnus-browse-exit ()
 748   "Quit browsing and return to the group buffer."
 749   (interactive)
 750   (when (eq major-mode 'gnus-browse-mode)
 751     (kill-buffer (current-buffer)))
 752   ;; Insert the newly subscribed groups in the group buffer.
 753   (save-excursion
 754     (set-buffer gnus-group-buffer)
 755     (gnus-group-list-groups nil))
 756   (if gnus-browse-return-buffer
 757       (gnus-configure-windows 'server 'force)
 758     (gnus-configure-windows 'group 'force)))
 759
 760 (defun gnus-browse-describe-briefly ()
 761   "Give a one line description of the group mode commands."
 762   (interactive)
 763   (gnus-message 6
 764                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 765
 766 (defun gnus-server-regenerate-server ()
 767   "Issue a command to the server to regenerate all its data structures."
 768   (interactive)
 769   (let ((server (gnus-server-server-name)))
 770     (unless server
 771       (error "No server on the current line"))
 772     (if (not (gnus-check-backend-function
 773               'request-regenerate (car (gnus-server-to-method server))))
 774         (error "This backend doesn't support regeneration")
 775       (gnus-message 5 "Requesting regeneration of %s..." server)
 776       (unless (gnus-open-server server)
 777         (error "Couldn't open server"))
 778       (if (gnus-request-regenerate server)
 779           (gnus-message 5 "Requesting regeneration of %s...done" server)
 780         (gnus-message 5 "Couldn't regenerate %s" server)))))
 781
 782 (provide 'gnus-srvr)
 783
 784 ;;; gnus-srvr.el ends here.