git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Semi-gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   7 ;; Keywords: mail, news, MIME
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Nothing in this file depends on any other parts of Gnus -- all
  29 ;; functions and macros in this file are utility functions that are
  30 ;; used by Gnus and may be used by any other package without loading
  31 ;; Gnus first.
  32
  33 ;; [Unfortunately, it does depend on other parts of Gnus, e.g. the
  34 ;; autoloads and defvars below...]
  35
  36 ;;; Code:
  37
  38 (eval-when-compile
  39   (require 'cl)
  40   ;; Fixme: this should be a gnus variable, not nnmail-.
  41   (defvar nnmail-pathname-coding-system)
  42
  43   ;; Inappropriate references to other parts of Gnus.
  44   (defvar gnus-emphasize-whitespace-regexp)
  45   )
  46
  47 (require 'time-date)
  48 (require 'netrc)
  49
  50 (eval-when-compile (require 'static))
  51
  52 (eval-and-compile
  53   (autoload 'message-fetch-field "message")
  54   (autoload 'gnus-get-buffer-window "gnus-win")
  55   (autoload 'rmail-insert-rmail-file-header "rmail")
  56   (autoload 'rmail-count-new-messages "rmail")
  57   (autoload 'rmail-show-message "rmail")
  58   (autoload 'nnheader-narrow-to-headers "nnheader")
  59   (autoload 'nnheader-replace-chars-in-string "nnheader"))
  60
  61 (eval-and-compile
  62   (cond
  63    ((fboundp 'replace-in-string)
  64     (defalias 'gnus-replace-in-string 'replace-in-string))
  65    ((fboundp 'replace-regexp-in-string)
  66     (defun gnus-replace-in-string  (string regexp newtext &optional literal)
  67       (replace-regexp-in-string regexp newtext string nil literal)))))
  68
  69 (defun gnus-boundp (variable)
  70   "Return non-nil if VARIABLE is bound and non-nil."
  71   (and (boundp variable)
  72        (symbol-value variable)))
  73
  74 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  75   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  76   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  77         (w (make-symbol "w"))
  78         (buf (make-symbol "buf"))
  79         (frame (make-symbol "frame")))
  80     `(let* ((,tempvar (selected-window))
  81             (,buf ,buffer)
  82             (,w (gnus-get-buffer-window ,buf 'visible))
  83             ,frame)
  84        (unwind-protect
  85            (progn
  86              (if ,w
  87                  (progn
  88                    (select-window ,w)
  89                    (set-buffer (window-buffer ,w)))
  90                (pop-to-buffer ,buf))
  91              ,@forms)
  92          (setq ,frame (selected-frame))
  93          (select-window ,tempvar)
  94          (select-frame ,frame)))))
  95
  96 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  97 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
  98
  99 (defmacro gnus-intern-safe (string hashtable)
 100   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
 101   `(let ((symbol (intern ,string ,hashtable)))
 102      (or (boundp symbol)
 103          (set symbol nil))
 104      symbol))
 105
 106 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
 107 ;; to limit the length of a string.  This function is necessary since
 108 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
 109 ;; Fixme: Why not `truncate-string-to-width'?
 110 (defsubst gnus-limit-string (str width)
 111   (if (> (length str) width)
 112       (substring str 0 width)
 113     str))
 114
 115 (defsubst gnus-goto-char (point)
 116   (and point (goto-char point)))
 117
 118 (defmacro gnus-buffer-exists-p (buffer)
 119   `(let ((buffer ,buffer))
 120      (when buffer
 121        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 122                 buffer))))
 123
 124 ;; The LOCAL arg to `add-hook' is interpreted differently in Emacs and
 125 ;; XEmacs.  In Emacs we don't need to call `make-local-hook' first.
 126 ;; It's harmless, though, so the main purpose of this alias is to shut
 127 ;; up the byte compiler.
 128 (defalias 'gnus-make-local-hook
 129   (if (eq (get 'make-local-hook 'byte-compile)
 130           'byte-compile-obsolete)
 131       'ignore                           ; Emacs
 132     'make-local-hook))                  ; XEmacs
 133
 134 (defun gnus-delete-first (elt list)
 135   "Delete by side effect the first occurrence of ELT as a member of LIST."
 136   (if (equal (car list) elt)
 137       (cdr list)
 138     (let ((total list))
 139       (while (and (cdr list)
 140                   (not (equal (cadr list) elt)))
 141         (setq list (cdr list)))
 142       (when (cdr list)
 143         (setcdr list (cddr list)))
 144       total)))
 145
 146 ;; Delete the current line (and the next N lines).
 147 (defmacro gnus-delete-line (&optional n)
 148   `(delete-region (point-at-bol)
 149                   (progn (forward-line ,(or n 1)) (point))))
 150
 151 (defun gnus-byte-code (func)
 152   "Return a form that can be `eval'ed based on FUNC."
 153   (let ((fval (indirect-function func)))
 154     (if (byte-code-function-p fval)
 155         (let ((flist (append fval nil)))
 156           (setcar flist 'byte-code)
 157           flist)
 158       (cons 'progn (cddr fval)))))
 159
 160 (defun gnus-extract-address-components (from)
 161   "Extract address components from a From header.
 162 Given an RFC-822 address FROM, extract full name and canonical address.
 163 Returns a list of the form (FULL-NAME CANONICAL-ADDRESS).  Much more simple
 164 solution than `mail-extract-address-components', which works much better, but
 165 is slower."
 166   (let (name address)
 167     ;; First find the address - the thing with the @ in it.  This may
 168     ;; not be accurate in mail addresses, but does the trick most of
 169     ;; the time in news messages.
 170     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 171       (setq address (substring from (match-beginning 0) (match-end 0))))
 172     ;; Then we check whether the "name <address>" format is used.
 173     (and address
 174          ;; Linear white space is not required.
 175          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 176          (and (setq name (substring from 0 (match-beginning 0)))
 177               ;; Strip any quotes from the name.
 178               (string-match "^\".*\"$" name)
 179               (setq name (substring name 1 (1- (match-end 0))))))
 180     ;; If not, then "address (name)" is used.
 181     (or name
 182         (and (string-match "(.+)" from)
 183              (setq name (substring from (1+ (match-beginning 0))
 184                                    (1- (match-end 0)))))
 185         (and (string-match "()" from)
 186              (setq name address))
 187         ;; XOVER might not support folded From headers.
 188         (and (string-match "(.*" from)
 189              (setq name (substring from (1+ (match-beginning 0))
 190                                    (match-end 0)))))
 191     (list (if (string= name "") nil name) (or address from))))
 192
 193
 194 (defun gnus-fetch-field (field)
 195   "Return the value of the header FIELD of current article."
 196   (save-excursion
 197     (save-restriction
 198       (let ((inhibit-point-motion-hooks t))
 199         (nnheader-narrow-to-headers)
 200         (message-fetch-field field)))))
 201
 202 (defun gnus-fetch-original-field (field)
 203   "Fetch FIELD from the original version of the current article."
 204   (with-current-buffer gnus-original-article-buffer
 205     (gnus-fetch-field field)))
 206
 207
 208 (defun gnus-goto-colon ()
 209   (beginning-of-line)
 210   (let ((eol (point-at-eol)))
 211     (goto-char (or (text-property-any (point) eol 'gnus-position t)
 212                    (search-forward ":" eol t)
 213                    (point)))))
 214
 215 (defun gnus-decode-newsgroups (newsgroups group &optional method)
 216   (let ((method (or method (gnus-find-method-for-group group))))
 217     (mapconcat (lambda (group)
 218                  (gnus-group-name-decode group (gnus-group-name-charset
 219                                                 method group)))
 220                (message-tokenize-header newsgroups)
 221                ",")))
 222
 223 (defun gnus-remove-text-with-property (prop)
 224   "Delete all text in the current buffer with text property PROP."
 225   (let ((start (point-min))
 226         end)
 227     (unless (get-text-property start prop)
 228       (setq start (next-single-property-change start prop)))
 229     (while start
 230       (setq end (text-property-any start (point-max) prop nil))
 231       (delete-region start (or end (point-max)))
 232       (setq start (when end
 233                     (next-single-property-change start prop))))))
 234
 235 (defun gnus-newsgroup-directory-form (newsgroup)
 236   "Make hierarchical directory name from NEWSGROUP name."
 237   (let* ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 238          (idx (string-match ":" newsgroup)))
 239     (concat
 240      (if idx (substring newsgroup 0 idx))
 241      (if idx "/")
 242      (nnheader-replace-chars-in-string
 243       (if idx (substring newsgroup (1+ idx)) newsgroup)
 244       ?. ?/))))
 245
 246 (defun gnus-newsgroup-savable-name (group)
 247   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 248   ;; with dots.
 249   (nnheader-replace-chars-in-string group ?/ ?.))
 250
 251 (defun gnus-string> (s1 s2)
 252   (not (or (string< s1 s2)
 253            (string= s1 s2))))
 254
 255 ;;; Time functions.
 256
 257 (defun gnus-file-newer-than (file date)
 258   (let ((fdate (nth 5 (file-attributes file))))
 259     (or (> (car fdate) (car date))
 260         (and (= (car fdate) (car date))
 261              (> (nth 1 fdate) (nth 1 date))))))
 262
 263 ;;; Keymap macros.
 264
 265 (defmacro gnus-local-set-keys (&rest plist)
 266   "Set the keys in PLIST in the current keymap."
 267   `(gnus-define-keys-1 (current-local-map) ',plist))
 268
 269 (defmacro gnus-define-keys (keymap &rest plist)
 270   "Define all keys in PLIST in KEYMAP."
 271   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 272
 273 (defmacro gnus-define-keys-safe (keymap &rest plist)
 274   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 275   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 276
 277 (put 'gnus-define-keys 'lisp-indent-function 1)
 278 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 279 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 280
 281 (defmacro gnus-define-keymap (keymap &rest plist)
 282   "Define all keys in PLIST in KEYMAP."
 283   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 284
 285 (put 'gnus-define-keymap 'lisp-indent-function 1)
 286
 287 (defun gnus-define-keys-1 (keymap plist &optional safe)
 288   (when (null keymap)
 289     (error "Can't set keys in a null keymap"))
 290   (cond ((symbolp keymap)
 291          (setq keymap (symbol-value keymap)))
 292         ((keymapp keymap))
 293         ((listp keymap)
 294          (set (car keymap) nil)
 295          (define-prefix-command (car keymap))
 296          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 297          (setq keymap (symbol-value (car keymap)))))
 298   (let (key)
 299     (while plist
 300       (when (symbolp (setq key (pop plist)))
 301         (setq key (symbol-value key)))
 302       (if (or (not safe)
 303               (eq (lookup-key keymap key) 'undefined))
 304           (define-key keymap key (pop plist))
 305         (pop plist)))))
 306
 307 (defun gnus-completing-read-with-default (default prompt &rest args)
 308   ;; Like `completing-read', except that DEFAULT is the default argument.
 309   (let* ((prompt (if default
 310                      (concat prompt " (default " default ") ")
 311                    (concat prompt " ")))
 312          (answer (apply 'completing-read prompt args)))
 313     (if (or (null answer) (zerop (length answer)))
 314         default
 315       answer)))
 316
 317 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 318 ;; the echo area.
 319 (defun gnus-y-or-n-p (prompt)
 320   (prog1
 321       (y-or-n-p prompt)
 322     (message "")))
 323
 324 (defun gnus-yes-or-no-p (prompt)
 325   (prog1
 326       (yes-or-no-p prompt)
 327     (message "")))
 328
 329 ;; By Frank Schmitt <ich@Frank-Schmitt.net>. Allows to have
 330 ;; age-depending date representations. (e.g. just the time if it's
 331 ;; from today, the day of the week if it's within the last 7 days and
 332 ;; the full date if it's older)
 333
 334 (defun gnus-seconds-today ()
 335   "Return the number of seconds passed today."
 336   (let ((now (decode-time (current-time))))
 337     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600))))
 338
 339 (defun gnus-seconds-month ()
 340   "Return the number of seconds passed this month."
 341   (let ((now (decode-time (current-time))))
 342     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 343        (* (- (car (nthcdr 3 now)) 1) 3600 24))))
 344
 345 (defun gnus-seconds-year ()
 346   "Return the number of seconds passed this year."
 347   (let ((now (decode-time (current-time)))
 348         (days (format-time-string "%j" (current-time))))
 349     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 350        (* (- (string-to-number days) 1) 3600 24))))
 351
 352 (defvar gnus-user-date-format-alist
 353   '(((gnus-seconds-today) . "%k:%M")
 354     (604800 . "%a %k:%M")                   ;;that's one week
 355     ((gnus-seconds-month) . "%a %d")
 356     ((gnus-seconds-year) . "%b %d")
 357     (t . "%b %d '%y"))                      ;;this one is used when no
 358                                             ;;other does match
 359   "Specifies date format depending on age of article.
 360 This is an alist of items (AGE . FORMAT).  AGE can be a number (of
 361 seconds) or a Lisp expression evaluating to a number.  When the age of
 362 the article is less than this number, then use `format-time-string'
 363 with the corresponding FORMAT for displaying the date of the article.
 364 If AGE is not a number or a Lisp expression evaluating to a
 365 non-number, then the corresponding FORMAT is used as a default value.
 366
 367 Note that the list is processed from the beginning, so it should be
 368 sorted by ascending AGE.  Also note that items following the first
 369 non-number AGE will be ignored.
 370
 371 You can use the functions `gnus-seconds-today', `gnus-seconds-month'
 372 and `gnus-seconds-year' in the AGE spec.  They return the number of
 373 seconds passed since the start of today, of this month, of this year,
 374 respectively.")
 375
 376 (defun gnus-user-date (messy-date)
 377   "Format the messy-date according to gnus-user-date-format-alist.
 378 Returns \"  ?  \" if there's bad input or if an other error occurs.
 379 Input should look like this: \"Sun, 14 Oct 2001 13:34:39 +0200\"."
 380   (condition-case ()
 381       (let* ((messy-date (time-to-seconds (safe-date-to-time messy-date)))
 382              (now (time-to-seconds (current-time)))
 383              ;;If we don't find something suitable we'll use this one
 384              (my-format "%b %d '%y"))
 385         (let* ((difference (- now messy-date))
 386                (templist gnus-user-date-format-alist)
 387                (top (eval (caar templist))))
 388           (while (if (numberp top) (< top difference) (not top))
 389             (progn
 390               (setq templist (cdr templist))
 391               (setq top (eval (caar templist)))))
 392           (if (stringp (cdr (car templist)))
 393               (setq my-format (cdr (car templist)))))
 394         (format-time-string (eval my-format) (seconds-to-time messy-date)))
 395     (error "  ?   ")))
 396
 397 (defun gnus-dd-mmm (messy-date)
 398   "Return a string like DD-MMM from a big messy string."
 399   (condition-case ()
 400       (format-time-string "%d-%b" (safe-date-to-time messy-date))
 401     (error "  -   ")))
 402
 403 (defmacro gnus-date-get-time (date)
 404   "Convert DATE string to Emacs time.
 405 Cache the result as a text property stored in DATE."
 406   ;; Either return the cached value...
 407   `(let ((d ,date))
 408      (if (equal "" d)
 409          '(0 0)
 410        (or (get-text-property 0 'gnus-time d)
 411            ;; or compute the value...
 412            (let ((time (safe-date-to-time d)))
 413              ;; and store it back in the string.
 414              (put-text-property 0 1 'gnus-time time d)
 415              time)))))
 416
 417 (defsubst gnus-time-iso8601 (time)
 418   "Return a string of TIME in YYYYMMDDTHHMMSS format."
 419   (format-time-string "%Y%m%dT%H%M%S" time))
 420
 421 (defun gnus-date-iso8601 (date)
 422   "Convert the DATE to YYYYMMDDTHHMMSS."
 423   (condition-case ()
 424       (gnus-time-iso8601 (gnus-date-get-time date))
 425     (error "")))
 426
 427 (defun gnus-mode-string-quote (string)
 428   "Quote all \"%\"'s in STRING."
 429   (gnus-replace-in-string string "%" "%%"))
 430
 431 ;; Make a hash table (default and minimum size is 256).
 432 ;; Optional argument HASHSIZE specifies the table size.
 433 (defun gnus-make-hashtable (&optional hashsize)
 434   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 435
 436 ;; Make a number that is suitable for hashing; bigger than MIN and
 437 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 438 ;; hardware modulo operation, so they implement it in software.  On
 439 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 440 ;; Yes, it's slower than actually computing the hash from the string!
 441 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 442 (defun gnus-create-hash-size (min)
 443   (let ((i 1))
 444     (while (< i min)
 445       (setq i (* 2 i)))
 446     i))
 447
 448 (defcustom gnus-verbose 7
 449   "*Integer that says how verbose Gnus should be.
 450 The higher the number, the more messages Gnus will flash to say what
 451 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 452 display most important messages; and at ten, Gnus will keep on
 453 jabbering all the time."
 454   :group 'gnus-start
 455   :type 'integer)
 456
 457 (defun gnus-message (level &rest args)
 458   "If LEVEL is lower than `gnus-verbose' print ARGS using `message'.
 459
 460 Guideline for numbers:
 461 1 - error messages, 3 - non-serious error messages, 5 - messages for things
 462 that take a long time, 7 - not very important messages on stuff, 9 - messages
 463 inside loops."
 464   (if (<= level gnus-verbose)
 465       (apply 'message args)
 466     ;; We have to do this format thingy here even if the result isn't
 467     ;; shown - the return value has to be the same as the return value
 468     ;; from `message'.
 469     (apply 'format args)))
 470
 471 (defun gnus-error (level &rest args)
 472   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 473   (when (<= (floor level) gnus-verbose)
 474     (apply 'message args)
 475     (ding)
 476     (let (duration)
 477       (when (and (floatp level)
 478                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 479         (sit-for duration))))
 480   nil)
 481
 482 (defun gnus-split-references (references)
 483   "Return a list of Message-IDs in REFERENCES."
 484   (let ((beg 0)
 485         ids)
 486     (while (string-match "<[^<]+[^< \t]" references beg)
 487       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 488             ids))
 489     (nreverse ids)))
 490
 491 (defsubst gnus-parent-id (references &optional n)
 492   "Return the last Message-ID in REFERENCES.
 493 If N, return the Nth ancestor instead."
 494   (when (and references
 495              (not (zerop (length references))))
 496     (if n
 497         (let ((ids (inline (gnus-split-references references))))
 498           (while (nthcdr n ids)
 499             (setq ids (cdr ids)))
 500           (car ids))
 501       (when (string-match "\\(<[^<]+>\\)[ \t]*\\'" references)
 502         (match-string 1 references)))))
 503
 504 (defun gnus-buffer-live-p (buffer)
 505   "Say whether BUFFER is alive or not."
 506   (and buffer
 507        (get-buffer buffer)
 508        (buffer-name (get-buffer buffer))))
 509
 510 (defun gnus-horizontal-recenter ()
 511   "Recenter the current buffer horizontally."
 512   (if (< (current-column) (/ (window-width) 2))
 513       (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0)
 514     (let* ((orig (point))
 515            (end (window-end (gnus-get-buffer-window (current-buffer) t)))
 516            (max 0))
 517       (when end
 518         ;; Find the longest line currently displayed in the window.
 519         (goto-char (window-start))
 520         (while (and (not (eobp))
 521                     (< (point) end))
 522           (end-of-line)
 523           (setq max (max max (current-column)))
 524           (forward-line 1))
 525         (goto-char orig)
 526         ;; Scroll horizontally to center (sort of) the point.
 527         (if (> max (window-width))
 528             (set-window-hscroll
 529              (gnus-get-buffer-window (current-buffer) t)
 530              (min (- (current-column) (/ (window-width) 3))
 531                   (+ 2 (- max (window-width)))))
 532           (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0))
 533         max))))
 534
 535 (defun gnus-read-event-char (&optional prompt)
 536   "Get the next event."
 537   (let ((event (read-event prompt)))
 538     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 539     (cons (and (numberp event) event) event)))
 540
 541 (defun gnus-sortable-date (date)
 542   "Make string suitable for sorting from DATE."
 543   (gnus-time-iso8601 (date-to-time date)))
 544
 545 (defun gnus-copy-file (file &optional to)
 546   "Copy FILE to TO."
 547   (interactive
 548    (list (read-file-name "Copy file: " default-directory)
 549          (read-file-name "Copy file to: " default-directory)))
 550   (unless to
 551     (setq to (read-file-name "Copy file to: " default-directory)))
 552   (when (file-directory-p to)
 553     (setq to (concat (file-name-as-directory to)
 554                      (file-name-nondirectory file))))
 555   (copy-file file to))
 556
 557 (defvar gnus-work-buffer " *gnus work*")
 558
 559 (defun gnus-set-work-buffer ()
 560   "Put point in the empty Gnus work buffer."
 561   (if (get-buffer gnus-work-buffer)
 562       (progn
 563         (set-buffer gnus-work-buffer)
 564         (erase-buffer))
 565     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 566     (kill-all-local-variables)
 567     (set-buffer-multibyte t)))
 568
 569 (defmacro gnus-group-real-name (group)
 570   "Find the real name of a foreign newsgroup."
 571   `(let ((gname ,group))
 572      (if (string-match "^[^:]+:" gname)
 573          (substring gname (match-end 0))
 574        gname)))
 575
 576 (defmacro gnus-group-server (group)
 577   "Find the server name of a foreign newsgroup.
 578 For example, (gnus-group-server \"nnimap+yxa:INBOX.foo\") would
 579 yield \"nnimap:yxa\"."
 580   `(let ((gname ,group))
 581      (if (string-match "^\\([^+]+\\).\\([^:]+\\):" gname)
 582          (format "%s:%s" (match-string 1 gname) (match-string 2 gname))
 583        (format "%s:%s" (car gnus-select-method) (cadr gnus-select-method)))))
 584
 585 (defun gnus-make-sort-function (funs)
 586   "Return a composite sort condition based on the functions in FUNS."
 587   (cond
 588    ;; Just a simple function.
 589    ((functionp funs) funs)
 590    ;; No functions at all.
 591    ((null funs) funs)
 592    ;; A list of functions.
 593    ((or (cdr funs)
 594         (listp (car funs)))
 595     (gnus-byte-compile
 596      `(lambda (t1 t2)
 597         ,(gnus-make-sort-function-1 (reverse funs)))))
 598    ;; A list containing just one function.
 599    (t
 600     (car funs))))
 601
 602 (defun gnus-make-sort-function-1 (funs)
 603   "Return a composite sort condition based on the functions in FUNS."
 604   (let ((function (car funs))
 605         (first 't1)
 606         (last 't2))
 607     (when (consp function)
 608       (cond
 609        ;; Reversed spec.
 610        ((eq (car function) 'not)
 611         (setq function (cadr function)
 612               first 't2
 613               last 't1))
 614        ((functionp function)
 615         ;; Do nothing.
 616         )
 617        (t
 618         (error "Invalid sort spec: %s" function))))
 619     (if (cdr funs)
 620         `(or (,function ,first ,last)
 621              (and (not (,function ,last ,first))
 622                   ,(gnus-make-sort-function-1 (cdr funs))))
 623       `(,function ,first ,last))))
 624
 625 (defun gnus-turn-off-edit-menu (type)
 626   "Turn off edit menu in `gnus-TYPE-mode-map'."
 627   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 628     [menu-bar edit] 'undefined))
 629
 630 (defmacro gnus-bind-print-variables (&rest forms)
 631   "Bind print-* variables and evaluate FORMS.
 632 This macro is used with `prin1', `pp', etc. in order to ensure printed
 633 Lisp objects are loadable.  Bind `print-quoted' and `print-readably'
 634 to t, and `print-escape-multibyte', `print-escape-newlines',
 635 `print-escape-nonascii', `print-length', `print-level' and
 636 `print-string-length' to nil."
 637   `(let ((print-quoted t)
 638          (print-readably t)
 639          ;;print-circle
 640          ;;print-continuous-numbering
 641          print-escape-multibyte
 642          print-escape-newlines
 643          print-escape-nonascii
 644          ;;print-gensym
 645          print-length
 646          print-level
 647          print-string-length)
 648      ,@forms))
 649
 650 (defun gnus-prin1 (form)
 651   "Use `prin1' on FORM in the current buffer.
 652 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 653 `print-level' to nil.  See also `gnus-bind-print-variables'."
 654   (gnus-bind-print-variables (prin1 form (current-buffer))))
 655
 656 (defun gnus-prin1-to-string (form)
 657   "The same as `prin1'.
 658 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 659 `print-level' to nil.  See also `gnus-bind-print-variables'."
 660   (gnus-bind-print-variables (prin1-to-string form)))
 661
 662 (defun gnus-pp (form)
 663   "Use `pp' on FORM in the current buffer.
 664 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 665 `print-level' to nil.  See also `gnus-bind-print-variables'."
 666   (gnus-bind-print-variables (pp form (current-buffer))))
 667
 668 (defun gnus-pp-to-string (form)
 669   "The same as `pp-to-string'.
 670 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 671 `print-level' to nil.  See also `gnus-bind-print-variables'."
 672   (gnus-bind-print-variables (pp-to-string form)))
 673
 674 (defun gnus-make-directory (directory)
 675   "Make DIRECTORY (and all its parents) if it doesn't exist."
 676   (require 'nnmail)
 677   (let ((file-name-coding-system nnmail-pathname-coding-system))
 678     (when (and directory
 679                (not (file-exists-p directory)))
 680       (make-directory directory t)))
 681   t)
 682
 683 (defun gnus-write-buffer (file)
 684   "Write the current buffer's contents to FILE."
 685   ;; Make sure the directory exists.
 686   (gnus-make-directory (file-name-directory file))
 687   (let ((file-name-coding-system nnmail-pathname-coding-system))
 688     ;; Write the buffer.
 689     (write-region (point-min) (point-max) file nil 'quietly)))
 690
 691 (defun gnus-write-buffer-as-binary (file)
 692   "Write the current buffer's contents to FILE without code conversion."
 693   ;; Make sure the directory exists.
 694   (gnus-make-directory (file-name-directory file))
 695   ;; Write the buffer.
 696   (write-region-as-binary (point-min) (point-max) file nil 'quietly))
 697
 698 (defun gnus-write-buffer-as-coding-system (coding-system file)
 699   "Write the current buffer's contents to FILE with code conversion."
 700   ;; Make sure the directory exists.
 701   (gnus-make-directory (file-name-directory file))
 702   ;; Write the buffer.
 703   (write-region-as-coding-system
 704    coding-system (point-min) (point-max) file nil 'quietly))
 705
 706 (defun gnus-delete-file (file)
 707   "Delete FILE if it exists."
 708   (when (file-exists-p file)
 709     (delete-file file)))
 710
 711 (defun gnus-strip-whitespace (string)
 712   "Return STRING stripped of all whitespace."
 713   (while (string-match "[\r\n\t ]+" string)
 714     (setq string (replace-match "" t t string)))
 715   string)
 716
 717 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 718   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 719   (save-match-data
 720     (save-excursion
 721       (save-restriction
 722         (goto-char beg)
 723         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 724           (gnus-put-text-property beg (match-beginning 0) prop val)
 725           (setq beg (point)))
 726         (gnus-put-text-property beg (point) prop val)))))
 727
 728 (defsubst gnus-put-overlay-excluding-newlines (beg end prop val)
 729   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 730   (save-match-data
 731     (save-excursion
 732       (save-restriction
 733         (goto-char beg)
 734         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 735           (gnus-overlay-put
 736            (gnus-make-overlay beg (match-beginning 0))
 737            prop val)
 738           (setq beg (point)))
 739         (gnus-overlay-put (gnus-make-overlay beg (point)) prop val)))))
 740
 741 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 742                                                                    prop val)
 743   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 744   (let ((b beg))
 745     (while (/= b end)
 746       (when (get-text-property b 'gnus-face)
 747         (setq b (next-single-property-change b 'gnus-face nil end)))
 748       (when (/= b end)
 749         (inline
 750           (gnus-put-text-property
 751            b (setq b (next-single-property-change b 'gnus-face nil end))
 752            prop val))))))
 753
 754 (defmacro gnus-faces-at (position)
 755   "Return a list of faces at POSITION."
 756   (if (featurep 'xemacs)
 757       `(let ((pos ,position))
 758          (mapcar-extents 'extent-face
 759                          nil (current-buffer) pos pos nil 'face))
 760     `(let ((pos ,position))
 761        (delq nil (cons (get-text-property pos 'face)
 762                        (mapcar
 763                         (lambda (overlay)
 764                           (overlay-get overlay 'face))
 765                         (overlays-at pos)))))))
 766
 767 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 768 ;;; The primary idea here is to try to protect internal datastructures
 769 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 770 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 771 ;;; updated at the same time, or information can be lost.
 772
 773 (defvar gnus-atomic-be-safe t
 774   "If t, certain operations will be protected from interruption by C-g.")
 775
 776 (defmacro gnus-atomic-progn (&rest forms)
 777   "Evaluate FORMS atomically, which means to protect the evaluation
 778 from being interrupted by the user.  An error from the forms themselves
 779 will return without finishing the operation.  Since interrupts from
 780 the user are disabled, it is recommended that only the most minimal
 781 operations are performed by FORMS.  If you wish to assign many
 782 complicated values atomically, compute the results into temporary
 783 variables and then do only the assignment atomically."
 784   `(let ((inhibit-quit gnus-atomic-be-safe))
 785      ,@forms))
 786
 787 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 788
 789 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 790   "Evaluate FORMS, but insure that the variables listed in PROTECT
 791 are not changed if anything in FORMS signals an error or otherwise
 792 non-locally exits.  The variables listed in PROTECT are updated atomically.
 793 It is safe to use gnus-atomic-progn-assign with long computations.
 794
 795 Note that if any of the symbols in PROTECT were unbound, they will be
 796 set to nil on a successful assignment.  In case of an error or other
 797 non-local exit, it will still be unbound."
 798   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 799                                                   (concat (symbol-name x)
 800                                                           "-tmp"))
 801                                                  x))
 802                                protect))
 803          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 804                                temp-sym-map))
 805          (temp-sym-let (mapcar (lambda (x) (list (car x)
 806                                                  `(and (boundp ',(cadr x))
 807                                                        ,(cadr x))))
 808                                temp-sym-map))
 809          (sym-temp-let sym-temp-map)
 810          (temp-sym-assign (apply 'append temp-sym-map))
 811          (sym-temp-assign (apply 'append sym-temp-map))
 812          (result (make-symbol "result-tmp")))
 813     `(let (,@temp-sym-let
 814            ,result)
 815        (let ,sym-temp-let
 816          (setq ,result (progn ,@forms))
 817          (setq ,@temp-sym-assign))
 818        (let ((inhibit-quit gnus-atomic-be-safe))
 819          (setq ,@sym-temp-assign))
 820        ,result)))
 821
 822 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 823 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 824
 825 (defmacro gnus-atomic-setq (&rest pairs)
 826   "Similar to setq, except that the real symbols are only assigned when
 827 there are no errors.  And when the real symbols are assigned, they are
 828 done so atomically.  If other variables might be changed via side-effect,
 829 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 830 with potentially long computations."
 831   (let ((tpairs pairs)
 832         syms)
 833     (while tpairs
 834       (push (car tpairs) syms)
 835       (setq tpairs (cddr tpairs)))
 836     `(gnus-atomic-progn-assign ,syms
 837        (setq ,@pairs))))
 838
 839 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 840
 841
 842 ;;; Functions for saving to babyl/mail files.
 843
 844 (eval-when-compile
 845   (condition-case nil
 846       (progn
 847         (require 'rmail)
 848         (autoload 'rmail-update-summary "rmailsum"))
 849     (error
 850      (define-compiler-macro rmail-select-summary (&rest body)
 851        ;; Rmail of the XEmacs version is supplied by the package, and
 852        ;; requires tm and apel packages.  However, there may be those
 853        ;; who haven't installed those packages.  This macro helps such
 854        ;; people even if they install those packages later.
 855        `(eval '(rmail-select-summary ,@body)))
 856      ;; If there's rmail but there's no tm (or there's apel of the
 857      ;; mainstream, not the XEmacs version), loading rmail of the XEmacs
 858      ;; version fails halfway, however it provides the rmail-select-summary
 859      ;; macro which uses the following functions:
 860      (autoload 'rmail-summary-displayed "rmail")
 861      (autoload 'rmail-maybe-display-summary "rmail")))
 862   (defvar rmail-default-rmail-file)
 863   (defvar mm-text-coding-system))
 864
 865 (defun gnus-output-to-rmail (filename &optional ask)
 866   "Append the current article to an Rmail file named FILENAME."
 867   (require 'rmail)
 868   (require 'mm-util)
 869   ;; Most of these codes are borrowed from rmailout.el.
 870   (setq filename (expand-file-name filename))
 871   (setq rmail-default-rmail-file filename)
 872   (let ((artbuf (current-buffer))
 873         (tmpbuf (get-buffer-create " *Gnus-output*")))
 874     (save-excursion
 875       (or (get-file-buffer filename)
 876           (file-exists-p filename)
 877           (if (or (not ask)
 878                   (gnus-yes-or-no-p
 879                    (concat "\"" filename "\" does not exist, create it? ")))
 880               (let ((file-buffer (create-file-buffer filename)))
 881                 (save-excursion
 882                   (set-buffer file-buffer)
 883                   (rmail-insert-rmail-file-header)
 884                   (let ((require-final-newline nil))
 885                     (gnus-write-buffer-as-coding-system
 886                      nnheader-text-coding-system filename)))
 887                 (kill-buffer file-buffer))
 888             (error "Output file does not exist")))
 889       (set-buffer tmpbuf)
 890       (erase-buffer)
 891       (insert-buffer-substring artbuf)
 892       (gnus-convert-article-to-rmail)
 893       ;; Decide whether to append to a file or to an Emacs buffer.
 894       (let ((outbuf (get-file-buffer filename)))
 895         (if (not outbuf)
 896             (let ((file-name-coding-system nnmail-pathname-coding-system))
 897               (write-region-as-binary (point-min) (point-max)
 898                                       filename 'append))
 899           ;; File has been visited, in buffer OUTBUF.
 900           (set-buffer outbuf)
 901           (let ((buffer-read-only nil)
 902                 (msg (and (boundp 'rmail-current-message)
 903                           (symbol-value 'rmail-current-message))))
 904             ;; If MSG is non-nil, buffer is in RMAIL mode.
 905             (when msg
 906               (widen)
 907               (narrow-to-region (point-max) (point-max)))
 908             (insert-buffer-substring tmpbuf)
 909             (when msg
 910               (goto-char (point-min))
 911               (widen)
 912               (search-backward "\n\^_")
 913               (narrow-to-region (point) (point-max))
 914               (rmail-count-new-messages t)
 915               (when (rmail-summary-exists)
 916                 (rmail-select-summary
 917                  (rmail-update-summary)))
 918               (rmail-count-new-messages t)
 919               (rmail-show-message msg))
 920             (save-buffer)))))
 921     (kill-buffer tmpbuf)))
 922
 923 (defun gnus-output-to-mail (filename &optional ask)
 924   "Append the current article to a mail file named FILENAME."
 925   (setq filename (expand-file-name filename))
 926   (let ((artbuf (current-buffer))
 927         (tmpbuf (get-buffer-create " *Gnus-output*")))
 928     (save-excursion
 929       ;; Create the file, if it doesn't exist.
 930       (when (and (not (get-file-buffer filename))
 931                  (not (file-exists-p filename)))
 932         (if (or (not ask)
 933                 (gnus-y-or-n-p
 934                  (concat "\"" filename "\" does not exist, create it? ")))
 935             (let ((file-buffer (create-file-buffer filename)))
 936               (save-excursion
 937                 (set-buffer file-buffer)
 938                 (let ((require-final-newline nil))
 939                   (gnus-write-buffer-as-coding-system
 940                    nnheader-text-coding-system filename)))
 941               (kill-buffer file-buffer))
 942           (error "Output file does not exist")))
 943       (set-buffer tmpbuf)
 944       (erase-buffer)
 945       (insert-buffer-substring artbuf)
 946       (goto-char (point-min))
 947       (if (looking-at "From ")
 948           (forward-line 1)
 949         (insert "From nobody " (current-time-string) "\n"))
 950       (let (case-fold-search)
 951         (while (re-search-forward "^From " nil t)
 952           (beginning-of-line)
 953           (insert ">")))
 954       ;; Decide whether to append to a file or to an Emacs buffer.
 955       (let ((outbuf (get-file-buffer filename)))
 956         (if (not outbuf)
 957             (let ((buffer-read-only nil))
 958               (save-excursion
 959                 (goto-char (point-max))
 960                 (forward-char -2)
 961                 (unless (looking-at "\n\n")
 962                   (goto-char (point-max))
 963                   (unless (bolp)
 964                     (insert "\n"))
 965                   (insert "\n"))
 966                 (goto-char (point-max))
 967                 (let ((file-name-coding-system nnmail-pathname-coding-system))
 968                   (write-region-as-binary (point-min) (point-max)
 969                                           filename 'append))))
 970           ;; File has been visited, in buffer OUTBUF.
 971           (set-buffer outbuf)
 972           (let ((buffer-read-only nil))
 973             (goto-char (point-max))
 974             (unless (eobp)
 975               (insert "\n"))
 976             (insert "\n")
 977             (insert-buffer-substring tmpbuf)))))
 978     (kill-buffer tmpbuf)))
 979
 980 (defun gnus-convert-article-to-rmail ()
 981   "Convert article in current buffer to Rmail message format."
 982   (let ((buffer-read-only nil))
 983     ;; Convert article directly into Babyl format.
 984     (goto-char (point-min))
 985     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 986     (while (search-forward "\n\^_" nil t) ;single char
 987       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 988     (goto-char (point-max))
 989     (insert "\^_")))
 990
 991 (defun gnus-map-function (funs arg)
 992   "Apply the result of the first function in FUNS to the second, and so on.
 993 ARG is passed to the first function."
 994   (while funs
 995     (setq arg (funcall (pop funs) arg)))
 996   arg)
 997
 998 (defun gnus-run-hooks (&rest funcs)
 999   "Does the same as `run-hooks', but saves the current buffer."
1000   (save-current-buffer
1001     (apply 'run-hooks funcs)))
1002
1003 ;;; Various
1004
1005 (defvar gnus-group-buffer)              ; Compiler directive
1006 (defun gnus-alive-p ()
1007   "Say whether Gnus is running or not."
1008   (and (boundp 'gnus-group-buffer)
1009        (get-buffer gnus-group-buffer)
1010        (save-excursion
1011          (set-buffer gnus-group-buffer)
1012          (eq major-mode 'gnus-group-mode))))
1013
1014 (defun gnus-remove-duplicates (list)
1015   (let (new)
1016     (while list
1017       (or (member (car list) new)
1018           (setq new (cons (car list) new)))
1019       (setq list (cdr list)))
1020     (nreverse new)))
1021
1022 (defun gnus-remove-if (predicate list)
1023   "Return a copy of LIST with all items satisfying PREDICATE removed."
1024   (let (out)
1025     (while list
1026       (unless (funcall predicate (car list))
1027         (push (car list) out))
1028       (setq list (cdr list)))
1029     (nreverse out)))
1030
1031 (if (fboundp 'assq-delete-all)
1032     (defalias 'gnus-delete-alist 'assq-delete-all)
1033   (defun gnus-delete-alist (key alist)
1034     "Delete from ALIST all elements whose car is KEY.
1035 Return the modified alist."
1036     (let (entry)
1037       (while (setq entry (assq key alist))
1038         (setq alist (delq entry alist)))
1039       alist)))
1040
1041 (defmacro gnus-pull (key alist &optional assoc-p)
1042   "Modify ALIST to be without KEY."
1043   (unless (symbolp alist)
1044     (error "Not a symbol: %s" alist))
1045   (let ((fun (if assoc-p 'assoc 'assq)))
1046     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
1047
1048 (defun gnus-globalify-regexp (re)
1049   "Return a regexp that matches a whole line, iff RE matches a part of it."
1050   (concat (unless (string-match "^\\^" re) "^.*")
1051           re
1052           (unless (string-match "\\$$" re) ".*$")))
1053
1054 (defun gnus-set-window-start (&optional point)
1055   "Set the window start to POINT, or (point) if nil."
1056   (let ((win (gnus-get-buffer-window (current-buffer) t)))
1057     (when win
1058       (set-window-start win (or point (point))))))
1059
1060 (defun gnus-annotation-in-region-p (b e)
1061   (if (= b e)
1062       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
1063     (text-property-any b e 'gnus-undeletable t)))
1064
1065 (defun gnus-or (&rest elems)
1066   "Return non-nil if any of the elements are non-nil."
1067   (catch 'found
1068     (while elems
1069       (when (pop elems)
1070         (throw 'found t)))))
1071
1072 (defun gnus-and (&rest elems)
1073   "Return non-nil if all of the elements are non-nil."
1074   (catch 'found
1075     (while elems
1076       (unless (pop elems)
1077         (throw 'found nil)))
1078     t))
1079
1080 (defun gnus-write-active-file (file hashtb &optional full-names)
1081   (let ((coding-system-for-write nnmail-active-file-coding-system))
1082     (with-temp-file file
1083       (mapatoms
1084        (lambda (sym)
1085          (when (and sym
1086                     (boundp sym)
1087                     (symbol-value sym))
1088            (insert (format "%S %d %d y\n"
1089                            (if full-names
1090                                sym
1091                              (intern (gnus-group-real-name (symbol-name sym))))
1092                            (or (cdr (symbol-value sym))
1093                                (car (symbol-value sym)))
1094                            (car (symbol-value sym))))))
1095        hashtb)
1096       (goto-char (point-max))
1097       (while (search-backward "\\." nil t)
1098         (delete-char 1)))))
1099
1100 ;; Fixme: Why not use `with-output-to-temp-buffer'?
1101 (defmacro gnus-with-output-to-file (file &rest body)
1102   (let ((buffer (make-symbol "output-buffer"))
1103         (size (make-symbol "output-buffer-size"))
1104         (leng (make-symbol "output-buffer-length"))
1105         (append (make-symbol "output-buffer-append")))
1106     `(let* ((,size 131072)
1107             (,buffer (make-string ,size 0))
1108             (,leng 0)
1109             (,append nil)
1110             (standard-output
1111              (lambda (c)
1112                (aset ,buffer ,leng c)
1113
1114                (if (= ,size (setq ,leng (1+ ,leng)))
1115                    (progn (write-region ,buffer nil ,file ,append 'no-msg)
1116                           (setq ,leng 0
1117                                 ,append t))))))
1118        ,@body
1119        (when (> ,leng 0)
1120          (let ((coding-system-for-write 'no-conversion))
1121          (write-region (substring ,buffer 0 ,leng) nil ,file
1122                        ,append 'no-msg))))))
1123
1124 (put 'gnus-with-output-to-file 'lisp-indent-function 1)
1125 (put 'gnus-with-output-to-file 'edebug-form-spec '(form body))
1126
1127 (if (fboundp 'union)
1128     (defalias 'gnus-union 'union)
1129   (defun gnus-union (l1 l2)
1130     "Set union of lists L1 and L2."
1131     (cond ((null l1) l2)
1132           ((null l2) l1)
1133           ((equal l1 l2) l1)
1134           (t
1135            (or (>= (length l1) (length l2))
1136                (setq l1 (prog1 l2 (setq l2 l1))))
1137            (while l2
1138              (or (member (car l2) l1)
1139                  (push (car l2) l1))
1140              (pop l2))
1141            l1))))
1142
1143 (defun gnus-add-text-properties-when
1144   (property value start end properties &optional object)
1145   "Like `gnus-add-text-properties', only applied on where PROPERTY is VALUE."
1146   (let (point)
1147     (while (and start
1148                 (< start end) ;; XEmacs will loop for every when start=end.
1149                 (setq point (text-property-not-all start end property value)))
1150       (gnus-add-text-properties start point properties object)
1151       (setq start (text-property-any point end property value)))
1152     (if start
1153         (gnus-add-text-properties start end properties object))))
1154
1155 (defun gnus-remove-text-properties-when
1156   (property value start end properties &optional object)
1157   "Like `remove-text-properties', only applied on where PROPERTY is VALUE."
1158   (let (point)
1159     (while (and start
1160                 (< start end)
1161                 (setq point (text-property-not-all start end property value)))
1162       (remove-text-properties start point properties object)
1163       (setq start (text-property-any point end property value)))
1164     (if start
1165         (remove-text-properties start end properties object))
1166     t))
1167
1168 ;; This might use `compare-strings' to reduce consing in the
1169 ;; case-insensitive case, but it has to cope with null args.
1170 ;; (`string-equal' uses symbol print names.)
1171 (defun gnus-string-equal (x y)
1172   "Like `string-equal', except it compares case-insensitively."
1173   (and (= (length x) (length y))
1174        (or (string-equal x y)
1175            (string-equal (downcase x) (downcase y)))))
1176
1177 (defcustom gnus-use-byte-compile t
1178   "If non-nil, byte-compile crucial run-time code.
1179 Setting it to nil has no effect after the first time `gnus-byte-compile'
1180 is run."
1181   :type 'boolean
1182   :version "21.4"
1183   :group 'gnus-various)
1184
1185 (defun gnus-byte-compile (form)
1186   "Byte-compile FORM if `gnus-use-byte-compile' is non-nil."
1187   (if gnus-use-byte-compile
1188       (progn
1189         (condition-case nil
1190             ;; Work around a bug in XEmacs 21.4
1191             (require 'byte-optimize)
1192           (error))
1193         (require 'bytecomp)
1194         (defalias 'gnus-byte-compile
1195           (lambda (form)
1196             (let ((byte-compile-warnings '(unresolved callargs redefine)))
1197               (byte-compile form))))
1198         (gnus-byte-compile form))
1199     form))
1200
1201 (defun gnus-remassoc (key alist)
1202   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1203 The modified LIST is returned.  If the first member
1204 of LIST has a car that is `equal' to KEY, there is no way to remove it
1205 by side effect; therefore, write `(setq foo (remassoc key foo))' to be
1206 sure of changing the value of `foo'."
1207   (when alist
1208     (if (equal key (caar alist))
1209         (cdr alist)
1210       (setcdr alist (gnus-remassoc key (cdr alist)))
1211       alist)))
1212
1213 (defun gnus-update-alist-soft (key value alist)
1214   (if value
1215       (cons (cons key value) (gnus-remassoc key alist))
1216     (gnus-remassoc key alist)))
1217
1218 (defun gnus-create-info-command (node)
1219   "Create a command that will go to info NODE."
1220   `(lambda ()
1221      (interactive)
1222      ,(concat "Enter the info system at node " node)
1223      (Info-goto-node ,node)
1224      (setq gnus-info-buffer (current-buffer))
1225      (gnus-configure-windows 'info)))
1226
1227 (defun gnus-not-ignore (&rest args)
1228   t)
1229
1230 (defvar gnus-directory-sep-char-regexp "/"
1231   "The regexp of directory separator character.
1232 If you find some problem with the directory separator character, try
1233 \"[/\\\\\]\" for some systems.")
1234
1235 (defun gnus-url-unhex (x)
1236   (if (> x ?9)
1237       (if (>= x ?a)
1238           (+ 10 (- x ?a))
1239         (+ 10 (- x ?A)))
1240     (- x ?0)))
1241
1242 ;; Fixme: Do it like QP.
1243 (defun gnus-url-unhex-string (str &optional allow-newlines)
1244   "Remove %XX, embedded spaces, etc in a url.
1245 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1246 decoding of carriage returns and line feeds in the string, which is normally
1247 forbidden in URL encoding."
1248   (let ((tmp "")
1249         (case-fold-search t))
1250     (while (string-match "%[0-9a-f][0-9a-f]" str)
1251       (let* ((start (match-beginning 0))
1252              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1253              (code (+ (* 16 ch1)
1254                       (gnus-url-unhex (elt str (+ start 2))))))
1255         (setq tmp (concat
1256                    tmp (substring str 0 start)
1257                    (cond
1258                     (allow-newlines
1259                      (char-to-string code))
1260                     ((or (= code ?\n) (= code ?\r))
1261                      " ")
1262                     (t (char-to-string code))))
1263               str (substring str (match-end 0)))))
1264     (setq tmp (concat tmp str))
1265     tmp))
1266
1267 (defun gnus-make-predicate (spec)
1268   "Transform SPEC into a function that can be called.
1269 SPEC is a predicate specifier that contains stuff like `or', `and',
1270 `not', lists and functions.  The functions all take one parameter."
1271   `(lambda (elem) ,(gnus-make-predicate-1 spec)))
1272
1273 (defun gnus-make-predicate-1 (spec)
1274   (cond
1275    ((symbolp spec)
1276     `(,spec elem))
1277    ((listp spec)
1278     (if (memq (car spec) '(or and not))
1279         `(,(car spec) ,@(mapcar 'gnus-make-predicate-1 (cdr spec)))
1280       (error "Invalid predicate specifier: %s" spec)))))
1281
1282 (defun gnus-completing-read (prompt table &optional predicate require-match
1283                                     history)
1284   (when (and history
1285              (not (boundp history)))
1286     (set history nil))
1287   (completing-read
1288    (if (symbol-value history)
1289        (concat prompt " (" (car (symbol-value history)) "): ")
1290      (concat prompt ": "))
1291    table
1292    predicate
1293    require-match
1294    nil
1295    history
1296    (car (symbol-value history))))
1297
1298 (defun gnus-graphic-display-p ()
1299   (or (and (fboundp 'display-graphic-p)
1300            (display-graphic-p))
1301       ;;;!!!This is bogus.  Fixme!
1302       (and (featurep 'xemacs)
1303            t)))
1304
1305 (put 'gnus-parse-without-error 'lisp-indent-function 0)
1306 (put 'gnus-parse-without-error 'edebug-form-spec '(body))
1307
1308 (defmacro gnus-parse-without-error (&rest body)
1309   "Allow continuing onto the next line even if an error occurs."
1310   `(while (not (eobp))
1311      (condition-case ()
1312          (progn
1313            ,@body
1314            (goto-char (point-max)))
1315        (error
1316         (gnus-error 4 "Invalid data on line %d"
1317                     (count-lines (point-min) (point)))
1318         (forward-line 1)))))
1319
1320 (defun gnus-cache-file-contents (file variable function)
1321   "Cache the contents of FILE in VARIABLE.  The contents come from FUNCTION."
1322   (let ((time (nth 5 (file-attributes file)))
1323         contents value)
1324     (if (or (null (setq value (symbol-value variable)))
1325             (not (equal (car value) file))
1326             (not (equal (nth 1 value) time)))
1327         (progn
1328           (setq contents (funcall function file))
1329           (set variable (list file time contents))
1330           contents)
1331       (nth 2 value))))
1332
1333 (defun gnus-multiple-choice (prompt choice &optional idx)
1334   "Ask user a multiple choice question.
1335 CHOICE is a list of the choice char and help message at IDX."
1336   (let (tchar buf)
1337     (save-window-excursion
1338       (save-excursion
1339         (while (not tchar)
1340           (message "%s (%s): "
1341                    prompt
1342                    (concat
1343                     (mapconcat (lambda (s) (char-to-string (car s)))
1344                                choice ", ") ", ?"))
1345           (setq tchar (read-char))
1346           (when (not (assq tchar choice))
1347             (setq tchar nil)
1348             (setq buf (get-buffer-create "*Gnus Help*"))
1349             (pop-to-buffer buf)
1350             (fundamental-mode)          ; for Emacs 20.4+
1351             (buffer-disable-undo)
1352             (erase-buffer)
1353             (insert prompt ":\n\n")
1354             (let ((max -1)
1355                   (list choice)
1356                   (alist choice)
1357                   (idx (or idx 1))
1358                   (i 0)
1359                   n width pad format)
1360               ;; find the longest string to display
1361               (while list
1362                 (setq n (length (nth idx (car list))))
1363                 (unless (> max n)
1364                   (setq max n))
1365                 (setq list (cdr list)))
1366               (setq max (+ max 4))      ; %c, `:', SPACE, a SPACE at end
1367               (setq n (/ (1- (window-width)) max)) ; items per line
1368               (setq width (/ (1- (window-width)) n)) ; width of each item
1369               ;; insert `n' items, each in a field of width `width'
1370               (while alist
1371                 (if (< i n)
1372                     ()
1373                   (setq i 0)
1374                   (delete-char -1)              ; the `\n' takes a char
1375                   (insert "\n"))
1376                 (setq pad (- width 3))
1377                 (setq format (concat "%c: %-" (int-to-string pad) "s"))
1378                 (insert (format format (caar alist) (nth idx (car alist))))
1379                 (setq alist (cdr alist))
1380                 (setq i (1+ i))))))))
1381     (if (buffer-live-p buf)
1382         (kill-buffer buf))
1383     tchar))
1384
1385 (defun gnus-select-frame-set-input-focus (frame)
1386   "Select FRAME, raise it, and set input focus, if possible."
1387   (cond ((featurep 'xemacs)
1388          (raise-frame frame)
1389          (select-frame frame)
1390          (focus-frame frame))
1391         ;; The function `select-frame-set-input-focus' won't set
1392         ;; the input focus under Emacs 21.2 and X window system.
1393         ;;((fboundp 'select-frame-set-input-focus)
1394         ;; (defalias 'gnus-select-frame-set-input-focus
1395         ;;   'select-frame-set-input-focus)
1396         ;; (select-frame-set-input-focus frame))
1397         (t
1398          (raise-frame frame)
1399          (select-frame frame)
1400          (cond ((and (eq window-system 'x)
1401                      (fboundp 'x-focus-frame))
1402                 (x-focus-frame frame))
1403                ((eq window-system 'w32)
1404                 (w32-focus-frame frame)))
1405          (when focus-follows-mouse
1406            (set-mouse-position frame (1- (frame-width frame)) 0)))))
1407
1408 (defun gnus-frame-or-window-display-name (object)
1409   "Given a frame or window, return the associated display name.
1410 Return nil otherwise."
1411   (if (featurep 'xemacs)
1412       (device-connection (dfw-device object))
1413     (if (or (framep object)
1414             (and (windowp object)
1415                  (setq object (window-frame object))))
1416         (let ((display (frame-parameter object 'display)))
1417           (if (and (stringp display)
1418                    ;; Exclude invalid display names.
1419                    (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'"
1420                                  display))
1421               display)))))
1422
1423 ;; Fixme: This has only one use (in gnus-agent), which isn't worthwhile.
1424 (defmacro gnus-mapcar (function seq1 &rest seqs2_n)
1425   "Apply FUNCTION to each element of the sequences, and make a list of the results.
1426 If there are several sequences, FUNCTION is called with that many arguments,
1427 and mapping stops as soon as the shortest sequence runs out.  With just one
1428 sequence, this is like `mapcar'.  With several, it is like the Common Lisp
1429 `mapcar' function extended to arbitrary sequence types."
1430
1431   (if seqs2_n
1432       (let* ((seqs (cons seq1 seqs2_n))
1433              (cnt 0)
1434              (heads (mapcar (lambda (seq)
1435                               (make-symbol (concat "head"
1436                                                    (int-to-string
1437                                                     (setq cnt (1+ cnt))))))
1438                             seqs))
1439              (result (make-symbol "result"))
1440              (result-tail (make-symbol "result-tail")))
1441         `(let* ,(let* ((bindings (cons nil nil))
1442                        (heads heads))
1443                   (nconc bindings (list (list result '(cons nil nil))))
1444                   (nconc bindings (list (list result-tail result)))
1445                   (while heads
1446                     (nconc bindings (list (list (pop heads) (pop seqs)))))
1447                   (cdr bindings))
1448            (while (and ,@heads)
1449              (setcdr ,result-tail (cons (funcall ,function
1450                                                  ,@(mapcar (lambda (h) (list 'car h))
1451                                                            heads))
1452                                         nil))
1453              (setq ,result-tail (cdr ,result-tail)
1454                    ,@(apply 'nconc (mapcar (lambda (h) (list h (list 'cdr h))) heads))))
1455            (cdr ,result)))
1456     `(mapcar ,function ,seq1)))
1457
1458 (if (fboundp 'merge)
1459     (defalias 'gnus-merge 'merge)
1460   ;; Adapted from cl-seq.el
1461   (defun gnus-merge (type list1 list2 pred)
1462     "Destructively merge lists LIST1 and LIST2 to produce a new list.
1463 Argument TYPE is for compatibility and ignored.
1464 Ordering of the elements is preserved according to PRED, a `less-than'
1465 predicate on the elements."
1466     (let ((res nil))
1467       (while (and list1 list2)
1468         (if (funcall pred (car list2) (car list1))
1469             (push (pop list2) res)
1470           (push (pop list1) res)))
1471       (nconc (nreverse res) list1 list2))))
1472
1473 (eval-when-compile
1474   (defvar xemacs-codename))
1475
1476 (defun gnus-emacs-version ()
1477   "Stringified Emacs version."
1478   (let ((system-v
1479          (cond
1480           ((eq gnus-user-agent 'emacs-gnus-config)
1481            system-configuration)
1482           ((eq gnus-user-agent 'emacs-gnus-type)
1483            (symbol-name system-type))
1484           (t nil))))
1485     (cond
1486      ((eq gnus-user-agent 'gnus)
1487       nil)
1488      ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1489       (concat "Emacs/" (match-string 1 emacs-version)
1490               (if system-v
1491                   (concat " (" system-v ")")
1492                 "")))
1493      ((string-match
1494        "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
1495        emacs-version)
1496       (concat
1497        (match-string 1 emacs-version)
1498        (format "/%d.%d" emacs-major-version emacs-minor-version)
1499        (if (match-beginning 3)
1500            (match-string 3 emacs-version)
1501          "")
1502        (if (boundp 'xemacs-codename)
1503            (concat
1504             " (" xemacs-codename
1505             (if system-v
1506                 (concat ", " system-v ")")
1507               ")"))
1508          "")))
1509      (t emacs-version))))
1510
1511 (defun gnus-rename-file (old-path new-path &optional trim)
1512   "Rename OLD-PATH as NEW-PATH.  If TRIM, recursively delete
1513 empty directories from OLD-PATH."
1514   (when (file-exists-p old-path)
1515     (let* ((old-dir (file-name-directory old-path))
1516            (old-name (file-name-nondirectory old-path))
1517            (new-dir (file-name-directory new-path))
1518            (new-name (file-name-nondirectory new-path))
1519            temp)
1520       (gnus-make-directory new-dir)
1521       (rename-file old-path new-path t)
1522       (when trim
1523         (while (progn (setq temp (directory-files old-dir))
1524                       (while (member (car temp) '("." ".."))
1525                         (setq temp (cdr temp)))
1526                       (= (length temp) 0))
1527           (delete-directory old-dir)
1528           (setq old-dir (file-name-as-directory
1529                          (file-truename
1530                           (concat old-dir "..")))))))))
1531
1532 (defun gnus-set-file-modes (filename mode)
1533   "Wrapper for set-file-modes."
1534   (ignore-errors
1535     (set-file-modes filename mode)))
1536
1537 (provide 'gnus-util)
1538
1539 ;;; gnus-util.el ends here