git.chise.org Git - elisp/gnus.git-/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'mm-util)
  27 (require 'mm-bodies)
  28 (require 'mm-encode)
  29 (require 'mm-decode)
  30 (eval-when-compile 'cl)
  31
  32 (eval-and-compile
  33   (autoload 'message-make-message-id "message")
  34   (autoload 'gnus-setup-posting-charset "gnus-msg")
  35   (autoload 'message-fetch-field "message")
  36   (autoload 'message-posting-charset "message"))
  37
  38 (defvar mml-generate-multipart-alist nil
  39   "*Alist of multipart generation functions.
  40 Each entry has the form (NAME . FUNCTION), where
  41 NAME is a string containing the name of the part (without the
  42 leading \"/multipart/\"),
  43 FUNCTION is a Lisp function which is called to generate the part.
  44
  45 The Lisp function has to supply the appropriate MIME headers and the
  46 contents of this part.")
  47
  48 (defvar mml-syntax-table
  49   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  50     (modify-syntax-entry ?\\ "/" table)
  51     (modify-syntax-entry ?< "(" table)
  52     (modify-syntax-entry ?> ")" table)
  53     (modify-syntax-entry ?@ "w" table)
  54     (modify-syntax-entry ?/ "w" table)
  55     (modify-syntax-entry ?= " " table)
  56     (modify-syntax-entry ?* " " table)
  57     (modify-syntax-entry ?\; " " table)
  58     (modify-syntax-entry ?\' " " table)
  59     table))
  60
  61 (defvar mml-boundary-function 'mml-make-boundary
  62   "A function called to suggest a boundary.
  63 The function may be called several times, and should try to make a new
  64 suggestion each time.  The function is called with one parameter,
  65 which is a number that says how many times the function has been
  66 called for this message.")
  67
  68 (defvar mml-confirmation-set nil
  69   "A list of symbols, each of which disables some warning.
  70 `unknown-encoding': always send messages contain characters with
  71 unknown encoding; `use-ascii': always use ASCII for those characters
  72 with unknown encoding; `multipart': always send messages with more than
  73 one charsets.")
  74
  75 (defvar mml-generate-mime-preprocess-function nil
  76   "A function called before generating a mime part.
  77 The function is called with one parameter, which is the part to be
  78 generated.")
  79
  80 (defvar mml-generate-mime-postprocess-function nil
  81   "A function called after generating a mime part.
  82 The function is called with one parameter, which is the generated part.")
  83
  84 (defvar mml-generate-default-type "text/plain")
  85
  86 (defvar mml-buffer-list nil)
  87
  88 (defun mml-generate-new-buffer (name)
  89   (let ((buf (generate-new-buffer name)))
  90     (push buf mml-buffer-list)
  91     buf))
  92
  93 (defun mml-destroy-buffers ()
  94   (let (kill-buffer-hook)
  95     (mapcar 'kill-buffer mml-buffer-list)
  96     (setq mml-buffer-list nil)))
  97
  98 (defun mml-parse ()
  99   "Parse the current buffer as an MML document."
 100   (goto-char (point-min))
 101   (let ((table (syntax-table)))
 102     (unwind-protect
 103         (progn
 104           (set-syntax-table mml-syntax-table)
 105           (mml-parse-1))
 106       (set-syntax-table table))))
 107
 108 (defun mml-parse-1 ()
 109   "Parse the current buffer as an MML document."
 110   (let (struct tag point contents charsets warn use-ascii no-markup-p)
 111     (while (and (not (eobp))
 112                 (not (looking-at "<#/multipart")))
 113       (cond
 114        ((looking-at "<#multipart")
 115         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 116        ((looking-at "<#external")
 117         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 118               struct))
 119        (t
 120         (if (or (looking-at "<#part") (looking-at "<#mml"))
 121             (setq tag (mml-read-tag)
 122                   no-markup-p nil
 123                   warn nil)
 124           (setq tag (list 'part '(type . "text/plain"))
 125                 no-markup-p t
 126                 warn t))
 127         (setq point (point)
 128               contents (mml-read-part (eq 'mml (car tag)))
 129               charsets (mm-find-mime-charset-region point (point)))
 130         (when (memq nil charsets)
 131           (if (or (memq 'unknown-encoding mml-confirmation-set)
 132                   (y-or-n-p
 133                    "Warning: You message contains characters with unknown encoding. Really send?"))
 134               (if (setq use-ascii
 135                         (or (memq 'use-ascii mml-confirmation-set)
 136                             (y-or-n-p "Use ASCII as charset?")))
 137                   (setq charsets (delq nil charsets))
 138                 (setq warn nil))
 139             (error "Edit your message to remove those characters")))
 140         (if (< (length charsets) 2)
 141             (if (or (not no-markup-p)
 142                     (string-match "[^ \t\r\n]" contents))
 143                 ;; Don't create blank parts.
 144                 (push (nconc tag (list (cons 'contents contents)))
 145                       struct))
 146           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 147                           tag point (point) use-ascii)))
 148             (when (and warn
 149                        (not (memq 'multipart mml-confirmation-set))
 150                        (not
 151                         (y-or-n-p
 152                          (format
 153                           "Warning: Your message contains more than %d parts.  Really send? "
 154                           (length nstruct)))))
 155               (error "Edit your message to use only one charset"))
 156             (setq struct (nconc nstruct struct)))))))
 157     (unless (eobp)
 158       (forward-line 1))
 159     (nreverse struct)))
 160
 161 (defun mml-parse-singlepart-with-multiple-charsets
 162   (orig-tag beg end &optional use-ascii)
 163   (save-excursion
 164     (save-restriction
 165       (narrow-to-region beg end)
 166       (goto-char (point-min))
 167       (let ((current (or (mm-mime-charset (mm-charset-after))
 168                          (and use-ascii 'us-ascii)))
 169             charset struct space newline paragraph)
 170         (while (not (eobp))
 171           (setq charset (mm-mime-charset (mm-charset-after)))
 172           (cond
 173            ;; The charset remains the same.
 174            ((eq charset 'us-ascii))
 175            ((or (and use-ascii (not charset))
 176                 (eq charset current))
 177             (setq space nil
 178                   newline nil
 179                   paragraph nil))
 180            ;; The initial charset was ascii.
 181            ((eq current 'us-ascii)
 182             (setq current charset
 183                   space nil
 184                   newline nil
 185                   paragraph nil))
 186            ;; We have a change in charsets.
 187            (t
 188             (push (append
 189                    orig-tag
 190                    (list (cons 'contents
 191                                (buffer-substring-no-properties
 192                                 beg (or paragraph newline space (point))))))
 193                   struct)
 194             (setq beg (or paragraph newline space (point))
 195                   current charset
 196                   space nil
 197                   newline nil
 198                   paragraph nil)))
 199           ;; Compute places where it might be nice to break the part.
 200           (cond
 201            ((memq (following-char) '(?  ?\t))
 202             (setq space (1+ (point))))
 203            ((and (eq (following-char) ?\n)
 204                  (not (bobp))
 205                  (eq (char-after (1- (point))) ?\n))
 206             (setq paragraph (point)))
 207            ((eq (following-char) ?\n)
 208             (setq newline (1+ (point)))))
 209           (forward-char 1))
 210         ;; Do the final part.
 211         (unless (= beg (point))
 212           (push (append orig-tag
 213                         (list (cons 'contents
 214                                     (buffer-substring-no-properties
 215                                      beg (point)))))
 216                 struct))
 217         struct))))
 218
 219 (defun mml-read-tag ()
 220   "Read a tag and return the contents."
 221   (let (contents name elem val)
 222     (forward-char 2)
 223     (setq name (buffer-substring-no-properties
 224                 (point) (progn (forward-sexp 1) (point))))
 225     (skip-chars-forward " \t\n")
 226     (while (not (looking-at ">"))
 227       (setq elem (buffer-substring-no-properties
 228                   (point) (progn (forward-sexp 1) (point))))
 229       (skip-chars-forward "= \t\n")
 230       (setq val (buffer-substring-no-properties
 231                  (point) (progn (forward-sexp 1) (point))))
 232       (when (string-match "^\"\\(.*\\)\"$" val)
 233         (setq val (match-string 1 val)))
 234       (push (cons (intern elem) val) contents)
 235       (skip-chars-forward " \t\n"))
 236     (forward-char 1)
 237     (skip-chars-forward " \t\n")
 238     (cons (intern name) (nreverse contents))))
 239
 240 (defun mml-read-part (&optional mml)
 241   "Return the buffer up till the next part, multipart or closing part or multipart.
 242 If MML is non-nil, return the buffer up till the correspondent mml tag."
 243   (let ((beg (point)) (count 1))
 244     ;; If the tag ended at the end of the line, we go to the next line.
 245     (when (looking-at "[ \t]*\n")
 246       (forward-line 1))
 247     (if mml
 248         (progn
 249           (while (and (> count 0) (not (eobp)))
 250             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 251                 (setq count (+ count (if (match-beginning 1) -1 1)))
 252               (goto-char (point-max))))
 253           (buffer-substring-no-properties beg (if (> count 0)
 254                                                   (point)
 255                                                 (match-beginning 0))))
 256       (if (re-search-forward
 257            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 258           (prog1
 259               (buffer-substring-no-properties beg (match-beginning 0))
 260             (if (or (not (match-beginning 1))
 261                     (equal (match-string 2) "multipart"))
 262                 (goto-char (match-beginning 0))
 263               (when (looking-at "[ \t]*\n")
 264                 (forward-line 1))))
 265         (buffer-substring-no-properties beg (goto-char (point-max)))))))
 266
 267 (defvar mml-boundary nil)
 268 (defvar mml-base-boundary "-=-=")
 269 (defvar mml-multipart-number 0)
 270
 271 (defun mml-generate-mime ()
 272   "Generate a MIME message based on the current MML document."
 273   (let ((cont (mml-parse))
 274         (mml-multipart-number mml-multipart-number))
 275     (if (not cont)
 276         nil
 277       (with-temp-buffer
 278         (if (and (consp (car cont))
 279                  (= (length cont) 1))
 280             (mml-generate-mime-1 (car cont))
 281           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 282                                       cont)))
 283         (buffer-string)))))
 284
 285 (defun mml-generate-mime-1 (cont)
 286   (save-restriction
 287     (narrow-to-region (point) (point))
 288     (if mml-generate-mime-preprocess-function
 289         (funcall mml-generate-mime-preprocess-function cont))
 290     (cond
 291      ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 292       (let (coded encoding charset filename type)
 293         (setq type (or (cdr (assq 'type cont)) "text/plain"))
 294         (if (member (car (split-string type "/")) '("text" "message"))
 295             (with-temp-buffer
 296               (cond
 297                ((cdr (assq 'buffer cont))
 298                 (insert-buffer-substring (cdr (assq 'buffer cont))))
 299                ((and (setq filename (cdr (assq 'filename cont)))
 300                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 301                 (mm-insert-file-contents filename))
 302                ((eq 'mml (car cont))
 303                 (insert (cdr (assq 'contents cont))))
 304                (t
 305                 (save-restriction
 306                   (narrow-to-region (point) (point))
 307                   (insert (cdr (assq 'contents cont)))
 308                   ;; Remove quotes from quoted tags.
 309                   (goto-char (point-min))
 310                   (while (re-search-forward
 311                           "<#!+/?\\(part\\|multipart\\|external\\|mml\\)" nil t)
 312                     (delete-region (+ (match-beginning 0) 2)
 313                                    (+ (match-beginning 0) 3))))))
 314               (cond
 315                ((eq (car cont) 'mml)
 316                 (let ((mml-boundary (funcall mml-boundary-function
 317                                              (incf mml-multipart-number)))
 318                       (mml-generate-default-type "text/plain"))
 319                   (mml-to-mime))
 320                 (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 321                   ;; ignore 0x1b, it is part of iso-2022-jp
 322                   (setq encoding (mm-body-7-or-8))))
 323                ((string= (car (split-string type "/")) "message")
 324                 (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 325                   ;; ignore 0x1b, it is part of iso-2022-jp
 326                   (setq encoding (mm-body-7-or-8))))
 327                (t
 328                 (setq charset (mm-encode-body))
 329                 (setq encoding (mm-body-encoding
 330                                 charset (cdr (assq 'encoding cont))))))
 331               (setq coded (buffer-string)))
 332           (mm-with-unibyte-buffer
 333             (cond
 334              ((cdr (assq 'buffer cont))
 335               (insert-buffer-substring (cdr (assq 'buffer cont))))
 336              ((and (setq filename (cdr (assq 'filename cont)))
 337                    (not (equal (cdr (assq 'nofile cont)) "yes")))
 338               (let ((coding-system-for-read mm-binary-coding-system))
 339                 (mm-insert-file-contents filename nil nil nil nil t)))
 340              (t
 341               (insert (cdr (assq 'contents cont)))))
 342             (setq encoding (mm-encode-buffer type)
 343                   coded (buffer-string))))
 344         (mml-insert-mime-headers cont type charset encoding)
 345         (insert "\n")
 346         (insert coded)))
 347      ((eq (car cont) 'external)
 348       (insert "Content-Type: message/external-body")
 349       (let ((parameters (mml-parameter-string
 350                          cont '(expiration size permission)))
 351             (name (cdr (assq 'name cont))))
 352         (when name
 353           (setq name (mml-parse-file-name name))
 354           (if (stringp name)
 355               (mml-insert-parameter
 356                (mail-header-encode-parameter "name" name)
 357                "access-type=local-file")
 358             (mml-insert-parameter
 359              (mail-header-encode-parameter
 360               "name" (file-name-nondirectory (nth 2 name)))
 361              (mail-header-encode-parameter "site" (nth 1 name))
 362              (mail-header-encode-parameter
 363               "directory" (file-name-directory (nth 2 name))))
 364             (mml-insert-parameter
 365              (concat "access-type="
 366                      (if (member (nth 0 name) '("ftp@" "anonymous@"))
 367                          "anon-ftp"
 368                        "ftp")))))
 369         (when parameters
 370           (mml-insert-parameter-string
 371            cont '(expiration size permission))))
 372       (insert "\n\n")
 373       (insert "Content-Type: " (cdr (assq 'type cont)) "\n")
 374       (insert "Content-ID: " (message-make-message-id) "\n")
 375       (insert "Content-Transfer-Encoding: "
 376               (or (cdr (assq 'encoding cont)) "binary"))
 377       (insert "\n\n")
 378       (insert (or (cdr (assq 'contents cont))))
 379       (insert "\n"))
 380      ((eq (car cont) 'multipart)
 381       (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 382              (mml-generate-default-type (if (equal type "digest")
 383                                             "message/rfc822"
 384                                           "text/plain"))
 385              (handler (assoc type mml-generate-multipart-alist)))
 386         (if handler
 387             (funcall (cdr handler) cont)
 388           ;; No specific handler.  Use default one.
 389           (let ((mml-boundary (mml-compute-boundary cont)))
 390             (insert (format "Content-Type: multipart/%s; boundary=\"%s\"\n"
 391                             type mml-boundary))
 392             ;; Skip `multipart' and `type' elements.
 393             (setq cont (cddr cont))
 394             (while cont
 395               (insert "\n--" mml-boundary "\n")
 396               (mml-generate-mime-1 (pop cont)))
 397             (insert "\n--" mml-boundary "--\n")))))
 398      (t
 399       (error "Invalid element: %S" cont)))
 400     (if mml-generate-mime-postprocess-function
 401         (funcall mml-generate-mime-postprocess-function cont))))
 402
 403 (defun mml-compute-boundary (cont)
 404   "Return a unique boundary that does not exist in CONT."
 405   (let ((mml-boundary (funcall mml-boundary-function
 406                                (incf mml-multipart-number))))
 407     ;; This function tries again and again until it has found
 408     ;; a unique boundary.
 409     (while (not (catch 'not-unique
 410                   (mml-compute-boundary-1 cont))))
 411     mml-boundary))
 412
 413 (defun mml-compute-boundary-1 (cont)
 414   (let (filename)
 415     (cond
 416      ((eq (car cont) 'part)
 417       (with-temp-buffer
 418         (cond
 419          ((cdr (assq 'buffer cont))
 420           (insert-buffer-substring (cdr (assq 'buffer cont))))
 421          ((and (setq filename (cdr (assq 'filename cont)))
 422                (not (equal (cdr (assq 'nofile cont)) "yes")))
 423           (mm-insert-file-contents filename))
 424          (t
 425           (insert (cdr (assq 'contents cont)))))
 426         (goto-char (point-min))
 427         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 428                                  nil t)
 429           (setq mml-boundary (funcall mml-boundary-function
 430                                       (incf mml-multipart-number)))
 431           (throw 'not-unique nil))))
 432      ((eq (car cont) 'multipart)
 433       (mapcar 'mml-compute-boundary-1 (cddr cont))))
 434     t))
 435
 436 (defun mml-make-boundary (number)
 437   (concat (make-string (% number 60) ?=)
 438           (if (> number 17)
 439               (format "%x" number)
 440             "")
 441           mml-base-boundary))
 442
 443 (defun mml-make-string (num string)
 444   (let ((out ""))
 445     (while (not (zerop (decf num)))
 446       (setq out (concat out string)))
 447     out))
 448
 449 (defun mml-insert-mime-headers (cont type charset encoding)
 450   (let (parameters disposition description)
 451     (setq parameters
 452           (mml-parameter-string
 453            cont '(name access-type expiration size permission)))
 454     (when (or charset
 455               parameters
 456               (not (equal type mml-generate-default-type)))
 457       (when (consp charset)
 458         (error
 459          "Can't encode a part with several charsets."))
 460       (insert "Content-Type: " type)
 461       (when charset
 462         (insert "; " (mail-header-encode-parameter
 463                       "charset" (symbol-name charset))))
 464       (when parameters
 465         (mml-insert-parameter-string
 466          cont '(name access-type expiration size permission)))
 467       (insert "\n"))
 468     (setq parameters
 469           (mml-parameter-string
 470            cont '(filename creation-date modification-date read-date)))
 471     (when (or (setq disposition (cdr (assq 'disposition cont)))
 472               parameters)
 473       (insert "Content-Disposition: " (or disposition "inline"))
 474       (when parameters
 475         (mml-insert-parameter-string
 476          cont '(filename creation-date modification-date read-date)))
 477       (insert "\n"))
 478     (unless (eq encoding '7bit)
 479       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 480     (when (setq description (cdr (assq 'description cont)))
 481       (insert "Content-Description: "
 482               (mail-encode-encoded-word-string description) "\n"))))
 483
 484 (defun mml-parameter-string (cont types)
 485   (let ((string "")
 486         value type)
 487     (while (setq type (pop types))
 488       (when (setq value (cdr (assq type cont)))
 489         ;; Strip directory component from the filename parameter.
 490         (when (eq type 'filename)
 491           (setq value (file-name-nondirectory value)))
 492         (setq string (concat string "; "
 493                              (mail-header-encode-parameter
 494                               (symbol-name type) value)))))
 495     (when (not (zerop (length string)))
 496       string)))
 497
 498 (defun mml-insert-parameter-string (cont types)
 499   (let (value type)
 500     (while (setq type (pop types))
 501       (when (setq value (cdr (assq type cont)))
 502         ;; Strip directory component from the filename parameter.
 503         (when (eq type 'filename)
 504           (setq value (file-name-nondirectory value)))
 505         (mml-insert-parameter
 506          (mail-header-encode-parameter
 507           (symbol-name type) value))))))
 508
 509 (defvar ange-ftp-path-format)
 510 (defvar efs-path-regexp)
 511 (defun mml-parse-file-name (path)
 512   (if (if (boundp 'efs-path-regexp)
 513           (string-match efs-path-regexp path)
 514         (if (boundp 'ange-ftp-path-format)
 515             (string-match (car ange-ftp-path-format))))
 516       (list (match-string 1 path) (match-string 2 path)
 517             (substring path (1+ (match-end 2))))
 518     path))
 519
 520 (defun mml-insert-buffer (buffer)
 521   "Insert BUFFER at point and quote any MML markup."
 522   (save-restriction
 523     (narrow-to-region (point) (point))
 524     (insert-buffer-substring buffer)
 525     (mml-quote-region (point-min) (point-max))
 526     (goto-char (point-max))))
 527
 528 ;;;
 529 ;;; Transforming MIME to MML
 530 ;;;
 531
 532 (defun mime-to-mml ()
 533   "Translate the current buffer (which should be a message) into MML."
 534   ;; First decode the head.
 535   (save-restriction
 536     (message-narrow-to-head)
 537     (mail-decode-encoded-word-region (point-min) (point-max)))
 538   (let ((handles (mm-dissect-buffer t)))
 539     (goto-char (point-min))
 540     (search-forward "\n\n" nil t)
 541     (delete-region (point) (point-max))
 542     (if (stringp (car handles))
 543         (mml-insert-mime handles)
 544       (mml-insert-mime handles t))
 545     (mm-destroy-parts handles))
 546   (save-restriction
 547     (message-narrow-to-head)
 548     ;; Remove them, they are confusing.
 549     (message-remove-header "Content-Type")
 550     (message-remove-header "MIME-Version")
 551     (message-remove-header "Content-Transfer-Encoding")))
 552
 553 (defun mml-to-mime ()
 554   "Translate the current buffer from MML to MIME."
 555   (message-encode-message-body)
 556   (save-restriction
 557     (message-narrow-to-headers-or-head)
 558     (let ((mail-parse-charset message-default-charset))
 559       (mail-encode-encoded-word-buffer))))
 560
 561 (defun mml-insert-mime (handle &optional no-markup)
 562   (let (textp buffer mmlp)
 563     ;; Determine type and stuff.
 564     (unless (stringp (car handle))
 565       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 566         (save-excursion
 567           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 568           (mm-insert-part handle)
 569           (if (setq mmlp (equal (mm-handle-media-type handle)
 570                                 "message/rfc822"))
 571               (mime-to-mml)))))
 572     (if mmlp
 573         (mml-insert-mml-markup handle nil t t)
 574       (unless (and no-markup
 575                    (equal (mm-handle-media-type handle) "text/plain"))
 576         (mml-insert-mml-markup handle buffer textp)))
 577     (cond
 578      (mmlp
 579       (insert-buffer buffer)
 580       (goto-char (point-max))
 581       (insert "<#/mml>\n"))
 582      ((stringp (car handle))
 583       (mapcar 'mml-insert-mime (cdr handle))
 584       (insert "<#/multipart>\n"))
 585      (textp
 586       (let ((text (mm-get-part handle))
 587             (charset (mail-content-type-get
 588                       (mm-handle-type handle) 'charset)))
 589         (insert (mm-decode-string text charset)))
 590       (goto-char (point-max)))
 591      (t
 592       (insert "<#/part>\n")))))
 593
 594 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 595   "Take a MIME handle and insert an MML tag."
 596   (if (stringp (car handle))
 597       (insert "<#multipart type=" (mm-handle-media-subtype handle)
 598               ">\n")
 599     (if mmlp
 600         (insert "<#mml type=" (mm-handle-media-type handle))
 601       (insert "<#part type=" (mm-handle-media-type handle)))
 602     (dolist (elem (append (cdr (mm-handle-type handle))
 603                           (cdr (mm-handle-disposition handle))))
 604       (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\""))
 605     (when (mm-handle-disposition handle)
 606       (insert " disposition=" (car (mm-handle-disposition handle))))
 607     (when buffer
 608       (insert " buffer=\"" (buffer-name buffer) "\""))
 609     (when nofile
 610       (insert " nofile=yes"))
 611     (when (mm-handle-description handle)
 612       (insert " description=\"" (mm-handle-description handle) "\""))
 613     (insert ">\n")))
 614
 615 (defun mml-insert-parameter (&rest parameters)
 616   "Insert PARAMETERS in a nice way."
 617   (dolist (param parameters)
 618     (insert ";")
 619     (let ((point (point)))
 620       (insert " " param)
 621       (when (> (current-column) 71)
 622         (goto-char point)
 623         (insert "\n ")
 624         (end-of-line)))))
 625
 626 ;;;
 627 ;;; Mode for inserting and editing MML forms
 628 ;;;
 629
 630 (defvar mml-mode-map
 631   (let ((map (make-sparse-keymap))
 632         (main (make-sparse-keymap)))
 633     (define-key map "f" 'mml-attach-file)
 634     (define-key map "b" 'mml-attach-buffer)
 635     (define-key map "e" 'mml-attach-external)
 636     (define-key map "q" 'mml-quote-region)
 637     (define-key map "m" 'mml-insert-multipart)
 638     (define-key map "p" 'mml-insert-part)
 639     (define-key map "v" 'mml-validate)
 640     (define-key map "P" 'mml-preview)
 641     (define-key map "n" 'mml-narrow-to-part)
 642     (define-key main "\M-m" map)
 643     main))
 644
 645 (easy-menu-define
 646  mml-menu mml-mode-map ""
 647  '("MML"
 648    ("Attach"
 649     ["File" mml-attach-file t]
 650     ["Buffer" mml-attach-buffer t]
 651     ["External" mml-attach-external t])
 652    ("Insert"
 653     ["Multipart" mml-insert-multipart t]
 654     ["Part" mml-insert-part t])
 655    ["Narrow" mml-narrow-to-part t]
 656    ["Quote" mml-quote-region t]
 657    ["Validate" mml-validate t]
 658    ["Preview" mml-preview t]))
 659
 660 (defvar mml-mode nil
 661   "Minor mode for editing MML.")
 662
 663 (defun mml-mode (&optional arg)
 664   "Minor mode for editing MML.
 665
 666 \\{mml-mode-map}"
 667   (interactive "P")
 668   (if (not (set (make-local-variable 'mml-mode)
 669                 (if (null arg) (not mml-mode)
 670                   (> (prefix-numeric-value arg) 0))))
 671       nil
 672     (set (make-local-variable 'mml-mode) t)
 673     (unless (assq 'mml-mode minor-mode-alist)
 674       (push `(mml-mode " MML") minor-mode-alist))
 675     (unless (assq 'mml-mode minor-mode-map-alist)
 676       (push (cons 'mml-mode mml-mode-map)
 677             minor-mode-map-alist)))
 678   (run-hooks 'mml-mode-hook))
 679
 680 ;;;
 681 ;;; Helper functions for reading MIME stuff from the minibuffer and
 682 ;;; inserting stuff to the buffer.
 683 ;;;
 684
 685 (defun mml-minibuffer-read-file (prompt)
 686   (let ((file (read-file-name prompt nil nil t)))
 687     ;; Prevent some common errors.  This is inspired by similar code in
 688     ;; VM.
 689     (when (file-directory-p file)
 690       (error "%s is a directory, cannot attach" file))
 691     (unless (file-exists-p file)
 692       (error "No such file: %s" file))
 693     (unless (file-readable-p file)
 694       (error "Permission denied: %s" file))
 695     file))
 696
 697 (defun mml-minibuffer-read-type (name &optional default)
 698   (let* ((default (or default
 699                       (mm-default-file-encoding name)
 700                       ;; Perhaps here we should check what the file
 701                       ;; looks like, and offer text/plain if it looks
 702                       ;; like text/plain.
 703                       "application/octet-stream"))
 704          (string (completing-read
 705                   (format "Content type (default %s): " default)
 706                   (mapcar
 707                    'list
 708                    (mm-delete-duplicates
 709                     (nconc
 710                      (mapcar 'cdr mailcap-mime-extensions)
 711                      (apply
 712                       'nconc
 713                       (mapcar
 714                        (lambda (l)
 715                          (delq nil
 716                                (mapcar
 717                                 (lambda (m)
 718                                   (let ((type (cdr (assq 'type (cdr m)))))
 719                                     (if (equal (cadr (split-string type "/"))
 720                                                "*")
 721                                         nil
 722                                       type)))
 723                                 (cdr l))))
 724                        mailcap-mime-data))))))))
 725     (if (not (equal string ""))
 726         string
 727       default)))
 728
 729 (defun mml-minibuffer-read-description ()
 730   (let ((description (read-string "One line description: ")))
 731     (when (string-match "\\`[ \t]*\\'" description)
 732       (setq description nil))
 733     description))
 734
 735 (defun mml-quote-region (beg end)
 736   "Quote the MML tags in the region."
 737   (interactive "r")
 738   (save-excursion
 739     (save-restriction
 740       ;; Temporarily narrow the region to defend from changes
 741       ;; invalidating END.
 742       (narrow-to-region beg end)
 743       (goto-char (point-min))
 744       ;; Quote parts.
 745       (while (re-search-forward
 746               "<#/?!*\\(multipart\\|part\\|external\\|mml\\)" nil t)
 747         ;; Insert ! after the #.
 748         (goto-char (+ (match-beginning 0) 2))
 749         (insert "!")))))
 750
 751 (defun mml-insert-tag (name &rest plist)
 752   "Insert an MML tag described by NAME and PLIST."
 753   (when (symbolp name)
 754     (setq name (symbol-name name)))
 755   (insert "<#" name)
 756   (while plist
 757     (let ((key (pop plist))
 758           (value (pop plist)))
 759       (when value
 760         ;; Quote VALUE if it contains suspicious characters.
 761         (when (string-match "[\"'\\~/*;() \t\n]" value)
 762           (setq value (prin1-to-string value)))
 763         (insert (format " %s=%s" key value)))))
 764   (insert ">\n"))
 765
 766 (defun mml-insert-empty-tag (name &rest plist)
 767   "Insert an empty MML tag described by NAME and PLIST."
 768   (when (symbolp name)
 769     (setq name (symbol-name name)))
 770   (apply #'mml-insert-tag name plist)
 771   (insert "<#/" name ">\n"))
 772
 773 ;;; Attachment functions.
 774
 775 (defun mml-attach-file (file &optional type description)
 776   "Attach a file to the outgoing MIME message.
 777 The file is not inserted or encoded until you send the message with
 778 `\\[message-send-and-exit]' or `\\[message-send]'.
 779
 780 FILE is the name of the file to attach.  TYPE is its content-type, a
 781 string of the form \"type/subtype\".  DESCRIPTION is a one-line
 782 description of the attachment."
 783   (interactive
 784    (let* ((file (mml-minibuffer-read-file "Attach file: "))
 785           (type (mml-minibuffer-read-type file))
 786           (description (mml-minibuffer-read-description)))
 787      (list file type description)))
 788   (mml-insert-empty-tag 'part 'type type 'filename file
 789                         'disposition "attachment" 'description description))
 790
 791 (defun mml-attach-buffer (buffer &optional type description)
 792   "Attach a buffer to the outgoing MIME message.
 793 See `mml-attach-file' for details of operation."
 794   (interactive
 795    (let* ((buffer (read-buffer "Attach buffer: "))
 796           (type (mml-minibuffer-read-type buffer "text/plain"))
 797           (description (mml-minibuffer-read-description)))
 798      (list buffer type description)))
 799   (mml-insert-empty-tag 'part 'type type 'buffer buffer
 800                         'disposition "attachment" 'description description))
 801
 802 (defun mml-attach-external (file &optional type description)
 803   "Attach an external file into the buffer.
 804 FILE is an ange-ftp/efs specification of the part location.
 805 TYPE is the MIME type to use."
 806   (interactive
 807    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
 808           (type (mml-minibuffer-read-type file))
 809           (description (mml-minibuffer-read-description)))
 810      (list file type description)))
 811   (mml-insert-empty-tag 'external 'type type 'name file
 812                         'disposition "attachment" 'description description))
 813
 814 (defun mml-insert-multipart (&optional type)
 815   (interactive (list (completing-read "Multipart type (default mixed): "
 816                                       '(("mixed") ("alternative") ("digest") ("parallel")
 817                                         ("signed") ("encrypted"))
 818                                       nil nil "mixed")))
 819   (or type
 820       (setq type "mixed"))
 821   (mml-insert-empty-tag "multipart" 'type type)
 822   (forward-line -1))
 823
 824 (defun mml-insert-part (&optional type)
 825   (interactive
 826    (list (mml-minibuffer-read-type "")))
 827   (mml-insert-tag 'part 'type type 'disposition "inline")
 828   (forward-line -1))
 829
 830 (defun mml-preview (&optional raw)
 831   "Display current buffer with Gnus, in a new buffer.
 832 If RAW, don't highlight the article."
 833   (interactive "P")
 834   (let ((buf (current-buffer))
 835         (message-posting-charset (or (gnus-setup-posting-charset
 836                                       (save-restriction
 837                                         (message-narrow-to-headers-or-head)
 838                                         (message-fetch-field "Newsgroups")))
 839                                      message-posting-charset)))
 840     (switch-to-buffer (get-buffer-create
 841                        (concat (if raw "*Raw MIME preview of "
 842                                  "*MIME preview of ") (buffer-name))))
 843     (erase-buffer)
 844     (insert-buffer buf)
 845     (if (re-search-forward
 846          (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
 847         (replace-match "\n"))
 848     (mml-to-mime)
 849     (if raw
 850         (mm-disable-multibyte)
 851       (let ((gnus-newsgroup-charset (car message-posting-charset)))
 852         (run-hooks 'gnus-article-decode-hook)
 853         (let ((gnus-newsgroup-name "dummy"))
 854           (gnus-article-prepare-display))))
 855     (fundamental-mode)
 856     (setq buffer-read-only t)
 857     (goto-char (point-min))))
 858
 859 (defun mml-validate ()
 860   "Validate the current MML document."
 861   (interactive)
 862   (mml-parse))
 863
 864 (provide 'mml)
 865
 866 ;;; mml.el ends here