git.chise.org Git - elisp/gnus.git-/blob - lisp/mail-source.el

   1 ;;; mail-source.el --- functions for fetching mail
   2 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news, mail
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)
  30   (require 'imap)
  31   (eval-when-compile (defvar display-time-mail-function)))
  32 (eval-and-compile
  33   (autoload 'pop3-movemail "pop3")
  34   (autoload 'pop3-get-message-count "pop3")
  35   (autoload 'nnheader-cancel-timer "nnheader")
  36   (autoload 'nnheader-run-at-time "nnheader"))
  37 (require 'format-spec)
  38 (require 'mm-util)
  39 (require 'message) ;; for `message-directory'
  40
  41 (defgroup mail-source nil
  42   "The mail-fetching library."
  43   :version "21.1"
  44   :group 'gnus)
  45
  46 ;; Define these at compile time to avoid dragging in imap always.
  47 (defconst mail-source-imap-authenticators
  48   (eval-when-compile
  49     (mapcar (lambda (a)
  50               (list 'const (car a)))
  51      imap-authenticator-alist)))
  52 (defconst mail-source-imap-streams
  53   (eval-when-compile
  54     (mapcar (lambda (a)
  55               (list 'const (car a)))
  56      imap-stream-alist)))
  57
  58 (defcustom mail-sources nil
  59   "*Where the mail backends will look for incoming mail.
  60 This variable is a list of mail source specifiers.
  61 See Info node `(gnus)Mail Source Specifiers'."
  62   :group 'mail-source
  63   :link '(custom-manual "(gnus)Mail Source Specifiers")
  64   :type `(repeat
  65           (choice :format "%[Value Menu%] %v"
  66                   :value (file)
  67                   (cons :tag "Spool file"
  68                         (const :format "" file)
  69                         (checklist :tag "Options" :greedy t
  70                                    (group :inline t
  71                                           (const :format "" :value :path)
  72                                           file)))
  73                   (cons :tag "Several files in a directory"
  74                         (const :format "" directory)
  75                         (checklist :tag "Options" :greedy t
  76                                    (group :inline t
  77                                           (const :format "" :value :path)
  78                                           (directory :tag "Path"))
  79                                    (group :inline t
  80                                           (const :format "" :value :suffix)
  81                                           (string :tag "Suffix"))
  82                                    (group :inline t
  83                                           (const :format "" :value :predicate)
  84                                           (function :tag "Predicate"))
  85                                    (group :inline t
  86                                           (const :format "" :value :prescript)
  87                                           (choice :tag "Prescript"
  88                                                   :value nil
  89                                                   (string :format "%v")
  90                                                   (function :format "%v")))
  91                                    (group :inline t
  92                                           (const :format "" :value :postscript)
  93                                           (choice :tag "Postscript"
  94                                                   :value nil
  95                                                   (string :format "%v")
  96                                                   (function :format "%v")))
  97                                    (group :inline t
  98                                           (const :format "" :value :plugged)
  99                                           (boolean :tag "Plugged"))))
 100                   (cons :tag "POP3 server"
 101                         (const :format "" pop)
 102                         (checklist :tag "Options" :greedy t
 103                                    (group :inline t
 104                                           (const :format "" :value :server)
 105                                           (string :tag "Server"))
 106                                    (group :inline t
 107                                           (const :format "" :value :port)
 108                                           (choice :tag "Port"
 109                                                   :value "pop3"
 110                                                   (number :format "%v")
 111                                                   (string :format "%v")))
 112                                    (group :inline t
 113                                           (const :format "" :value :user)
 114                                           (string :tag "User"))
 115                                    (group :inline t
 116                                           (const :format "" :value :password)
 117                                           (string :tag "Password"))
 118                                    (group :inline t
 119                                           (const :format "" :value :program)
 120                                           (string :tag "Program"))
 121                                    (group :inline t
 122                                           (const :format "" :value :prescript)
 123                                           (choice :tag "Prescript"
 124                                                   :value nil
 125                                                   (string :format "%v")
 126                                                   (function :format "%v")))
 127                                    (group :inline t
 128                                           (const :format "" :value :postscript)
 129                                           (choice :tag "Postscript"
 130                                                   :value nil
 131                                                   (string :format "%v")
 132                                                   (function :format "%v")))
 133                                    (group :inline t
 134                                           (const :format "" :value :function)
 135                                           (function :tag "Function"))
 136                                    (group :inline t
 137                                           (const :format ""
 138                                                  :value :authentication)
 139                                           (choice :tag "Authentication"
 140                                                   :value apop
 141                                                   (const password)
 142                                                   (const apop)))
 143                                    (group :inline t
 144                                           (const :format "" :value :plugged)
 145                                           (boolean :tag "Plugged"))))
 146                   (cons :tag "Maildir (qmail, postfix...)"
 147                         (const :format "" maildir)
 148                         (checklist :tag "Options" :greedy t
 149                                    (group :inline t
 150                                           (const :format "" :value :path)
 151                                           (directory :tag "Path"))
 152                                    (group :inline t
 153                                           (const :format "" :value :plugged)
 154                                           (boolean :tag "Plugged"))))
 155                   (cons :tag "IMAP server"
 156                         (const :format "" imap)
 157                         (checklist :tag "Options" :greedy t
 158                                    (group :inline t
 159                                           (const :format "" :value :server)
 160                                           (string :tag "Server"))
 161                                    (group :inline t
 162                                           (const :format "" :value :port)
 163                                           (choice :tag "Port"
 164                                                   :value 143
 165                                                   number string))
 166                                    (group :inline t
 167                                           (const :format "" :value :user)
 168                                           (string :tag "User"))
 169                                    (group :inline t
 170                                           (const :format "" :value :password)
 171                                           (string :tag "Password"))
 172                                    (group :inline t
 173                                           (const :format "" :value :stream)
 174                                           (choice :tag "Stream"
 175                                                   :value network
 176                                                   ,@mail-source-imap-streams))
 177                                    (group :inline t
 178                                           (const :format "" :value :program)
 179                                           (string :tag "Program"))
 180                                    (group :inline t
 181                                           (const :format ""
 182                                                  :value :authenticator)
 183                                           (choice :tag "Authenticator"
 184                                                   :value login
 185                                                   ,@mail-source-imap-authenticators))
 186                                    (group :inline t
 187                                           (const :format "" :value :mailbox)
 188                                           (string :tag "Mailbox"
 189                                                   :value "INBOX"))
 190                                    (group :inline t
 191                                           (const :format "" :value :predicate)
 192                                           (string :tag "Predicate"
 193                                                   :value "UNSEEN UNDELETED"))
 194                                    (group :inline t
 195                                           (const :format "" :value :fetchflag)
 196                                           (string :tag "Fetchflag"
 197                                                   :value  "\\Deleted"))
 198                                    (group :inline t
 199                                           (const :format ""
 200                                                  :value :dontexpunge)
 201                                           (boolean :tag "Dontexpunge"))
 202                                    (group :inline t
 203                                           (const :format "" :value :plugged)
 204                                           (boolean :tag "Plugged"))))
 205                   (cons :tag "Webmail server"
 206                         (const :format "" webmail)
 207                         (checklist :tag "Options" :greedy t
 208                                    (group :inline t
 209                                          (const :format "" :value :subtype)
 210                                          ;; Should be generated from
 211                                          ;; `webmail-type-definition', but we
 212                                          ;; can't require webmail without W3.
 213                                          (choice :tag "Subtype"
 214                                                  :value hotmail
 215                                                  (const hotmail)
 216                                                  (const yahoo)
 217                                                  (const netaddress)
 218                                                  (const netscape)
 219                                                  (const my-deja)))
 220                                    (group :inline t
 221                                           (const :format "" :value :user)
 222                                           (string :tag "User"))
 223                                    (group :inline t
 224                                           (const :format "" :value :password)
 225                                           (string :tag "Password"))
 226                                    (group :inline t
 227                                           (const :format ""
 228                                                  :value :dontexpunge)
 229                                           (boolean :tag "Dontexpunge"))
 230                                    (group :inline t
 231                                           (const :format "" :value :plugged)
 232                                           (boolean :tag "Plugged")))))))
 233
 234 (defcustom mail-source-ignore-errors nil
 235   "*Ignore errors when querying mail sources.
 236 If nil, the user will be prompted when an error occurs.  If non-nil,
 237 the error will be ignored.")
 238
 239 (defcustom mail-source-primary-source nil
 240   "*Primary source for incoming mail.
 241 If non-nil, this maildrop will be checked periodically for new mail."
 242   :group 'mail-source
 243   :type 'sexp)
 244
 245 (defcustom mail-source-flash t
 246   "*If non-nil, flash periodically when mail is available."
 247   :group 'mail-source
 248   :type 'boolean)
 249
 250 (defcustom mail-source-crash-box "~/.emacs-mail-crash-box"
 251   "File where mail will be stored while processing it."
 252   :group 'mail-source
 253   :type 'file)
 254
 255 (defcustom mail-source-directory message-directory
 256   "Directory where files (if any) will be stored."
 257   :group 'mail-source
 258   :type 'directory)
 259
 260 (defcustom mail-source-default-file-modes 384
 261   "Set the mode bits of all new mail files to this integer."
 262   :group 'mail-source
 263   :type 'integer)
 264
 265 (defcustom mail-source-delete-incoming t
 266   "*If non-nil, delete incoming files after handling.
 267 If t, delete immediately, if nil, never delete.  If a positive number, delete
 268 files older than number of days."
 269   ;; Note: The removing happens in `mail-source-callback', i.e. no old
 270   ;; incoming files will be deleted, unless you receive new mail.
 271   ;;
 272   ;; You may also set this to `nil' and call `mail-source-delete-old-incoming'
 273   ;; from a hook or interactively.
 274   :group 'mail-source
 275   :type '(choice (const :tag "immediately" t)
 276                  (const :tag "never" nil)
 277                  (integer :tag "days")))
 278
 279 (defcustom mail-source-delete-old-incoming-confirm t
 280   "*If non-nil, ask for for confirmation before deleting old incoming files.
 281 This variable only applies when `mail-source-delete-incoming' is a positive
 282 number."
 283   :group 'mail-source
 284   :type 'boolean)
 285
 286 (defcustom mail-source-incoming-file-prefix "Incoming"
 287   "Prefix for file name for storing incoming mail"
 288   :group 'mail-source
 289   :type 'string)
 290
 291 (defcustom mail-source-report-new-mail-interval 5
 292   "Interval in minutes between checks for new mail."
 293   :group 'mail-source
 294   :type 'number)
 295
 296 (defcustom mail-source-idle-time-delay 5
 297   "Number of idle seconds to wait before checking for new mail."
 298   :group 'mail-source
 299   :type 'number)
 300
 301 (defcustom mail-source-movemail-program nil
 302   "If non-nil, name of program for fetching new mail."
 303   :group 'mail-source
 304   :type '(choice (const nil) string))
 305
 306 ;;; Internal variables.
 307
 308 (defvar mail-source-string ""
 309   "A dynamically bound string that says what the current mail source is.")
 310
 311 (defvar mail-source-new-mail-available nil
 312   "Flag indicating when new mail is available.")
 313
 314 (eval-and-compile
 315   (defvar mail-source-common-keyword-map
 316     '((:plugged))
 317     "Mapping from keywords to default values.
 318 Common keywords should be listed here.")
 319
 320   (defvar mail-source-keyword-map
 321     '((file
 322        (:prescript)
 323        (:prescript-delay)
 324        (:postscript)
 325        (:path (or (getenv "MAIL")
 326                   (expand-file-name (user-login-name) rmail-spool-directory))))
 327       (directory
 328        (:prescript)
 329        (:prescript-delay)
 330        (:postscript)
 331        (:path)
 332        (:suffix ".spool")
 333        (:predicate identity))
 334       (pop
 335        (:prescript)
 336        (:prescript-delay)
 337        (:postscript)
 338        (:server (getenv "MAILHOST"))
 339        (:port 110)
 340        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 341        (:program)
 342        (:function)
 343        (:password)
 344        (:authentication password))
 345       (maildir
 346        (:path (or (getenv "MAILDIR") "~/Maildir/"))
 347        (:subdirs ("new" "cur"))
 348        (:function))
 349       (imap
 350        (:server (getenv "MAILHOST"))
 351        (:port)
 352        (:stream)
 353        (:program)
 354        (:authentication)
 355        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 356        (:password)
 357        (:mailbox "INBOX")
 358        (:predicate "UNSEEN UNDELETED")
 359        (:fetchflag "\\Deleted")
 360        (:dontexpunge))
 361       (webmail
 362        (:subtype hotmail)
 363        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 364        (:password)
 365        (:dontexpunge)
 366        (:authentication password)))
 367     "Mapping from keywords to default values.
 368 All keywords that can be used must be listed here."))
 369
 370 (defvar mail-source-fetcher-alist
 371   '((file mail-source-fetch-file)
 372     (directory mail-source-fetch-directory)
 373     (pop mail-source-fetch-pop)
 374     (maildir mail-source-fetch-maildir)
 375     (imap mail-source-fetch-imap)
 376     (webmail mail-source-fetch-webmail))
 377   "A mapping from source type to fetcher function.")
 378
 379 (defvar mail-source-password-cache nil)
 380
 381 (defvar mail-source-plugged t)
 382
 383 ;;; Functions
 384
 385 (eval-and-compile
 386   (defun mail-source-strip-keyword (keyword)
 387     "Strip the leading colon off the KEYWORD."
 388     (intern (substring (symbol-name keyword) 1))))
 389
 390 (eval-and-compile
 391   (defun mail-source-bind-1 (type)
 392     (let* ((defaults (cdr (assq type mail-source-keyword-map)))
 393            default bind)
 394       (while (setq default (pop defaults))
 395         (push (list (mail-source-strip-keyword (car default))
 396                     nil)
 397               bind))
 398       bind)))
 399
 400 (defmacro mail-source-bind (type-source &rest body)
 401   "Return a `let' form that binds all variables in source TYPE.
 402 TYPE-SOURCE is a list where the first element is the TYPE, and
 403 the second variable is the SOURCE.
 404 At run time, the mail source specifier SOURCE will be inspected,
 405 and the variables will be set according to it.  Variables not
 406 specified will be given default values.
 407
 408 After this is done, BODY will be executed in the scope
 409 of the `let' form.
 410
 411 The variables bound and their default values are described by
 412 the `mail-source-keyword-map' variable."
 413   `(let ,(mail-source-bind-1 (car type-source))
 414      (mail-source-set-1 ,(cadr type-source))
 415      ,@body))
 416
 417 (put 'mail-source-bind 'lisp-indent-function 1)
 418 (put 'mail-source-bind 'edebug-form-spec '(sexp body))
 419
 420 (defun mail-source-set-1 (source)
 421   (let* ((type (pop source))
 422          (defaults (cdr (assq type mail-source-keyword-map)))
 423          default value keyword)
 424     (while (setq default (pop defaults))
 425       (set (mail-source-strip-keyword (setq keyword (car default)))
 426            (if (setq value (plist-get source keyword))
 427                (mail-source-value value)
 428              (mail-source-value (cadr default)))))))
 429
 430 (eval-and-compile
 431   (defun mail-source-bind-common-1 ()
 432     (let* ((defaults mail-source-common-keyword-map)
 433            default bind)
 434       (while (setq default (pop defaults))
 435         (push (list (mail-source-strip-keyword (car default))
 436                     nil)
 437               bind))
 438       bind)))
 439
 440 (defun mail-source-set-common-1 (source)
 441   (let* ((type (pop source))
 442          (defaults mail-source-common-keyword-map)
 443          (defaults-1 (cdr (assq type mail-source-keyword-map)))
 444          default value keyword)
 445     (while (setq default (pop defaults))
 446       (set (mail-source-strip-keyword (setq keyword (car default)))
 447            (if (setq value (plist-get source keyword))
 448                (mail-source-value value)
 449              (if (setq value (assq  keyword defaults-1))
 450                  (mail-source-value (cadr value))
 451                (mail-source-value (cadr default))))))))
 452
 453 (defmacro mail-source-bind-common (source &rest body)
 454   "Return a `let' form that binds all common variables.
 455 See `mail-source-bind'."
 456   `(let ,(mail-source-bind-common-1)
 457      (mail-source-set-common-1 source)
 458      ,@body))
 459
 460 (put 'mail-source-bind-common 'lisp-indent-function 1)
 461 (put 'mail-source-bind-common 'edebug-form-spec '(sexp body))
 462
 463 (defun mail-source-value (value)
 464   "Return the value of VALUE."
 465   (cond
 466    ;; String
 467    ((stringp value)
 468     value)
 469    ;; Function
 470    ((and (listp value)
 471          (functionp (car value)))
 472     (eval value))
 473    ;; Just return the value.
 474    (t
 475     value)))
 476
 477 (defun mail-source-fetch (source callback)
 478   "Fetch mail from SOURCE and call CALLBACK zero or more times.
 479 CALLBACK will be called with the name of the file where (some of)
 480 the mail from SOURCE is put.
 481 Return the number of files that were found."
 482   (mail-source-bind-common source
 483     (if (or mail-source-plugged plugged)
 484         (save-excursion
 485           (let ((function (cadr (assq (car source) mail-source-fetcher-alist)))
 486                 (found 0))
 487             (unless function
 488               (error "%S is an invalid mail source specification" source))
 489             ;; If there's anything in the crash box, we do it first.
 490             (when (file-exists-p mail-source-crash-box)
 491               (message "Processing mail from %s..." mail-source-crash-box)
 492               (setq found (mail-source-callback
 493                            callback mail-source-crash-box)))
 494             (+ found
 495                (if (or debug-on-quit debug-on-error)
 496                    (funcall function source callback)
 497                  (condition-case err
 498                      (funcall function source callback)
 499                    (error
 500                     (if (and (not mail-source-ignore-errors)
 501                              (not
 502                               (yes-or-no-p
 503                                (format "Mail source %s error (%s).  Continue? "
 504                                        (if (memq ':password source)
 505                                            (let ((s (copy-sequence source)))
 506                                              (setcar (cdr (memq ':password s))
 507                                                      "********")
 508                                              s)
 509                                          source)
 510                                        (cadr err)))))
 511                       (error "Cannot get new mail"))
 512                     0)))))))))
 513
 514 (defun mail-source-delete-old-incoming (&optional age confirm)
 515   "Remove incoming files older than AGE days.
 516 If CONFIRM is non-nil, ask for confirmation before removing a file."
 517   (interactive "P")
 518   (let* ((high2days (/ 65536.0 60 60 24));; convert high bits to days
 519          (low2days  (/ 1.0 65536.0))     ;; convert low bits to days
 520          (diff (if (natnump age) age 30));; fallback, if no valid AGE given
 521          currday files)
 522     (setq files (directory-files
 523                  mail-source-directory t
 524                  (concat mail-source-incoming-file-prefix "*"))
 525           currday (* (car (current-time)) high2days)
 526           currday (+ currday (* low2days (nth 1 (current-time)))))
 527     (while files
 528       (let* ((ffile (car files))
 529              (bfile (gnus-replace-in-string
 530                      ffile "\\`.*/\\([^/]+\\)\\'" "\\1"))
 531              (filetime (nth 5 (file-attributes ffile)))
 532              (fileday (* (car filetime) high2days))
 533              (fileday (+ fileday (* low2days (nth 1 filetime)))))
 534         (setq files (cdr files))
 535         (when (and (> (- currday fileday) diff)
 536                    (gnus-message 8 "File `%s' is older than %s day(s)"
 537                                  bfile diff)
 538                    (or (not confirm)
 539                        (y-or-n-p (concat "Remove file `" bfile "'? "))))
 540           (delete-file ffile))))))
 541
 542 (defun mail-source-callback (callback info)
 543   "Call CALLBACK on the mail file, and then remove the mail file.
 544 Pass INFO on to CALLBACK."
 545   (if (or (not (file-exists-p mail-source-crash-box))
 546           (zerop (nth 7 (file-attributes mail-source-crash-box))))
 547       (progn
 548         (when (file-exists-p mail-source-crash-box)
 549           (delete-file mail-source-crash-box))
 550         0)
 551     (prog1
 552         (funcall callback mail-source-crash-box info)
 553       (when (file-exists-p mail-source-crash-box)
 554         ;; Delete or move the incoming mail out of the way.
 555         (if (eq mail-source-delete-incoming t)
 556             (delete-file mail-source-crash-box)
 557           (let ((incoming
 558                  (mm-make-temp-file
 559                   (expand-file-name
 560                    mail-source-incoming-file-prefix
 561                    mail-source-directory))))
 562             (unless (file-exists-p (file-name-directory incoming))
 563               (make-directory (file-name-directory incoming) t))
 564             (rename-file mail-source-crash-box incoming t)
 565             ;; remove old incoming files?
 566             (when (natnump mail-source-delete-incoming)
 567               (mail-source-delete-old-incoming
 568                mail-source-delete-incoming
 569                mail-source-delete-old-incoming-confirm))))))))
 570
 571 (defun mail-source-movemail (from to)
 572   "Move FROM to TO using movemail."
 573   (if (not (file-writable-p to))
 574       (error "Can't write to crash box %s.  Not moving mail" to)
 575     (let ((to (file-truename (expand-file-name to)))
 576           errors result)
 577       (setq to (file-truename to)
 578             from (file-truename from))
 579       ;; Set TO if have not already done so, and rename or copy
 580       ;; the file FROM to TO if and as appropriate.
 581       (cond
 582        ((file-exists-p to)
 583         ;; The crash box exists already.
 584         t)
 585        ((not (file-exists-p from))
 586         ;; There is no inbox.
 587         (setq to nil))
 588        ((zerop (nth 7 (file-attributes from)))
 589         ;; Empty file.
 590         (setq to nil))
 591        (t
 592         ;; If getting from mail spool directory, use movemail to move
 593         ;; rather than just renaming, so as to interlock with the
 594         ;; mailer.
 595         (unwind-protect
 596             (save-excursion
 597               (setq errors (generate-new-buffer " *mail source loss*"))
 598               (let ((default-directory "/"))
 599                 (setq result
 600                       (apply
 601                        'call-process
 602                        (append
 603                         (list
 604                          (or mail-source-movemail-program
 605                              (expand-file-name "movemail" exec-directory))
 606                          nil errors nil from to)))))
 607               (when (file-exists-p to)
 608                 (set-file-modes to mail-source-default-file-modes))
 609               (if (and (or (not (buffer-modified-p errors))
 610                            (zerop (buffer-size errors)))
 611                        (zerop result))
 612                   ;; No output => movemail won.
 613                   t
 614                 (set-buffer errors)
 615                 ;; There may be a warning about older revisions.  We
 616                 ;; ignore that.
 617                 (goto-char (point-min))
 618                 (if (search-forward "older revision" nil t)
 619                     t
 620                   ;; Probably a real error.
 621                   (subst-char-in-region (point-min) (point-max) ?\n ?\  )
 622                   (goto-char (point-max))
 623                   (skip-chars-backward " \t")
 624                   (delete-region (point) (point-max))
 625                   (goto-char (point-min))
 626                   (when (looking-at "movemail: ")
 627                     (delete-region (point-min) (match-end 0)))
 628                   ;; Result may be a signal description string.
 629                   (unless (yes-or-no-p
 630                            (format "movemail: %s (%s return).  Continue? "
 631                                    (buffer-string) result))
 632                     (error "%s" (buffer-string)))
 633                   (setq to nil)))))))
 634       (when (and errors
 635                  (buffer-name errors))
 636         (kill-buffer errors))
 637       ;; Return whether we moved successfully or not.
 638       to)))
 639
 640 (defun mail-source-movemail-and-remove (from to)
 641   "Move FROM to TO using movemail, then remove FROM if empty."
 642   (or (not (mail-source-movemail from to))
 643       (not (zerop (nth 7 (file-attributes from))))
 644       (delete-file from)))
 645
 646 (defun mail-source-fetch-with-program (program)
 647   (zerop (call-process shell-file-name nil nil nil
 648                        shell-command-switch program)))
 649
 650 (defun mail-source-run-script (script spec &optional delay)
 651   (when script
 652     (if (functionp script)
 653         (funcall script)
 654       (mail-source-call-script
 655        (format-spec script spec))))
 656   (when delay
 657     (sleep-for delay)))
 658
 659 (defun mail-source-call-script (script)
 660   (let ((background nil))
 661     (when (string-match "& *$" script)
 662       (setq script (substring script 0 (match-beginning 0))
 663             background 0))
 664     (call-process shell-file-name nil background nil
 665                   shell-command-switch script)))
 666
 667 ;;;
 668 ;;; Different fetchers
 669 ;;;
 670
 671 (defun mail-source-fetch-file (source callback)
 672   "Fetcher for single-file sources."
 673   (mail-source-bind (file source)
 674     (mail-source-run-script
 675      prescript (format-spec-make ?t mail-source-crash-box)
 676      prescript-delay)
 677     (let ((mail-source-string (format "file:%s" path)))
 678       (if (mail-source-movemail path mail-source-crash-box)
 679           (prog1
 680               (mail-source-callback callback path)
 681             (mail-source-run-script
 682              postscript (format-spec-make ?t mail-source-crash-box)))
 683         0))))
 684
 685 (defun mail-source-fetch-directory (source callback)
 686   "Fetcher for directory sources."
 687   (mail-source-bind (directory source)
 688     (mail-source-run-script
 689      prescript (format-spec-make ?t path) prescript-delay)
 690     (let ((found 0)
 691           (mail-source-string (format "directory:%s" path)))
 692       (dolist (file (directory-files
 693                      path t (concat (regexp-quote suffix) "$")))
 694         (when (and (file-regular-p file)
 695                    (funcall predicate file)
 696                    (mail-source-movemail file mail-source-crash-box))
 697           (incf found (mail-source-callback callback file))))
 698       (mail-source-run-script postscript (format-spec-make ?t path))
 699       found)))
 700
 701 (defun mail-source-fetch-pop (source callback)
 702   "Fetcher for single-file sources."
 703   (mail-source-bind (pop source)
 704     (mail-source-run-script
 705      prescript
 706      (format-spec-make ?p password ?t mail-source-crash-box
 707                        ?s server ?P port ?u user)
 708      prescript-delay)
 709     (let ((from (format "%s:%s:%s" server user port))
 710           (mail-source-string (format "pop:%s@%s" user server))
 711           result)
 712       (when (eq authentication 'password)
 713         (setq password
 714               (or password
 715                   (cdr (assoc from mail-source-password-cache))
 716                   (read-passwd
 717                    (format "Password for %s at %s: " user server)))))
 718       (when server
 719         (setenv "MAILHOST" server))
 720       (setq result
 721             (cond
 722              (program
 723               (mail-source-fetch-with-program
 724                (format-spec
 725                 program
 726                 (format-spec-make ?p password ?t mail-source-crash-box
 727                                   ?s server ?P port ?u user))))
 728              (function
 729               (funcall function mail-source-crash-box))
 730              ;; The default is to use pop3.el.
 731              (t
 732               (let ((pop3-password password)
 733                     (pop3-maildrop user)
 734                     (pop3-mailhost server)
 735                     (pop3-port port)
 736                     (pop3-authentication-scheme
 737                      (if (eq authentication 'apop) 'apop 'pass)))
 738                 (if (or debug-on-quit debug-on-error)
 739                     (save-excursion (pop3-movemail mail-source-crash-box))
 740                   (condition-case err
 741                       (save-excursion (pop3-movemail mail-source-crash-box))
 742                     (error
 743                      ;; We nix out the password in case the error
 744                      ;; was because of a wrong password being given.
 745                      (setq mail-source-password-cache
 746                            (delq (assoc from mail-source-password-cache)
 747                                  mail-source-password-cache))
 748                      (signal (car err) (cdr err)))))))))
 749       (if result
 750           (progn
 751             (when (eq authentication 'password)
 752               (unless (assoc from mail-source-password-cache)
 753                 (push (cons from password) mail-source-password-cache)))
 754             (prog1
 755                 (mail-source-callback callback server)
 756               ;; Update display-time's mail flag, if relevant.
 757               (if (equal source mail-source-primary-source)
 758                   (setq mail-source-new-mail-available nil))
 759               (mail-source-run-script
 760                postscript
 761                (format-spec-make ?p password ?t mail-source-crash-box
 762                                  ?s server ?P port ?u user))))
 763         ;; We nix out the password in case the error
 764         ;; was because of a wrong password being given.
 765         (setq mail-source-password-cache
 766               (delq (assoc from mail-source-password-cache)
 767                     mail-source-password-cache))
 768         0))))
 769
 770 (defun mail-source-check-pop (source)
 771   "Check whether there is new mail."
 772   (mail-source-bind (pop source)
 773     (let ((from (format "%s:%s:%s" server user port))
 774           (mail-source-string (format "pop:%s@%s" user server))
 775           result)
 776       (when (eq authentication 'password)
 777         (setq password
 778               (or password
 779                   (cdr (assoc from mail-source-password-cache))
 780                   (read-passwd
 781                    (format "Password for %s at %s: " user server))))
 782         (unless (assoc from mail-source-password-cache)
 783           (push (cons from password) mail-source-password-cache)))
 784       (when server
 785         (setenv "MAILHOST" server))
 786       (setq result
 787             (cond
 788              ;; No easy way to check whether mail is waiting for these.
 789              (program)
 790              (function)
 791              ;; The default is to use pop3.el.
 792              (t
 793               (let ((pop3-password password)
 794                     (pop3-maildrop user)
 795                     (pop3-mailhost server)
 796                     (pop3-port port)
 797                     (pop3-authentication-scheme
 798                      (if (eq authentication 'apop) 'apop 'pass)))
 799                 (if (or debug-on-quit debug-on-error)
 800                     (save-excursion (pop3-get-message-count))
 801                   (condition-case err
 802                       (save-excursion (pop3-get-message-count))
 803                     (error
 804                      ;; We nix out the password in case the error
 805                      ;; was because of a wrong password being given.
 806                      (setq mail-source-password-cache
 807                            (delq (assoc from mail-source-password-cache)
 808                                  mail-source-password-cache))
 809                      (signal (car err) (cdr err)))))))))
 810       (if result
 811           ;; Inform display-time that we have new mail.
 812           (setq mail-source-new-mail-available (> result 0))
 813         ;; We nix out the password in case the error
 814         ;; was because of a wrong password being given.
 815         (setq mail-source-password-cache
 816               (delq (assoc from mail-source-password-cache)
 817                     mail-source-password-cache)))
 818       result)))
 819
 820 (defun mail-source-touch-pop ()
 821   "Open and close a POP connection shortly.
 822 POP server should be defined in `mail-source-primary-source' (which is
 823 preferred) or `mail-sources'.  You may use it for the POP-before-SMTP
 824 authentication.  To do that, you need to set the option
 825 `message-send-mail-function' to `message-smtpmail-send-it' and put the
 826 following line in .gnus file:
 827
 828 \(add-hook 'message-send-mail-hook 'mail-source-touch-pop)
 829 "
 830   (let ((sources (if mail-source-primary-source
 831                      (list mail-source-primary-source)
 832                    mail-sources)))
 833     (while sources
 834       (if (eq 'pop (car (car sources)))
 835           (mail-source-check-pop (car sources)))
 836       (setq sources (cdr sources)))))
 837
 838 (defun mail-source-new-mail-p ()
 839   "Handler for `display-time' to indicate when new mail is available."
 840   ;; Flash (ie. ring the visible bell) if mail is available.
 841   (if (and mail-source-flash mail-source-new-mail-available)
 842       (let ((visible-bell t))
 843         (ding)))
 844   ;; Only report flag setting; flag is updated on a different schedule.
 845   mail-source-new-mail-available)
 846
 847
 848 (defvar mail-source-report-new-mail nil)
 849 (defvar mail-source-report-new-mail-timer nil)
 850 (defvar mail-source-report-new-mail-idle-timer nil)
 851
 852 (eval-when-compile
 853   (if (featurep 'xemacs)
 854       (require 'itimer)
 855     (require 'timer)))
 856
 857 (defun mail-source-start-idle-timer ()
 858   ;; Start our idle timer if necessary, so we delay the check until the
 859   ;; user isn't typing.
 860   (unless mail-source-report-new-mail-idle-timer
 861     (setq mail-source-report-new-mail-idle-timer
 862           (run-with-idle-timer
 863            mail-source-idle-time-delay
 864            nil
 865            (lambda ()
 866              (unwind-protect
 867                  (mail-source-check-pop mail-source-primary-source)
 868                (setq mail-source-report-new-mail-idle-timer nil)))))
 869     ;; Since idle timers created when Emacs is already in the idle
 870     ;; state don't get activated until Emacs _next_ becomes idle, we
 871     ;; need to force our timer to be considered active now.  We do
 872     ;; this by being naughty and poking the timer internals directly
 873     ;; (element 0 of the vector is nil if the timer is active).
 874     (aset mail-source-report-new-mail-idle-timer 0 nil)))
 875
 876 (defun mail-source-report-new-mail (arg)
 877   "Toggle whether to report when new mail is available.
 878 This only works when `display-time' is enabled."
 879   (interactive "P")
 880   (if (not mail-source-primary-source)
 881       (error "Need to set `mail-source-primary-source' to check for new mail"))
 882   (let ((on (if (null arg)
 883                 (not mail-source-report-new-mail)
 884               (> (prefix-numeric-value arg) 0))))
 885     (setq mail-source-report-new-mail on)
 886     (and mail-source-report-new-mail-timer
 887          (nnheader-cancel-timer mail-source-report-new-mail-timer))
 888     (and mail-source-report-new-mail-idle-timer
 889          (nnheader-cancel-timer mail-source-report-new-mail-idle-timer))
 890     (setq mail-source-report-new-mail-timer nil)
 891     (setq mail-source-report-new-mail-idle-timer nil)
 892     (if on
 893         (progn
 894           (require 'time)
 895           ;; display-time-mail-function is an Emacs 21 feature.
 896           (setq display-time-mail-function #'mail-source-new-mail-p)
 897           ;; Set up the main timer.
 898           (setq mail-source-report-new-mail-timer
 899                 (nnheader-run-at-time
 900                  (* 60 mail-source-report-new-mail-interval)
 901                  (* 60 mail-source-report-new-mail-interval)
 902                  #'mail-source-start-idle-timer))
 903           ;; When you get new mail, clear "Mail" from the mode line.
 904           (add-hook 'nnmail-post-get-new-mail-hook
 905                     'display-time-event-handler)
 906           (message "Mail check enabled"))
 907       (setq display-time-mail-function nil)
 908       (remove-hook 'nnmail-post-get-new-mail-hook
 909                    'display-time-event-handler)
 910       (message "Mail check disabled"))))
 911
 912 (defun mail-source-fetch-maildir (source callback)
 913   "Fetcher for maildir sources."
 914   (mail-source-bind (maildir source)
 915     (let ((found 0)
 916           mail-source-string)
 917       (unless (string-match "/$" path)
 918         (setq path (concat path "/")))
 919       (dolist (subdir subdirs)
 920         (when (file-directory-p (concat path subdir))
 921           (setq mail-source-string (format "maildir:%s%s" path subdir))
 922           (dolist (file (directory-files (concat path subdir) t))
 923             (when (and (not (file-directory-p file))
 924                        (not (if function
 925                                 (funcall function file mail-source-crash-box)
 926                               (let ((coding-system-for-write
 927                                      mm-text-coding-system)
 928                                     (coding-system-for-read
 929                                      mm-text-coding-system))
 930                                 (with-temp-file mail-source-crash-box
 931                                   (insert-file-contents file)
 932                                   (goto-char (point-min))
 933 ;;;                               ;; Unix mail format
 934 ;;;                               (unless (looking-at "\n*From ")
 935 ;;;                                 (insert "From maildir "
 936 ;;;                                         (current-time-string) "\n"))
 937 ;;;                               (while (re-search-forward "^From " nil t)
 938 ;;;                                 (replace-match ">From "))
 939 ;;;                               (goto-char (point-max))
 940 ;;;                               (insert "\n\n")
 941                                   ;; MMDF mail format
 942                                   (insert "\001\001\001\001\n"))
 943                                 (delete-file file)))))
 944               (incf found (mail-source-callback callback file))))))
 945       found)))
 946
 947 (eval-and-compile
 948   (autoload 'imap-open "imap")
 949   (autoload 'imap-authenticate "imap")
 950   (autoload 'imap-mailbox-select "imap")
 951   (autoload 'imap-mailbox-unselect "imap")
 952   (autoload 'imap-mailbox-close "imap")
 953   (autoload 'imap-search "imap")
 954   (autoload 'imap-fetch "imap")
 955   (autoload 'imap-close "imap")
 956   (autoload 'imap-error-text "imap")
 957   (autoload 'imap-message-flags-add "imap")
 958   (autoload 'imap-list-to-message-set "imap")
 959   (autoload 'imap-range-to-message-set "imap")
 960   (autoload 'nnheader-ms-strip-cr "nnheader"))
 961
 962 (defvar mail-source-imap-file-coding-system 'binary
 963   "Coding system for the crashbox made by `mail-source-fetch-imap'.")
 964
 965 (defun mail-source-fetch-imap (source callback)
 966   "Fetcher for imap sources."
 967   (mail-source-bind (imap source)
 968     (let* ((from (format "%s:%s:%s" server user port))
 969            (found 0)
 970            (buffer-name " *imap source*")
 971            (buf (get-buffer-create (generate-new-buffer-name buffer-name)))
 972            (mail-source-string (format "imap:%s:%s" server mailbox))
 973            (imap-shell-program (or (list program) imap-shell-program))
 974            remove)
 975       (if (and (imap-open server port stream authentication buffer-name)
 976                (imap-authenticate
 977                 user (or (cdr (assoc from mail-source-password-cache))
 978                          password) buf)
 979                (imap-mailbox-select mailbox nil buf))
 980           (let ((coding-system-for-write mail-source-imap-file-coding-system)
 981                 str)
 982             (with-temp-file mail-source-crash-box
 983               ;; Avoid converting 8-bit chars from inserted strings to
 984               ;; multibyte.
 985               (mm-disable-multibyte)
 986               ;; remember password
 987               (with-current-buffer buf
 988                 (when (or imap-password
 989                           (assoc from mail-source-password-cache))
 990                   (push (cons from imap-password) mail-source-password-cache)))
 991               ;; if predicate is nil, use all uids
 992               (dolist (uid (imap-search (or predicate "1:*") buf))
 993                 (when (setq str
 994                             (if (imap-capability 'IMAP4rev1 buf)
 995                                 (caddar (imap-fetch uid "BODY.PEEK[]"
 996                                                     'BODYDETAIL nil buf))
 997                               (imap-fetch uid "RFC822.PEEK" 'RFC822 nil buf)))
 998                   (push uid remove)
 999                   (insert "From imap " (current-time-string) "\n")
1000                   (save-excursion
1001                     (insert str "\n\n"))
1002                   (while (re-search-forward "^From " nil t)
1003                     (replace-match ">From "))
1004                   (goto-char (point-max))))
1005               (nnheader-ms-strip-cr))
1006             (incf found (mail-source-callback callback server))
1007             (when (and remove fetchflag)
1008               (imap-message-flags-add
1009                (imap-range-to-message-set (gnus-compress-sequence remove))
1010                fetchflag nil buf))
1011             (if dontexpunge
1012                 (imap-mailbox-unselect buf)
1013               (imap-mailbox-close nil buf))
1014             (imap-close buf))
1015         (imap-close buf)
1016         ;; We nix out the password in case the error
1017         ;; was because of a wrong password being given.
1018         (setq mail-source-password-cache
1019               (delq (assoc from mail-source-password-cache)
1020                     mail-source-password-cache))
1021         (error (imap-error-text buf)))
1022       (kill-buffer buf)
1023       found)))
1024
1025 (eval-and-compile
1026   (autoload 'webmail-fetch "webmail"))
1027
1028 (defun mail-source-fetch-webmail (source callback)
1029   "Fetch for webmail source."
1030   (mail-source-bind (webmail source)
1031     (let ((mail-source-string (format "webmail:%s:%s" subtype user))
1032           (webmail-newmail-only dontexpunge)
1033           (webmail-move-to-trash-can (not dontexpunge)))
1034       (when (eq authentication 'password)
1035         (setq password
1036               (or password
1037                   (cdr (assoc (format "webmail:%s:%s" subtype user)
1038                               mail-source-password-cache))
1039                   (read-passwd
1040                    (format "Password for %s at %s: " user subtype))))
1041         (when (and password
1042                    (not (assoc (format "webmail:%s:%s" subtype user)
1043                                mail-source-password-cache)))
1044           (push (cons (format "webmail:%s:%s" subtype user) password)
1045                 mail-source-password-cache)))
1046       (webmail-fetch mail-source-crash-box subtype user password)
1047       (mail-source-callback callback (symbol-name subtype)))))
1048
1049 (provide 'mail-source)
1050
1051 ;;; mail-source.el ends here