git.chise.org Git - elisp/gnus.git-/blob - lisp/mail-source.el

   1 ;;; mail-source.el --- functions for fetching mail
   2 ;; Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news, mail
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)
  30   (require 'imap)
  31   (eval-when-compile (defvar display-time-mail-function)))
  32 (eval-and-compile
  33   (defvar pop3-leave-mail-on-server)
  34   (autoload 'pop3-movemail "pop3")
  35   (autoload 'pop3-get-message-count "pop3")
  36   (autoload 'nnheader-cancel-timer "nnheader")
  37   (autoload 'nnheader-run-at-time "nnheader"))
  38 (require 'format-spec)
  39 (require 'message) ;; for `message-directory'
  40
  41 (defgroup mail-source nil
  42   "The mail-fetching library."
  43   :version "21.1"
  44   :group 'gnus)
  45
  46 ;; Define these at compile time to avoid dragging in imap always.
  47 (defconst mail-source-imap-authenticators
  48   (eval-when-compile
  49     (mapcar (lambda (a)
  50               (list 'const (car a)))
  51             imap-authenticator-alist)))
  52 (defconst mail-source-imap-streams
  53   (eval-when-compile
  54     (mapcar (lambda (a)
  55               (list 'const (car a)))
  56             imap-stream-alist)))
  57
  58 (defcustom mail-sources nil
  59   "*Where the mail backends will look for incoming mail.
  60 This variable is a list of mail source specifiers.
  61 See Info node `(gnus)Mail Source Specifiers'."
  62   :group 'mail-source
  63   :type `(repeat
  64           (choice :format "%[Value Menu%] %v"
  65                   :value (file)
  66                   (cons :tag "Spool file"
  67                         (const :format "" file)
  68                         (checklist :tag "Options" :greedy t
  69                                    (group :inline t
  70                                           (const :format "" :value :path)
  71                                           file)))
  72                   (cons :tag "Several files in a directory"
  73                         (const :format "" directory)
  74                         (checklist :tag "Options" :greedy t
  75                                    (group :inline t
  76                                           (const :format "" :value :path)
  77                                           (directory :tag "Path"))
  78                                    (group :inline t
  79                                           (const :format "" :value :suffix)
  80                                           (string :tag "Suffix"))
  81                                    (group :inline t
  82                                           (const :format "" :value :predicate)
  83                                           (function :tag "Predicate"))
  84                                    (group :inline t
  85                                           (const :format "" :value :prescript)
  86                                           (string :tag "Prescript"))
  87                                    (group :inline t
  88                                           (const :format "" :value :postscript)
  89                                           (string :tag "Postscript"))
  90                                    (group :inline t
  91                                           (const :format "" :value :plugged)
  92                                           (boolean :tag "Plugged"))))
  93                   (cons :tag "POP3 server"
  94                         (const :format "" pop)
  95                         (checklist :tag "Options" :greedy t
  96                                    (group :inline t
  97                                           (const :format "" :value :server)
  98                                           (string :tag "Server"))
  99                                    (group :inline t
 100                                           (const :format "" :value :port)
 101                                           (choice :tag "Port"
 102                                                   :value "pop3"
 103                                                   (number :format "%v")
 104                                                   (string :format "%v")))
 105                                    (group :inline t
 106                                           (const :format "" :value :user)
 107                                           (string :tag "User"))
 108                                    (group :inline t
 109                                           (const :format "" :value :password)
 110                                           (string :tag "Password"))
 111                                    (group :inline t
 112                                           (const :format "" :value :program)
 113                                           (string :tag "Program"))
 114                                    (group :inline t
 115                                           (const :format "" :value :prescript)
 116                                           (string :tag "Prescript"))
 117                                    (group :inline t
 118                                           (const :format "" :value :postscript)
 119                                           (string :tag "Postscript"))
 120                                    (group :inline t
 121                                           (const :format "" :value :function)
 122                                           (function :tag "Function"))
 123                                    (group :inline t
 124                                           (const :format ""
 125                                                  :value :authentication)
 126                                           (choice :tag "Authentication"
 127                                                   :value apop
 128                                                   (const password)
 129                                                   (const apop)))
 130                                    (group :inline t
 131                                           (const :format "" :value :plugged)
 132                                           (boolean :tag "Plugged"))))
 133                   (cons :tag "Maildir (qmail, postfix...)"
 134                         (const :format "" maildir)
 135                         (checklist :tag "Options" :greedy t
 136                                    (group :inline t
 137                                           (const :format "" :value :path)
 138                                           (directory :tag "Path"))
 139                                    (group :inline t
 140                                           (const :format "" :value :plugged)
 141                                           (boolean :tag "Plugged"))))
 142                   (cons :tag "IMAP server"
 143                         (const :format "" imap)
 144                         (checklist :tag "Options" :greedy t
 145                                    (group :inline t
 146                                           (const :format "" :value :server)
 147                                           (string :tag "Server"))
 148                                    (group :inline t
 149                                           (const :format "" :value :port)
 150                                           (choice :tag "Port"
 151                                                   :value 143
 152                                                   number string))
 153                                    (group :inline t
 154                                           (const :format "" :value :user)
 155                                           (string :tag "User"))
 156                                    (group :inline t
 157                                           (const :format "" :value :password)
 158                                           (string :tag "Password"))
 159                                    (group :inline t
 160                                           (const :format "" :value :stream)
 161                                           (choice :tag "Stream"
 162                                                   :value network
 163                                                   ,@mail-source-imap-streams))
 164                                    (group :inline t
 165                                           (const :format "" :value :program)
 166                                           (string :tag "Program"))
 167                                    (group :inline t
 168                                           (const :format ""
 169                                                  :value :authenticator)
 170                                           (choice :tag "Authenticator"
 171                                                   :value login
 172                                                   ,@mail-source-imap-authenticators))
 173                                    (group :inline t
 174                                           (const :format "" :value :mailbox)
 175                                           (string :tag "Mailbox"
 176                                                   :value "INBOX"))
 177                                    (group :inline t
 178                                           (const :format "" :value :predicate)
 179                                           (string :tag "Predicate"
 180                                                   :value "UNSEEN UNDELETED"))
 181                                    (group :inline t
 182                                           (const :format "" :value :fetchflag)
 183                                           (string :tag "Fetchflag"
 184                                                   :value  "\\Deleted"))
 185                                    (group :inline t
 186                                           (const :format ""
 187                                                  :value :dontexpunge)
 188                                           (boolean :tag "Dontexpunge"))
 189                                    (group :inline t
 190                                           (const :format "" :value :plugged)
 191                                           (boolean :tag "Plugged"))))
 192                   (cons :tag "Webmail server"
 193                         (const :format "" webmail)
 194                         (checklist :tag "Options" :greedy t
 195                                    (group :inline t
 196                                           (const :format "" :value :subtype)
 197                                           ;; Should be generated from
 198                                           ;; `webmail-type-definition', but we
 199                                           ;; can't require webmail without W3.
 200                                           (choice :tag "Subtype"
 201                                                   :value hotmail
 202                                                   (const hotmail)
 203                                                   (const yahoo)
 204                                                   (const netaddress)
 205                                                   (const netscape)
 206                                                   (const my-deja)))
 207                                    (group :inline t
 208                                           (const :format "" :value :user)
 209                                           (string :tag "User"))
 210                                    (group :inline t
 211                                           (const :format "" :value :password)
 212                                           (string :tag "Password"))
 213                                    (group :inline t
 214                                           (const :format ""
 215                                                  :value :dontexpunge)
 216                                           (boolean :tag "Dontexpunge"))
 217                                    (group :inline t
 218                                           (const :format "" :value :plugged)
 219                                           (boolean :tag "Plugged")))))))
 220
 221 (defcustom mail-source-primary-source nil
 222   "*Primary source for incoming mail.
 223 If non-nil, this maildrop will be checked periodically for new mail."
 224   :group 'mail-source
 225   :type 'sexp)
 226
 227 (defcustom mail-source-flash t
 228   "*If non-nil, flash periodically when mail is available."
 229   :group 'mail-source
 230   :type 'boolean)
 231
 232 (defcustom mail-source-crash-box "~/.emacs-mail-crash-box"
 233   "File where mail will be stored while processing it."
 234   :group 'mail-source
 235   :type 'file)
 236
 237 (defcustom mail-source-directory message-directory
 238   "Directory where files (if any) will be stored."
 239   :group 'mail-source
 240   :type 'directory)
 241
 242 (defcustom mail-source-default-file-modes 384
 243   "Set the mode bits of all new mail files to this integer."
 244   :group 'mail-source
 245   :type 'integer)
 246
 247 (defcustom mail-source-delete-incoming nil
 248   "*If non-nil, delete incoming files after handling."
 249   :group 'mail-source
 250   :type 'boolean)
 251
 252 (defcustom mail-source-incoming-file-prefix "Incoming"
 253   "Prefix for file name for storing incoming mail"
 254   :group 'mail-source
 255   :type 'string)
 256
 257 (defcustom mail-source-report-new-mail-interval 5
 258   "Interval in minutes between checks for new mail."
 259   :group 'mail-source
 260   :type 'number)
 261
 262 (defcustom mail-source-idle-time-delay 5
 263   "Number of idle seconds to wait before checking for new mail."
 264   :group 'mail-source
 265   :type 'number)
 266
 267 (defcustom mail-source-movemail-program nil
 268   "If non-nil, name of program for fetching new mail."
 269   :group 'mail-source
 270   :type '(choice (const nil) string))
 271
 272 ;;; Internal variables.
 273
 274 (defvar mail-source-string ""
 275   "A dynamically bound string that says what the current mail source is.")
 276
 277 (defvar mail-source-new-mail-available nil
 278   "Flag indicating when new mail is available.")
 279
 280 (eval-and-compile
 281   (defvar mail-source-common-keyword-map
 282     '((:plugged))
 283     "Mapping from keywords to default values.
 284 Common keywords should be listed here.")
 285
 286   (defvar mail-source-keyword-map
 287     '((file
 288        (:prescript)
 289        (:prescript-delay)
 290        (:postscript)
 291        (:path (or (getenv "MAIL")
 292                   (expand-file-name (user-login-name) rmail-spool-directory))))
 293       (directory
 294        (:prescript)
 295        (:prescript-delay)
 296        (:postscript)
 297        (:path)
 298        (:suffix ".spool")
 299        (:predicate identity))
 300       (pop
 301        (:prescript)
 302        (:prescript-delay)
 303        (:postscript)
 304        (:server (getenv "MAILHOST"))
 305        (:port 110)
 306        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 307        (:program)
 308        (:function)
 309        (:password)
 310        (:connection)
 311        (:authentication password)
 312        (:leave))
 313       (maildir
 314        (:path (or (getenv "MAILDIR") "~/Maildir/"))
 315        (:subdirs ("new" "cur"))
 316        (:function))
 317       (imap
 318        (:server (getenv "MAILHOST"))
 319        (:port)
 320        (:stream)
 321        (:program)
 322        (:authentication)
 323        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 324        (:password)
 325        (:mailbox "INBOX")
 326        (:predicate "UNSEEN UNDELETED")
 327        (:fetchflag "\\Deleted")
 328        (:dontexpunge))
 329       (webmail
 330        (:subtype hotmail)
 331        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 332        (:password)
 333        (:dontexpunge)
 334        (:authentication password)))
 335     "Mapping from keywords to default values.
 336 All keywords that can be used must be listed here."))
 337
 338 (defvar mail-source-fetcher-alist
 339   '((file mail-source-fetch-file)
 340     (directory mail-source-fetch-directory)
 341     (pop mail-source-fetch-pop)
 342     (maildir mail-source-fetch-maildir)
 343     (imap mail-source-fetch-imap)
 344     (webmail mail-source-fetch-webmail))
 345   "A mapping from source type to fetcher function.")
 346
 347 (defvar mail-source-password-cache nil)
 348
 349 (defvar mail-source-plugged t)
 350
 351 ;;; Functions
 352
 353 (eval-and-compile
 354   (defun mail-source-strip-keyword (keyword)
 355     "Strip the leading colon off the KEYWORD."
 356     (intern (substring (symbol-name keyword) 1))))
 357
 358 (eval-and-compile
 359   (defun mail-source-bind-1 (type)
 360     (let* ((defaults (cdr (assq type mail-source-keyword-map)))
 361            default bind)
 362       (while (setq default (pop defaults))
 363         (push (list (mail-source-strip-keyword (car default))
 364                     nil)
 365               bind))
 366       bind)))
 367
 368 (defmacro mail-source-bind (type-source &rest body)
 369   "Return a `let' form that binds all variables in source TYPE.
 370 TYPE-SOURCE is a list where the first element is the TYPE, and
 371 the second variable is the SOURCE.
 372 At run time, the mail source specifier SOURCE will be inspected,
 373 and the variables will be set according to it.  Variables not
 374 specified will be given default values.
 375
 376 After this is done, BODY will be executed in the scope
 377 of the `let' form.
 378
 379 The variables bound and their default values are described by
 380 the `mail-source-keyword-map' variable."
 381   `(let ,(mail-source-bind-1 (car type-source))
 382      (mail-source-set-1 ,(cadr type-source))
 383      ,@body))
 384
 385 (put 'mail-source-bind 'lisp-indent-function 1)
 386 (put 'mail-source-bind 'edebug-form-spec '(sexp body))
 387
 388 (defun mail-source-set-1 (source)
 389   (let* ((type (pop source))
 390          (defaults (cdr (assq type mail-source-keyword-map)))
 391          default value keyword)
 392     (while (setq default (pop defaults))
 393       (set (mail-source-strip-keyword (setq keyword (car default)))
 394            (if (setq value (plist-get source keyword))
 395                (mail-source-value value)
 396              (mail-source-value (cadr default)))))))
 397
 398 (eval-and-compile
 399   (defun mail-source-bind-common-1 ()
 400     (let* ((defaults mail-source-common-keyword-map)
 401            default bind)
 402       (while (setq default (pop defaults))
 403         (push (list (mail-source-strip-keyword (car default))
 404                     nil)
 405               bind))
 406       bind)))
 407
 408 (defun mail-source-set-common-1 (source)
 409   (let* ((type (pop source))
 410          (defaults mail-source-common-keyword-map)
 411          (defaults-1 (cdr (assq type mail-source-keyword-map)))
 412          default value keyword)
 413     (while (setq default (pop defaults))
 414       (set (mail-source-strip-keyword (setq keyword (car default)))
 415            (if (setq value (plist-get source keyword))
 416                (mail-source-value value)
 417              (if (setq value (assq  keyword defaults-1))
 418                  (mail-source-value (cadr value))
 419                (mail-source-value (cadr default))))))))
 420
 421 (defmacro mail-source-bind-common (source &rest body)
 422   "Return a `let' form that binds all common variables.
 423 See `mail-source-bind'."
 424   `(let ,(mail-source-bind-common-1)
 425      (mail-source-set-common-1 source)
 426      ,@body))
 427
 428 (put 'mail-source-bind-common 'lisp-indent-function 1)
 429 (put 'mail-source-bind-common 'edebug-form-spec '(sexp body))
 430
 431 (defun mail-source-value (value)
 432   "Return the value of VALUE."
 433   (cond
 434    ;; String
 435    ((stringp value)
 436     value)
 437    ;; Function
 438    ((and (listp value)
 439          (functionp (car value)))
 440     (eval value))
 441    ;; Just return the value.
 442    (t
 443     value)))
 444
 445 (defun mail-source-fetch (source callback)
 446   "Fetch mail from SOURCE and call CALLBACK zero or more times.
 447 CALLBACK will be called with the name of the file where (some of)
 448 the mail from SOURCE is put.
 449 Return the number of files that were found."
 450   (mail-source-bind-common source
 451     (if (or mail-source-plugged plugged)
 452         (save-excursion
 453           (let ((function (cadr (assq (car source) mail-source-fetcher-alist)))
 454                 (found 0))
 455             (unless function
 456               (error "%S is an invalid mail source specification" source))
 457             ;; If there's anything in the crash box, we do it first.
 458             (when (file-exists-p mail-source-crash-box)
 459               (message "Processing mail from %s..." mail-source-crash-box)
 460               (setq found (mail-source-callback
 461                            callback mail-source-crash-box)))
 462             (+ found
 463                (if (or debug-on-quit debug-on-error)
 464                    (funcall function source callback)
 465                  (condition-case err
 466                      (funcall function source callback)
 467                    (error
 468                     (unless (yes-or-no-p
 469                              (format "Mail source %s error (%s).  Continue? "
 470                                      (if (memq ':password source)
 471                                          (let ((s (copy-sequence source)))
 472                                            (setcar (cdr (memq ':password s))
 473                                                    "********")
 474                                            s)
 475                                        source)
 476                                      (cadr err)))
 477                       (error "Cannot get new mail"))
 478                     0)))))))))
 479
 480 (eval-and-compile
 481   (if (fboundp 'make-temp-file)
 482       (defalias 'mail-source-make-complex-temp-name 'make-temp-file)
 483     (defun mail-source-make-complex-temp-name (prefix)
 484       (let ((newname (make-temp-name prefix))
 485             (newprefix prefix))
 486         (while (file-exists-p newname)
 487           (setq newprefix (concat newprefix "x"))
 488           (setq newname (make-temp-name newprefix)))
 489         newname))))
 490
 491 (defun mail-source-callback (callback info)
 492   "Call CALLBACK on the mail file, and then remove the mail file.
 493 Pass INFO on to CALLBACK."
 494   (if (or (not (file-exists-p mail-source-crash-box))
 495           (zerop (nth 7 (file-attributes mail-source-crash-box))))
 496       (progn
 497         (when (file-exists-p mail-source-crash-box)
 498           (delete-file mail-source-crash-box))
 499         0)
 500     (prog1
 501         (funcall callback mail-source-crash-box info)
 502       (when (file-exists-p mail-source-crash-box)
 503         ;; Delete or move the incoming mail out of the way.
 504         (if mail-source-delete-incoming
 505             (delete-file mail-source-crash-box)
 506           (let ((incoming
 507                  (mail-source-make-complex-temp-name
 508                   (expand-file-name
 509                    mail-source-incoming-file-prefix
 510                    mail-source-directory))))
 511             (unless (file-exists-p (file-name-directory incoming))
 512               (make-directory (file-name-directory incoming) t))
 513             (rename-file mail-source-crash-box incoming t)))))))
 514
 515 (defun mail-source-movemail (from to)
 516   "Move FROM to TO using movemail."
 517   (if (not (file-writable-p to))
 518       (error "Can't write to crash box %s.  Not moving mail" to)
 519     (let ((to (file-truename (expand-file-name to)))
 520           errors result)
 521       (setq to (file-truename to)
 522             from (file-truename from))
 523       ;; Set TO if have not already done so, and rename or copy
 524       ;; the file FROM to TO if and as appropriate.
 525       (cond
 526        ((file-exists-p to)
 527         ;; The crash box exists already.
 528         t)
 529        ((not (file-exists-p from))
 530         ;; There is no inbox.
 531         (setq to nil))
 532        ((zerop (nth 7 (file-attributes from)))
 533         ;; Empty file.
 534         (setq to nil))
 535        (t
 536         ;; If getting from mail spool directory, use movemail to move
 537         ;; rather than just renaming, so as to interlock with the
 538         ;; mailer.
 539         (unwind-protect
 540             (save-excursion
 541               (setq errors (generate-new-buffer " *mail source loss*"))
 542               (let ((default-directory "/"))
 543                 (setq result
 544                       (apply
 545                        'call-process
 546                        (append
 547                         (list
 548                          (or mail-source-movemail-program
 549                              (expand-file-name "movemail" exec-directory))
 550                          nil errors nil from to)))))
 551               (when (file-exists-p to)
 552                 (set-file-modes to mail-source-default-file-modes))
 553               (if (and (or (not (buffer-modified-p errors))
 554                            (zerop (buffer-size errors)))
 555                        (zerop result))
 556                   ;; No output => movemail won.
 557                   t
 558                 (set-buffer errors)
 559                 ;; There may be a warning about older revisions.  We
 560                 ;; ignore that.
 561                 (goto-char (point-min))
 562                 (if (search-forward "older revision" nil t)
 563                     t
 564                   ;; Probably a real error.
 565                   (subst-char-in-region (point-min) (point-max) ?\n ?\  )
 566                   (goto-char (point-max))
 567                   (skip-chars-backward " \t")
 568                   (delete-region (point) (point-max))
 569                   (goto-char (point-min))
 570                   (when (looking-at "movemail: ")
 571                     (delete-region (point-min) (match-end 0)))
 572                   ;; Result may be a signal description string.
 573                   (unless (yes-or-no-p
 574                            (format "movemail: %s (%s return).  Continue? "
 575                                    (buffer-string) result))
 576                     (error "%s" (buffer-string)))
 577                   (setq to nil)))))))
 578       (when (and errors
 579                  (buffer-name errors))
 580         (kill-buffer errors))
 581       ;; Return whether we moved successfully or not.
 582       to)))
 583
 584 (defun mail-source-movemail-and-remove (from to)
 585   "Move FROM to TO using movemail, then remove FROM if empty."
 586   (or (not (mail-source-movemail from to))
 587       (not (zerop (nth 7 (file-attributes from))))
 588       (delete-file from)))
 589
 590 (defvar mail-source-read-passwd nil)
 591 (defun mail-source-read-passwd (prompt &rest args)
 592   "Read a password using PROMPT.
 593 If ARGS, PROMPT is used as an argument to `format'."
 594   (let ((prompt
 595          (if args
 596              (apply 'format prompt args)
 597            prompt)))
 598     (unless mail-source-read-passwd
 599       (if (or (fboundp 'read-passwd) (load "passwd" t))
 600           (setq mail-source-read-passwd 'read-passwd)
 601         (unless (fboundp 'ange-ftp-read-passwd)
 602           (autoload 'ange-ftp-read-passwd "ange-ftp"))
 603         (setq mail-source-read-passwd 'ange-ftp-read-passwd)))
 604     (funcall mail-source-read-passwd prompt)))
 605
 606 (defun mail-source-fetch-with-program (program)
 607   (zerop (call-process shell-file-name nil nil nil
 608                        shell-command-switch program)))
 609
 610 (defun mail-source-run-script (script spec &optional delay)
 611   (when script
 612     (if (and (symbolp script) (fboundp script))
 613         (funcall script)
 614       (mail-source-call-script
 615        (format-spec script spec))))
 616   (when delay
 617     (sleep-for delay)))
 618
 619 (defun mail-source-call-script (script)
 620   (let ((background nil))
 621     (when (string-match "& *$" script)
 622       (setq script (substring script 0 (match-beginning 0))
 623             background 0))
 624     (call-process shell-file-name nil background nil
 625                   shell-command-switch script)))
 626
 627 ;;;
 628 ;;; Different fetchers
 629 ;;;
 630
 631 (defun mail-source-fetch-file (source callback)
 632   "Fetcher for single-file sources."
 633   (mail-source-bind (file source)
 634     (mail-source-run-script
 635      prescript (format-spec-make ?t mail-source-crash-box)
 636      prescript-delay)
 637     (let ((mail-source-string (format "file:%s" path)))
 638       (if (mail-source-movemail path mail-source-crash-box)
 639           (prog1
 640               (mail-source-callback callback path)
 641             (mail-source-run-script
 642              postscript (format-spec-make ?t mail-source-crash-box)))
 643         0))))
 644
 645 (defun mail-source-fetch-directory (source callback)
 646   "Fetcher for directory sources."
 647   (mail-source-bind (directory source)
 648     (mail-source-run-script
 649      prescript (format-spec-make ?t path)
 650      prescript-delay)
 651     (let ((found 0)
 652           (mail-source-string (format "directory:%s" path)))
 653       (dolist (file (directory-files
 654                      path t (concat (regexp-quote suffix) "$")))
 655         (when (and (file-regular-p file)
 656                    (funcall predicate file)
 657                    (mail-source-movemail file mail-source-crash-box))
 658           (incf found (mail-source-callback callback file))))
 659       (mail-source-run-script
 660        postscript (format-spec-make ?t path))
 661       found)))
 662
 663 (defun mail-source-fetch-pop (source callback)
 664   "Fetcher for single-file sources."
 665   (mail-source-bind (pop source)
 666     (mail-source-run-script
 667      prescript
 668      (format-spec-make ?p password ?t mail-source-crash-box
 669                        ?s server ?P port ?u user)
 670      prescript-delay)
 671     (let ((from (format "%s:%s:%s" server user port))
 672           (mail-source-string (format "pop:%s@%s" user server))
 673           result)
 674       (when (eq authentication 'password)
 675         (setq password
 676               (or password
 677                   (cdr (assoc from mail-source-password-cache))
 678                   (mail-source-read-passwd
 679                    (format "Password for %s at %s: " user server)))))
 680       (when server
 681         (setenv "MAILHOST" server))
 682       (setq result
 683             (cond
 684              (program
 685               (mail-source-fetch-with-program
 686                (format-spec
 687                 program
 688                 (format-spec-make ?p password ?t mail-source-crash-box
 689                                   ?s server ?P port ?u user))))
 690              (function
 691               (funcall function mail-source-crash-box))
 692              ;; The default is to use pop3.el.
 693              (t
 694               (let ((pop3-password password)
 695                     (pop3-maildrop user)
 696                     (pop3-mailhost server)
 697                     (pop3-port port)
 698                     (pop3-authentication-scheme
 699                      (if (eq authentication 'apop) 'apop 'pass))
 700                     (pop3-connection-type connection)
 701                     (pop3-leave-mail-on-server
 702                      (or leave
 703                          (and (boundp 'pop3-leave-mail-on-server)
 704                               pop3-leave-mail-on-server))))
 705                 (if (or debug-on-quit debug-on-error)
 706                     (save-excursion (pop3-movemail mail-source-crash-box))
 707                   (condition-case err
 708                       (save-excursion (pop3-movemail mail-source-crash-box))
 709                     (error
 710                      ;; We nix out the password in case the error
 711                      ;; was because of a wrong password being given.
 712                      (setq mail-source-password-cache
 713                            (delq (assoc from mail-source-password-cache)
 714                                  mail-source-password-cache))
 715                      (signal (car err) (cdr err)))))))))
 716       (if result
 717           (progn
 718             (when (eq authentication 'password)
 719               (unless (assoc from mail-source-password-cache)
 720                 (push (cons from password) mail-source-password-cache)))
 721             (prog1
 722                 (mail-source-callback callback server)
 723               ;; Update display-time's mail flag, if relevant.
 724               (if (equal source mail-source-primary-source)
 725                   (setq mail-source-new-mail-available nil))
 726               (mail-source-run-script
 727                postscript
 728                (format-spec-make ?p password ?t mail-source-crash-box
 729                                  ?s server ?P port ?u user))))
 730         ;; We nix out the password in case the error
 731         ;; was because of a wrong password being given.
 732         (setq mail-source-password-cache
 733               (delq (assoc from mail-source-password-cache)
 734                     mail-source-password-cache))
 735         0))))
 736
 737 (defun mail-source-check-pop (source)
 738   "Check whether there is new mail."
 739   (mail-source-bind (pop source)
 740     (let ((from (format "%s:%s:%s" server user port))
 741           (mail-source-string (format "pop:%s@%s" user server))
 742           result)
 743       (when (eq authentication 'password)
 744         (setq password
 745               (or password
 746                   (cdr (assoc from mail-source-password-cache))
 747                   (mail-source-read-passwd
 748                    (format "Password for %s at %s: " user server))))
 749         (unless (assoc from mail-source-password-cache)
 750           (push (cons from password) mail-source-password-cache)))
 751       (when server
 752         (setenv "MAILHOST" server))
 753       (setq result
 754             (cond
 755              ;; No easy way to check whether mail is waiting for these.
 756              (program)
 757              (function)
 758              ;; The default is to use pop3.el.
 759              (t
 760               (let ((pop3-password password)
 761                     (pop3-maildrop user)
 762                     (pop3-mailhost server)
 763                     (pop3-port port)
 764                     (pop3-authentication-scheme
 765                      (if (eq authentication 'apop) 'apop 'pass)))
 766                 (if (or debug-on-quit debug-on-error)
 767                     (save-excursion (pop3-get-message-count))
 768                   (condition-case err
 769                       (save-excursion (pop3-get-message-count))
 770                     (error
 771                      ;; We nix out the password in case the error
 772                      ;; was because of a wrong password being given.
 773                      (setq mail-source-password-cache
 774                            (delq (assoc from mail-source-password-cache)
 775                                  mail-source-password-cache))
 776                      (signal (car err) (cdr err)))))))))
 777       (if result
 778           ;; Inform display-time that we have new mail.
 779           (setq mail-source-new-mail-available (> result 0))
 780         ;; We nix out the password in case the error
 781         ;; was because of a wrong password being given.
 782         (setq mail-source-password-cache
 783               (delq (assoc from mail-source-password-cache)
 784                     mail-source-password-cache)))
 785       result)))
 786
 787 (defun mail-source-touch-pop ()
 788   "Open and close a POP connection shortly.
 789 POP server should be defined in `mail-source-primary-source' (which is
 790 preferred) or `mail-sources'.  You may use it for the POP-before-SMTP
 791 authentication.  To do that, you need to set the option
 792 `message-send-mail-function' to `message-send-mail-with-smtp' or
 793 `message-smtpmail-send-it' and put the following line in .gnus file:
 794
 795 \(add-hook 'message-send-mail-hook 'mail-source-touch-pop)
 796 "
 797   (let ((sources (if mail-source-primary-source
 798                      (list mail-source-primary-source)
 799                    mail-sources)))
 800     (while sources
 801       (if (eq 'pop (car (car sources)))
 802           (mail-source-check-pop (car sources)))
 803       (setq sources (cdr sources)))))
 804
 805 (defun mail-source-new-mail-p ()
 806   "Handler for `display-time' to indicate when new mail is available."
 807   ;; Flash (ie. ring the visible bell) if mail is available.
 808   (if (and mail-source-flash mail-source-new-mail-available)
 809       (let ((visible-bell t))
 810         (ding)))
 811   ;; Only report flag setting; flag is updated on a different schedule.
 812   mail-source-new-mail-available)
 813
 814
 815 (defvar mail-source-report-new-mail nil)
 816 (defvar mail-source-report-new-mail-timer nil)
 817 (defvar mail-source-report-new-mail-idle-timer nil)
 818
 819 (eval-when-compile
 820   (if (featurep 'xemacs)
 821       (require 'itimer)
 822     (require 'timer)))
 823
 824 (defun mail-source-start-idle-timer ()
 825   ;; Start our idle timer if necessary, so we delay the check until the
 826   ;; user isn't typing.
 827   (unless mail-source-report-new-mail-idle-timer
 828     (setq mail-source-report-new-mail-idle-timer
 829           (run-with-idle-timer
 830            mail-source-idle-time-delay
 831            nil
 832            (lambda ()
 833              (unwind-protect
 834                  (mail-source-check-pop mail-source-primary-source)
 835                (setq mail-source-report-new-mail-idle-timer nil)))))
 836     ;; Since idle timers created when Emacs is already in the idle
 837     ;; state don't get activated until Emacs _next_ becomes idle, we
 838     ;; need to force our timer to be considered active now.  We do
 839     ;; this by being naughty and poking the timer internals directly
 840     ;; (element 0 of the vector is nil if the timer is active).
 841     (aset mail-source-report-new-mail-idle-timer 0 nil)))
 842
 843 (defun mail-source-report-new-mail (arg)
 844   "Toggle whether to report when new mail is available.
 845 This only works when `display-time' is enabled."
 846   (interactive "P")
 847   (if (not mail-source-primary-source)
 848       (error "Need to set `mail-source-primary-source' to check for new mail"))
 849   (let ((on (if (null arg)
 850                 (not mail-source-report-new-mail)
 851               (> (prefix-numeric-value arg) 0))))
 852     (setq mail-source-report-new-mail on)
 853     (and mail-source-report-new-mail-timer
 854          (nnheader-cancel-timer mail-source-report-new-mail-timer))
 855     (and mail-source-report-new-mail-idle-timer
 856          (nnheader-cancel-timer mail-source-report-new-mail-idle-timer))
 857     (setq mail-source-report-new-mail-timer nil)
 858     (setq mail-source-report-new-mail-idle-timer nil)
 859     (if on
 860         (progn
 861           (require 'time)
 862           ;; display-time-mail-function is an Emacs 21 feature.
 863           (setq display-time-mail-function #'mail-source-new-mail-p)
 864           ;; Set up the main timer.
 865           (setq mail-source-report-new-mail-timer
 866                 (nnheader-run-at-time
 867                  (* 60 mail-source-report-new-mail-interval)
 868                  (* 60 mail-source-report-new-mail-interval)
 869                  #'mail-source-start-idle-timer))
 870           ;; When you get new mail, clear "Mail" from the mode line.
 871           (add-hook 'nnmail-post-get-new-mail-hook
 872                     'display-time-event-handler)
 873           (message "Mail check enabled"))
 874       (setq display-time-mail-function nil)
 875       (remove-hook 'nnmail-post-get-new-mail-hook
 876                    'display-time-event-handler)
 877       (message "Mail check disabled"))))
 878
 879 (defun mail-source-fetch-maildir (source callback)
 880   "Fetcher for maildir sources."
 881   (mail-source-bind (maildir source)
 882     (let ((found 0)
 883           mail-source-string)
 884       (unless (string-match "/$" path)
 885         (setq path (concat path "/")))
 886       (dolist (subdir subdirs)
 887         (when (file-directory-p (concat path subdir))
 888           (setq mail-source-string (format "maildir:%s%s" path subdir))
 889           (dolist (file (directory-files (concat path subdir) t))
 890             (when (and (not (file-directory-p file))
 891                        (not (if function
 892                                 (funcall function file mail-source-crash-box)
 893                               (let ((coding-system-for-write
 894                                      nnheader-text-coding-system)
 895                                     (coding-system-for-read
 896                                      nnheader-text-coding-system)
 897                                     (output-coding-system
 898                                      nnheader-text-coding-system)
 899                                     (input-coding-system
 900                                      nnheader-text-coding-system))
 901                                 (with-temp-file mail-source-crash-box
 902                                   (insert-file-contents file)
 903                                   (goto-char (point-min))
 904 ;;;                               ;; Unix mail format
 905 ;;;                               (unless (looking-at "\n*From ")
 906 ;;;                                 (insert "From maildir "
 907 ;;;                                         (current-time-string) "\n"))
 908 ;;;                               (while (re-search-forward "^From " nil t)
 909 ;;;                                 (replace-match ">From "))
 910 ;;;                               (goto-char (point-max))
 911 ;;;                               (insert "\n\n")
 912                                   ;; MMDF mail format
 913                                   (insert "\001\001\001\001\n"))
 914                                 (delete-file file)))))
 915               (incf found (mail-source-callback callback file))))))
 916       found)))
 917
 918 (eval-and-compile
 919   (autoload 'imap-open "imap")
 920   (autoload 'imap-authenticate "imap")
 921   (autoload 'imap-mailbox-select "imap")
 922   (autoload 'imap-mailbox-unselect "imap")
 923   (autoload 'imap-mailbox-close "imap")
 924   (autoload 'imap-search "imap")
 925   (autoload 'imap-fetch "imap")
 926   (autoload 'imap-close "imap")
 927   (autoload 'imap-error-text "imap")
 928   (autoload 'imap-message-flags-add "imap")
 929   (autoload 'imap-list-to-message-set "imap")
 930   (autoload 'imap-range-to-message-set "imap"))
 931
 932 (defvar mail-source-imap-file-coding-system 'binary
 933   "Coding system for the crashbox made by `mail-source-fetch-imap'.")
 934
 935 (defun mail-source-fetch-imap (source callback)
 936   "Fetcher for imap sources."
 937   (mail-source-bind (imap source)
 938     (let ((from (format "%s:%s:%s" server user port))
 939           (found 0)
 940           (buf (get-buffer-create
 941                 (format " *imap source %s:%s:%s *" server user mailbox)))
 942           (mail-source-string (format "imap:%s:%s" server mailbox))
 943           (imap-shell-program (or (list program) imap-shell-program))
 944           remove)
 945       (if (and (imap-open server port stream authentication buf)
 946                (imap-authenticate
 947                 user (or (cdr (assoc from mail-source-password-cache))
 948                          password) buf)
 949                (imap-mailbox-select mailbox nil buf))
 950           (let ((coding-system-for-write mail-source-imap-file-coding-system)
 951                 (output-coding-system mail-source-imap-file-coding-system)
 952                 str)
 953             (with-temp-file mail-source-crash-box
 954               ;; Avoid converting 8-bit chars from inserted strings to
 955               ;; multibyte.
 956               (set-buffer-multibyte nil)
 957               ;; remember password
 958               (with-current-buffer buf
 959                 (when (or imap-password
 960                           (assoc from mail-source-password-cache))
 961                   (push (cons from imap-password) mail-source-password-cache)))
 962               ;; if predicate is nil, use all uids
 963               (dolist (uid (imap-search (or predicate "1:*") buf))
 964                 (when (setq str
 965                             (if (imap-capability 'IMAP4rev1 buf)
 966                                 (caddar (imap-fetch uid "BODY.PEEK[]"
 967                                                     'BODYDETAIL nil buf))
 968                               (imap-fetch uid "RFC822.PEEK" 'RFC822 nil buf)))
 969                   (push uid remove)
 970                   (insert "From imap " (current-time-string) "\n")
 971                   (save-excursion
 972                     (insert str "\n\n"))
 973                   (while (re-search-forward "^From " nil t)
 974                     (replace-match ">From "))
 975                   (goto-char (point-max))))
 976               (nnheader-ms-strip-cr))
 977             (incf found (mail-source-callback callback server))
 978             (when (and remove fetchflag)
 979               (imap-message-flags-add
 980                (imap-range-to-message-set (gnus-compress-sequence remove))
 981                fetchflag nil buf))
 982             (if dontexpunge
 983                 (imap-mailbox-unselect buf)
 984               (imap-mailbox-close nil buf))
 985             (imap-close buf))
 986         (imap-close buf)
 987         ;; We nix out the password in case the error
 988         ;; was because of a wrong password being given.
 989         (setq mail-source-password-cache
 990               (delq (assoc from mail-source-password-cache)
 991                     mail-source-password-cache))
 992         (error (imap-error-text buf)))
 993       (kill-buffer buf)
 994       found)))
 995
 996 (eval-and-compile
 997   (autoload 'webmail-fetch "webmail"))
 998
 999 (defun mail-source-fetch-webmail (source callback)
1000   "Fetch for webmail source."
1001   (mail-source-bind (webmail source)
1002     (let ((mail-source-string (format "webmail:%s:%s" subtype user))
1003           (webmail-newmail-only dontexpunge)
1004           (webmail-move-to-trash-can (not dontexpunge)))
1005       (when (eq authentication 'password)
1006         (setq password
1007               (or password
1008                   (cdr (assoc (format "webmail:%s:%s" subtype user)
1009                               mail-source-password-cache))
1010                   (mail-source-read-passwd
1011                    (format "Password for %s at %s: " user subtype))))
1012         (when (and password
1013                    (not (assoc (format "webmail:%s:%s" subtype user)
1014                                mail-source-password-cache)))
1015           (push (cons (format "webmail:%s:%s" subtype user) password)
1016                 mail-source-password-cache)))
1017       (webmail-fetch mail-source-crash-box subtype user password)
1018       (mail-source-callback callback (symbol-name subtype)))))
1019
1020 (provide 'mail-source)
1021
1022 ;;; mail-source.el ends here