git.chise.org Git - elisp/gnus.git-/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'mm-util)
  27 (require 'mm-bodies)
  28 (require 'mm-encode)
  29 (require 'mm-decode)
  30 (require 'mml-sec)
  31 (eval-when-compile (require 'cl))
  32
  33 (eval-and-compile
  34   (autoload 'message-make-message-id "message")
  35   (autoload 'gnus-setup-posting-charset "gnus-msg")
  36   (autoload 'message-fetch-field "message")
  37   (autoload 'message-posting-charset "message"))
  38
  39 (defvar mml-generate-multipart-alist nil
  40   "*Alist of multipart generation functions.
  41 Each entry has the form (NAME . FUNCTION), where
  42 NAME is a string containing the name of the part (without the
  43 leading \"/multipart/\"),
  44 FUNCTION is a Lisp function which is called to generate the part.
  45
  46 The Lisp function has to supply the appropriate MIME headers and the
  47 contents of this part.")
  48
  49 (defvar mml-syntax-table
  50   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  51     (modify-syntax-entry ?\\ "/" table)
  52     (modify-syntax-entry ?< "(" table)
  53     (modify-syntax-entry ?> ")" table)
  54     (modify-syntax-entry ?@ "w" table)
  55     (modify-syntax-entry ?/ "w" table)
  56     (modify-syntax-entry ?= " " table)
  57     (modify-syntax-entry ?* " " table)
  58     (modify-syntax-entry ?\; " " table)
  59     (modify-syntax-entry ?\' " " table)
  60     table))
  61
  62 (defvar mml-boundary-function 'mml-make-boundary
  63   "A function called to suggest a boundary.
  64 The function may be called several times, and should try to make a new
  65 suggestion each time.  The function is called with one parameter,
  66 which is a number that says how many times the function has been
  67 called for this message.")
  68
  69 (defvar mml-confirmation-set nil
  70   "A list of symbols, each of which disables some warning.
  71 `unknown-encoding': always send messages contain characters with
  72 unknown encoding; `use-ascii': always use ASCII for those characters
  73 with unknown encoding; `multipart': always send messages with more than
  74 one charsets.")
  75
  76 (defvar mml-generate-default-type "text/plain")
  77
  78 (defvar mml-buffer-list nil)
  79
  80 (defun mml-generate-new-buffer (name)
  81   (let ((buf (generate-new-buffer name)))
  82     (push buf mml-buffer-list)
  83     buf))
  84
  85 (defun mml-destroy-buffers ()
  86   (let (kill-buffer-hook)
  87     (mapcar 'kill-buffer mml-buffer-list)
  88     (setq mml-buffer-list nil)))
  89
  90 (defun mml-parse ()
  91   "Parse the current buffer as an MML document."
  92   (goto-char (point-min))
  93   (let ((table (syntax-table)))
  94     (unwind-protect
  95         (progn
  96           (set-syntax-table mml-syntax-table)
  97           (mml-parse-1))
  98       (set-syntax-table table))))
  99
 100 (defun mml-parse-1 ()
 101   "Parse the current buffer as an MML document."
 102   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 103     (while (and (not (eobp))
 104                 (not (looking-at "<#/multipart")))
 105       (cond
 106        ((looking-at "<#multipart")
 107         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 108        ((looking-at "<#external")
 109         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 110               struct))
 111        (t
 112         (if (or (looking-at "<#part") (looking-at "<#mml"))
 113             (setq tag (mml-read-tag)
 114                   no-markup-p nil
 115                   warn nil)
 116           (setq tag (list 'part '(type . "text/plain"))
 117                 no-markup-p t
 118                 warn t))
 119         (setq raw (cdr (assq 'raw tag))
 120               point (point)
 121               contents (mml-read-part (eq 'mml (car tag)))
 122               charsets (if raw nil
 123                          (mm-find-mime-charset-region point (point))))
 124         (when (and (not raw) (memq nil charsets))
 125           (if (or (memq 'unknown-encoding mml-confirmation-set)
 126                   (y-or-n-p
 127                    "Message contains characters with unknown encoding.  Really send?"))
 128               (if (setq use-ascii
 129                         (or (memq 'use-ascii mml-confirmation-set)
 130                             (y-or-n-p "Use ASCII as charset?")))
 131                   (setq charsets (delq nil charsets))
 132                 (setq warn nil))
 133             (error "Edit your message to remove those characters")))
 134         (if (or raw
 135                 (eq 'mml (car tag))
 136                 (< (length charsets) 2))
 137             (if (or (not no-markup-p)
 138                     (string-match "[^ \t\r\n]" contents))
 139                 ;; Don't create blank parts.
 140                 (push (nconc tag (list (cons 'contents contents)))
 141                       struct))
 142           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 143                           tag point (point) use-ascii)))
 144             (when (and warn
 145                        (not (memq 'multipart mml-confirmation-set))
 146                        (not
 147                         (y-or-n-p
 148                          (format
 149                           "Warning: Your message contains more than %d parts.  Really send? "
 150                           (length nstruct)))))
 151               (error "Edit your message to use only one charset"))
 152             (setq struct (nconc nstruct struct)))))))
 153     (unless (eobp)
 154       (forward-line 1))
 155     (nreverse struct)))
 156
 157 (defun mml-parse-singlepart-with-multiple-charsets
 158   (orig-tag beg end &optional use-ascii)
 159   (save-excursion
 160     (save-restriction
 161       (narrow-to-region beg end)
 162       (goto-char (point-min))
 163       (let ((current (or (mm-mime-charset (mm-charset-after))
 164                          (and use-ascii 'us-ascii)))
 165             charset struct space newline paragraph)
 166         (while (not (eobp))
 167           (setq charset (mm-mime-charset (mm-charset-after)))
 168           (cond
 169            ;; The charset remains the same.
 170            ((eq charset 'us-ascii))
 171            ((or (and use-ascii (not charset))
 172                 (eq charset current))
 173             (setq space nil
 174                   newline nil
 175                   paragraph nil))
 176            ;; The initial charset was ascii.
 177            ((eq current 'us-ascii)
 178             (setq current charset
 179                   space nil
 180                   newline nil
 181                   paragraph nil))
 182            ;; We have a change in charsets.
 183            (t
 184             (push (append
 185                    orig-tag
 186                    (list (cons 'contents
 187                                (buffer-substring-no-properties
 188                                 beg (or paragraph newline space (point))))))
 189                   struct)
 190             (setq beg (or paragraph newline space (point))
 191                   current charset
 192                   space nil
 193                   newline nil
 194                   paragraph nil)))
 195           ;; Compute places where it might be nice to break the part.
 196           (cond
 197            ((memq (following-char) '(?  ?\t))
 198             (setq space (1+ (point))))
 199            ((and (eq (following-char) ?\n)
 200                  (not (bobp))
 201                  (eq (char-after (1- (point))) ?\n))
 202             (setq paragraph (point)))
 203            ((eq (following-char) ?\n)
 204             (setq newline (1+ (point)))))
 205           (forward-char 1))
 206         ;; Do the final part.
 207         (unless (= beg (point))
 208           (push (append orig-tag
 209                         (list (cons 'contents
 210                                     (buffer-substring-no-properties
 211                                      beg (point)))))
 212                 struct))
 213         struct))))
 214
 215 (defun mml-read-tag ()
 216   "Read a tag and return the contents."
 217   (let (contents name elem val)
 218     (forward-char 2)
 219     (setq name (buffer-substring-no-properties
 220                 (point) (progn (forward-sexp 1) (point))))
 221     (skip-chars-forward " \t\n")
 222     (while (not (looking-at ">[ \t]*\n?"))
 223       (setq elem (buffer-substring-no-properties
 224                   (point) (progn (forward-sexp 1) (point))))
 225       (skip-chars-forward "= \t\n")
 226       (setq val (buffer-substring-no-properties
 227                  (point) (progn (forward-sexp 1) (point))))
 228       (when (string-match "^\"\\(.*\\)\"$" val)
 229         (setq val (match-string 1 val)))
 230       (push (cons (intern elem) val) contents)
 231       (skip-chars-forward " \t\n"))
 232     (goto-char (match-end 0))
 233     ;; Don't skip the leading space.
 234     ;;(skip-chars-forward " \t\n")
 235     (cons (intern name) (nreverse contents))))
 236
 237 (defun mml-read-part (&optional mml)
 238   "Return the buffer up till the next part, multipart or closing part or multipart.
 239 If MML is non-nil, return the buffer up till the correspondent mml tag."
 240   (let ((beg (point)) (count 1))
 241     ;; If the tag ended at the end of the line, we go to the next line.
 242     (when (looking-at "[ \t]*\n")
 243       (forward-line 1))
 244     (if mml
 245         (progn
 246           (while (and (> count 0) (not (eobp)))
 247             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 248                 (setq count (+ count (if (match-beginning 1) -1 1)))
 249               (goto-char (point-max))))
 250           (buffer-substring-no-properties beg (if (> count 0)
 251                                                   (point)
 252                                                 (match-beginning 0))))
 253       (if (re-search-forward
 254            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 255           (prog1
 256               (buffer-substring-no-properties beg (match-beginning 0))
 257             (if (or (not (match-beginning 1))
 258                     (equal (match-string 2) "multipart"))
 259                 (goto-char (match-beginning 0))
 260               (when (looking-at "[ \t]*\n")
 261                 (forward-line 1))))
 262         (buffer-substring-no-properties beg (goto-char (point-max)))))))
 263
 264 (defvar mml-boundary nil)
 265 (defvar mml-base-boundary "-=-=")
 266 (defvar mml-multipart-number 0)
 267
 268 (defun mml-generate-mime ()
 269   "Generate a MIME message based on the current MML document."
 270   (let ((cont (mml-parse))
 271         (mml-multipart-number mml-multipart-number))
 272     (if (not cont)
 273         nil
 274       (with-temp-buffer
 275         (if (and (consp (car cont))
 276                  (= (length cont) 1))
 277             (mml-generate-mime-1 (car cont))
 278           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 279                                       cont)))
 280         (buffer-string)))))
 281
 282 (defun mml-generate-mime-1 (cont)
 283   (let ((mm-use-ultra-safe-encoding
 284          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 285     (save-restriction
 286       (narrow-to-region (point) (point))
 287       (cond
 288        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 289         (let ((raw (cdr (assq 'raw cont)))
 290               coded encoding charset filename type)
 291           (setq type (or (cdr (assq 'type cont)) "text/plain"))
 292           (if (and (not raw)
 293                    (member (car (split-string type "/")) '("text" "message")))
 294               (with-temp-buffer
 295                 (cond
 296                  ((cdr (assq 'buffer cont))
 297                   (insert-buffer-substring (cdr (assq 'buffer cont))))
 298                  ((and (setq filename (cdr (assq 'filename cont)))
 299                        (not (equal (cdr (assq 'nofile cont)) "yes")))
 300                   (mm-insert-file-contents filename))
 301                  ((eq 'mml (car cont))
 302                   (insert (cdr (assq 'contents cont))))
 303                  (t
 304                   (save-restriction
 305                     (narrow-to-region (point) (point))
 306                     (insert (cdr (assq 'contents cont)))
 307                     ;; Remove quotes from quoted tags.
 308                     (goto-char (point-min))
 309                     (while (re-search-forward
 310                             "<#!+/?\\(part\\|multipart\\|external\\|mml\\)" nil t)
 311                       (delete-region (+ (match-beginning 0) 2)
 312                                      (+ (match-beginning 0) 3))))))
 313                 (cond
 314                  ((eq (car cont) 'mml)
 315                   (let ((mml-boundary (funcall mml-boundary-function
 316                                                (incf mml-multipart-number)))
 317                         (mml-generate-default-type "text/plain"))
 318                     (mml-to-mime))
 319                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 320                     ;; ignore 0x1b, it is part of iso-2022-jp
 321                     (setq encoding (mm-body-7-or-8))))
 322                  ((string= (car (split-string type "/")) "message")
 323                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 324                     ;; ignore 0x1b, it is part of iso-2022-jp
 325                     (setq encoding (mm-body-7-or-8))))
 326                  (t
 327                   (setq charset (mm-encode-body))
 328                   (setq encoding (mm-body-encoding
 329                                   charset (cdr (assq 'encoding cont))))))
 330                 (setq coded (buffer-string)))
 331             (mm-with-unibyte-buffer
 332               (cond
 333                ((cdr (assq 'buffer cont))
 334                 (insert-buffer-substring (cdr (assq 'buffer cont))))
 335                ((and (setq filename (cdr (assq 'filename cont)))
 336                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 337                 (let ((coding-system-for-read mm-binary-coding-system))
 338                   (mm-insert-file-contents filename nil nil nil nil t)))
 339                (t
 340                 (insert (cdr (assq 'contents cont)))))
 341               (setq encoding (mm-encode-buffer type)
 342                     coded (buffer-string))))
 343           (mml-insert-mime-headers cont type charset encoding)
 344           (insert "\n")
 345           (insert coded)))
 346        ((eq (car cont) 'external)
 347         (insert "Content-Type: message/external-body")
 348         (let ((parameters (mml-parameter-string
 349                            cont '(expiration size permission)))
 350               (name (cdr (assq 'name cont))))
 351           (when name
 352             (setq name (mml-parse-file-name name))
 353             (if (stringp name)
 354                 (mml-insert-parameter
 355                  (mail-header-encode-parameter "name" name)
 356                  "access-type=local-file")
 357               (mml-insert-parameter
 358                (mail-header-encode-parameter
 359                 "name" (file-name-nondirectory (nth 2 name)))
 360                (mail-header-encode-parameter "site" (nth 1 name))
 361                (mail-header-encode-parameter
 362                 "directory" (file-name-directory (nth 2 name))))
 363               (mml-insert-parameter
 364                (concat "access-type="
 365                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 366                            "anon-ftp"
 367                          "ftp")))))
 368           (when parameters
 369             (mml-insert-parameter-string
 370              cont '(expiration size permission))))
 371         (insert "\n\n")
 372         (insert "Content-Type: " (cdr (assq 'type cont)) "\n")
 373         (insert "Content-ID: " (message-make-message-id) "\n")
 374         (insert "Content-Transfer-Encoding: "
 375                 (or (cdr (assq 'encoding cont)) "binary"))
 376         (insert "\n\n")
 377         (insert (or (cdr (assq 'contents cont))))
 378         (insert "\n"))
 379        ((eq (car cont) 'multipart)
 380         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 381                (mml-generate-default-type (if (equal type "digest")
 382                                               "message/rfc822"
 383                                             "text/plain"))
 384                (handler (assoc type mml-generate-multipart-alist)))
 385           (if handler
 386               (funcall (cdr handler) cont)
 387             ;; No specific handler.  Use default one.
 388             (let ((mml-boundary (mml-compute-boundary cont)))
 389               (insert (format "Content-Type: multipart/%s; boundary=\"%s\"\n"
 390                               type mml-boundary))
 391               ;; Skip `multipart' and `type' elements.
 392               (setq cont (cddr cont))
 393               (while cont
 394                 (insert "\n--" mml-boundary "\n")
 395                 (mml-generate-mime-1 (pop cont)))
 396               (insert "\n--" mml-boundary "--\n")))))
 397        (t
 398         (error "Invalid element: %S" cont)))
 399       (let ((item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 400             sender recipients)
 401         (when item
 402           (if (setq sender (cdr (assq 'sender cont)))
 403               (message-options-set 'message-sender sender))
 404           (if (setq recipients (cdr (assq 'recipients cont)))
 405               (message-options-set 'message-sender recipients))
 406           (funcall (nth 1 item) cont)))
 407       (let ((item (assoc (cdr (assq 'encrypt cont)) mml-encrypt-alist))
 408             sender recipients)
 409         (when item
 410           (if (setq sender (cdr (assq 'sender cont)))
 411               (message-options-set 'message-sender sender))
 412           (if (setq recipients (cdr (assq 'recipients cont)))
 413               (message-options-set 'message-sender recipients))
 414           (funcall (nth 1 item) cont))))))
 415
 416 (defun mml-compute-boundary (cont)
 417   "Return a unique boundary that does not exist in CONT."
 418   (let ((mml-boundary (funcall mml-boundary-function
 419                                (incf mml-multipart-number))))
 420     ;; This function tries again and again until it has found
 421     ;; a unique boundary.
 422     (while (not (catch 'not-unique
 423                   (mml-compute-boundary-1 cont))))
 424     mml-boundary))
 425
 426 (defun mml-compute-boundary-1 (cont)
 427   (let (filename)
 428     (cond
 429      ((eq (car cont) 'part)
 430       (with-temp-buffer
 431         (cond
 432          ((cdr (assq 'buffer cont))
 433           (insert-buffer-substring (cdr (assq 'buffer cont))))
 434          ((and (setq filename (cdr (assq 'filename cont)))
 435                (not (equal (cdr (assq 'nofile cont)) "yes")))
 436           (mm-insert-file-contents filename))
 437          (t
 438           (insert (cdr (assq 'contents cont)))))
 439         (goto-char (point-min))
 440         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 441                                  nil t)
 442           (setq mml-boundary (funcall mml-boundary-function
 443                                       (incf mml-multipart-number)))
 444           (throw 'not-unique nil))))
 445      ((eq (car cont) 'multipart)
 446       (mapcar 'mml-compute-boundary-1 (cddr cont))))
 447     t))
 448
 449 (defun mml-make-boundary (number)
 450   (concat (make-string (% number 60) ?=)
 451           (if (> number 17)
 452               (format "%x" number)
 453             "")
 454           mml-base-boundary))
 455
 456 (defun mml-insert-mime-headers (cont type charset encoding)
 457   (let (parameters disposition description)
 458     (setq parameters
 459           (mml-parameter-string
 460            cont '(name access-type expiration size permission)))
 461     (when (or charset
 462               parameters
 463               (not (equal type mml-generate-default-type)))
 464       (when (consp charset)
 465         (error
 466          "Can't encode a part with several charsets."))
 467       (insert "Content-Type: " type)
 468       (when charset
 469         (insert "; " (mail-header-encode-parameter
 470                       "charset" (symbol-name charset))))
 471       (when parameters
 472         (mml-insert-parameter-string
 473          cont '(name access-type expiration size permission)))
 474       (insert "\n"))
 475     (setq parameters
 476           (mml-parameter-string
 477            cont '(filename creation-date modification-date read-date)))
 478     (when (or (setq disposition (cdr (assq 'disposition cont)))
 479               parameters)
 480       (insert "Content-Disposition: " (or disposition "inline"))
 481       (when parameters
 482         (mml-insert-parameter-string
 483          cont '(filename creation-date modification-date read-date)))
 484       (insert "\n"))
 485     (unless (eq encoding '7bit)
 486       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 487     (when (setq description (cdr (assq 'description cont)))
 488       (insert "Content-Description: "
 489               (mail-encode-encoded-word-string description) "\n"))))
 490
 491 (defun mml-parameter-string (cont types)
 492   (let ((string "")
 493         value type)
 494     (while (setq type (pop types))
 495       (when (setq value (cdr (assq type cont)))
 496         ;; Strip directory component from the filename parameter.
 497         (when (eq type 'filename)
 498           (setq value (file-name-nondirectory value)))
 499         (setq string (concat string "; "
 500                              (mail-header-encode-parameter
 501                               (symbol-name type) value)))))
 502     (when (not (zerop (length string)))
 503       string)))
 504
 505 (defun mml-insert-parameter-string (cont types)
 506   (let (value type)
 507     (while (setq type (pop types))
 508       (when (setq value (cdr (assq type cont)))
 509         ;; Strip directory component from the filename parameter.
 510         (when (eq type 'filename)
 511           (setq value (file-name-nondirectory value)))
 512         (mml-insert-parameter
 513          (mail-header-encode-parameter
 514           (symbol-name type) value))))))
 515
 516 (defvar ange-ftp-name-format)
 517 (defvar efs-path-regexp)
 518 (defun mml-parse-file-name (path)
 519   (if (if (boundp 'efs-path-regexp)
 520           (string-match efs-path-regexp path)
 521         (if (boundp 'ange-ftp-name-format)
 522             (string-match (car ange-ftp-name-format) path)))
 523       (list (match-string 1 path) (match-string 2 path)
 524             (substring path (1+ (match-end 2))))
 525     path))
 526
 527 (defun mml-insert-buffer (buffer)
 528   "Insert BUFFER at point and quote any MML markup."
 529   (save-restriction
 530     (narrow-to-region (point) (point))
 531     (insert-buffer-substring buffer)
 532     (mml-quote-region (point-min) (point-max))
 533     (goto-char (point-max))))
 534
 535 ;;;
 536 ;;; Transforming MIME to MML
 537 ;;;
 538
 539 (defun mime-to-mml ()
 540   "Translate the current buffer (which should be a message) into MML."
 541   ;; First decode the head.
 542   (save-restriction
 543     (message-narrow-to-head)
 544     (mail-decode-encoded-word-region (point-min) (point-max)))
 545   (let ((handles (mm-dissect-buffer t)))
 546     (goto-char (point-min))
 547     (search-forward "\n\n" nil t)
 548     (delete-region (point) (point-max))
 549     (if (stringp (car handles))
 550         (mml-insert-mime handles)
 551       (mml-insert-mime handles t))
 552     (mm-destroy-parts handles))
 553   (save-restriction
 554     (message-narrow-to-head)
 555     ;; Remove them, they are confusing.
 556     (message-remove-header "Content-Type")
 557     (message-remove-header "MIME-Version")
 558     (message-remove-header "Content-Transfer-Encoding")))
 559
 560 (defun mml-to-mime ()
 561   "Translate the current buffer from MML to MIME."
 562   (message-encode-message-body)
 563   (save-restriction
 564     (message-narrow-to-headers-or-head)
 565     (let ((mail-parse-charset message-default-charset))
 566       (mail-encode-encoded-word-buffer))))
 567
 568 (defun mml-insert-mime (handle &optional no-markup)
 569   (let (textp buffer mmlp)
 570     ;; Determine type and stuff.
 571     (unless (stringp (car handle))
 572       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 573         (save-excursion
 574           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 575           (mm-insert-part handle)
 576           (if (setq mmlp (equal (mm-handle-media-type handle)
 577                                 "message/rfc822"))
 578               (mime-to-mml)))))
 579     (if mmlp
 580         (mml-insert-mml-markup handle nil t t)
 581       (unless (and no-markup
 582                    (equal (mm-handle-media-type handle) "text/plain"))
 583         (mml-insert-mml-markup handle buffer textp)))
 584     (cond
 585      (mmlp
 586       (insert-buffer buffer)
 587       (goto-char (point-max))
 588       (insert "<#/mml>\n"))
 589      ((stringp (car handle))
 590       (mapcar 'mml-insert-mime (cdr handle))
 591       (insert "<#/multipart>\n"))
 592      (textp
 593       (let ((text (mm-get-part handle))
 594             (charset (mail-content-type-get
 595                       (mm-handle-type handle) 'charset)))
 596         (insert (mm-decode-string text charset)))
 597       (goto-char (point-max)))
 598      (t
 599       (insert "<#/part>\n")))))
 600
 601 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 602   "Take a MIME handle and insert an MML tag."
 603   (if (stringp (car handle))
 604       (insert "<#multipart type=" (mm-handle-media-subtype handle)
 605               ">\n")
 606     (if mmlp
 607         (insert "<#mml type=" (mm-handle-media-type handle))
 608       (insert "<#part type=" (mm-handle-media-type handle)))
 609     (dolist (elem (append (cdr (mm-handle-type handle))
 610                           (cdr (mm-handle-disposition handle))))
 611       (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\""))
 612     (when (mm-handle-disposition handle)
 613       (insert " disposition=" (car (mm-handle-disposition handle))))
 614     (when buffer
 615       (insert " buffer=\"" (buffer-name buffer) "\""))
 616     (when nofile
 617       (insert " nofile=yes"))
 618     (when (mm-handle-description handle)
 619       (insert " description=\"" (mm-handle-description handle) "\""))
 620     (insert ">\n")))
 621
 622 (defun mml-insert-parameter (&rest parameters)
 623   "Insert PARAMETERS in a nice way."
 624   (dolist (param parameters)
 625     (insert ";")
 626     (let ((point (point)))
 627       (insert " " param)
 628       (when (> (current-column) 71)
 629         (goto-char point)
 630         (insert "\n ")
 631         (end-of-line)))))
 632
 633 ;;;
 634 ;;; Mode for inserting and editing MML forms
 635 ;;;
 636
 637 (defvar mml-mode-map
 638   (let ((sign (make-sparse-keymap))
 639         (encrypt (make-sparse-keymap))
 640         (map (make-sparse-keymap))
 641         (main (make-sparse-keymap)))
 642     (define-key sign "p" 'mml-secure-sign-pgpmime)
 643     (define-key sign "s" 'mml-secure-sign-smime)
 644     (define-key encrypt "p" 'mml-secure-encrypt-pgpmime)
 645     (define-key encrypt "s" 'mml-secure-encrypt-smime)
 646     (define-key map "f" 'mml-attach-file)
 647     (define-key map "b" 'mml-attach-buffer)
 648     (define-key map "e" 'mml-attach-external)
 649     (define-key map "q" 'mml-quote-region)
 650     (define-key map "m" 'mml-insert-multipart)
 651     (define-key map "p" 'mml-insert-part)
 652     (define-key map "v" 'mml-validate)
 653     (define-key map "P" 'mml-preview)
 654     (define-key map "s" sign)
 655     (define-key map "c" encrypt)
 656     ;;(define-key map "n" 'mml-narrow-to-part)
 657     (define-key main "\M-m" map)
 658     main))
 659
 660 (easy-menu-define
 661  mml-menu mml-mode-map ""
 662  '("MML"
 663    ("Attach"
 664     ["File" mml-attach-file t]
 665     ["Buffer" mml-attach-buffer t]
 666     ["External" mml-attach-external t])
 667    ("Insert"
 668     ["Multipart" mml-insert-multipart t]
 669     ["Part" mml-insert-part t])
 670    ("Security"
 671     ("Sign"
 672      ["PGP/MIME" mml-secure-sign-pgpmime t]
 673      ["S/MIME" mml-secure-sign-smime t])
 674     ("Encrypt"
 675      ["PGP/MIME" mml-secure-encrypt-pgpmime t]
 676      ["S/MIME" mml-secure-encrypt-smime t]))
 677    ;;["Narrow" mml-narrow-to-part t]
 678    ["Quote" mml-quote-region t]
 679    ["Validate" mml-validate t]
 680    ["Preview" mml-preview t]))
 681
 682 (defvar mml-mode nil
 683   "Minor mode for editing MML.")
 684
 685 (defun mml-mode (&optional arg)
 686   "Minor mode for editing MML.
 687
 688 \\{mml-mode-map}"
 689   (interactive "P")
 690   (when (set (make-local-variable 'mml-mode)
 691              (if (null arg) (not mml-mode)
 692                (> (prefix-numeric-value arg) 0)))
 693     (gnus-add-minor-mode 'mml-mode " MML" mml-mode-map)
 694     (easy-menu-add mml-menu mml-mode-map)
 695     (run-hooks 'mml-mode-hook)))
 696
 697 ;;;
 698 ;;; Helper functions for reading MIME stuff from the minibuffer and
 699 ;;; inserting stuff to the buffer.
 700 ;;;
 701
 702 (defun mml-minibuffer-read-file (prompt)
 703   (let ((file (read-file-name prompt nil nil t)))
 704     ;; Prevent some common errors.  This is inspired by similar code in
 705     ;; VM.
 706     (when (file-directory-p file)
 707       (error "%s is a directory, cannot attach" file))
 708     (unless (file-exists-p file)
 709       (error "No such file: %s" file))
 710     (unless (file-readable-p file)
 711       (error "Permission denied: %s" file))
 712     file))
 713
 714 (defun mml-minibuffer-read-type (name &optional default)
 715   (mailcap-parse-mimetypes)
 716   (let* ((default (or default
 717                       (mm-default-file-encoding name)
 718                       ;; Perhaps here we should check what the file
 719                       ;; looks like, and offer text/plain if it looks
 720                       ;; like text/plain.
 721                       "application/octet-stream"))
 722          (string (completing-read
 723                   (format "Content type (default %s): " default)
 724                   (mapcar 'list (mailcap-mime-types)))))
 725     (if (not (equal string ""))
 726         string
 727       default)))
 728
 729 (defun mml-minibuffer-read-description ()
 730   (let ((description (read-string "One line description: ")))
 731     (when (string-match "\\`[ \t]*\\'" description)
 732       (setq description nil))
 733     description))
 734
 735 (defun mml-quote-region (beg end)
 736   "Quote the MML tags in the region."
 737   (interactive "r")
 738   (save-excursion
 739     (save-restriction
 740       ;; Temporarily narrow the region to defend from changes
 741       ;; invalidating END.
 742       (narrow-to-region beg end)
 743       (goto-char (point-min))
 744       ;; Quote parts.
 745       (while (re-search-forward
 746               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
 747         ;; Insert ! after the #.
 748         (goto-char (+ (match-beginning 0) 2))
 749         (insert "!")))))
 750
 751 (defun mml-insert-tag (name &rest plist)
 752   "Insert an MML tag described by NAME and PLIST."
 753   (when (symbolp name)
 754     (setq name (symbol-name name)))
 755   (insert "<#" name)
 756   (while plist
 757     (let ((key (pop plist))
 758           (value (pop plist)))
 759       (when value
 760         ;; Quote VALUE if it contains suspicious characters.
 761         (when (string-match "[\"'\\~/*;() \t\n]" value)
 762           (setq value (prin1-to-string value)))
 763         (insert (format " %s=%s" key value)))))
 764   (insert ">\n"))
 765
 766 (defun mml-insert-empty-tag (name &rest plist)
 767   "Insert an empty MML tag described by NAME and PLIST."
 768   (when (symbolp name)
 769     (setq name (symbol-name name)))
 770   (apply #'mml-insert-tag name plist)
 771   (insert "<#/" name ">\n"))
 772
 773 ;;; Attachment functions.
 774
 775 (defun mml-attach-file (file &optional type description)
 776   "Attach a file to the outgoing MIME message.
 777 The file is not inserted or encoded until you send the message with
 778 `\\[message-send-and-exit]' or `\\[message-send]'.
 779
 780 FILE is the name of the file to attach.  TYPE is its content-type, a
 781 string of the form \"type/subtype\".  DESCRIPTION is a one-line
 782 description of the attachment."
 783   (interactive
 784    (let* ((file (mml-minibuffer-read-file "Attach file: "))
 785           (type (mml-minibuffer-read-type file))
 786           (description (mml-minibuffer-read-description)))
 787      (list file type description)))
 788   (mml-insert-empty-tag 'part 'type type 'filename file
 789                         'disposition "attachment" 'description description))
 790
 791 (defun mml-attach-buffer (buffer &optional type description)
 792   "Attach a buffer to the outgoing MIME message.
 793 See `mml-attach-file' for details of operation."
 794   (interactive
 795    (let* ((buffer (read-buffer "Attach buffer: "))
 796           (type (mml-minibuffer-read-type buffer "text/plain"))
 797           (description (mml-minibuffer-read-description)))
 798      (list buffer type description)))
 799   (mml-insert-empty-tag 'part 'type type 'buffer buffer
 800                         'disposition "attachment" 'description description))
 801
 802 (defun mml-attach-external (file &optional type description)
 803   "Attach an external file into the buffer.
 804 FILE is an ange-ftp/efs specification of the part location.
 805 TYPE is the MIME type to use."
 806   (interactive
 807    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
 808           (type (mml-minibuffer-read-type file))
 809           (description (mml-minibuffer-read-description)))
 810      (list file type description)))
 811   (mml-insert-empty-tag 'external 'type type 'name file
 812                         'disposition "attachment" 'description description))
 813
 814 (defun mml-insert-multipart (&optional type)
 815   (interactive (list (completing-read "Multipart type (default mixed): "
 816                                       '(("mixed") ("alternative") ("digest") ("parallel")
 817                                         ("signed") ("encrypted"))
 818                                       nil nil "mixed")))
 819   (or type
 820       (setq type "mixed"))
 821   (mml-insert-empty-tag "multipart" 'type type)
 822   (forward-line -1))
 823
 824 (defun mml-insert-part (&optional type)
 825   (interactive
 826    (list (mml-minibuffer-read-type "")))
 827   (mml-insert-tag 'part 'type type 'disposition "inline")
 828   (forward-line -1))
 829
 830 (defun mml-preview (&optional raw)
 831   "Display current buffer with Gnus, in a new buffer.
 832 If RAW, don't highlight the article."
 833   (interactive "P")
 834   (let ((buf (current-buffer))
 835         (message-options message-options)
 836         (message-posting-charset (or (gnus-setup-posting-charset
 837                                       (save-restriction
 838                                         (message-narrow-to-headers-or-head)
 839                                         (message-fetch-field "Newsgroups")))
 840                                      message-posting-charset)))
 841     (message-options-set-recipient)
 842     (switch-to-buffer (generate-new-buffer
 843                        (concat (if raw "*Raw MIME preview of "
 844                                  "*MIME preview of ") (buffer-name))))
 845     (erase-buffer)
 846     (insert-buffer buf)
 847     (if (re-search-forward
 848          (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
 849         (replace-match "\n"))
 850     (mml-to-mime)
 851     (if raw
 852         (when (fboundp 'set-buffer-multibyte)
 853           (let ((s (buffer-string)))
 854             ;; Insert the content into unibyte buffer.
 855             (erase-buffer)
 856             (mm-disable-multibyte)
 857             (insert s)))
 858       (let ((gnus-newsgroup-charset (car message-posting-charset)))
 859         (run-hooks 'gnus-article-decode-hook)
 860         (let ((gnus-newsgroup-name "dummy"))
 861           (gnus-article-prepare-display))))
 862     (fundamental-mode)
 863     (setq buffer-read-only t)
 864     (goto-char (point-min))))
 865
 866 (defun mml-validate ()
 867   "Validate the current MML document."
 868   (interactive)
 869   (mml-parse))
 870
 871 (provide 'mml)
 872
 873 ;;; mml.el ends here