git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for MIME things
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'static))
  28
  29 (eval-when-compile (require 'cl))
  30 (require 'mail-prsvr)
  31
  32 (defvar mm-mime-mule-charset-alist
  33   '((us-ascii ascii)
  34     (iso-8859-1 latin-iso8859-1)
  35     (iso-8859-2 latin-iso8859-2)
  36     (iso-8859-3 latin-iso8859-3)
  37     (iso-8859-4 latin-iso8859-4)
  38     (iso-8859-5 cyrillic-iso8859-5)
  39     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
  40     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
  41     ;; charset is koi8-r, not iso-8859-5.
  42     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
  43     (iso-8859-6 arabic-iso8859-6)
  44     (iso-8859-7 greek-iso8859-7)
  45     (iso-8859-8 hebrew-iso8859-8)
  46     (iso-8859-9 latin-iso8859-9)
  47     (viscii vietnamese-viscii-lower)
  48     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
  49     (euc-kr korean-ksc5601)
  50     (cn-gb-2312 chinese-gb2312)
  51     (cn-big5 chinese-big5-1 chinese-big5-2)
  52     (tibetan tibetan)
  53     (thai-tis620 thai-tis620)
  54     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
  55     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
  56                    latin-jisx0201 japanese-jisx0208-1978
  57                    chinese-gb2312 japanese-jisx0208
  58                    korean-ksc5601 japanese-jisx0212
  59                    katakana-jisx0201)
  60     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
  61                     latin-jisx0201 japanese-jisx0208-1978
  62                     chinese-gb2312 japanese-jisx0208
  63                     korean-ksc5601 japanese-jisx0212
  64                     chinese-cns11643-1 chinese-cns11643-2)
  65     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
  66                     cyrillic-iso8859-5 greek-iso8859-7
  67                     latin-jisx0201 japanese-jisx0208-1978
  68                     chinese-gb2312 japanese-jisx0208
  69                     korean-ksc5601 japanese-jisx0212
  70                     chinese-cns11643-1 chinese-cns11643-2
  71                     chinese-cns11643-3 chinese-cns11643-4
  72                     chinese-cns11643-5 chinese-cns11643-6
  73                     chinese-cns11643-7)
  74     (utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e))
  75   "Alist of MIME-charset/MULE-charsets.")
  76
  77 (eval-and-compile
  78   (mapcar
  79    (lambda (elem)
  80      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  81        (if (fboundp (car elem))
  82            (defalias nfunc (car elem))
  83          (defalias nfunc (cdr elem)))))
  84    '((decode-coding-string . (lambda (s a) s))
  85      (encode-coding-string . (lambda (s a) s))
  86      (encode-coding-region . ignore)
  87      (coding-system-list . ignore)
  88      (decode-coding-region . ignore)
  89      (char-int . identity)
  90      (device-type . ignore)
  91      (coding-system-equal . equal)
  92      (annotationp . ignore)
  93      (set-buffer-file-coding-system . ignore)
  94      (make-char
  95       . (lambda (charset int)
  96           (int-to-char int)))
  97      (read-coding-system
  98       . (lambda (prompt)
  99           "Prompt the user for a coding system."
 100           (completing-read
 101            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 102                           mm-mime-mule-charset-alist))))
 103      (read-charset
 104       . (lambda (prompt)
 105           "Return a charset."
 106           (intern
 107            (completing-read
 108             prompt
 109             (mapcar (lambda (e) (list (symbol-name (car e))))
 110                     mm-mime-mule-charset-alist)
 111             nil t))))
 112      (subst-char-in-string
 113       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
 114           "Replace characters in STRING from FROM to TO."
 115           (let ((string (substring string 0))   ;Copy string.
 116                 (len (length string))
 117                 (idx 0))
 118             ;; Replace all occurrences of FROM with TO.
 119             (while (< idx len)
 120               (when (= (aref string idx) from)
 121                 (aset string idx to))
 122               (setq idx (1+ idx)))
 123             string)))
 124       )))
 125
 126 (eval-and-compile
 127   (defalias 'mm-char-or-char-int-p
 128     (cond
 129      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
 130      ((fboundp 'char-valid-p) 'char-valid-p)
 131      (t 'identity))))
 132
 133 (defvar mm-coding-system-list nil)
 134 (defun mm-get-coding-system-list ()
 135   "Get the coding system list."
 136   (or mm-coding-system-list
 137       (setq mm-coding-system-list (mm-coding-system-list))))
 138
 139 (defvar mm-charset-synonym-alist
 140   '((big5 . cn-big5)
 141     (gb2312 . cn-gb-2312)
 142     (x-ctext . ctext))
 143   "A mapping from invalid charset names to the real charset names.")
 144
 145 (defun mm-coding-system-p (sym)
 146   "Return non-nil if SYM is a coding system."
 147   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 148       (memq sym (mm-get-coding-system-list))))
 149
 150 (defvar mm-binary-coding-system
 151   (cond
 152    ((mm-coding-system-p 'binary) 'binary)
 153    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 154    (t nil))
 155   "100% binary coding system.")
 156
 157 (defvar mm-text-coding-system
 158   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 159           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 160         (and (mm-coding-system-p 'raw-text) 'raw-text))
 161       mm-binary-coding-system)
 162   "Text-safe coding system (For removing ^M).")
 163
 164 (defvar mm-text-coding-system-for-write nil
 165   "Text coding system for write.")
 166
 167 (defvar mm-auto-save-coding-system
 168   (cond
 169    ((mm-coding-system-p 'emacs-mule)
 170     (if (memq system-type '(windows-nt ms-dos ms-windows))
 171         (if (mm-coding-system-p 'emacs-mule-dos)
 172             'emacs-mule-dos mm-binary-coding-system)
 173       'emacs-mule))
 174    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 175    (t mm-binary-coding-system))
 176   "Coding system of auto save file.")
 177
 178 ;;; Internal variables:
 179
 180 ;;; Functions:
 181
 182 (defun mm-mule-charset-to-mime-charset (charset)
 183   "Return the MIME charset corresponding to MULE CHARSET."
 184   (let ((alist mm-mime-mule-charset-alist)
 185         out)
 186     (while alist
 187       (when (memq charset (cdar alist))
 188         (setq out (caar alist)
 189               alist nil))
 190       (pop alist))
 191     out))
 192
 193 (defun mm-charset-to-coding-system (charset &optional lbt)
 194   "Return coding-system corresponding to CHARSET.
 195 CHARSET is a symbol naming a MIME charset.
 196 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 197 used as the line break code type of the coding system."
 198   (when (stringp charset)
 199     (setq charset (intern (downcase charset))))
 200   (setq charset
 201         (or (cdr (assq charset mm-charset-synonym-alist))
 202             charset))
 203   (when lbt
 204     (setq charset (intern (format "%s-%s" charset lbt))))
 205   (cond
 206    ;; Running in a non-MULE environment.
 207    ((null (mm-get-coding-system-list))
 208     charset)
 209    ;; ascii
 210    ((eq charset 'us-ascii)
 211     'ascii)
 212    ;; Check to see whether we can handle this charset.
 213    ((memq charset (mm-get-coding-system-list))
 214     charset)
 215    ;; Nope.
 216    (t
 217     nil)))
 218
 219 (defsubst mm-replace-chars-in-string (string from to)
 220   (mm-subst-char-in-string from to string))
 221
 222 (defsubst mm-enable-multibyte ()
 223   "Enable multibyte in the current buffer."
 224   (when (and (fboundp 'set-buffer-multibyte)
 225              (boundp 'enable-multibyte-characters)
 226              (default-value 'enable-multibyte-characters))
 227     (set-buffer-multibyte t)))
 228
 229 (defsubst mm-disable-multibyte ()
 230   "Disable multibyte in the current buffer."
 231   (when (fboundp 'set-buffer-multibyte)
 232     (set-buffer-multibyte nil)))
 233
 234 (defsubst mm-enable-multibyte-mule4 ()
 235   "Enable multibyte in the current buffer.
 236 Only used in Emacs Mule 4."
 237   (when (and (fboundp 'set-buffer-multibyte)
 238              (boundp 'enable-multibyte-characters)
 239              (default-value 'enable-multibyte-characters)
 240              (not (charsetp 'eight-bit-control)))
 241     (set-buffer-multibyte t)))
 242
 243 (defsubst mm-disable-multibyte-mule4 ()
 244   "Disable multibyte in the current buffer.
 245 Only used in Emacs Mule 4."
 246   (when (and (fboundp 'set-buffer-multibyte)
 247              (not (charsetp 'eight-bit-control)))
 248     (set-buffer-multibyte nil)))
 249
 250 (defun mm-preferred-coding-system (charset)
 251   ;; A typo in some Emacs versions.
 252   (or (get-charset-property charset 'prefered-coding-system)
 253       (get-charset-property charset 'preferred-coding-system)))
 254
 255 (defun mm-charset-after (&optional pos)
 256   "Return charset of a character in current buffer at position POS.
 257 If POS is nil, it defauls to the current point.
 258 If POS is out of range, the value is nil.
 259 If the charset is `composition', return the actual one."
 260   (let ((char (char-after pos)) charset)
 261     (if (< (mm-char-int char) 128)
 262         (setq charset 'ascii)
 263       ;; charset-after is fake in some Emacsen.
 264       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 265       (if (eq charset 'composition)
 266           (let ((p (or pos (point))))
 267             (cadr (find-charset-region p (1+ p))))
 268         (if (and charset (not (memq charset '(ascii eight-bit-control
 269                                                     eight-bit-graphic))))
 270             charset
 271           (or
 272            mail-parse-mule-charset ;; cached mule-charset
 273            (progn
 274              (setq mail-parse-mule-charset
 275                    (and (boundp 'current-language-environment)
 276                       (car (last
 277                             (assq 'charset
 278                                   (assoc current-language-environment
 279                                          language-info-alist))))))
 280              (if (or (not mail-parse-mule-charset)
 281                      (eq mail-parse-mule-charset 'ascii))
 282                  (setq mail-parse-mule-charset
 283                        (or (car (last (assq mail-parse-charset
 284                                             mm-mime-mule-charset-alist)))
 285                            'latin-iso8859-1)))
 286              mail-parse-mule-charset)))))))
 287
 288 (defun mm-mime-charset (charset)
 289   "Return the MIME charset corresponding to the MULE CHARSET."
 290   (if (eq charset 'unknown)
 291       (error "8-bit characters are found in the message, please specify charset."))
 292   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 293       ;; This exists in Emacs 20.
 294       (or
 295        (and (mm-preferred-coding-system charset)
 296             (coding-system-get
 297              (mm-preferred-coding-system charset) 'mime-charset))
 298        (and (eq charset 'ascii)
 299             'us-ascii)
 300        (mm-preferred-coding-system charset)
 301        (mm-mule-charset-to-mime-charset charset))
 302     ;; This is for XEmacs.
 303     (mm-mule-charset-to-mime-charset charset)))
 304
 305 (defun mm-delete-duplicates (list)
 306   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 307   (let (result head)
 308     (while list
 309       (setq head (car list))
 310       (setq list (delete head list))
 311       (setq result (cons head result)))
 312     (nreverse result)))
 313
 314 (defun mm-find-mime-charset-region (b e)
 315   "Return the MIME charsets needed to encode the region between B and E."
 316   (let ((charsets (mapcar 'mm-mime-charset
 317                           (delq 'ascii
 318                                 (mm-find-charset-region b e)))))
 319     (when (memq 'iso-2022-jp-2 charsets)
 320       (setq charsets (delq 'iso-2022-jp charsets)))
 321     (setq charsets (mm-delete-duplicates charsets))
 322     (if (and (> (length charsets) 1)
 323              (fboundp 'find-coding-systems-region)
 324              (memq 'utf-8 (find-coding-systems-region b e)))
 325         '(utf-8)
 326       charsets)))
 327
 328 (defsubst mm-multibyte-p ()
 329   "Say whether multibyte is enabled."
 330   (if (and (not (featurep 'xemacs))
 331            (boundp 'enable-multibyte-characters))
 332       enable-multibyte-characters
 333     (featurep 'mule)))
 334
 335 (defmacro mm-with-unibyte-buffer (&rest forms)
 336   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 337 See also `with-temp-file' and `with-output-to-string'."
 338   (let ((temp-buffer (make-symbol "temp-buffer"))
 339         (multibyte (make-symbol "multibyte")))
 340     `(if (or (featurep 'xemacs)
 341              (not (boundp 'enable-multibyte-characters)))
 342          (with-temp-buffer ,@forms)
 343        (let ((,multibyte (default-value 'enable-multibyte-characters))
 344              ,temp-buffer)
 345          (unwind-protect
 346              (progn
 347                (setq-default enable-multibyte-characters nil)
 348                (setq ,temp-buffer
 349                      (get-buffer-create (generate-new-buffer-name " *temp*")))
 350                (unwind-protect
 351                    (with-current-buffer ,temp-buffer
 352                      (let ((buffer-file-coding-system mm-binary-coding-system)
 353                            (coding-system-for-read mm-binary-coding-system)
 354                            (coding-system-for-write mm-binary-coding-system))
 355                        ,@forms))
 356                  (and (buffer-name ,temp-buffer)
 357                       (kill-buffer ,temp-buffer))))
 358            (setq-default enable-multibyte-characters ,multibyte))))))
 359 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 360 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 361
 362 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 363   "Evaluate FORMS there like `progn' in current buffer."
 364   (let ((multibyte (make-symbol "multibyte")))
 365     `(if (or (featurep 'xemacs)
 366              (not (fboundp 'set-buffer-multibyte)))
 367          (progn
 368            ,@forms)
 369        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 370          (unwind-protect
 371              (let ((buffer-file-coding-system mm-binary-coding-system)
 372                    (coding-system-for-read mm-binary-coding-system)
 373                    (coding-system-for-write mm-binary-coding-system))
 374                (set-buffer-multibyte nil)
 375                (setq-default enable-multibyte-characters nil)
 376                ,@forms)
 377            (setq-default enable-multibyte-characters ,multibyte)
 378            (set-buffer-multibyte ,multibyte))))))
 379 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 380 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 381
 382 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 383   "Evaluate FORMS there like `progn' in current buffer.
 384 Mule4 only."
 385   (let ((multibyte (make-symbol "multibyte")))
 386     `(if (or (featurep 'xemacs)
 387              (not (fboundp 'set-buffer-multibyte))
 388              (charsetp 'eight-bit-control)) ;; For Emacs Mule 4 only.
 389          (progn
 390            ,@forms)
 391        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 392          (unwind-protect
 393              (let ((buffer-file-coding-system mm-binary-coding-system)
 394                    (coding-system-for-read mm-binary-coding-system)
 395                    (coding-system-for-write mm-binary-coding-system))
 396                (set-buffer-multibyte nil)
 397                (setq-default enable-multibyte-characters nil)
 398                ,@forms)
 399            (setq-default enable-multibyte-characters ,multibyte)
 400            (set-buffer-multibyte ,multibyte))))))
 401 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 402 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 403
 404 (defmacro mm-with-unibyte (&rest forms)
 405   "Set default `enable-multibyte-characters' to `nil', eval the FORMS."
 406   (let ((multibyte (make-symbol "multibyte")))
 407     `(if (or (featurep 'xemacs)
 408              (not (boundp 'enable-multibyte-characters)))
 409          (progn ,@forms)
 410        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 411          (unwind-protect
 412              (progn
 413                (setq-default enable-multibyte-characters nil)
 414                ,@forms)
 415            (setq-default enable-multibyte-characters ,multibyte))))))
 416 (put 'mm-with-unibyte 'lisp-indent-function 0)
 417 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 418
 419 (defun mm-find-charset-region (b e)
 420   "Return a list of charsets in the region."
 421   (cond
 422    ((and (mm-multibyte-p)
 423          (fboundp 'find-charset-region))
 424     ;; Remove composition since the base charsets have been included.
 425     (delq 'composition (find-charset-region b e)))
 426    (t
 427     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 428     (save-excursion
 429       (save-restriction
 430         (narrow-to-region b e)
 431         (goto-char (point-min))
 432         (skip-chars-forward "\0-\177")
 433         (if (eobp)
 434             '(ascii)
 435           (let (charset)
 436             (setq charset
 437                   (and (boundp 'current-language-environment)
 438                        (car (last (assq 'charset
 439                                         (assoc current-language-environment
 440                                                language-info-alist))))))
 441             (if (eq charset 'ascii) (setq charset nil))
 442             (or charset
 443                 (setq charset
 444                       (car (last (assq mail-parse-charset
 445                                        mm-mime-mule-charset-alist)))))
 446             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 447
 448 (static-if (fboundp 'shell-quote-argument)
 449     (defalias 'mm-quote-arg 'shell-quote-argument)
 450   (defun mm-quote-arg (arg)
 451     "Return a version of ARG that is safe to evaluate in a shell."
 452     (let ((pos 0) new-pos accum)
 453       ;; *** bug: we don't handle newline characters properly
 454       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 455         (push (substring arg pos new-pos) accum)
 456         (push "\\" accum)
 457         (push (list (aref arg new-pos)) accum)
 458         (setq pos (1+ new-pos)))
 459       (if (= pos 0)
 460           arg
 461         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 462
 463 (defun mm-auto-mode-alist ()
 464   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 465   (let ((alist auto-mode-alist)
 466         out)
 467     (while alist
 468       (when (listp (cdar alist))
 469         (push (car alist) out))
 470       (pop alist))
 471     (nreverse out)))
 472
 473 (defvar mm-inhibit-file-name-handlers
 474   '(jka-compr-handler)
 475   "A list of handlers doing (un)compression (etc) thingies.")
 476
 477 (defun mm-insert-file-contents (filename &optional visit beg end replace
 478                                          inhibit)
 479   "Like `insert-file-contents', q.v., but only reads in the file.
 480 A buffer may be modified in several ways after reading into the buffer due
 481 to advanced Emacs features, such as file-name-handlers, format decoding,
 482 find-file-hooks, etc.
 483 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 484   This function ensures that none of these modifications will take place."
 485   (let ((format-alist nil)
 486         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 487         (default-major-mode 'fundamental-mode)
 488         (enable-local-variables nil)
 489         (after-insert-file-functions nil)
 490         (enable-local-eval nil)
 491         (find-file-hooks nil)
 492         (inhibit-file-name-operation (if inhibit
 493                                          'insert-file-contents
 494                                        inhibit-file-name-operation))
 495         (inhibit-file-name-handlers
 496          (if inhibit
 497              (append mm-inhibit-file-name-handlers
 498                      inhibit-file-name-handlers)
 499            inhibit-file-name-handlers)))
 500     (insert-file-contents filename visit beg end replace)))
 501
 502 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 503   "Append the contents of the region to the end of file FILENAME.
 504 When called from a function, expects three arguments,
 505 START, END and FILENAME.  START and END are buffer positions
 506 saying what text to write.
 507 Optional fourth argument specifies the coding system to use when
 508 encoding the file.
 509 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 510   (let ((coding-system-for-write
 511          (or codesys mm-text-coding-system-for-write
 512              mm-text-coding-system))
 513         (inhibit-file-name-operation (if inhibit
 514                                          'append-to-file
 515                                        inhibit-file-name-operation))
 516         (inhibit-file-name-handlers
 517          (if inhibit
 518              (append mm-inhibit-file-name-handlers
 519                      inhibit-file-name-handlers)
 520            inhibit-file-name-handlers)))
 521     (append-to-file start end filename)))
 522
 523 (defun mm-write-region (start end filename &optional append visit lockname
 524                               coding-system inhibit)
 525
 526   "Like `write-region'.
 527 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 528   (let ((coding-system-for-write
 529          (or coding-system mm-text-coding-system-for-write
 530              mm-text-coding-system))
 531         (inhibit-file-name-operation (if inhibit
 532                                          'write-region
 533                                        inhibit-file-name-operation))
 534         (inhibit-file-name-handlers
 535          (if inhibit
 536              (append mm-inhibit-file-name-handlers
 537                      inhibit-file-name-handlers)
 538            inhibit-file-name-handlers)))
 539     (write-region start end filename append visit lockname)))
 540
 541 (provide 'mm-util)
 542
 543 ;;; mm-util.el ends here