git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mail-parse)
  29 (require 'gnus-mailcap)
  30 (require 'mm-bodies)
  31 (eval-when-compile (require 'cl)
  32                    (require 'term))
  33
  34 (eval-and-compile
  35   (autoload 'mm-inline-partial "mm-partial")
  36   (autoload 'mm-inline-external-body "mm-extern")
  37   (autoload 'mm-insert-inline "mm-view"))
  38
  39 (add-hook 'gnus-exit-gnus-hook 'mm-destroy-postponed-undisplay-list)
  40
  41 (defgroup mime-display ()
  42   "Display of MIME in mail and news articles."
  43   :link '(custom-manual "(emacs-mime)Display Customization")
  44   :version "21.1"
  45   :group 'mail
  46   :group 'news
  47   :group 'multimedia)
  48
  49 (defgroup mime-security ()
  50   "MIME security in mail and news articles."
  51   :link '(custom-manual "(emacs-mime)Display Customization")
  52   :group 'mail
  53   :group 'news
  54   :group 'multimedia)
  55
  56 ;;; Convenience macros.
  57
  58 (defmacro mm-handle-buffer (handle)
  59   `(nth 0 ,handle))
  60 (defmacro mm-handle-type (handle)
  61   `(nth 1 ,handle))
  62 (defsubst mm-handle-media-type (handle)
  63   (if (stringp (car handle))
  64       (car handle)
  65     (car (mm-handle-type handle))))
  66 (defsubst mm-handle-media-supertype (handle)
  67   (car (split-string (mm-handle-media-type handle) "/")))
  68 (defsubst mm-handle-media-subtype (handle)
  69   (cadr (split-string (mm-handle-media-type handle) "/")))
  70 (defmacro mm-handle-encoding (handle)
  71   `(nth 2 ,handle))
  72 (defmacro mm-handle-undisplayer (handle)
  73   `(nth 3 ,handle))
  74 (defmacro mm-handle-set-undisplayer (handle function)
  75   `(setcar (nthcdr 3 ,handle) ,function))
  76 (defmacro mm-handle-disposition (handle)
  77   `(nth 4 ,handle))
  78 (defmacro mm-handle-description (handle)
  79   `(nth 5 ,handle))
  80 (defmacro mm-handle-cache (handle)
  81   `(nth 6 ,handle))
  82 (defmacro mm-handle-set-cache (handle contents)
  83   `(setcar (nthcdr 6 ,handle) ,contents))
  84 (defmacro mm-handle-id (handle)
  85   `(nth 7 ,handle))
  86 (defmacro mm-handle-multipart-original-buffer (handle)
  87   `(get-text-property 0 'buffer (car ,handle)))
  88 (defmacro mm-handle-multipart-from (handle)
  89   `(get-text-property 0 'from (car ,handle)))
  90 (defmacro mm-handle-multipart-ctl-parameter (handle parameter)
  91   `(get-text-property 0 ,parameter (car ,handle)))
  92
  93 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
  94                                     disposition description cache
  95                                     id)
  96   `(list ,buffer ,type ,encoding ,undisplayer
  97          ,disposition ,description ,cache ,id))
  98
  99 (defcustom mm-text-html-renderer
 100   (cond ((locate-library "w3") 'w3)
 101         ((executable-find "w3m") (if (locate-library "w3m")
 102                                      'w3m
 103                                    'w3m-standalone))
 104         ((executable-find "links") 'links)
 105         ((executable-find "lynx") 'lynx)
 106         (t 'html2text))
 107   "Render of HTML contents.
 108 It is one of defined renderer types, or a rendering function.
 109 The defined renderer types are:
 110 `w3'   : use Emacs/W3;
 111 `w3m'  : use emacs-w3m;
 112 `w3m-standalone': use w3m;
 113 `links': use links;
 114 `lynx' : use lynx;
 115 `html2text' : use html2text;
 116 nil    : use external viewer."
 117   :type '(choice (const w3)
 118                  (const w3m)
 119                  (const w3m-standalone)
 120                  (const links)
 121                  (const lynx)
 122                  (const html2text)
 123                  (const nil)
 124                  (function))
 125   :version "21.3"
 126   :group 'mime-display)
 127
 128 (defvar mm-inline-text-html-renderer nil
 129   "Function used for rendering inline HTML contents.
 130 It is suggested to customize `mm-text-html-renderer' instead.")
 131
 132 (defcustom mm-inline-text-html-with-images nil
 133   "If non-nil, Gnus will allow retrieving images in HTML contents with
 134 the <img> tags.  It has no effect on Emacs/w3.  See also the
 135 documentation for the `mm-w3m-safe-url-regexp' variable."
 136   :type 'boolean
 137   :group 'mime-display)
 138
 139 (defcustom mm-w3m-safe-url-regexp "\\`cid:"
 140   "Regexp matching URLs which are considered to be safe.
 141 Some HTML mails might contain a nasty trick used by spammers, using
 142 the <img> tag which is far more evil than the [Click Here!] button.
 143 It is most likely intended to check whether the ominous spam mail has
 144 reached your eyes or not, in which case the spammer knows for sure
 145 that your email address is valid.  It is done by embedding an
 146 identifier string into a URL that you might automatically retrieve
 147 when displaying the image.  The default value is \"\\\\`cid:\" which only
 148 matches parts embedded to the Multipart/Related type MIME contents and
 149 Gnus will never connect to the spammer's site arbitrarily.  You may
 150 set this variable to nil if you consider all urls to be safe."
 151   :type '(choice (regexp :tag "Regexp")
 152                  (const :tag "All URLs are safe" nil))
 153   :group 'mime-display)
 154
 155 (defcustom mm-inline-text-html-with-w3m-keymap t
 156   "If non-nil, use emacs-w3m command keys in the article buffer."
 157   :type 'boolean
 158   :group 'mime-display)
 159
 160 (defcustom mm-enable-external t
 161   "Indicate whether external MIME handlers should be used.
 162
 163 If t, all defined external MIME handlers are used.  If nil, files are saved by
 164 `mailcap-save-binary-file'.  If it is the symbol `ask', you are prompted
 165 before the external MIME handler is invoked."
 166   :version "21.4"
 167   :type '(choice (const :tag "Always" t)
 168                  (const :tag "Never" nil)
 169                  (const :tag "Ask" ask))
 170   :group 'mime-display)
 171
 172 (defcustom mm-inline-media-tests
 173   '(("image/p?jpeg"
 174      mm-inline-image
 175      (lambda (handle)
 176        (mm-valid-and-fit-image-p 'jpeg handle)))
 177     ("image/png"
 178      mm-inline-image
 179      (lambda (handle)
 180        (mm-valid-and-fit-image-p 'png handle)))
 181     ("image/gif"
 182      mm-inline-image
 183      (lambda (handle)
 184        (mm-valid-and-fit-image-p 'gif handle)))
 185     ("image/tiff"
 186      mm-inline-image
 187      (lambda (handle)
 188        (mm-valid-and-fit-image-p 'tiff handle)) )
 189     ("image/xbm"
 190      mm-inline-image
 191      (lambda (handle)
 192        (mm-valid-and-fit-image-p 'xbm handle)))
 193     ("image/x-xbitmap"
 194      mm-inline-image
 195      (lambda (handle)
 196        (mm-valid-and-fit-image-p 'xbm handle)))
 197     ("image/xpm"
 198      mm-inline-image
 199      (lambda (handle)
 200        (mm-valid-and-fit-image-p 'xpm handle)))
 201     ("image/x-xpixmap"
 202      mm-inline-image
 203      (lambda (handle)
 204        (mm-valid-and-fit-image-p 'xpm handle)))
 205     ("image/bmp"
 206      mm-inline-image
 207      (lambda (handle)
 208        (mm-valid-and-fit-image-p 'bmp handle)))
 209     ("image/x-portable-bitmap"
 210      mm-inline-image
 211      (lambda (handle)
 212        (mm-valid-and-fit-image-p 'pbm handle)))
 213     ("text/plain" mm-inline-text identity)
 214     ("text/enriched" mm-inline-text identity)
 215     ("text/richtext" mm-inline-text identity)
 216     ("text/x-patch" mm-display-patch-inline
 217      (lambda (handle)
 218        (locate-library "diff-mode")))
 219     ("application/emacs-lisp" mm-display-elisp-inline identity)
 220     ("application/x-emacs-lisp" mm-display-elisp-inline identity)
 221     ("text/html"
 222      mm-inline-text-html
 223      (lambda (handle)
 224        (or mm-inline-text-html-renderer
 225            mm-text-html-renderer)))
 226     ("text/x-vcard"
 227      mm-inline-text-vcard
 228      (lambda (handle)
 229        (or (featurep 'vcard)
 230            (locate-library "vcard"))))
 231     ("message/delivery-status" mm-inline-text identity)
 232     ("message/rfc822" mm-inline-message identity)
 233     ("message/partial" mm-inline-partial identity)
 234     ("message/external-body" mm-inline-external-body identity)
 235     ("text/.*" mm-inline-text identity)
 236     ("audio/wav" mm-inline-audio
 237      (lambda (handle)
 238        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 239             (device-sound-enabled-p))))
 240     ("audio/au"
 241      mm-inline-audio
 242      (lambda (handle)
 243        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 244             (device-sound-enabled-p))))
 245     ("application/pgp-signature" ignore identity)
 246     ("application/x-pkcs7-signature" ignore identity)
 247     ("application/pkcs7-signature" ignore identity)
 248     ("application/x-pkcs7-mime" ignore identity)
 249     ("application/pkcs7-mime" ignore identity)
 250     ("multipart/alternative" ignore identity)
 251     ("multipart/mixed" ignore identity)
 252     ("multipart/related" ignore identity)
 253     ;; Disable audio and image
 254     ("audio/.*" ignore ignore)
 255     ("image/.*" ignore ignore)
 256     ;; Default to displaying as text
 257     (".*" mm-inline-text mm-readable-p))
 258   "Alist of media types/tests saying whether types can be displayed inline."
 259   :type '(repeat (list (regexp :tag "MIME type")
 260                        (function :tag "Display function")
 261                        (function :tag "Display test")))
 262   :group 'mime-display)
 263
 264 (defcustom mm-inlined-types
 265   '("image/.*" "text/.*" "message/delivery-status" "message/rfc822"
 266     "message/partial" "message/external-body" "application/emacs-lisp"
 267     "application/x-emacs-lisp"
 268     "application/pgp-signature" "application/x-pkcs7-signature"
 269     "application/pkcs7-signature" "application/x-pkcs7-mime"
 270     "application/pkcs7-mime")
 271   "List of media types that are to be displayed inline.
 272 See also `mm-inline-media-tests', which says how to display a media
 273 type inline."
 274   :type '(repeat string)
 275   :group 'mime-display)
 276
 277 (defcustom mm-keep-viewer-alive-types
 278   '("application/postscript" "application/msword" "application/vnd.ms-excel"
 279     "application/pdf" "application/x-dvi")
 280   "List of media types for which the external viewer will not be killed
 281 when selecting a different article."
 282   :type '(repeat string)
 283   :group 'mime-display)
 284
 285 (defcustom mm-automatic-display
 286   '("text/plain" "text/enriched" "text/richtext" "text/html"
 287     "text/x-vcard" "image/.*" "message/delivery-status" "multipart/.*"
 288     "message/rfc822" "text/x-patch" "application/pgp-signature"
 289     "application/emacs-lisp" "application/x-emacs-lisp"
 290     "application/x-pkcs7-signature"
 291     "application/pkcs7-signature" "application/x-pkcs7-mime"
 292     "application/pkcs7-mime")
 293   "A list of MIME types to be displayed automatically."
 294   :type '(repeat string)
 295   :group 'mime-display)
 296
 297 (defcustom mm-attachment-override-types '("text/x-vcard"
 298                                           "application/pkcs7-mime"
 299                                           "application/x-pkcs7-mime"
 300                                           "application/pkcs7-signature"
 301                                           "application/x-pkcs7-signature")
 302   "Types to have \"attachment\" ignored if they can be displayed inline."
 303   :type '(repeat string)
 304   :group 'mime-display)
 305
 306 (defcustom mm-inline-override-types nil
 307   "Types to be treated as attachments even if they can be displayed inline."
 308   :type '(repeat string)
 309   :group 'mime-display)
 310
 311 (defcustom mm-automatic-external-display nil
 312   "List of MIME type regexps that will be displayed externally automatically."
 313   :type '(repeat string)
 314   :group 'mime-display)
 315
 316 (defcustom mm-discouraged-alternatives nil
 317   "List of MIME types that are discouraged when viewing multipart/alternative.
 318 Viewing agents are supposed to view the last possible part of a message,
 319 as that is supposed to be the richest.  However, users may prefer other
 320 types instead, and this list says what types are most unwanted.  If,
 321 for instance, text/html parts are very unwanted, and text/richtext are
 322 somewhat unwanted, then the value of this variable should be set
 323 to:
 324
 325  (\"text/html\" \"text/richtext\")"
 326   :type '(repeat string)
 327   :group 'mime-display)
 328
 329 (defcustom mm-tmp-directory
 330   (if (fboundp 'temp-directory)
 331       (temp-directory)
 332     (if (boundp 'temporary-file-directory)
 333         temporary-file-directory
 334       "/tmp/"))
 335   "Where mm will store its temporary files."
 336   :type 'directory
 337   :group 'mime-display)
 338
 339 (defcustom mm-inline-large-images nil
 340   "If non-nil, then all images fit in the buffer."
 341   :type 'boolean
 342   :group 'mime-display)
 343
 344 (defvar mm-file-name-rewrite-functions
 345   '(mm-file-name-delete-control mm-file-name-delete-gotchas)
 346   "*List of functions used for rewriting file names of MIME parts.
 347 Each function takes a file name as input and returns a file name.
 348
 349 Ready-made functions include
 350 `mm-file-name-delete-control'
 351 `mm-file-name-delete-gotchas'
 352 `mm-file-name-delete-whitespace',
 353 `mm-file-name-trim-whitespace',
 354 `mm-file-name-collapse-whitespace',
 355 `mm-file-name-replace-whitespace',
 356 `capitalize', `downcase', `upcase', and
 357 `upcase-initials'.")
 358
 359 (defvar mm-path-name-rewrite-functions nil
 360   "*List of functions for rewriting the full file names of MIME parts.
 361 This is used when viewing parts externally, and is meant for
 362 transforming the absolute name so that non-compliant programs can find
 363 the file where it's saved.
 364
 365 Each function takes a file name as input and returns a file name.")
 366
 367 (defvar mm-file-name-replace-whitespace nil
 368   "String used for replacing whitespace characters; default is `\"_\"'.")
 369
 370 (defcustom mm-default-directory nil
 371   "The default directory where mm will save files.
 372 If not set, `default-directory' will be used."
 373   :type '(choice directory (const :tag "Default" nil))
 374   :group 'mime-display)
 375
 376 (defcustom mm-attachment-file-modes 384
 377   "Set the mode bits of saved attachments to this integer."
 378   :type 'integer
 379   :group 'mime-display)
 380
 381 (defcustom mm-external-terminal-program "xterm"
 382   "The program to start an external terminal."
 383   :type 'string
 384   :group 'mime-display)
 385
 386 ;;; Internal variables.
 387
 388 (defvar mm-last-shell-command "")
 389 (defvar mm-content-id-alist nil)
 390 (defvar mm-postponed-undisplay-list nil)
 391
 392 ;; According to RFC2046, in particular, in a digest, the default
 393 ;; Content-Type value for a body part is changed from "text/plain" to
 394 ;; "message/rfc822".
 395 (defvar mm-dissect-default-type "text/plain")
 396
 397 (autoload 'mml2015-verify "mml2015")
 398 (autoload 'mml2015-verify-test "mml2015")
 399 (autoload 'mml-smime-verify "mml-smime")
 400 (autoload 'mml-smime-verify-test "mml-smime")
 401
 402 (defvar mm-verify-function-alist
 403   '(("application/pgp-signature" mml2015-verify "PGP" mml2015-verify-test)
 404     ("application/x-gnus-pgp-signature" mm-uu-pgp-signed-extract-1 "PGP"
 405      mm-uu-pgp-signed-test)
 406     ("application/pkcs7-signature" mml-smime-verify "S/MIME"
 407      mml-smime-verify-test)
 408     ("application/x-pkcs7-signature" mml-smime-verify "S/MIME"
 409      mml-smime-verify-test)))
 410
 411 (defcustom mm-verify-option 'never
 412   "Option of verifying signed parts.
 413 `never', not verify; `always', always verify;
 414 `known', only verify known protocols.  Otherwise, ask user."
 415   :type '(choice (item always)
 416                  (item never)
 417                  (item :tag "only known protocols" known)
 418                  (item :tag "ask" nil))
 419   :group 'mime-security)
 420
 421 (autoload 'mml2015-decrypt "mml2015")
 422 (autoload 'mml2015-decrypt-test "mml2015")
 423
 424 (defvar mm-decrypt-function-alist
 425   '(("application/pgp-encrypted" mml2015-decrypt "PGP" mml2015-decrypt-test)
 426     ("application/x-gnus-pgp-encrypted" mm-uu-pgp-encrypted-extract-1 "PGP"
 427      mm-uu-pgp-encrypted-test)))
 428
 429 (defcustom mm-decrypt-option nil
 430   "Option of decrypting encrypted parts.
 431 `never', not decrypt; `always', always decrypt;
 432 `known', only decrypt known protocols.  Otherwise, ask user."
 433   :type '(choice (item always)
 434                  (item never)
 435                  (item :tag "only known protocols" known)
 436                  (item :tag "ask" nil))
 437   :group 'mime-security)
 438
 439 (defvar mm-viewer-completion-map
 440   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 441     (set-keymap-parent map minibuffer-local-completion-map)
 442     map)
 443   "Keymap for input viewer with completion.")
 444
 445 ;; Should we bind other key to minibuffer-complete-word?
 446 (define-key mm-viewer-completion-map " " 'self-insert-command)
 447
 448 (defvar mm-viewer-completion-map
 449   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 450     (set-keymap-parent map minibuffer-local-completion-map)
 451     map)
 452   "Keymap for input viewer with completion.")
 453
 454 ;; Should we bind other key to minibuffer-complete-word?
 455 (define-key mm-viewer-completion-map " " 'self-insert-command)
 456
 457 ;;; The functions.
 458
 459 (defun mm-alist-to-plist (alist)
 460   "Convert association list ALIST into the equivalent property-list form.
 461 The plist is returned.  This converts from
 462
 463 \((a . 1) (b . 2) (c . 3))
 464
 465 into
 466
 467 \(a 1 b 2 c 3)
 468
 469 The original alist is not modified.  See also `destructive-alist-to-plist'."
 470   (let (plist)
 471     (while alist
 472       (let ((el (car alist)))
 473         (setq plist (cons (cdr el) (cons (car el) plist))))
 474       (setq alist (cdr alist)))
 475     (nreverse plist)))
 476
 477 (defun mm-keep-viewer-alive-p (handle)
 478   "Say whether external viewer for HANDLE should stay alive."
 479   (let ((types mm-keep-viewer-alive-types)
 480         (type (mm-handle-media-type handle))
 481         ty)
 482     (catch 'found
 483       (while (setq ty (pop types))
 484         (when (string-match ty type)
 485           (throw 'found t))))))
 486
 487 (defun mm-handle-set-external-undisplayer (handle function)
 488   "Set the undisplayer for HANDLE to FUNCTION.
 489 Postpone undisplaying of viewers for types in
 490 `mm-keep-viewer-alive-types'."
 491   (if (mm-keep-viewer-alive-p handle)
 492       (let ((new-handle (copy-sequence handle)))
 493         (mm-handle-set-undisplayer new-handle function)
 494         (mm-handle-set-undisplayer handle nil)
 495         (push new-handle mm-postponed-undisplay-list))
 496     (mm-handle-set-undisplayer handle function)))
 497
 498 (defun mm-destroy-postponed-undisplay-list ()
 499   (when mm-postponed-undisplay-list
 500     (message "Destroying external MIME viewers")
 501     (mm-destroy-parts mm-postponed-undisplay-list)))
 502
 503 (defun mm-dissect-buffer (&optional no-strict-mime loose-mime)
 504   "Dissect the current buffer and return a list of MIME handles."
 505   (save-excursion
 506     (let (ct ctl type subtype cte cd description id result from)
 507       (save-restriction
 508         (mail-narrow-to-head)
 509         (when (or no-strict-mime
 510                   loose-mime
 511                   (mail-fetch-field "mime-version"))
 512           (setq ct (mail-fetch-field "content-type")
 513                 ctl (ignore-errors (mail-header-parse-content-type ct))
 514                 cte (mail-fetch-field "content-transfer-encoding")
 515                 cd (mail-fetch-field "content-disposition")
 516                 description (mail-fetch-field "content-description")
 517                 from (mail-fetch-field "from")
 518                 id (mail-fetch-field "content-id"))
 519           ;; FIXME: In some circumstances, this code is running within
 520           ;; an unibyte macro.  mail-extract-address-components
 521           ;; creates unibyte buffers. This `if', though not a perfect
 522           ;; solution, avoids most of them.
 523           (if from
 524               (setq from (cadr (mail-extract-address-components from))))))
 525       (if (or (not ctl)
 526               (not (string-match "/" (car ctl))))
 527           (mm-dissect-singlepart
 528            (list mm-dissect-default-type)
 529            (and cte (intern (downcase (mail-header-strip cte))))
 530            no-strict-mime
 531            (and cd (ignore-errors (mail-header-parse-content-disposition cd)))
 532            description)
 533         (setq type (split-string (car ctl) "/"))
 534         (setq subtype (cadr type)
 535               type (pop type))
 536         (setq
 537          result
 538          (cond
 539           ((equal type "multipart")
 540            (let ((mm-dissect-default-type (if (equal subtype "digest")
 541                                               "message/rfc822"
 542                                             "text/plain"))
 543                  (start (cdr (assq 'start (cdr ctl)))))
 544              (add-text-properties 0 (length (car ctl))
 545                                   (mm-alist-to-plist (cdr ctl)) (car ctl))
 546
 547              ;; what really needs to be done here is a way to link a
 548              ;; MIME handle back to it's parent MIME handle (in a multilevel
 549              ;; MIME article).  That would probably require changing
 550              ;; the mm-handle API so we simply store the multipart buffert
 551              ;; name as a text property of the "multipart/whatever" string.
 552              (add-text-properties 0 (length (car ctl))
 553                                   (list 'buffer (mm-copy-to-buffer)
 554                                         'from from
 555                                         'start start)
 556                                   (car ctl))
 557              (cons (car ctl) (mm-dissect-multipart ctl))))
 558           (t
 559            (mm-possibly-verify-or-decrypt
 560             (mm-dissect-singlepart
 561              ctl
 562              (and cte (intern (downcase (mail-header-strip cte))))
 563              no-strict-mime
 564              (and cd (ignore-errors
 565                        (mail-header-parse-content-disposition cd)))
 566              description id)
 567             ctl))))
 568         (when id
 569           (when (string-match " *<\\(.*\\)> *" id)
 570             (setq id (match-string 1 id)))
 571           (push (cons id result) mm-content-id-alist))
 572         result))))
 573
 574 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 575   (when (or force
 576             (if (equal "text/plain" (car ctl))
 577                 ;; FIXME: This is a kludge.  Proper fix is to make
 578                 ;; gnus-display-mime invoke mm-uu-dissect on all
 579                 ;; textual MIME parts, and stop using mm-fill-flowed
 580                 ;; here.
 581                 (and mm-fill-flowed (assoc 'format ctl))
 582               t))
 583     (mm-make-handle
 584      (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 585
 586 (defun mm-dissect-multipart (ctl)
 587   (goto-char (point-min))
 588   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 589          (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 590          start parts
 591          (end (save-excursion
 592                 (goto-char (point-max))
 593                 (if (re-search-backward close-delimiter nil t)
 594                     (match-beginning 0)
 595                   (point-max)))))
 596     (setq boundary (concat (regexp-quote boundary) "[ \t]*$"))
 597     (while (and (< (point) end) (re-search-forward boundary end t))
 598       (goto-char (match-beginning 0))
 599       (when start
 600         (save-excursion
 601           (save-restriction
 602             (narrow-to-region start (point))
 603             (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 604       (end-of-line 2)
 605       (or (looking-at boundary)
 606           (forward-line 1))
 607       (setq start (point)))
 608     (when (and start (< start end))
 609       (save-excursion
 610         (save-restriction
 611           (narrow-to-region start end)
 612           (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 613     (mm-possibly-verify-or-decrypt (nreverse parts) ctl)))
 614
 615 (defun mm-copy-to-buffer ()
 616   "Copy the contents of the current buffer to a fresh buffer."
 617   (save-excursion
 618     (let ((flag enable-multibyte-characters)
 619           (new-buffer (generate-new-buffer " *mm*")))
 620       (goto-char (point-min))
 621       (search-forward-regexp "^\n" nil t)
 622       (save-restriction
 623         (narrow-to-region (point) (point-max))
 624         (when flag
 625           (set-buffer-multibyte nil))
 626         (copy-to-buffer new-buffer (point-min) (point-max))
 627         (when flag
 628           (set-buffer-multibyte t)))
 629       new-buffer)))
 630
 631 (defun mm-display-parts (handle &optional no-default)
 632   (if (stringp (car handle))
 633       (mapcar 'mm-display-parts (cdr handle))
 634     (if (bufferp (car handle))
 635         (save-restriction
 636           (narrow-to-region (point) (point))
 637           (mm-display-part handle)
 638           (goto-char (point-max)))
 639       (mapcar 'mm-display-parts handle))))
 640
 641 (defun mm-display-part (handle &optional no-default)
 642   "Display the MIME part represented by HANDLE.
 643 Returns nil if the part is removed; inline if displayed inline;
 644 external if displayed external."
 645   (save-excursion
 646     (mailcap-parse-mailcaps)
 647     (if (mm-handle-displayed-p handle)
 648         (mm-remove-part handle)
 649       (let* ((type (mm-handle-media-type handle))
 650              (method (mailcap-mime-info type))
 651              (filename (or (mail-content-type-get
 652                             (mm-handle-disposition handle) 'filename)
 653                            (mail-content-type-get
 654                             (mm-handle-type handle) 'name)
 655                            "<file>"))
 656              (external mm-enable-external))
 657         (if (and (mm-inlinable-p handle)
 658                  (mm-inlined-p handle))
 659             (progn
 660               (forward-line 1)
 661               (mm-display-inline handle)
 662               'inline)
 663           (when (or method
 664                     (not no-default))
 665             (if (and (not method)
 666                      (equal "text" (car (split-string type))))
 667                 (progn
 668                   (forward-line 1)
 669                   (mm-insert-inline handle (mm-get-part handle))
 670                   'inline)
 671               (if (and method ;; If nil, we always use "save".
 672                        (stringp method) ;; 'mailcap-save-binary-file
 673                        (or (eq mm-enable-external t)
 674                            (and (eq mm-enable-external 'ask)
 675                                 (y-or-n-p
 676                                  (concat
 677                                   "Display part (" type
 678                                   ") using external program"
 679                                   ;; Can non-string method ever happen?
 680                                   (if (stringp method)
 681                                       (concat
 682                                        " \"" (format method filename) "\"")
 683                                     "")
 684                                   "? ")))))
 685                   (setq external t)
 686                 (setq external nil))
 687               (if external
 688                   (mm-display-external
 689                    handle (or method 'mailcap-save-binary-file))
 690                 (mm-display-external
 691                  handle 'mailcap-save-binary-file)))))))))
 692
 693 (defun mm-display-external (handle method)
 694   "Display HANDLE using METHOD."
 695   (let ((outbuf (current-buffer)))
 696     (mm-with-unibyte-buffer
 697       (if (functionp method)
 698           (let ((cur (current-buffer)))
 699             (if (eq method 'mailcap-save-binary-file)
 700                 (progn
 701                   (set-buffer (generate-new-buffer " *mm*"))
 702                   (setq method nil))
 703               (mm-insert-part handle)
 704               (let ((win (get-buffer-window cur t)))
 705                 (when win
 706                   (select-window win)))
 707               (switch-to-buffer (generate-new-buffer " *mm*")))
 708             (buffer-disable-undo)
 709             (mm-set-buffer-file-coding-system mm-binary-coding-system)
 710             (insert-buffer-substring cur)
 711             (goto-char (point-min))
 712             (when method
 713               (message "Viewing with %s" method))
 714             (let ((mm (current-buffer))
 715                   (non-viewer (assq 'non-viewer
 716                                     (mailcap-mime-info
 717                                      (mm-handle-media-type handle) t))))
 718               (unwind-protect
 719                   (if method
 720                       (funcall method)
 721                     (mm-save-part handle))
 722                 (when (and (not non-viewer)
 723                            method)
 724                   (mm-handle-set-undisplayer handle mm)))))
 725         ;; The function is a string to be executed.
 726         (mm-insert-part handle)
 727         (let* ((dir (mm-make-temp-file
 728                      (expand-file-name "emm." mm-tmp-directory) 'dir))
 729                (filename (or
 730                           (mail-content-type-get
 731                            (mm-handle-disposition handle) 'filename)
 732                           (mail-content-type-get
 733                            (mm-handle-type handle) 'name)))
 734                (mime-info (mailcap-mime-info
 735                            (mm-handle-media-type handle) t))
 736                (needsterm (or (assoc "needsterm" mime-info)
 737                               (assoc "needsterminal" mime-info)))
 738                (copiousoutput (assoc "copiousoutput" mime-info))
 739                file buffer)
 740           ;; We create a private sub-directory where we store our files.
 741           (set-file-modes dir 448)
 742           (if filename
 743               (setq file (expand-file-name
 744                           (gnus-map-function mm-file-name-rewrite-functions
 745                                              (file-name-nondirectory filename))
 746                           dir))
 747             (setq file (mm-make-temp-file (expand-file-name "mm." dir))))
 748           (let ((coding-system-for-write mm-binary-coding-system))
 749             (write-region (point-min) (point-max) file nil 'nomesg))
 750           (message "Viewing with %s" method)
 751           (cond
 752            (needsterm
 753             (let ((command (mm-mailcap-command
 754                             method file (mm-handle-type handle))))
 755               (unwind-protect
 756                   (if window-system
 757                       (start-process "*display*" nil
 758                                      mm-external-terminal-program
 759                                      "-e" shell-file-name
 760                                      shell-command-switch command)
 761                     (require 'term)
 762                     (require 'gnus-win)
 763                     (set-buffer
 764                      (setq buffer
 765                            (make-term "display"
 766                                       shell-file-name
 767                                       nil
 768                                       shell-command-switch command)))
 769                     (term-mode)
 770                     (term-char-mode)
 771                     (set-process-sentinel
 772                      (get-buffer-process buffer)
 773                      `(lambda (process state)
 774                         (if (eq 'exit (process-status process))
 775                             (gnus-configure-windows
 776                              ',gnus-current-window-configuration))))
 777                     (gnus-configure-windows 'display-term))
 778                 (mm-handle-set-external-undisplayer handle (cons file buffer)))
 779               (message "Displaying %s..." command))
 780             'external)
 781            (copiousoutput
 782             (with-current-buffer outbuf
 783               (forward-line 1)
 784               (mm-insert-inline
 785                handle
 786                (unwind-protect
 787                    (progn
 788                      (call-process shell-file-name nil
 789                                    (setq buffer
 790                                          (generate-new-buffer " *mm*"))
 791                                    nil
 792                                    shell-command-switch
 793                                    (mm-mailcap-command
 794                                     method file (mm-handle-type handle)))
 795                      (if (buffer-live-p buffer)
 796                          (save-excursion
 797                            (set-buffer buffer)
 798                            (buffer-string))))
 799                  (progn
 800                    (ignore-errors (delete-file file))
 801                    (ignore-errors (delete-directory
 802                                    (file-name-directory file)))
 803                    (ignore-errors (kill-buffer buffer))))))
 804             'inline)
 805            (t
 806             (let ((command (mm-mailcap-command
 807                             method file (mm-handle-type handle))))
 808               (unwind-protect
 809                   (start-process "*display*"
 810                                  (setq buffer
 811                                        (generate-new-buffer " *mm*"))
 812                                  shell-file-name
 813                                  shell-command-switch command)
 814                 (mm-handle-set-external-undisplayer
 815                  handle (cons file buffer)))
 816               (message "Displaying %s..." command))
 817             'external)))))))
 818
 819 (defun mm-mailcap-command (method file type-list)
 820   (let ((ctl (cdr type-list))
 821         (beg 0)
 822         (uses-stdin t)
 823         out sub total)
 824     (while (string-match "%{\\([^}]+\\)}\\|'%s'\\|\"%s\"\\|%s\\|%t\\|%%"
 825                          method beg)
 826       (push (substring method beg (match-beginning 0)) out)
 827       (setq beg (match-end 0)
 828             total (match-string 0 method)
 829             sub (match-string 1 method))
 830       (cond
 831        ((string= total "%%")
 832         (push "%" out))
 833        ((or (string= total "%s")
 834             ;; We do our own quoting.
 835             (string= total "'%s'")
 836             (string= total "\"%s\""))
 837         (setq uses-stdin nil)
 838         (push (shell-quote-argument
 839                (gnus-map-function mm-path-name-rewrite-functions file)) out))
 840        ((string= total "%t")
 841         (push (shell-quote-argument (car type-list)) out))
 842        (t
 843         (push (shell-quote-argument (or (cdr (assq (intern sub) ctl)) "")) out))))
 844     (push (substring method beg (length method)) out)
 845     (when uses-stdin
 846       (push "<" out)
 847       (push (shell-quote-argument
 848              (gnus-map-function mm-path-name-rewrite-functions file))
 849             out))
 850     (mapconcat 'identity (nreverse out) "")))
 851
 852 (defun mm-remove-parts (handles)
 853   "Remove the displayed MIME parts represented by HANDLES."
 854   (if (and (listp handles)
 855            (bufferp (car handles)))
 856       (mm-remove-part handles)
 857     (let (handle)
 858       (while (setq handle (pop handles))
 859         (cond
 860          ((stringp handle)
 861           (when (buffer-live-p (get-text-property 0 'buffer handle))
 862             (kill-buffer (get-text-property 0 'buffer handle))))
 863          ((and (listp handle)
 864                (stringp (car handle)))
 865           (mm-remove-parts (cdr handle)))
 866          (t
 867           (mm-remove-part handle)))))))
 868
 869 (defun mm-destroy-parts (handles)
 870   "Remove the displayed MIME parts represented by HANDLES."
 871   (if (and (listp handles)
 872            (bufferp (car handles)))
 873       (mm-destroy-part handles)
 874     (let (handle)
 875       (while (setq handle (pop handles))
 876         (cond
 877          ((stringp handle)
 878           (when (buffer-live-p (get-text-property 0 'buffer handle))
 879             (kill-buffer (get-text-property 0 'buffer handle))))
 880          ((and (listp handle)
 881                (stringp (car handle)))
 882           (mm-destroy-parts handle))
 883          (t
 884           (mm-destroy-part handle)))))))
 885
 886 (defun mm-remove-part (handle)
 887   "Remove the displayed MIME part represented by HANDLE."
 888   (when (listp handle)
 889     (let ((object (mm-handle-undisplayer handle)))
 890       (ignore-errors
 891         (cond
 892          ;; Internally displayed part.
 893          ((mm-annotationp object)
 894           (delete-annotation object))
 895          ((or (functionp object)
 896               (and (listp object)
 897                    (eq (car object) 'lambda)))
 898           (funcall object))
 899          ;; Externally displayed part.
 900          ((consp object)
 901           (condition-case ()
 902               (while (get-buffer-process (cdr object))
 903                 (interrupt-process (get-buffer-process (cdr object)))
 904                 (message "Waiting for external displayer to die...")
 905                 (sit-for 1))
 906             (quit)
 907             (error))
 908           (ignore-errors (and (cdr object) (kill-buffer (cdr object))))
 909           (message "Waiting for external displayer to die...done")
 910           (ignore-errors (delete-file (car object)))
 911           (ignore-errors (delete-directory (file-name-directory
 912                                             (car object)))))
 913          ((bufferp object)
 914           (when (buffer-live-p object)
 915             (kill-buffer object)))))
 916       (mm-handle-set-undisplayer handle nil))))
 917
 918 (defun mm-display-inline (handle)
 919   (let* ((type (mm-handle-media-type handle))
 920          (function (cadr (mm-assoc-string-match mm-inline-media-tests type))))
 921     (funcall function handle)
 922     (goto-char (point-min))))
 923
 924 (defun mm-assoc-string-match (alist type)
 925   (dolist (elem alist)
 926     (when (string-match (car elem) type)
 927       (return elem))))
 928
 929 (defun mm-automatic-display-p (handle)
 930   "Say whether the user wants HANDLE to be displayed automatically."
 931   (let ((methods mm-automatic-display)
 932         (type (mm-handle-media-type handle))
 933         method result)
 934     (while (setq method (pop methods))
 935       (when (and (not (mm-inline-override-p handle))
 936                  (string-match method type))
 937         (setq result t
 938               methods nil)))
 939     result))
 940
 941 (defun mm-inlinable-p (handle)
 942   "Say whether HANDLE can be displayed inline."
 943   (let ((alist mm-inline-media-tests)
 944         (type (mm-handle-media-type handle))
 945         test)
 946     (while alist
 947       (when (string-match (caar alist) type)
 948         (setq test (caddar alist)
 949               alist nil)
 950         (setq test (funcall test handle)))
 951       (pop alist))
 952     test))
 953
 954 (defun mm-inlined-p (handle)
 955   "Say whether the user wants HANDLE to be displayed inline."
 956   (let ((methods mm-inlined-types)
 957         (type (mm-handle-media-type handle))
 958         method result)
 959     (while (setq method (pop methods))
 960       (when (and (not (mm-inline-override-p handle))
 961                  (string-match method type))
 962         (setq result t
 963               methods nil)))
 964     result))
 965
 966 (defun mm-attachment-override-p (handle)
 967   "Say whether HANDLE should have attachment behavior overridden."
 968   (let ((types mm-attachment-override-types)
 969         (type (mm-handle-media-type handle))
 970         ty)
 971     (catch 'found
 972       (while (setq ty (pop types))
 973         (when (and (string-match ty type)
 974                    (mm-inlinable-p handle))
 975           (throw 'found t))))))
 976
 977 (defun mm-inline-override-p (handle)
 978   "Say whether HANDLE should have inline behavior overridden."
 979   (let ((types mm-inline-override-types)
 980         (type (mm-handle-media-type handle))
 981         ty)
 982     (catch 'found
 983       (while (setq ty (pop types))
 984         (when (string-match ty type)
 985           (throw 'found t))))))
 986
 987 (defun mm-automatic-external-display-p (type)
 988   "Return the user-defined method for TYPE."
 989   (let ((methods mm-automatic-external-display)
 990         method result)
 991     (while (setq method (pop methods))
 992       (when (string-match method type)
 993         (setq result t
 994               methods nil)))
 995     result))
 996
 997 (defun mm-destroy-part (handle)
 998   "Destroy the data structures connected to HANDLE."
 999   (when (listp handle)
1000     (mm-remove-part handle)
1001     (when (buffer-live-p (mm-handle-buffer handle))
1002       (kill-buffer (mm-handle-buffer handle)))))
1003
1004 (defun mm-handle-displayed-p (handle)
1005   "Say whether HANDLE is displayed or not."
1006   (mm-handle-undisplayer handle))
1007
1008 ;;;
1009 ;;; Functions for outputting parts
1010 ;;;
1011
1012 (defun mm-get-part (handle)
1013   "Return the contents of HANDLE as a string."
1014   (mm-with-unibyte-buffer
1015     (insert (with-current-buffer (mm-handle-buffer handle)
1016               (mm-with-unibyte-current-buffer
1017                 (buffer-string))))
1018     (mm-decode-content-transfer-encoding
1019      (mm-handle-encoding handle)
1020      (mm-handle-media-type handle))
1021     (buffer-string)))
1022
1023 (defun mm-insert-part (handle)
1024   "Insert the contents of HANDLE in the current buffer."
1025   (let ((cur (current-buffer)))
1026     (save-excursion
1027       (if (member (mm-handle-media-supertype handle) '("text" "message"))
1028           (with-temp-buffer
1029             (insert-buffer-substring (mm-handle-buffer handle))
1030             (prog1
1031                 (mm-decode-content-transfer-encoding
1032                  (mm-handle-encoding handle)
1033                  (mm-handle-media-type handle))
1034               (let ((temp (current-buffer)))
1035                 (set-buffer cur)
1036                 (insert-buffer-substring temp))))
1037         (mm-with-unibyte-buffer
1038           (insert-buffer-substring (mm-handle-buffer handle))
1039           (prog1
1040               (mm-decode-content-transfer-encoding
1041                (mm-handle-encoding handle)
1042                (mm-handle-media-type handle))
1043             (let ((temp (current-buffer)))
1044               (set-buffer cur)
1045               (insert-buffer-substring temp))))))))
1046
1047 (defun mm-file-name-delete-whitespace (file-name)
1048   "Remove all whitespace characters from FILE-NAME."
1049   (while (string-match "\\s-+" file-name)
1050     (setq file-name (replace-match "" t t file-name)))
1051   file-name)
1052
1053 (defun mm-file-name-trim-whitespace (file-name)
1054   "Remove leading and trailing whitespace characters from FILE-NAME."
1055   (when (string-match "\\`\\s-+" file-name)
1056     (setq file-name (substring file-name (match-end 0))))
1057   (when (string-match "\\s-+\\'" file-name)
1058     (setq file-name (substring file-name 0 (match-beginning 0))))
1059   file-name)
1060
1061 (defun mm-file-name-collapse-whitespace (file-name)
1062   "Collapse multiple whitespace characters in FILE-NAME."
1063   (while (string-match "\\s-\\s-+" file-name)
1064     (setq file-name (replace-match " " t t file-name)))
1065   file-name)
1066
1067 (defun mm-file-name-replace-whitespace (file-name)
1068   "Replace whitespace characters in FILE-NAME with underscores.
1069 Set the option `mm-file-name-replace-whitespace' to any other
1070 string if you do not like underscores."
1071   (let ((s (or mm-file-name-replace-whitespace "_")))
1072     (while (string-match "\\s-" file-name)
1073       (setq file-name (replace-match s t t file-name))))
1074   file-name)
1075
1076 (defun mm-file-name-delete-control (filename)
1077   "Delete control characters from FILENAME."
1078   (gnus-replace-in-string filename "[\x00-\x1f\x7f]" ""))
1079
1080 (defun mm-file-name-delete-gotchas (filename)
1081   "Delete shell gotchas from FILENAME."
1082   (setq filename (gnus-replace-in-string filename "[<>|]" ""))
1083   (gnus-replace-in-string filename "^[.-]+" ""))
1084
1085 (defun mm-save-part (handle)
1086   "Write HANDLE to a file."
1087   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1088          (filename (mail-content-type-get
1089                     (mm-handle-disposition handle) 'filename))
1090          file)
1091     (when filename
1092       (setq filename (gnus-map-function mm-file-name-rewrite-functions
1093                                         (file-name-nondirectory filename))))
1094     (setq file
1095           (mm-with-multibyte
1096             (read-file-name "Save MIME part to: "
1097                             (or mm-default-directory default-directory)
1098                             nil nil (or filename name ""))))
1099     (setq mm-default-directory (file-name-directory file))
1100     (and (or (not (file-exists-p file))
1101              (yes-or-no-p (format "File %s already exists; overwrite? "
1102                                   file)))
1103          (progn
1104            (mm-save-part-to-file handle file)
1105            file))))
1106
1107 (defun mm-save-part-to-file (handle file)
1108   (mm-with-unibyte-buffer
1109     (mm-insert-part handle)
1110     (let ((coding-system-for-write 'binary)
1111           (current-file-modes (default-file-modes))
1112           ;; Don't re-compress .gz & al.  Arguably we should make
1113           ;; `file-name-handler-alist' nil, but that would chop
1114           ;; ange-ftp, which is reasonable to use here.
1115           (inhibit-file-name-operation 'write-region)
1116           (inhibit-file-name-handlers
1117            (cons 'jka-compr-handler inhibit-file-name-handlers)))
1118       (set-default-file-modes mm-attachment-file-modes)
1119       (unwind-protect
1120           (write-region (point-min) (point-max) file)
1121         (set-default-file-modes current-file-modes)))))
1122
1123 (defun mm-pipe-part (handle)
1124   "Pipe HANDLE to a process."
1125   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1126          (command
1127           (read-string "Shell command on MIME part: " mm-last-shell-command)))
1128     (mm-with-unibyte-buffer
1129       (mm-insert-part handle)
1130       (let ((coding-system-for-write 'binary))
1131         (shell-command-on-region (point-min) (point-max) command nil)))))
1132
1133 (defun mm-interactively-view-part (handle)
1134   "Display HANDLE using METHOD."
1135   (let* ((type (mm-handle-media-type handle))
1136          (methods
1137           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
1138                   (mailcap-mime-info type 'all)))
1139          (method (let ((minibuffer-local-completion-map
1140                         mm-viewer-completion-map))
1141                    (completing-read "Viewer: " methods))))
1142     (when (string= method "")
1143       (error "No method given"))
1144     (if (string-match "^[^% \t]+$" method)
1145         (setq method (concat method " %s")))
1146     (mm-display-external handle method)))
1147
1148 (defun mm-preferred-alternative (handles &optional preferred)
1149   "Say which of HANDLES are preferred."
1150   (let ((prec (if preferred (list preferred)
1151                 (mm-preferred-alternative-precedence handles)))
1152         p h result type handle)
1153     (while (setq p (pop prec))
1154       (setq h handles)
1155       (while h
1156         (setq handle (car h))
1157         (setq type (mm-handle-media-type handle))
1158         (when (and (equal p type)
1159                    (mm-automatic-display-p handle)
1160                    (or (stringp (car handle))
1161                        (not (mm-handle-disposition handle))
1162                        (equal (car (mm-handle-disposition handle))
1163                               "inline")))
1164           (setq result handle
1165                 h nil
1166                 prec nil))
1167         (pop h)))
1168     result))
1169
1170 (defun mm-preferred-alternative-precedence (handles)
1171   "Return the precedence based on HANDLES and `mm-discouraged-alternatives'."
1172   (let ((seq (nreverse (mapcar #'mm-handle-media-type
1173                                handles))))
1174     (dolist (disc (reverse mm-discouraged-alternatives))
1175       (dolist (elem (copy-sequence seq))
1176         (when (string-match disc elem)
1177           (setq seq (nconc (delete elem seq) (list elem))))))
1178     seq))
1179
1180 (defun mm-get-content-id (id)
1181   "Return the handle(s) referred to by ID."
1182   (cdr (assoc id mm-content-id-alist)))
1183
1184 (defconst mm-image-type-regexps
1185   '(("/\\*.*XPM.\\*/" . xpm)
1186     ("P[1-6]" . pbm)
1187     ("GIF8" . gif)
1188     ("\377\330" . jpeg)
1189     ("\211PNG\r\n" . png)
1190     ("#define" . xbm)
1191     ("\\(MM\0\\*\\)\\|\\(II\\*\0\\)" . tiff)
1192     ("%!PS" . postscript))
1193   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
1194 When the first bytes of an image file match REGEXP, it is assumed to
1195 be of image type IMAGE-TYPE.")
1196
1197 ;; Steal from image.el. image-type-from-data suffers multi-line matching bug.
1198 (defun mm-image-type-from-buffer ()
1199   "Determine the image type from data in the current buffer.
1200 Value is a symbol specifying the image type or nil if type cannot
1201 be determined."
1202   (let ((types mm-image-type-regexps)
1203         type)
1204     (goto-char (point-min))
1205     (while (and types (null type))
1206       (let ((regexp (car (car types)))
1207             (image-type (cdr (car types))))
1208         (when (looking-at regexp)
1209           (setq type image-type))
1210         (setq types (cdr types))))
1211     type))
1212
1213 (defun mm-get-image (handle)
1214   "Return an image instance based on HANDLE."
1215   (let ((type (mm-handle-media-subtype handle))
1216         spec)
1217     ;; Allow some common translations.
1218     (setq type
1219           (cond
1220            ((equal type "x-pixmap")
1221             "xpm")
1222            ((equal type "x-xbitmap")
1223             "xbm")
1224            ((equal type "x-portable-bitmap")
1225             "pbm")
1226            (t type)))
1227     (or (mm-handle-cache handle)
1228         (mm-with-unibyte-buffer
1229           (mm-insert-part handle)
1230           (prog1
1231               (setq spec
1232                     (ignore-errors
1233                       ;; Avoid testing `make-glyph' since W3 may define
1234                       ;; a bogus version of it.
1235                       (if (fboundp 'create-image)
1236                           (create-image (buffer-string)
1237                                         (or (mm-image-type-from-buffer)
1238                                             (intern type))
1239                                         'data-p)
1240                         (mm-create-image-xemacs type))))
1241             (mm-handle-set-cache handle spec))))))
1242
1243 (defun mm-create-image-xemacs (type)
1244   (cond
1245    ((equal type "xbm")
1246     ;; xbm images require special handling, since
1247     ;; the only way to create glyphs from these
1248     ;; (without a ton of work) is to write them
1249     ;; out to a file, and then create a file
1250     ;; specifier.
1251     (let ((file (mm-make-temp-file
1252                  (expand-file-name "emm.xbm"
1253                                    mm-tmp-directory))))
1254       (unwind-protect
1255           (progn
1256             (write-region (point-min) (point-max) file)
1257             (make-glyph (list (cons 'x file))))
1258         (ignore-errors
1259           (delete-file file)))))
1260    (t
1261     (make-glyph
1262      (vector
1263       (or (mm-image-type-from-buffer)
1264           (intern type))
1265       :data (buffer-string))))))
1266
1267 (defun mm-image-fit-p (handle)
1268   "Say whether the image in HANDLE will fit the current window."
1269   (let ((image (mm-get-image handle)))
1270     (if (fboundp 'glyph-width)
1271         ;; XEmacs' glyphs can actually tell us about their width, so
1272         ;; lets be nice and smart about them.
1273         (or mm-inline-large-images
1274             (and (< (glyph-width image) (window-pixel-width))
1275                  (< (glyph-height image) (window-pixel-height))))
1276       (let* ((size (image-size image))
1277              (w (car size))
1278              (h (cdr size)))
1279         (or mm-inline-large-images
1280             (and (< h (1- (window-height))) ; Don't include mode line.
1281                  (< w (window-width))))))))
1282
1283 (defun mm-valid-image-format-p (format)
1284   "Say whether FORMAT can be displayed natively by Emacs."
1285   (cond
1286    ;; Handle XEmacs
1287    ((fboundp 'valid-image-instantiator-format-p)
1288     (valid-image-instantiator-format-p format))
1289    ;; Handle Emacs 21
1290    ((fboundp 'image-type-available-p)
1291     (and (display-graphic-p)
1292          (image-type-available-p format)))
1293    ;; Nobody else can do images yet.
1294    (t
1295     nil)))
1296
1297 (defun mm-valid-and-fit-image-p (format handle)
1298   "Say whether FORMAT can be displayed natively and HANDLE fits the window."
1299   (and (mm-valid-image-format-p format)
1300        (mm-image-fit-p handle)))
1301
1302 (defun mm-find-part-by-type (handles type &optional notp recursive)
1303   "Search in HANDLES for part with TYPE.
1304 If NOTP, returns first non-matching part.
1305 If RECURSIVE, search recursively."
1306   (let (handle)
1307     (while handles
1308       (if (and recursive (stringp (caar handles)))
1309           (if (setq handle (mm-find-part-by-type (cdar handles) type
1310                                                  notp recursive))
1311               (setq handles nil))
1312         (if (if notp
1313                 (not (equal (mm-handle-media-type (car handles)) type))
1314               (equal (mm-handle-media-type (car handles)) type))
1315             (setq handle (car handles)
1316                   handles nil)))
1317       (setq handles (cdr handles)))
1318     handle))
1319
1320 (defun mm-find-raw-part-by-type (ctl type &optional notp)
1321   (goto-char (point-min))
1322   (let* ((boundary (concat "--" (mm-handle-multipart-ctl-parameter ctl
1323                                                                    'boundary)))
1324          (close-delimiter (concat "^" (regexp-quote boundary) "--[ \t]*$"))
1325          start
1326          (end (save-excursion
1327                 (goto-char (point-max))
1328                 (if (re-search-backward close-delimiter nil t)
1329                     (match-beginning 0)
1330                   (point-max))))
1331          result)
1332     (setq boundary (concat "^" (regexp-quote boundary) "[ \t]*$"))
1333     (while (and (not result)
1334                 (re-search-forward boundary end t))
1335       (goto-char (match-beginning 0))
1336       (when start
1337         (save-excursion
1338           (save-restriction
1339             (narrow-to-region start (1- (point)))
1340             (when (let ((ctl (ignore-errors
1341                                (mail-header-parse-content-type
1342                                 (mail-fetch-field "content-type")))))
1343                     (if notp
1344                         (not (equal (car ctl) type))
1345                       (equal (car ctl) type)))
1346               (setq result (buffer-string))))))
1347       (forward-line 1)
1348       (setq start (point)))
1349     (when (and (not result) start)
1350       (save-excursion
1351         (save-restriction
1352           (narrow-to-region start end)
1353           (when (let ((ctl (ignore-errors
1354                              (mail-header-parse-content-type
1355                               (mail-fetch-field "content-type")))))
1356                   (if notp
1357                       (not (equal (car ctl) type))
1358                     (equal (car ctl) type)))
1359             (setq result (buffer-string))))))
1360     result))
1361
1362 (defvar mm-security-handle nil)
1363
1364 (defsubst mm-set-handle-multipart-parameter (handle parameter value)
1365   ;; HANDLE could be a CTL.
1366   (when handle
1367     (put-text-property 0 (length (car handle)) parameter value
1368                        (car handle))))
1369
1370 (defun mm-possibly-verify-or-decrypt (parts ctl)
1371   (let ((type (car ctl))
1372         (subtype (cadr (split-string (car ctl) "/")))
1373         (mm-security-handle ctl) ;; (car CTL) is the type.
1374         protocol func functest)
1375     (cond
1376      ((or (equal type "application/x-pkcs7-mime")
1377           (equal type "application/pkcs7-mime"))
1378       (with-temp-buffer
1379         (when (and (cond
1380                     ((eq mm-decrypt-option 'never) nil)
1381                     ((eq mm-decrypt-option 'always) t)
1382                     ((eq mm-decrypt-option 'known) t)
1383                     (t (y-or-n-p
1384                         (format "Decrypt (S/MIME) part? "))))
1385                    (mm-view-pkcs7 parts))
1386           (setq parts (mm-dissect-buffer t)))))
1387      ((equal subtype "signed")
1388       (unless (and (setq protocol
1389                          (mm-handle-multipart-ctl-parameter ctl 'protocol))
1390                    (not (equal protocol "multipart/mixed")))
1391         ;; The message is broken or draft-ietf-openpgp-multsig-01.
1392         (let ((protocols mm-verify-function-alist))
1393           (while protocols
1394             (if (and (or (not (setq functest (nth 3 (car protocols))))
1395                          (funcall functest parts ctl))
1396                      (mm-find-part-by-type parts (caar protocols) nil t))
1397                 (setq protocol (caar protocols)
1398                       protocols nil)
1399               (setq protocols (cdr protocols))))))
1400       (setq func (nth 1 (assoc protocol mm-verify-function-alist)))
1401       (when (cond
1402              ((eq mm-verify-option 'never) nil)
1403              ((eq mm-verify-option 'always) t)
1404              ((eq mm-verify-option 'known)
1405               (and func
1406                    (or (not (setq functest
1407                                   (nth 3 (assoc protocol
1408                                                 mm-verify-function-alist))))
1409                        (funcall functest parts ctl))))
1410              (t
1411               (y-or-n-p
1412                (format "Verify signed (%s) part? "
1413                        (or (nth 2 (assoc protocol mm-verify-function-alist))
1414                            (format "protocol=%s" protocol))))))
1415         (save-excursion
1416           (if func
1417               (funcall func parts ctl)
1418             (mm-set-handle-multipart-parameter
1419              mm-security-handle 'gnus-details
1420              (format "Unknown sign protocol (%s)" protocol))))))
1421      ((equal subtype "encrypted")
1422       (unless (setq protocol
1423                     (mm-handle-multipart-ctl-parameter ctl 'protocol))
1424         ;; The message is broken.
1425         (let ((parts parts))
1426           (while parts
1427             (if (assoc (mm-handle-media-type (car parts))
1428                        mm-decrypt-function-alist)
1429                 (setq protocol (mm-handle-media-type (car parts))
1430                       parts nil)
1431               (setq parts (cdr parts))))))
1432       (setq func (nth 1 (assoc protocol mm-decrypt-function-alist)))
1433       (when (cond
1434              ((eq mm-decrypt-option 'never) nil)
1435              ((eq mm-decrypt-option 'always) t)
1436              ((eq mm-decrypt-option 'known)
1437               (and func
1438                    (or (not (setq functest
1439                                   (nth 3 (assoc protocol
1440                                                 mm-decrypt-function-alist))))
1441                        (funcall functest parts ctl))))
1442              (t
1443               (y-or-n-p
1444                (format "Decrypt (%s) part? "
1445                        (or (nth 2 (assoc protocol mm-decrypt-function-alist))
1446                            (format "protocol=%s" protocol))))))
1447         (save-excursion
1448           (if func
1449               (setq parts (funcall func parts ctl))
1450             (mm-set-handle-multipart-parameter
1451              mm-security-handle 'gnus-details
1452              (format "Unknown encrypt protocol (%s)" protocol))))))
1453      (t nil))
1454     parts))
1455
1456 (defun mm-multiple-handles (handles)
1457   (and (listp handles)
1458        (> (length handles) 1)
1459        (or (listp (car handles))
1460            (stringp (car handles)))))
1461
1462 (defun mm-complicated-handles (handles)
1463   (and (listp (car handles))
1464        (> (length handles) 1)))
1465
1466 (defun mm-merge-handles (handles1 handles2)
1467   (append
1468    (if (listp (car handles1))
1469        handles1
1470      (list handles1))
1471    (if (listp (car handles2))
1472        handles2
1473      (list handles2))))
1474
1475 (defun mm-readable-p (handle)
1476   "Say whether the content of HANDLE is readable."
1477   (and (< (with-current-buffer (mm-handle-buffer handle)
1478             (buffer-size)) 10000)
1479        (mm-with-unibyte-buffer
1480          (mm-insert-part handle)
1481          (and (eq (mm-body-7-or-8) '7bit)
1482               (not (mm-long-lines-p 76))))))
1483
1484 (provide 'mm-decode)
1485
1486 ;;; mm-decode.el ends here