git.chise.org Git - elisp/gnus.git-/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'nnheader)
  33 (require 'nnmail)
  34 (require 'gnus-start)
  35 (require 'nnmh)
  36 (require 'nnoo)
  37
  38 (nnoo-declare nndraft
  39   nnmh)
  40
  41 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  42   "Where nndraft will store its files."
  43   nnmh-directory)
  44
  45 \f
  46
  47 (defvoo nndraft-current-group "" nil nnmh-current-group)
  48 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  49 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  50
  51 (defconst nndraft-version "nndraft 1.0")
  52 (defvoo nndraft-status-string "" nil nnmh-status-string)
  53
  54 \f
  55
  56 ;;; Interface functions.
  57
  58 (nnoo-define-basics nndraft)
  59
  60 (deffoo nndraft-open-server (server &optional defs)
  61   (nnoo-change-server 'nndraft server defs)
  62   (cond
  63    ((not (file-exists-p nndraft-directory))
  64     (nndraft-close-server)
  65     (nnheader-report 'nndraft "No such file or directory: %s"
  66                      nndraft-directory))
  67    ((not (file-directory-p (file-truename nndraft-directory)))
  68     (nndraft-close-server)
  69     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  70    (t
  71     (nnheader-report 'nndraft "Opened server %s using directory %s"
  72                      server nndraft-directory)
  73     t)))
  74
  75 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  76   (nndraft-possibly-change-group group)
  77   (save-excursion
  78     (set-buffer nntp-server-buffer)
  79     (erase-buffer)
  80     (let* (article)
  81       ;; We don't support fetching by Message-ID.
  82       (if (stringp (car articles))
  83           'headers
  84         (while articles
  85           (narrow-to-region (point) (point))
  86           (when (nndraft-request-article
  87                  (setq article (pop articles)) group server (current-buffer))
  88             (goto-char (point-min))
  89             (if (search-forward "\n\n" nil t)
  90                 (forward-line -1)
  91               (goto-char (point-max)))
  92             (delete-region (point) (point-max))
  93             (goto-char (point-min))
  94             (insert (format "221 %d Article retrieved.\n" article))
  95             (widen)
  96             (goto-char (point-max))
  97             (insert ".\n")))
  98
  99         (nnheader-fold-continuation-lines)
 100         'headers))))
 101
 102 (deffoo nndraft-request-article (id &optional group server buffer)
 103   (nndraft-possibly-change-group group)
 104   (when (numberp id)
 105     ;; We get the newest file of the auto-saved file and the
 106     ;; "real" file.
 107     (let* ((file (nndraft-article-filename id))
 108            (auto (nndraft-auto-save-file-name file))
 109            (newest (if (file-newer-than-file-p file auto) file auto))
 110            (nntp-server-buffer (or buffer nntp-server-buffer)))
 111       (when (and (file-exists-p newest)
 112                  (let ((nnmail-file-coding-system
 113                         (if (file-newer-than-file-p file auto)
 114                             (if (member group '("drafts" "delayed"))
 115                                 message-draft-coding-system
 116                               nnheader-text-coding-system)
 117                           nnheader-auto-save-coding-system)))
 118                    (nnmail-find-file newest)))
 119         (save-excursion
 120           (set-buffer nntp-server-buffer)
 121           (goto-char (point-min))
 122           ;; If there's a mail header separator in this file,
 123           ;; we remove it.
 124           (when (re-search-forward
 125                  (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 126             (replace-match "" t t)))
 127         t))))
 128
 129 (deffoo nndraft-request-restore-buffer (article &optional group server)
 130   "Request a new buffer that is restored to the state of ARTICLE."
 131   (nndraft-possibly-change-group group)
 132   (when (nndraft-request-article article group server (current-buffer))
 133     (message-remove-header "xref")
 134     (message-remove-header "lines")
 135     ;; Articles in nndraft:queue are considered as sent messages.  The
 136     ;; Date field should be the time when they are sent.
 137     ;;(message-remove-header "date")
 138     t))
 139
 140 (deffoo nndraft-request-update-info (group info &optional server)
 141   (nndraft-possibly-change-group group)
 142   (gnus-info-set-read
 143    info
 144    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 145                               (nndraft-articles) t))
 146   (let ((marks (nth 3 info)))
 147     (when marks
 148       ;; Nix out all marks except the `unsend'-able article marks.
 149       (setcar (nthcdr 3 info)
 150               (if (assq 'unsend marks)
 151                   (list (assq 'unsend marks))
 152                 nil))))
 153   t)
 154
 155 (defun nndraft-generate-headers ()
 156   (message-generate-headers
 157    (message-headers-to-generate
 158     message-required-headers message-draft-headers nil)))
 159
 160 (deffoo nndraft-request-associate-buffer (group)
 161   "Associate the current buffer with some article in the draft group."
 162   (nndraft-open-server "")
 163   (nndraft-request-group group)
 164   (nndraft-possibly-change-group group)
 165   (let ((gnus-verbose-backends nil)
 166         (buf (current-buffer))
 167         article file)
 168     (with-temp-buffer
 169       (insert-buffer-substring buf)
 170       (setq article (nndraft-request-accept-article
 171                      group (nnoo-current-server 'nndraft) t 'noinsert)
 172             file (nndraft-article-filename article)))
 173     (setq buffer-file-name (expand-file-name file)
 174           buffer-auto-save-file-name (make-auto-save-file-name))
 175     (clear-visited-file-modtime)
 176     (push 'nndraft-generate-headers write-contents-hooks)
 177     article))
 178
 179 (deffoo nndraft-request-group (group &optional server dont-check)
 180   (nndraft-possibly-change-group group)
 181   (unless dont-check
 182     (let* ((pathname (nnmail-group-pathname group nndraft-directory))
 183            (file-name-coding-system nnmail-pathname-coding-system)
 184            dir file)
 185       (nnheader-re-read-dir pathname)
 186       (setq dir (mapcar (lambda (name) (string-to-int (substring name 1)))
 187                         (directory-files pathname nil "^#[0-9]+#$" t)))
 188       (dolist (n dir)
 189         (unless (file-exists-p
 190                  (setq file (expand-file-name (int-to-string n) pathname)))
 191           (rename-file (nndraft-auto-save-file-name file) file)))))
 192   (nnoo-parent-function 'nndraft
 193                         'nnmh-request-group
 194                         (list group server dont-check)))
 195
 196 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 197   (nndraft-possibly-change-group group)
 198   (let* ((nnmh-allow-delete-final t)
 199          (res (nnoo-parent-function 'nndraft
 200                                     'nnmh-request-expire-articles
 201                                     (list articles group server force)))
 202          article)
 203     ;; Delete all the "state" files of articles that have been expired.
 204     (while articles
 205       (unless (memq (setq article (pop articles)) res)
 206         (let ((auto (nndraft-auto-save-file-name
 207                      (nndraft-article-filename article))))
 208           (when (file-exists-p auto)
 209             (funcall nnmail-delete-file-function auto)))
 210         (dolist (backup
 211                  (let ((kept-new-versions 1)
 212                        (kept-old-versions 0))
 213                    (find-backup-file-name
 214                     (nndraft-article-filename article))))
 215           (when (file-exists-p backup)
 216             (funcall nnmail-delete-file-function backup)))))
 217     res))
 218
 219 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 220   (nndraft-possibly-change-group group)
 221   (let ((gnus-verbose-backends nil))
 222     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 223                           (list group server last noinsert))))
 224
 225 (deffoo nndraft-request-replace-article (article group buffer)
 226   (nndraft-possibly-change-group group)
 227   (let ((nnmail-file-coding-system
 228          (if (member group '("drafts" "delayed"))
 229              message-draft-coding-system
 230            nnheader-text-coding-system)))
 231     (nnoo-parent-function 'nndraft 'nnmh-request-replace-article
 232                           (list article group buffer))))
 233
 234 (deffoo nndraft-request-create-group (group &optional server args)
 235   (nndraft-possibly-change-group group)
 236   (if (file-exists-p nndraft-current-directory)
 237       (if (file-directory-p nndraft-current-directory)
 238           t
 239         nil)
 240     (condition-case ()
 241         (progn
 242           (gnus-make-directory nndraft-current-directory)
 243           t)
 244       (file-error nil))))
 245
 246 \f
 247 ;;; Low-Level Interface
 248
 249 (defun nndraft-possibly-change-group (group)
 250   (when (and group
 251              (not (equal group nndraft-current-group)))
 252     (nndraft-open-server "")
 253     (setq nndraft-current-group group)
 254     (setq nndraft-current-directory
 255           (nnheader-concat nndraft-directory group))))
 256
 257 (defun nndraft-article-filename (article &rest args)
 258   (apply 'concat
 259          (file-name-as-directory nndraft-current-directory)
 260          (int-to-string article)
 261          args))
 262
 263 (defun nndraft-auto-save-file-name (file)
 264   (save-excursion
 265     (prog1
 266         (progn
 267           (set-buffer (get-buffer-create " *draft tmp*"))
 268           (setq buffer-file-name file)
 269           (make-auto-save-file-name))
 270       (kill-buffer (current-buffer)))))
 271
 272 (defun nndraft-articles ()
 273   "Return the list of messages in the group."
 274   (gnus-make-directory nndraft-current-directory)
 275   (sort
 276    (mapcar 'string-to-int
 277            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 278    '<))
 279
 280 (nnoo-import nndraft
 281   (nnmh
 282    nnmh-retrieve-headers
 283    nnmh-request-group
 284    nnmh-close-group
 285    nnmh-request-list
 286    nnmh-request-newsgroups
 287    nnmh-request-move-article))
 288
 289 (provide 'nndraft)
 290
 291 ;;; nndraft.el ends here