git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28 (require 'mailcap)
  29 (require 'mm-bodies)
  30
  31 ;;; Convenience macros.
  32
  33 (defmacro mm-handle-buffer (handle)
  34   `(nth 0 ,handle))
  35 (defmacro mm-handle-type (handle)
  36   `(nth 1 ,handle))
  37 (defmacro mm-handle-encoding (handle)
  38   `(nth 2 ,handle))
  39 (defmacro mm-handle-undisplayer (handle)
  40   `(nth 3 ,handle))
  41 (defmacro mm-handle-set-undisplayer (handle function)
  42   `(setcar (nthcdr 3 ,handle) ,function))
  43 (defmacro mm-handle-disposition (handle)
  44   `(nth 4 ,handle))
  45 (defmacro mm-handle-description (handle)
  46   `(nth 5 ,handle))
  47
  48 (defvar mm-inline-media-tests
  49   '(("image/jpeg" mm-inline-image (featurep 'jpeg))
  50     ("image/png" mm-inline-image (featurep 'png))
  51     ("image/gif" mm-inline-image (featurep 'gif))
  52     ("image/tiff" mm-inline-image (featurep 'tiff))
  53     ("image/xbm" mm-inline-image (eq (device-type) 'x))
  54     ("image/xpm" mm-inline-image (featurep 'xpm))
  55     ("image/bmp" mm-inline-image (featurep 'bmp))
  56     ("text/plain" mm-inline-text t)
  57     ("text/enriched" mm-inline-text t)
  58     ("text/richtext" mm-inline-text t)
  59     ("text/html" mm-inline-text (featurep 'w3))
  60     ("message/delivery-status" mm-inline-text t)
  61     ("audio/wav" mm-inline-audio
  62      (and (or (featurep 'nas-sound) (featurep 'native-sound))
  63           (device-sound-enabled-p)))
  64     ("audio/au" mm-inline-audio
  65      (and (or (featurep 'nas-sound) (featurep 'native-sound))
  66           (device-sound-enabled-p))))
  67   "Alist of media types/test that say whether the media types can be displayed inline.")
  68
  69 (defvar mm-user-display-methods
  70   '(("image/.*" . inline)
  71     ("text/.*" . inline)
  72     ("message/delivery-status" . inline)))
  73
  74 (defvar mm-user-automatic-display
  75   '("text/plain" "text/enriched" "text/richtext" "text/html" "image/gif"
  76     "message/delivery-status" "multipart/.*"))
  77
  78 (defvar mm-alternative-precedence
  79   '("text/plain" "text/enriched" "text/richtext" "text/html")
  80   "List that describes the precedence of alternative parts.")
  81
  82 (defvar mm-tmp-directory "/tmp/"
  83   "Where mm will store its temporary files.")
  84
  85 ;;; Internal variables.
  86
  87 (defvar mm-dissection-list nil)
  88 (defvar mm-last-shell-command "")
  89 (defvar mm-content-id-alist nil)
  90
  91 ;;; The functions.
  92
  93 (defun mm-dissect-buffer (&optional no-strict-mime)
  94   "Dissect the current buffer and return a list of MIME handles."
  95   (save-excursion
  96     (let (ct ctl type subtype cte cd description id result)
  97       (save-restriction
  98         (mail-narrow-to-head)
  99         (when (and (or no-strict-mime
 100                        (mail-fetch-field "mime-version"))
 101                    (setq ct (mail-fetch-field "content-type")))
 102           (setq ctl (condition-case () (mail-header-parse-content-type ct)
 103                       (error nil))
 104                 cte (mail-fetch-field "content-transfer-encoding")
 105                 cd (mail-fetch-field "content-disposition")
 106                 description (mail-fetch-field "content-description")
 107                 id (mail-fetch-field "content-id"))))
 108       (if (not ctl)
 109           (mm-dissect-singlepart '("text/plain") nil no-strict-mime nil nil)
 110         (setq type (split-string (car ctl) "/"))
 111         (setq subtype (cadr type)
 112               type (pop type))
 113         (setq
 114          result
 115          (cond
 116           ((equal type "multipart")
 117            (cons (car ctl) (mm-dissect-multipart ctl)))
 118           (t
 119            (mm-dissect-singlepart
 120             ctl
 121             (and cte (intern (downcase (mail-header-remove-whitespace
 122                                         (mail-header-remove-comments
 123                                          cte)))))
 124             no-strict-mime
 125             (and cd (condition-case ()
 126                         (mail-header-parse-content-disposition cd)
 127                       (error nil)))))))
 128         (when id
 129           (push (cons id result) mm-content-id-alist))
 130         result))))
 131
 132 (defun mm-dissect-singlepart (ctl cte &optional force cdl description)
 133   (when (or force
 134             (not (equal "text/plain" (car ctl))))
 135     (let ((res (list (mm-copy-to-buffer) ctl cte nil cdl description)))
 136       (push (car res) mm-dissection-list)
 137       res)))
 138
 139 (defun mm-remove-all-parts ()
 140   "Remove all MIME handles."
 141   (interactive)
 142   (mapcar 'mm-remove-part mm-dissection-list)
 143   (setq mm-dissection-list nil))
 144
 145 (defun mm-dissect-multipart (ctl)
 146   (goto-char (point-min))
 147   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 148         (close-delimiter (concat boundary "--[ \t]*$"))
 149         start parts
 150         (end (save-excursion
 151                (goto-char (point-max))
 152                (if (re-search-backward close-delimiter nil t)
 153                    (match-beginning 0)
 154                  (point-max)))))
 155     (while (search-forward boundary end t)
 156       (goto-char (match-beginning 0))
 157       (when start
 158         (save-excursion
 159           (save-restriction
 160             (narrow-to-region start (point))
 161             (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 162       (forward-line 2)
 163       (setq start (point)))
 164     (when start
 165       (save-excursion
 166         (save-restriction
 167           (narrow-to-region start end)
 168           (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 169     (nreverse parts)))
 170
 171 (defun mm-copy-to-buffer ()
 172   "Copy the contents of the current buffer to a fresh buffer."
 173   (save-excursion
 174     (let ((obuf (current-buffer))
 175           beg)
 176       (goto-char (point-min))
 177       (search-forward "\n\n" nil t)
 178       (setq beg (point))
 179       (set-buffer (generate-new-buffer " *mm*"))
 180       (insert-buffer-substring obuf beg)
 181       (current-buffer))))
 182
 183 (defun mm-inlinable-part-p (type)
 184   "Say whether TYPE can be displayed inline."
 185   (eq (mm-user-method type) 'inline))
 186
 187 (defun mm-display-part (handle &optional no-default)
 188   "Display the MIME part represented by HANDLE."
 189   (save-excursion
 190     (mailcap-parse-mailcaps)
 191     (if (mm-handle-displayed-p handle)
 192         (mm-remove-part handle)
 193       (let* ((type (car (mm-handle-type handle)))
 194              (method (mailcap-mime-info type))
 195              (user-method (mm-user-method type)))
 196         (if (eq user-method 'inline)
 197             (progn
 198               (forward-line 1)
 199               (mm-display-inline handle))
 200           (when (or user-method
 201                     method
 202                     (not no-default))
 203             (mm-display-external
 204              handle (or user-method method 'mailcap-save-binary-file))))))))
 205
 206 (defun mm-display-external (handle method)
 207   "Display HANDLE using METHOD."
 208   (mm-with-unibyte-buffer
 209     (insert-buffer-substring (mm-handle-buffer handle))
 210     (mm-decode-content-transfer-encoding
 211      (mm-handle-encoding handle) (car (mm-handle-type handle)))
 212     (if (functionp method)
 213         (let ((cur (current-buffer)))
 214           (if (eq method 'mailcap-save-binary-file)
 215               (set-buffer (generate-new-buffer "*mm*"))
 216             (let ((win (get-buffer-window cur t)))
 217               (when win
 218                 (select-window win)))
 219             (switch-to-buffer (generate-new-buffer "*mm*")))
 220           (buffer-disable-undo)
 221           (mm-set-buffer-file-coding-system 'no-conversion)
 222           (insert-buffer-substring cur)
 223           (funcall method)
 224           (mm-handle-set-undisplayer handle (current-buffer)))
 225       (let* ((dir (make-temp-name (expand-file-name "emm." mm-tmp-directory)))
 226              (filename (mail-content-type-get
 227                         (mm-handle-disposition handle) 'filename))
 228              (needsterm (assoc "needsterm"
 229                                (mailcap-mime-info
 230                                 (car (mm-handle-type handle)) t)))
 231              process file)
 232         ;; We create a private sub-directory where we store our files.
 233         (make-directory dir)
 234         (set-file-modes dir 448)
 235         (if filename
 236             (setq file (expand-file-name (file-name-nondirectory filename)
 237                                          dir))
 238           (setq file (make-temp-name (expand-file-name "mm." dir))))
 239         (write-region (point-min) (point-max)
 240                       file nil 'nomesg nil 'no-conversion)
 241         (setq process
 242               (if needsterm
 243                   (start-process "*display*" nil
 244                                  "xterm"
 245                                  "-e" shell-file-name "-c"
 246                                  (format method
 247                                          (mm-quote-arg file)))
 248                 (start-process "*display*" (generate-new-buffer "*mm*")
 249                                shell-file-name
 250                                "-c" (format method
 251                                             (mm-quote-arg file)))))
 252         (mm-handle-set-undisplayer handle (cons file process))
 253         (message "Displaying %s..." (format method file))))))
 254
 255 (defun mm-remove-parts (handles)
 256   "Remove the displayed MIME parts represented by HANDLE."
 257   (if (and (listp handles)
 258            (bufferp (car handles)))
 259       (mm-remove-part handles)
 260     (let (handle)
 261       (while (setq handle (pop handles))
 262         (cond
 263          ((stringp handle)
 264           )
 265          ((and (listp handle)
 266                (stringp (car handle)))
 267           (mm-remove-parts (cdr handle)))
 268          (t
 269           (mm-remove-part handle)))))))
 270
 271 (defun mm-destroy-parts (handles)
 272   "Remove the displayed MIME parts represented by HANDLE."
 273   (if (and (listp handles)
 274            (bufferp (car handles)))
 275       (mm-destroy-part handles)
 276     (let (handle)
 277       (while (setq handle (pop handles))
 278         (cond
 279          ((stringp handle)
 280           )
 281          ((and (listp handle)
 282                (stringp (car handle)))
 283           (mm-destroy-parts (cdr handle)))
 284          (t
 285           (mm-destroy-part handle)))))))
 286
 287 (defun mm-remove-part (handle)
 288   "Remove the displayed MIME part represented by HANDLE."
 289   (when (listp handle)
 290     (let ((object (mm-handle-undisplayer handle)))
 291       (condition-case ()
 292           (cond
 293            ;; Internally displayed part.
 294            ((mm-annotationp object)
 295             (delete-annotation object))
 296            ((or (functionp object)
 297                 (and (listp object)
 298                      (eq (car object) 'lambda)))
 299             (funcall object))
 300            ;; Externally displayed part.
 301            ((consp object)
 302             (condition-case ()
 303                 (delete-file (car object))
 304               (error nil))
 305             (condition-case ()
 306                 (delete-directory (file-name-directory (car object)))
 307               (error nil))
 308             (condition-case ()
 309                 (kill-process (cdr object))
 310               (error nil)))
 311            ((bufferp object)
 312             (when (buffer-live-p object)
 313               (kill-buffer object))))
 314         (error nil))
 315       (mm-handle-set-undisplayer handle nil))))
 316
 317 (defun mm-display-inline (handle)
 318   (let* ((type (car (mm-handle-type handle)))
 319          (function (cadr (assoc type mm-inline-media-tests))))
 320     (funcall function handle)
 321     (goto-char (point-min))))
 322
 323 (defun mm-inlinable-p (type)
 324   "Say whether TYPE can be displayed inline."
 325   (let ((alist mm-inline-media-tests)
 326         test)
 327     (while alist
 328       (when (equal type (caar alist))
 329         (setq test (caddar alist)
 330               alist nil)
 331         (setq test (eval test)))
 332       (pop alist))
 333     test))
 334
 335 (defun mm-user-method (type)
 336   "Return the user-defined method for TYPE."
 337   (let ((methods mm-user-display-methods)
 338         method result)
 339     (while (setq method (pop methods))
 340       (when (string-match (car method) type)
 341         (when (or (not (eq (cdr method) 'inline))
 342                   (mm-inlinable-p type))
 343           (setq result (cdr method)
 344                 methods nil))))
 345     result))
 346
 347 (defun mm-automatic-display-p (type)
 348   "Return the user-defined method for TYPE."
 349   (let ((methods mm-user-automatic-display)
 350         method result)
 351     (while (setq method (pop methods))
 352       (when (string-match method type)
 353         (setq result t
 354               methods nil)))
 355     result))
 356
 357 (defun add-mime-display-method (type method)
 358   "Make parts of TYPE be displayed with METHOD.
 359 This overrides entries in the mailcap file."
 360   (push (cons type method) mm-user-display-methods))
 361
 362 (defun mm-destroy-part (handle)
 363   "Destroy the data structures connected to HANDLE."
 364   (when (listp handle)
 365     (mm-remove-part handle)
 366     (when (buffer-live-p (mm-handle-buffer handle))
 367       (kill-buffer (mm-handle-buffer handle)))))
 368
 369 (defun mm-handle-displayed-p (handle)
 370   "Say whether HANDLE is displayed or not."
 371   (mm-handle-undisplayer handle))
 372
 373 (defun mm-quote-arg (arg)
 374   "Return a version of ARG that is safe to evaluate in a shell."
 375   (let ((pos 0) new-pos accum)
 376     ;; *** bug: we don't handle newline characters properly
 377     (while (setq new-pos (string-match "[!`\"$\\& \t{} ]" arg pos))
 378       (push (substring arg pos new-pos) accum)
 379       (push "\\" accum)
 380       (push (list (aref arg new-pos)) accum)
 381       (setq pos (1+ new-pos)))
 382     (if (= pos 0)
 383         arg
 384       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 385
 386 ;;;
 387 ;;; Functions for outputting parts
 388 ;;;
 389
 390 (defun mm-get-part (handle)
 391   "Return the contents of HANDLE as a string."
 392   (mm-with-unibyte-buffer
 393     (insert-buffer-substring (mm-handle-buffer handle))
 394     (mm-decode-content-transfer-encoding
 395      (mm-handle-encoding handle)
 396      (car (mm-handle-type handle)))
 397     (buffer-string)))
 398
 399 (defvar mm-default-directory nil)
 400
 401 (defun mm-save-part (handle)
 402   "Write HANDLE to a file."
 403   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
 404          (filename (mail-content-type-get
 405                     (mm-handle-disposition handle) 'filename))
 406          file)
 407     (when filename
 408       (setq filename (file-name-nondirectory filename)))
 409     (setq file
 410           (read-file-name "Save MIME part to: "
 411                           (expand-file-name
 412                            (or filename name "")
 413                            (or mm-default-directory default-directory))))
 414     (setq mm-default-directory (file-name-directory file))
 415     (mm-with-unibyte-buffer
 416       (insert-buffer-substring (mm-handle-buffer handle))
 417       (mm-decode-content-transfer-encoding
 418        (mm-handle-encoding handle)
 419        (car (mm-handle-type handle)))
 420       (when (or (not (file-exists-p file))
 421                 (yes-or-no-p (format "File %s already exists; overwrite? "
 422                                      file)))
 423         (write-region (point-min) (point-max) file)))))
 424
 425 (defun mm-pipe-part (handle)
 426   "Pipe HANDLE to a process."
 427   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
 428          (command
 429           (read-string "Shell command on MIME part: " mm-last-shell-command)))
 430     (mm-with-unibyte-buffer
 431       (insert-buffer-substring (mm-handle-buffer handle))
 432       (mm-decode-content-transfer-encoding
 433        (mm-handle-encoding handle)
 434        (car (mm-handle-type handle)))
 435       (shell-command-on-region (point-min) (point-max) command nil))))
 436
 437 (defun mm-interactively-view-part (handle)
 438   "Display HANDLE using METHOD."
 439   (let* ((type (car (mm-handle-type handle)))
 440          (methods
 441           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
 442                   (mailcap-mime-info type 'all)))
 443          (method (completing-read "Viewer: " methods)))
 444     (mm-display-external (copy-sequence handle) method)))
 445
 446 (defun mm-preferred-alternative (handles &optional preferred)
 447   "Say which of HANDLES are preferred."
 448   (let ((prec (if preferred (list preferred) mm-alternative-precedence))
 449         p h result type)
 450     (while (setq p (pop prec))
 451       (setq h handles)
 452       (while h
 453         (setq type
 454               (if (stringp (caar h))
 455                   (caar h)
 456                 (car (mm-handle-type (car h)))))
 457         (when (and (equal p type)
 458                    (mm-automatic-display-p type)
 459                    (or (stringp (caar h))
 460                        (not (mm-handle-disposition (car h)))
 461                        (equal (car (mm-handle-disposition (car h)))
 462                               "inline")))
 463           (setq result (car h)
 464                 h nil
 465                 prec nil))
 466         (pop h)))
 467     result))
 468
 469 (defun mm-get-content-id (id)
 470   "Return the handle(s) referred to by ID."
 471   (cdr (assoc id mm-content-id-alist)))
 472
 473 (provide 'mm-decode)
 474
 475 ;; mm-decode.el ends here