git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-mailcap.el

   1 ;;; mm-mailcap.el --- Functions for displaying MIME parts
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: William M. Perry <wmperry@aventail.com>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'cl))
  31 (require 'mail-parse)
  32
  33 (defvar mm-mailcap-parse-args-syntax-table
  34   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  35     (modify-syntax-entry ?' "\"" table)
  36     (modify-syntax-entry ?` "\"" table)
  37     (modify-syntax-entry ?{ "(" table)
  38     (modify-syntax-entry ?} ")" table)
  39     table)
  40   "A syntax table for parsing sgml attributes.")
  41
  42 (defvar mm-mailcap-mime-data
  43   '(("application"
  44      ("x-x509-ca-cert"
  45       (viewer . ssl-view-site-cert)
  46       (test . (fboundp 'ssl-view-site-cert))
  47       (type . "application/x-x509-ca-cert"))
  48      ("x-x509-user-cert"
  49       (viewer . ssl-view-user-cert)
  50       (test . (fboundp 'ssl-view-user-cert))
  51       (type . "application/x-x509-user-cert"))
  52      ("octet-stream"
  53       (viewer . mm-mailcap-save-binary-file)
  54       (non-viewer . t)
  55       (type ."application/octet-stream"))
  56      ("dvi"
  57       (viewer . "open %s")
  58       (type   . "application/dvi")
  59       (test   . (eq (mm-device-type) 'ns)))
  60      ("dvi"
  61       (viewer . "xdvi %s")
  62       (test   . (eq (mm-device-type) 'x))
  63       ("needsx11")
  64       (type   . "application/dvi"))
  65      ("dvi"
  66       (viewer . "dvitty %s")
  67       (test   . (not (getenv "DISPLAY")))
  68       (type   . "application/dvi"))
  69      ("emacs-lisp"
  70       (viewer . mm-mailcap-maybe-eval)
  71       (type   . "application/emacs-lisp"))
  72      ("x-tar"
  73       (viewer . mm-mailcap-save-binary-file)
  74       (non-viewer . t)
  75       (type   . "application/x-tar"))
  76      ("x-latex"
  77       (viewer . tex-mode)
  78       (test   . (fboundp 'tex-mode))
  79       (type   . "application/x-latex"))
  80      ("x-tex"
  81       (viewer . tex-mode)
  82       (test   . (fboundp 'tex-mode))
  83       (type   . "application/x-tex"))
  84      ("latex"
  85       (viewer . tex-mode)
  86       (test   . (fboundp 'tex-mode))
  87       (type   . "application/latex"))
  88      ("tex"
  89       (viewer . tex-mode)
  90       (test   . (fboundp 'tex-mode))
  91       (type   . "application/tex"))
  92      ("texinfo"
  93       (viewer . texinfo-mode)
  94       (test   . (fboundp 'texinfo-mode))
  95       (type   . "application/tex"))
  96      ("zip"
  97       (viewer . mm-mailcap-save-binary-file)
  98       (non-viewer . t)
  99       (type   . "application/zip")
 100       ("copiousoutput"))
 101      ("pdf"
 102       (viewer . "acroread %s")
 103       (type   . "application/pdf"))
 104      ("postscript"
 105       (viewer . "open %s")
 106       (type   . "application/postscript")
 107       (test   . (eq (mm-device-type) 'ns)))
 108      ("postscript"
 109       (viewer . "ghostview -dSAFER %s")
 110       (type . "application/postscript")
 111       (test   . (eq (mm-device-type) 'x))
 112       ("needsx11"))
 113      ("postscript"
 114       (viewer . "ps2ascii %s")
 115       (type . "application/postscript")
 116       (test . (not (getenv "DISPLAY")))
 117       ("copiousoutput")))
 118     ("audio"
 119      ("x-mpeg"
 120       (viewer . "maplay %s")
 121       (type   . "audio/x-mpeg"))
 122      (".*"
 123       (viewer . mm-mailcap-save-binary-file)
 124       (non-viewer . t)
 125       (test   . (or (featurep 'nas-sound)
 126                       (featurep 'native-sound)))
 127       (type   . "audio/*"))
 128      (".*"
 129       (viewer . "showaudio")
 130       (type   . "audio/*")))
 131     ("message"
 132      ("rfc-*822"
 133       (viewer . mm-view-message)
 134       (test   . (and (featurep 'gnus)
 135                      (gnus-alive-p)))
 136       (type   . "message/rfc822"))
 137      ("rfc-*822"
 138       (viewer . vm-mode)
 139       (test   . (fboundp 'vm-mode))
 140       (type   . "message/rfc822"))
 141      ("rfc-*822"
 142       (viewer . w3-mode)
 143       (test   . (fboundp 'w3-mode))
 144       (type   . "message/rfc822"))
 145      ("rfc-*822"
 146       (viewer . view-mode)
 147       (test   . (fboundp 'view-mode))
 148       (type   . "message/rfc822"))
 149      ("rfc-*822"
 150       (viewer . fundamental-mode)
 151       (type   . "message/rfc822")))
 152     ("image"
 153      ("x-xwd"
 154       (viewer  . "xwud -in %s")
 155       (type    . "image/x-xwd")
 156       ("compose" . "xwd -frame > %s")
 157       (test    . (eq (mm-device-type) 'x))
 158       ("needsx11"))
 159      ("x11-dump"
 160       (viewer . "xwud -in %s")
 161       (type . "image/x-xwd")
 162       ("compose" . "xwd -frame > %s")
 163       (test   . (eq (mm-device-type) 'x))
 164       ("needsx11"))
 165      ("windowdump"
 166       (viewer . "xwud -in %s")
 167       (type . "image/x-xwd")
 168       ("compose" . "xwd -frame > %s")
 169       (test   . (eq (mm-device-type) 'x))
 170       ("needsx11"))
 171      (".*"
 172       (viewer . "aopen %s")
 173       (type   . "image/*")
 174       (test   . (eq (mm-device-type) 'ns)))
 175      (".*"
 176       (viewer . "display %s")
 177       (type . "image/*")
 178       (test   . (eq (mm-device-type) 'x))
 179       ("needsx11"))
 180      (".*"
 181       (viewer . "ee %s")
 182       (type . "image/*")
 183       (test   . (eq (mm-device-type) 'x))
 184       ("needsx11")))
 185     ("text"
 186      ("plain"
 187       (viewer  . w3-mode)
 188       (test    . (fboundp 'w3-mode))
 189       (type    . "text/plain"))
 190      ("plain"
 191       (viewer  . view-mode)
 192       (test    . (fboundp 'view-mode))
 193       (type    . "text/plain"))
 194      ("plain"
 195       (viewer  . fundamental-mode)
 196       (type    . "text/plain"))
 197      ("enriched"
 198       (viewer . enriched-decode-region)
 199       (test   . (fboundp 'enriched-decode))
 200       (type   . "text/enriched"))
 201      ("html"
 202       (viewer . mm-w3-prepare-buffer)
 203       (test   . (fboundp 'w3-prepare-buffer))
 204       (type   . "text/html")))
 205     ("video"
 206      ("mpeg"
 207       (viewer . "mpeg_play %s")
 208       (type   . "video/mpeg")
 209       (test   . (eq (mm-device-type) 'x))
 210       ("needsx11")))
 211     ("x-world"
 212      ("x-vrml"
 213       (viewer  . "webspace -remote %s -URL %u")
 214       (type    . "x-world/x-vrml")
 215       ("description"
 216        "VRML document")))
 217     ("archive"
 218      ("tar"
 219       (viewer . tar-mode)
 220       (type . "archive/tar")
 221       (test . (fboundp 'tar-mode)))))
 222      "The mailcap structure is an assoc list of assoc lists.
 223 1st assoc list is keyed on the major content-type
 224 2nd assoc list is keyed on the minor content-type (which can be a regexp)
 225
 226 Which looks like:
 227 -----------------
 228  ((\"application\"
 229    (\"postscript\" . <info>))
 230   (\"text\"
 231    (\"plain\" . <info>)))
 232
 233 Where <info> is another assoc list of the various information
 234 related to the mailcap RFC.  This is keyed on the lowercase
 235 attribute name (viewer, test, etc).  This looks like:
 236  ((viewer . viewerinfo)
 237   (test   . testinfo)
 238   (xxxx   . \"string\"))
 239
 240 Where viewerinfo specifies how the content-type is viewed.  Can be
 241 a string, in which case it is run through a shell, with
 242 appropriate parameters, or a symbol, in which case the symbol is
 243 funcall'd, with the buffer as an argument.
 244
 245 testinfo is a list of strings, or nil.  If nil, it means the
 246 viewer specified is always valid.  If it is a list of strings,
 247 these are used to determine whether a viewer passes the 'test' or
 248 not.")
 249
 250 (defvar mm-mailcap-download-directory nil
 251   "*Where downloaded files should go by default.")
 252
 253 (defvar mm-mailcap-temporary-directory
 254   (cond ((fboundp 'temp-directory) (temp-directory))
 255         ((boundp 'temporary-file-directory) temporary-file-directory)
 256         ("/tmp/"))
 257   "*Where temporary files go.")
 258
 259 ;;;
 260 ;;; Utility functions
 261 ;;;
 262
 263 (defun mm-mailcap-generate-unique-filename (&optional fmt)
 264   "Generate a unique filename in mm-mailcap-temporary-directory"
 265   (if (not fmt)
 266       (let ((base (format "mm-mailcap-tmp.%d" (user-real-uid)))
 267             (fname "")
 268             (x 0))
 269         (setq fname (format "%s%d" base x))
 270         (while (file-exists-p
 271                 (expand-file-name fname mm-mailcap-temporary-directory))
 272           (setq x (1+ x)
 273                 fname (concat base (int-to-string x))))
 274         (expand-file-name fname mm-mailcap-temporary-directory))
 275     (let ((base (concat "mm" (int-to-string (user-real-uid))))
 276           (fname "")
 277           (x 0))
 278       (setq fname (format fmt (concat base (int-to-string x))))
 279       (while (file-exists-p
 280               (expand-file-name fname mm-mailcap-temporary-directory))
 281         (setq x (1+ x)
 282               fname (format fmt (concat base (int-to-string x)))))
 283       (expand-file-name fname mm-mailcap-temporary-directory))))
 284
 285 (defun mm-mailcap-save-binary-file ()
 286   (goto-char (point-min))
 287   (unwind-protect
 288       (let ((file (read-file-name
 289                    "Filename to save as: "
 290                    (or mm-mailcap-download-directory "~/")))
 291             (require-final-newline nil))
 292         (write-region (point-min) (point-max) file))
 293     (kill-buffer (current-buffer))))
 294
 295 (defun mm-mailcap-maybe-eval ()
 296   "Maybe evaluate a buffer of emacs lisp code"
 297   (if (yes-or-no-p "This is emacs-lisp code, evaluate it? ")
 298       (eval-buffer (current-buffer))
 299     (emacs-lisp-mode)))
 300
 301 ;;;
 302 ;;; The mailcap parser
 303 ;;;
 304
 305 (defun mm-mailcap-replace-regexp (regexp to-string)
 306   ;; Quiet replace-regexp.
 307   (goto-char (point-min))
 308   (while (re-search-forward regexp nil t)
 309     (replace-match to-string t nil)))
 310
 311 (defvar mm-mailcap-parsed-p nil)
 312
 313 (defun mm-mailcap-parse-mailcaps (&optional path force)
 314   "Parse out all the mailcaps specified in a unix-style path string PATH.
 315 If FORCE, re-parse even if already parsed."
 316   (interactive (list nil t))
 317   (when (or (not mm-mailcap-parsed-p)
 318             force)
 319     (cond
 320      (path nil)
 321      ((getenv "MAILCAPS") (setq path (getenv "MAILCAPS")))
 322      ((memq system-type '(ms-dos ms-windows windows-nt))
 323       (setq path (mapconcat 'expand-file-name
 324                             '("~/mail.cap" "~/etc/mail.cap" "~/.mailcap")
 325                             ";")))
 326      (t (setq path (mapconcat 'expand-file-name
 327                               '("~/.mailcap"
 328                                 "/etc/mailcap:/usr/etc/mailcap"
 329                                 "/usr/local/etc/mailcap") ":"))))
 330     (let ((fnames (reverse
 331                    (split-string
 332                     path (if (memq system-type
 333                                    '(ms-dos ms-windows windows-nt))
 334                              ";"
 335                            ":"))))
 336           fname)
 337       (while fnames
 338         (setq fname (car fnames))
 339        (if (and (file-exists-p fname) (file-readable-p fname)
 340                 (file-regular-p fname))
 341             (mm-mailcap-parse-mailcap (car fnames)))
 342         (setq fnames (cdr fnames))))
 343     (setq mm-mailcap-parsed-p t)))
 344
 345 (defun mm-mailcap-parse-mailcap (fname)
 346   ;; Parse out the mailcap file specified by FNAME
 347   (let (major                           ; The major mime type (image/audio/etc)
 348         minor                           ; The minor mime type (gif, basic, etc)
 349         save-pos                        ; Misc saved positions used in parsing
 350         viewer                          ; How to view this mime type
 351         info                            ; Misc info about this mime type
 352         )
 353     (with-temp-buffer
 354       (insert-file-contents fname)
 355       (set-syntax-table mm-mailcap-parse-args-syntax-table)
 356       (mm-mailcap-replace-regexp "#.*" "")      ; Remove all comments
 357       (mm-mailcap-replace-regexp "\n+" "\n") ; And blank lines
 358       (mm-mailcap-replace-regexp "\\\\[ \t\n]+" " ") ; And collapse spaces
 359       (mm-mailcap-replace-regexp (concat (regexp-quote "\\") "[ \t]*\n") "")
 360       (goto-char (point-max))
 361       (skip-chars-backward " \t\n")
 362       (delete-region (point) (point-max))
 363       (goto-char (point-min))
 364       (while (not (eobp))
 365         (skip-chars-forward " \t\n")
 366         (setq save-pos (point)
 367               info nil)
 368         (skip-chars-forward "^/; \t\n")
 369         (downcase-region save-pos (point))
 370         (setq major (buffer-substring save-pos (point)))
 371         (skip-chars-forward " \t\n")
 372         (setq minor "")
 373         (when (eq (char-after) ?/)
 374           (forward-char)
 375           (skip-chars-forward " \t\n")
 376           (setq save-pos (point))
 377           (skip-chars-forward "^; \t\n")
 378           (downcase-region save-pos (point))
 379           (setq minor
 380                 (cond
 381                  ((eq ?* (or (char-after save-pos) 0)) ".*")
 382                  ((= (point) save-pos) ".*")
 383                  (t (regexp-quote (buffer-substring save-pos (point)))))))
 384         (skip-chars-forward " \t\n")
 385         ;;; Got the major/minor chunks, now for the viewers/etc
 386         ;;; The first item _must_ be a viewer, according to the
 387         ;;; RFC for mailcap files (#1343)
 388         (setq viewer "")
 389         (when (eq (char-after) ?\;)
 390           (forward-char)
 391           (skip-chars-forward " \t\n")
 392           (setq save-pos (point))
 393           (skip-chars-forward "^;\n")
 394           ;; skip \;
 395           (while (eq (char-before) ?\\)
 396             (backward-delete-char 1)
 397             (forward-char)
 398             (skip-chars-forward "^;\n"))
 399           (if (eq (or (char-after save-pos) 0) ?')
 400               (setq viewer (progn
 401                              (narrow-to-region (1+ save-pos) (point))
 402                              (goto-char (point-min))
 403                              (prog1
 404                                  (read (current-buffer))
 405                                (goto-char (point-max))
 406                                (widen))))
 407             (setq viewer (buffer-substring save-pos (point)))))
 408         (setq save-pos (point))
 409         (end-of-line)
 410         (unless (equal viewer "")
 411           (setq info (nconc (list (cons 'viewer viewer)
 412                                   (cons 'type (concat major "/"
 413                                                       (if (string= minor ".*")
 414                                                           "*" minor))))
 415                             (mm-mailcap-parse-mailcap-extras save-pos (point))))
 416           (mm-mailcap-mailcap-entry-passes-test info)
 417           (mm-mailcap-add-mailcap-entry major minor info))))))
 418
 419 (defun mm-mailcap-parse-mailcap-extras (st nd)
 420   ;; Grab all the extra stuff from a mailcap entry
 421   (let (
 422         name                            ; From name=
 423         value                           ; its value
 424         results                         ; Assoc list of results
 425         name-pos                        ; Start of XXXX= position
 426         val-pos                         ; Start of value position
 427         done                            ; Found end of \'d ;s?
 428         )
 429     (save-restriction
 430       (narrow-to-region st nd)
 431       (goto-char (point-min))
 432       (skip-chars-forward " \n\t;")
 433       (while (not (eobp))
 434         (setq done nil)
 435         (setq name-pos (point))
 436         (skip-chars-forward "^ \n\t=;")
 437         (downcase-region name-pos (point))
 438         (setq name (buffer-substring name-pos (point)))
 439         (skip-chars-forward " \t\n")
 440         (if (not (eq (char-after (point)) ?=)) ; There is no value
 441             (setq value t)
 442           (skip-chars-forward " \t\n=")
 443           (setq val-pos (point))
 444           (if (memq (char-after val-pos) '(?\" ?'))
 445               (progn
 446                 (setq val-pos (1+ val-pos))
 447                 (condition-case nil
 448                     (progn
 449                       (forward-sexp 1)
 450                       (backward-char 1))
 451                   (error (goto-char (point-max)))))
 452             (while (not done)
 453               (skip-chars-forward "^;")
 454               (if (eq (char-after (1- (point))) ?\\ )
 455                   (progn
 456                     (subst-char-in-region (1- (point)) (point) ?\\ ? )
 457                     (skip-chars-forward ";"))
 458                 (setq done t))))
 459           (setq value (buffer-substring val-pos (point))))
 460         (setq results (cons (cons name value) results))
 461         (skip-chars-forward " \";\n\t"))
 462       results)))
 463
 464 (defun mm-mailcap-mailcap-entry-passes-test (info)
 465   ;; Return t iff a mailcap entry passes its test clause or no test
 466   ;; clause is present.
 467   (let (status                          ; Call-process-regions return value
 468         (test (assq 'test info))        ; The test clause
 469         )
 470     (setq status (and test (split-string (cdr test) " ")))
 471     (if (and (or (assoc "needsterm" info)
 472                  (assoc "needsterminal" info)
 473                  (assoc "needsx11" info))
 474              (not (getenv "DISPLAY")))
 475         (setq status nil)
 476       (cond
 477        ((and (equal (nth 0 status) "test")
 478              (equal (nth 1 status) "-n")
 479              (or (equal (nth 2 status) "$DISPLAY")
 480                  (equal (nth 2 status) "\"$DISPLAY\"")))
 481         (setq status (if (getenv "DISPLAY") t nil)))
 482        ((and (equal (nth 0 status) "test")
 483              (equal (nth 1 status) "-z")
 484              (or (equal (nth 2 status) "$DISPLAY")
 485                  (equal (nth 2 status) "\"$DISPLAY\"")))
 486         (setq status (if (getenv "DISPLAY") nil t)))
 487        (test nil)
 488        (t nil)))
 489     (and test (listp test) (setcdr test status))))
 490
 491 ;;;
 492 ;;; The action routines.
 493 ;;;
 494
 495 (defun mm-mailcap-possible-viewers (major minor)
 496   ;; Return a list of possible viewers from MAJOR for minor type MINOR
 497   (let ((exact '())
 498         (wildcard '()))
 499     (while major
 500       (cond
 501        ((equal (car (car major)) minor)
 502         (setq exact (cons (cdr (car major)) exact)))
 503        ((and minor (string-match (car (car major)) minor))
 504         (setq wildcard (cons (cdr (car major)) wildcard))))
 505       (setq major (cdr major)))
 506     (nconc (nreverse exact) (nreverse wildcard))))
 507
 508 (defun mm-mailcap-unescape-mime-test (test type-info)
 509   (let (save-pos save-chr subst)
 510     (cond
 511      ((symbolp test) test)
 512      ((and (listp test) (symbolp (car test))) test)
 513      ((or (stringp test)
 514           (and (listp test) (stringp (car test))
 515                (setq test (mapconcat 'identity test " "))))
 516       (with-temp-buffer
 517         (insert test)
 518         (goto-char (point-min))
 519         (while (not (eobp))
 520           (skip-chars-forward "^%")
 521           (if (/= (- (point)
 522                      (progn (skip-chars-backward "\\\\")
 523                             (point)))
 524                   0)                    ; It is an escaped %
 525               (progn
 526                 (delete-char 1)
 527                 (skip-chars-forward "%."))
 528             (setq save-pos (point))
 529             (skip-chars-forward "%")
 530             (setq save-chr (char-after (point)))
 531             (cond
 532              ((null save-chr) nil)
 533              ((= save-chr ?t)
 534               (delete-region save-pos (progn (forward-char 1) (point)))
 535               (insert (or (cdr (assq 'type type-info)) "\"\"")))
 536              ((= save-chr ?M)
 537               (delete-region save-pos (progn (forward-char 1) (point)))
 538               (insert "\"\""))
 539              ((= save-chr ?n)
 540               (delete-region save-pos (progn (forward-char 1) (point)))
 541               (insert "\"\""))
 542              ((= save-chr ?F)
 543               (delete-region save-pos (progn (forward-char 1) (point)))
 544               (insert "\"\""))
 545              ((= save-chr ?{)
 546               (forward-char 1)
 547               (skip-chars-forward "^}")
 548               (downcase-region (+ 2 save-pos) (point))
 549               (setq subst (buffer-substring (+ 2 save-pos) (point)))
 550               (delete-region save-pos (1+ (point)))
 551               (insert (or (cdr (assoc subst type-info)) "\"\"")))
 552              (t nil))))
 553         (buffer-string)))
 554      (t (error "Bad value to mm-mailcap-unescape-mime-test. %s" test)))))
 555
 556 (defvar mm-mailcap-viewer-test-cache nil)
 557
 558 (defun mm-mailcap-viewer-passes-test (viewer-info type-info)
 559   ;; Return non-nil iff the viewer specified by VIEWER-INFO passes its
 560   ;; test clause (if any).
 561   (let* ((test-info (assq 'test viewer-info))
 562          (test (cdr test-info))
 563          (otest test)
 564          (viewer (cdr (assoc 'viewer viewer-info)))
 565          (default-directory (expand-file-name "~/"))
 566          status parsed-test cache result)
 567     (if (setq cache (assoc test mm-mailcap-viewer-test-cache))
 568         (cadr cache)
 569       (setq
 570        result
 571        (cond
 572         ((not test-info) t)             ; No test clause
 573         ((not test) nil)                ; Already failed test
 574         ((eq test t) t)                 ; Already passed test
 575         ((and (symbolp test)            ; Lisp function as test
 576               (fboundp test))
 577          (funcall test type-info))
 578         ((and (symbolp test)            ; Lisp variable as test
 579               (boundp test))
 580          (symbol-value test))
 581         ((and (listp test)              ; List to be eval'd
 582               (symbolp (car test)))
 583          (eval test))
 584         (t
 585          (setq test (mm-mailcap-unescape-mime-test test type-info)
 586                test (list shell-file-name nil nil nil
 587                           shell-command-switch test)
 588                status (apply 'call-process test))
 589          (= 0 status))))
 590       (push (list otest result) mm-mailcap-viewer-test-cache)
 591       result)))
 592
 593 (defun mm-mailcap-add-mailcap-entry (major minor info)
 594   (let ((old-major (assoc major mm-mailcap-mime-data)))
 595     (if (null old-major)                ; New major area
 596         (setq mm-mailcap-mime-data
 597               (cons (cons major (list (cons minor info)))
 598                     mm-mailcap-mime-data))
 599       (let ((cur-minor (assoc minor old-major)))
 600         (cond
 601          ((or (null cur-minor)          ; New minor area, or
 602               (assq 'test info))        ; Has a test, insert at beginning
 603           (setcdr old-major (cons (cons minor info) (cdr old-major))))
 604          ((and (not (assq 'test info)) ; No test info, replace completely
 605                (not (assq 'test cur-minor)))
 606           (setcdr cur-minor info))
 607          (t
 608           (setcdr old-major (cons (cons minor info) (cdr old-major)))))))))
 609
 610 (defun mm-mailcap-add (type viewer &optional test)
 611   "Add VIEWER as a handler for TYPE.
 612 If TEST is not given, it defaults to t."
 613   (let ((tl (split-string type "/")))
 614     (when (or (not (car tl))
 615               (not (cadr tl)))
 616       (error "%s is not a valid MIME type" type))
 617     (mm-mailcap-add-mailcap-entry
 618      (car tl) (cadr tl)
 619      `((viewer . ,viewer)
 620        (test . ,(if test test t))
 621        (type . ,type)))))
 622
 623 ;;;
 624 ;;; The main whabbo
 625 ;;;
 626
 627 (defun mm-mailcap-viewer-lessp (x y)
 628   ;; Return t iff viewer X is more desirable than viewer Y
 629   (let ((x-wild (string-match "[*?]" (or (cdr-safe (assq 'type x)) "")))
 630         (y-wild (string-match "[*?]" (or (cdr-safe (assq 'type y)) "")))
 631         (x-lisp (not (stringp (or (cdr-safe (assq 'viewer x)) ""))))
 632         (y-lisp (not (stringp (or (cdr-safe (assq 'viewer y)) "")))))
 633     (cond
 634      ((and x-wild (not y-wild))
 635       nil)
 636      ((and (not x-wild) y-wild)
 637       t)
 638      ((and (not y-lisp) x-lisp)
 639       t)
 640      (t nil))))
 641
 642 (defun mm-mailcap-mime-info (string &optional request)
 643   "Get the MIME viewer command for STRING, return nil if none found.
 644 Expects a complete content-type header line as its argument.
 645
 646 Second argument REQUEST specifies what information to return.  If it is
 647 nil or the empty string, the viewer (second field of the mailcap
 648 entry) will be returned.  If it is a string, then the mailcap field
 649 corresponding to that string will be returned (print, description,
 650 whatever).  If a number, then all the information for this specific
 651 viewer is returned.  If `all', then all possible viewers for
 652 this type is returned."
 653   (let (
 654         major                           ; Major encoding (text, etc)
 655         minor                           ; Minor encoding (html, etc)
 656         info                            ; Other info
 657         save-pos                        ; Misc. position during parse
 658         major-info                      ; (assoc major mm-mailcap-mime-data)
 659         minor-info                      ; (assoc minor major-info)
 660         test                            ; current test proc.
 661         viewers                         ; Possible viewers
 662         passed                          ; Viewers that passed the test
 663         viewer                          ; The one and only viewer
 664         ctl)
 665     (save-excursion
 666       (setq ctl (mail-header-parse-content-type (or string "text/plain")))
 667       (setq major (if ctl
 668                       (symbol-name (mime-content-type-primary-type ctl))
 669                     string))
 670       (setq minor (and ctl (symbol-name (mime-content-type-subtype ctl))))
 671       (when (setq major-info (cdr (assoc major mm-mailcap-mime-data)))
 672         (when (setq viewers (mm-mailcap-possible-viewers major-info minor))
 673           (setq info (mapcar (lambda (a) (cons (symbol-name (car a))
 674                                                (cdr a)))
 675                              (cdr ctl)))
 676           (while viewers
 677             (if (mm-mailcap-viewer-passes-test (car viewers) info)
 678                 (setq passed (cons (car viewers) passed)))
 679             (setq viewers (cdr viewers)))
 680           (setq passed (sort (nreverse passed) 'mm-mailcap-viewer-lessp))
 681           (setq viewer (car passed))))
 682       (when (and (stringp (cdr (assq 'viewer viewer)))
 683                  passed)
 684         (setq viewer (car passed)))
 685       (cond
 686        ((and (null viewer) (not (equal major "default")) request)
 687         (mm-mailcap-mime-info "default" request))
 688        ((or (null request) (equal request ""))
 689         (mm-mailcap-unescape-mime-test (cdr (assq 'viewer viewer)) info))
 690        ((stringp request)
 691         (if (or (eq request 'test) (eq request 'viewer))
 692             (mm-mailcap-unescape-mime-test
 693              (cdr-safe (assoc request viewer)) info)))
 694        ((eq request 'all)
 695         passed)
 696        (t
 697         ;; MUST make a copy *sigh*, else we modify mm-mailcap-mime-data
 698         (setq viewer (copy-tree viewer))
 699         (let ((view (assq 'viewer viewer))
 700               (test (assq 'test viewer)))
 701           (if view (setcdr view (mm-mailcap-unescape-mime-test (cdr view) info)))
 702           (if test (setcdr test (mm-mailcap-unescape-mime-test (cdr test) info))))
 703         viewer)))))
 704
 705 ;;;
 706 ;;; Experimental MIME-types parsing
 707 ;;;
 708
 709 (defvar mm-mailcap-mime-extensions
 710   '((""          . "text/plain")
 711     (".abs"      . "audio/x-mpeg")
 712     (".aif"      . "audio/aiff")
 713     (".aifc"     . "audio/aiff")
 714     (".aiff"     . "audio/aiff")
 715     (".ano"      . "application/x-annotator")
 716     (".au"       . "audio/ulaw")
 717     (".avi"      . "video/x-msvideo")
 718     (".bcpio"    . "application/x-bcpio")
 719     (".bin"      . "application/octet-stream")
 720     (".cdf"      . "application/x-netcdr")
 721     (".cpio"     . "application/x-cpio")
 722     (".csh"      . "application/x-csh")
 723     (".dvi"      . "application/x-dvi")
 724     (".el"       . "application/emacs-lisp")
 725     (".eps"      . "application/postscript")
 726     (".etx"      . "text/x-setext")
 727     (".exe"      . "application/octet-stream")
 728     (".fax"      . "image/x-fax")
 729     (".gif"      . "image/gif")
 730     (".hdf"      . "application/x-hdf")
 731     (".hqx"      . "application/mac-binhex40")
 732     (".htm"      . "text/html")
 733     (".html"     . "text/html")
 734     (".icon"     . "image/x-icon")
 735     (".ief"      . "image/ief")
 736     (".jpg"      . "image/jpeg")
 737     (".macp"     . "image/x-macpaint")
 738     (".man"      . "application/x-troff-man")
 739     (".me"       . "application/x-troff-me")
 740     (".mif"      . "application/mif")
 741     (".mov"      . "video/quicktime")
 742     (".movie"    . "video/x-sgi-movie")
 743     (".mp2"      . "audio/x-mpeg")
 744     (".mp3"      . "audio/x-mpeg")
 745     (".mp2a"     . "audio/x-mpeg2")
 746     (".mpa"      . "audio/x-mpeg")
 747     (".mpa2"     . "audio/x-mpeg2")
 748     (".mpe"      . "video/mpeg")
 749     (".mpeg"     . "video/mpeg")
 750     (".mpega"    . "audio/x-mpeg")
 751     (".mpegv"    . "video/mpeg")
 752     (".mpg"      . "video/mpeg")
 753     (".mpv"      . "video/mpeg")
 754     (".ms"       . "application/x-troff-ms")
 755     (".nc"       . "application/x-netcdf")
 756     (".nc"       . "application/x-netcdf")
 757     (".oda"      . "application/oda")
 758     (".patch"    . "text/x-patch")
 759     (".pbm"      . "image/x-portable-bitmap")
 760     (".pdf"      . "application/pdf")
 761     (".pgm"      . "image/portable-graymap")
 762     (".pict"     . "image/pict")
 763     (".png"      . "image/png")
 764     (".pnm"      . "image/x-portable-anymap")
 765     (".ppm"      . "image/portable-pixmap")
 766     (".ps"       . "application/postscript")
 767     (".qt"       . "video/quicktime")
 768     (".ras"      . "image/x-raster")
 769     (".rgb"      . "image/x-rgb")
 770     (".rtf"      . "application/rtf")
 771     (".rtx"      . "text/richtext")
 772     (".sh"       . "application/x-sh")
 773     (".sit"      . "application/x-stuffit")
 774     (".snd"      . "audio/basic")
 775     (".src"      . "application/x-wais-source")
 776     (".tar"      . "archive/tar")
 777     (".tcl"      . "application/x-tcl")
 778     (".tcl"      . "application/x-tcl")
 779     (".tex"      . "application/x-tex")
 780     (".texi"     . "application/texinfo")
 781     (".tga"      . "image/x-targa")
 782     (".tif"      . "image/tiff")
 783     (".tiff"     . "image/tiff")
 784     (".tr"       . "application/x-troff")
 785     (".troff"    . "application/x-troff")
 786     (".tsv"      . "text/tab-separated-values")
 787     (".txt"      . "text/plain")
 788     (".vbs"      . "video/mpeg")
 789     (".vox"      . "audio/basic")
 790     (".vrml"     . "x-world/x-vrml")
 791     (".wav"      . "audio/x-wav")
 792     (".wrl"      . "x-world/x-vrml")
 793     (".xbm"      . "image/xbm")
 794     (".xpm"      . "image/xpm")
 795     (".xwd"      . "image/windowdump")
 796     (".zip"      . "application/zip")
 797     (".ai"       . "application/postscript")
 798     (".jpe"      . "image/jpeg")
 799     (".jpeg"     . "image/jpeg"))
 800   "An assoc list of file extensions and corresponding MIME content-types.")
 801
 802 (defun mm-mailcap-parse-mimetypes (&optional path)
 803   ;; Parse out all the mimetypes specified in a unix-style path string PATH
 804   (cond
 805    (path nil)
 806    ((getenv "MIMETYPES") (setq path (getenv "MIMETYPES")))
 807    ((memq system-type '(ms-dos ms-windows windows-nt))
 808     (setq path (mapconcat 'expand-file-name
 809                           '("~/mime.typ" "~/etc/mime.typ") ";")))
 810    (t (setq path (mapconcat 'expand-file-name
 811                             '("~/.mime-types"
 812                               "/etc/mime-types:/usr/etc/mime-types"
 813                               "/usr/local/etc/mime-types"
 814                               "/usr/local/www/conf/mime-types") ":"))))
 815   (let ((fnames (reverse
 816                  (split-string path
 817                                (if (memq system-type
 818                                          '(ms-dos ms-windows windows-nt))
 819                                    ";" ":"))))
 820         fname)
 821     (while fnames
 822       (setq fname (car fnames))
 823       (if (and (file-exists-p fname) (file-readable-p fname))
 824           (mm-mailcap-parse-mimetype-file (car fnames)))
 825       (setq fnames (cdr fnames)))))
 826
 827 (defun mm-mailcap-parse-mimetype-file (fname)
 828   ;; Parse out a mime-types file
 829   (let (type                            ; The MIME type for this line
 830         extns                           ; The extensions for this line
 831         save-pos                        ; Misc. saved buffer positions
 832         )
 833     (with-temp-buffer
 834       (insert-file-contents fname)
 835       (mm-mailcap-replace-regexp "#.*" "")
 836       (mm-mailcap-replace-regexp "\n+" "\n")
 837       (mm-mailcap-replace-regexp "[ \t]+$" "")
 838       (goto-char (point-max))
 839       (skip-chars-backward " \t\n")
 840       (delete-region (point) (point-max))
 841       (goto-char (point-min))
 842       (while (not (eobp))
 843         (skip-chars-forward " \t\n")
 844         (setq save-pos (point))
 845         (skip-chars-forward "^ \t")
 846         (downcase-region save-pos (point))
 847         (setq type (buffer-substring save-pos (point)))
 848         (while (not (eolp))
 849           (skip-chars-forward " \t")
 850           (setq save-pos (point))
 851           (skip-chars-forward "^ \t\n")
 852           (setq extns (cons (buffer-substring save-pos (point)) extns)))
 853         (while extns
 854           (setq mm-mailcap-mime-extensions
 855                 (cons
 856                  (cons (if (= (string-to-char (car extns)) ?.)
 857                            (car extns)
 858                          (concat "." (car extns))) type)
 859                  mm-mailcap-mime-extensions)
 860                 extns (cdr extns)))))))
 861
 862 (defun mm-mailcap-extension-to-mime (extn)
 863   "Return the MIME content type of the file extensions EXTN."
 864   (if (and (stringp extn)
 865            (not (eq (string-to-char extn) ?.)))
 866       (setq extn (concat "." extn)))
 867   (cdr (assoc (downcase extn) mm-mailcap-mime-extensions)))
 868
 869 (defvar mm-mailcap-binary-suffixes
 870   (if (memq system-type '(ms-dos windows-nt))
 871       '(".exe" ".com" ".bat" ".cmd" ".btm" "")
 872     '("")))
 873
 874 (defun mm-mailcap-command-p (command)
 875   "Say whether COMMAND is in the exec path.
 876 The path of COMMAND will be returned iff COMMAND is a command."
 877   (let ((path (if (file-name-absolute-p command) '(nil) exec-path))
 878         file dir)
 879     (catch 'found
 880       (while (setq dir (pop path))
 881         (let ((suffixes mm-mailcap-binary-suffixes))
 882           (while suffixes
 883             (when (and (file-executable-p
 884                         (setq file (expand-file-name
 885                                     (concat command (pop suffixes))
 886                                     dir)))
 887                        (not (file-directory-p file)))
 888               (throw 'found file))))))))
 889
 890 (defun mm-mailcap-mime-types ()
 891   "Return a list of MIME media types."
 892   (delete-duplicates (mapcar 'cdr mm-mailcap-mime-extensions)))
 893
 894 (provide 'mm-mailcap)
 895
 896 ;;; mm-mailcap.el ends here