git.chise.org Git - elisp/gnus.git-/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'nnheader)
  29 (require 'nnmail)
  30 (require 'gnus-start)
  31 (require 'nnmh)
  32 (require 'nnoo)
  33 (eval-when-compile
  34   (require 'cl)
  35   ;; This is just to shut up the byte-compiler.
  36   (fset 'nndraft-request-group 'ignore))
  37
  38 (nnoo-declare nndraft
  39   nnmh)
  40
  41 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  42   "Where nndraft will store its files."
  43   nnmh-directory)
  44
  45 \f
  46
  47 (defvoo nndraft-current-group "" nil nnmh-current-group)
  48 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  49 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  50
  51 (defconst nndraft-version "nndraft 1.0")
  52 (defvoo nndraft-status-string "" nil nnmh-status-string)
  53
  54 \f
  55
  56 ;;; Interface functions.
  57
  58 (nnoo-define-basics nndraft)
  59
  60 (deffoo nndraft-open-server (server &optional defs)
  61   (nnoo-change-server 'nndraft server defs)
  62   (cond
  63    ((not (file-exists-p nndraft-directory))
  64     (nndraft-close-server)
  65     (nnheader-report 'nndraft "No such file or directory: %s"
  66                      nndraft-directory))
  67    ((not (file-directory-p (file-truename nndraft-directory)))
  68     (nndraft-close-server)
  69     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  70    (t
  71     (nnheader-report 'nndraft "Opened server %s using directory %s"
  72                      server nndraft-directory)
  73     t)))
  74
  75 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  76   (nndraft-possibly-change-group group)
  77   (save-excursion
  78     (set-buffer nntp-server-buffer)
  79     (erase-buffer)
  80     (let* (article)
  81       ;; We don't support fetching by Message-ID.
  82       (if (stringp (car articles))
  83           'headers
  84         (while articles
  85           (narrow-to-region (point) (point))
  86           (when (nndraft-request-article
  87                  (setq article (pop articles)) group server (current-buffer))
  88             (goto-char (point-min))
  89             (if (search-forward "\n\n" nil t)
  90                 (forward-line -1)
  91               (goto-char (point-max)))
  92             (delete-region (point) (point-max))
  93             (goto-char (point-min))
  94             (insert (format "221 %d Article retrieved.\n" article))
  95             (widen)
  96             (goto-char (point-max))
  97             (insert ".\n")))
  98
  99         (nnheader-fold-continuation-lines)
 100         'headers))))
 101
 102 (deffoo nndraft-request-article (id &optional group server buffer)
 103   (nndraft-possibly-change-group group)
 104   (when (numberp id)
 105     ;; We get the newest file of the auto-saved file and the
 106     ;; "real" file.
 107     (let* ((file (nndraft-article-filename id))
 108            (auto (nndraft-auto-save-file-name file))
 109            (newest (if (file-newer-than-file-p file auto) file auto))
 110            (nntp-server-buffer (or buffer nntp-server-buffer)))
 111       (when (and (file-exists-p newest)
 112                  (nnmail-find-file newest))
 113         (save-excursion
 114           (set-buffer nntp-server-buffer)
 115           (goto-char (point-min))
 116           ;; If there's a mail header separator in this file,
 117           ;; we remove it.
 118           (when (re-search-forward
 119                  (concat "^" mail-header-separator "$") nil t)
 120             (replace-match "" t t)))
 121         t))))
 122
 123 (deffoo nndraft-request-restore-buffer (article &optional group server)
 124   "Request a new buffer that is restored to the state of ARTICLE."
 125   (nndraft-possibly-change-group group)
 126   (when (nndraft-request-article article group server (current-buffer))
 127     (message-remove-header "xref")
 128     (message-remove-header "lines")
 129     t))
 130
 131 (deffoo nndraft-request-update-info (group info &optional server)
 132   (nndraft-possibly-change-group group)
 133   (gnus-info-set-read
 134    info
 135    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 136                               (nndraft-articles) t))
 137   (let (marks)
 138     (when (setq marks (nth 3 info))
 139       (setcar (nthcdr 3 info)
 140               (if (assq 'unsend marks)
 141                   (list (assq 'unsend marks))
 142                 nil))))
 143   t)
 144
 145 (deffoo nndraft-request-associate-buffer (group)
 146   "Associate the current buffer with some article in the draft group."
 147   (nndraft-open-server "")
 148   (nndraft-request-group group)
 149   (nndraft-possibly-change-group group)
 150   (let ((gnus-verbose-backends nil)
 151         (buf (current-buffer))
 152          article file)
 153     (with-temp-buffer
 154       (insert-buffer buf)
 155       (setq article (nndraft-request-accept-article
 156                      group (nnoo-current-server 'nndraft) t 'noinsert)
 157             file (nndraft-article-filename article)))
 158     (setq buffer-file-name (expand-file-name file)
 159           buffer-auto-save-file-name (make-auto-save-file-name))
 160     (clear-visited-file-modtime)
 161     article))
 162
 163 (defun nndraft-save-mime-part (file part)
 164   "Save MIME PART belonging to the FILE."
 165   (write-region (point-min) (point-max)
 166                 (format "%s.%d" file part)))
 167
 168 (defun nndraft-get-mime-part (file part)
 169   "Save MIME PART belonging to the FILE."
 170   (insert-file-contents (format "%s.%d" file part)))
 171
 172 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 173   (nndraft-possibly-change-group group)
 174   (let* ((nnmh-allow-delete-final t)
 175          (res (nnoo-parent-function 'nndraft
 176                                     'nnmh-request-expire-articles
 177                                     (list articles group server force)))
 178          article)
 179     ;; Delete all the "state" files of articles that have been expired.
 180     (while articles
 181       (unless (memq (setq article (pop articles)) res)
 182         (let ((auto (nndraft-auto-save-file-name
 183                      (nndraft-article-filename article))))
 184           (when (file-exists-p auto)
 185             (funcall nnmail-delete-file-function auto)))))
 186     res))
 187
 188 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 189   (nndraft-possibly-change-group group)
 190   (let ((gnus-verbose-backends nil))
 191     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 192                           (list group server last noinsert))))
 193
 194 (deffoo nndraft-request-create-group (group &optional server args)
 195   (nndraft-possibly-change-group group)
 196   (if (file-exists-p nndraft-current-directory)
 197       (if (file-directory-p nndraft-current-directory)
 198           t
 199         nil)
 200     (condition-case ()
 201         (progn
 202           (gnus-make-directory nndraft-current-directory)
 203           t)
 204       (file-error nil))))
 205
 206 \f
 207 ;;; Low-Level Interface
 208
 209 (defun nndraft-possibly-change-group (group)
 210   (when (and group
 211              (not (equal group nndraft-current-group)))
 212     (nndraft-open-server "")
 213     (setq nndraft-current-group group)
 214     (setq nndraft-current-directory
 215           (nnheader-concat nndraft-directory group))))
 216
 217 (defun nndraft-article-filename (article &rest args)
 218   (apply 'concat
 219          (file-name-as-directory nndraft-current-directory)
 220          (int-to-string article)
 221          args))
 222
 223 (defun nndraft-auto-save-file-name (file)
 224   (save-excursion
 225     (prog1
 226         (progn
 227           (set-buffer (get-buffer-create " *draft tmp*"))
 228           (setq buffer-file-name file)
 229           (make-auto-save-file-name))
 230       (kill-buffer (current-buffer)))))
 231
 232 (defun nndraft-articles ()
 233   "Return the list of messages in the group."
 234   (gnus-make-directory nndraft-current-directory)
 235   (sort
 236    (mapcar 'string-to-int
 237            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 238    '<))
 239
 240 (nnoo-import nndraft
 241   (nnmh
 242    nnmh-retrieve-headers
 243    nnmh-request-group
 244    nnmh-close-group
 245    nnmh-request-list
 246    nnmh-request-newsgroups
 247    nnmh-request-move-article
 248    nnmh-request-replace-article))
 249
 250 (provide 'nndraft)
 251
 252 ;;; nndraft.el ends here